lisp/battery.el

   1 ;;; battery.el --- display battery status information  -*- coding: utf-8 -*-
   2
   3 ;; Copyright (C) 1997-1998, 2000-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Ralph Schleicher <rs@nunatak.allgaeu.org>
   6 ;; Keywords: hardware
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; There is at present support for GNU/Linux, OS X and Windows.  This
  26 ;; library supports both the `/proc/apm' file format of Linux version
  27 ;; 1.3.58 or newer and the `/proc/acpi/' directory structure of Linux
  28 ;; 2.4.20 and 2.6.  Darwin (OS X) is supported by using the `pmset'
  29 ;; program.  Windows is supported by the GetSystemPowerStatus API call.
  30
  31 ;;; Code:
  32
  33 (require 'timer)
  34 (eval-when-compile (require 'cl-lib))
  35 \f
  36 (defgroup battery nil
  37   "Display battery status information."
  38   :prefix "battery-"
  39   :group 'hardware)
  40
  41 ;; Either BATn or yeeloong-bat, basically.
  42 (defconst battery--linux-sysfs-regexp "[bB][aA][tT][0-9]?$")
  43
  44 (defcustom battery-status-function
  45   (cond ((and (eq system-type 'gnu/linux)
  46               (file-readable-p "/proc/apm"))
  47          'battery-linux-proc-apm)
  48         ((and (eq system-type 'gnu/linux)
  49               (file-directory-p "/proc/acpi/battery"))
  50          'battery-linux-proc-acpi)
  51         ((and (eq system-type 'gnu/linux)
  52               (file-directory-p "/sys/class/power_supply/")
  53               (directory-files "/sys/class/power_supply/" nil
  54                                battery--linux-sysfs-regexp))
  55          'battery-linux-sysfs)
  56         ((and (eq system-type 'berkeley-unix)
  57               (file-executable-p "/usr/sbin/apm"))
  58          'battery-bsd-apm)
  59         ((and (eq system-type 'darwin)
  60               (condition-case nil
  61                   (with-temp-buffer
  62                     (and (eq (call-process "pmset" nil t nil "-g" "ps") 0)
  63                          (> (buffer-size) 0)))
  64                 (error nil)))
  65          'battery-pmset)
  66         ((fboundp 'w32-battery-status)
  67          'w32-battery-status))
  68   "Function for getting battery status information.
  69 The function has to return an alist of conversion definitions.
  70 Its cons cells are of the form
  71
  72     (CONVERSION . REPLACEMENT-TEXT)
  73
  74 CONVERSION is the character code of a \"conversion specification\"
  75 introduced by a `%' character in a control string."
  76   :type '(choice (const nil) function)
  77   :group 'battery)
  78
  79 (defcustom battery-echo-area-format
  80   (cond ((eq battery-status-function 'battery-linux-proc-acpi)
  81          "Power %L, battery %B at %r (%p%% load, remaining time %t)")
  82         ((eq battery-status-function 'battery-linux-sysfs)
  83          "Power %L, battery %B (%p%% load, remaining time %t)")
  84         ((eq battery-status-function 'battery-pmset)
  85          "%L power, battery %B (%p%% load, remaining time %t)")
  86         (battery-status-function
  87          "Power %L, battery %B (%p%% load, remaining time %t)"))
  88   "Control string formatting the string to display in the echo area.
  89 Ordinary characters in the control string are printed as-is, while
  90 conversion specifications introduced by a `%' character in the control
  91 string are substituted as defined by the current value of the variable
  92 `battery-status-function'.  Here are the ones generally available:
  93 %c Current capacity (mAh or mWh)
  94 %r Current rate of charge or discharge
  95 %B Battery status (verbose)
  96 %b Battery status: empty means high, `-' means low,
  97    `!' means critical, and `+' means charging
  98 %d Temperature (in degrees Celsius)
  99 %L AC line status (verbose)
 100 %p Battery load percentage
 101 %m Remaining time (to charge or discharge) in minutes
 102 %h Remaining time (to charge or discharge) in hours
 103 %t Remaining time (to charge or discharge) in the form `h:min'"
 104   :type '(choice string (const nil))
 105   :group 'battery)
 106
 107 (defvar battery-mode-line-string nil
 108   "String to display in the mode line.")
 109 ;;;###autoload (put 'battery-mode-line-string 'risky-local-variable t)
 110
 111 (defcustom battery-mode-line-limit 100
 112   "Percentage of full battery load below which display battery status"
 113   :version "24.1"
 114   :type 'integer
 115   :group 'battery)
 116
 117 (defcustom battery-mode-line-format
 118   (cond ((eq battery-status-function 'battery-linux-proc-acpi)
 119          "[%b%p%%,%d°C]")
 120         (battery-status-function
 121          "[%b%p%%]"))
 122   "Control string formatting the string to display in the mode line.
 123 Ordinary characters in the control string are printed as-is, while
 124 conversion specifications introduced by a `%' character in the control
 125 string are substituted as defined by the current value of the variable
 126 `battery-status-function'.  Here are the ones generally available:
 127 %c Current capacity (mAh or mWh)
 128 %r Current rate of charge or discharge
 129 %B Battery status (verbose)
 130 %b Battery status: empty means high, `-' means low,
 131    `!' means critical, and `+' means charging
 132 %d Temperature (in degrees Celsius)
 133 %L AC line status (verbose)
 134 %p Battery load percentage
 135 %m Remaining time (to charge or discharge) in minutes
 136 %h Remaining time (to charge or discharge) in hours
 137 %t Remaining time (to charge or discharge) in the form `h:min'"
 138   :type '(choice string (const nil))
 139   :group 'battery)
 140
 141 (defcustom battery-update-interval 60
 142   "Seconds after which the battery status will be updated."
 143   :type 'integer
 144   :group 'battery)
 145
 146 (defcustom battery-load-low 25
 147   "Upper bound of low battery load percentage.
 148 A battery load percentage below this number is considered low."
 149   :type 'integer
 150   :group 'battery)
 151
 152 (defcustom battery-load-critical 10
 153   "Upper bound of critical battery load percentage.
 154 A battery load percentage below this number is considered critical."
 155   :type 'integer
 156   :group 'battery)
 157
 158 (defvar battery-update-timer nil
 159   "Interval timer object.")
 160
 161 ;;;###autoload
 162 (defun battery ()
 163   "Display battery status information in the echo area.
 164 The text being displayed in the echo area is controlled by the variables
 165 `battery-echo-area-format' and `battery-status-function'."
 166   (interactive)
 167   (message "%s" (if (and battery-echo-area-format battery-status-function)
 168                     (battery-format battery-echo-area-format
 169                                     (funcall battery-status-function))
 170                   "Battery status not available")))
 171
 172 ;;;###autoload
 173 (define-minor-mode display-battery-mode
 174   "Toggle battery status display in mode line (Display Battery mode).
 175 With a prefix argument ARG, enable Display Battery mode if ARG is
 176 positive, and disable it otherwise.  If called from Lisp, enable
 177 the mode if ARG is omitted or nil.
 178
 179 The text displayed in the mode line is controlled by
 180 `battery-mode-line-format' and `battery-status-function'.
 181 The mode line is be updated every `battery-update-interval'
 182 seconds."
 183   :global t :group 'battery
 184   (setq battery-mode-line-string "")
 185   (or global-mode-string (setq global-mode-string '("")))
 186   (and battery-update-timer (cancel-timer battery-update-timer))
 187   (if (and battery-status-function battery-mode-line-format)
 188       (if (not display-battery-mode)
 189           (setq global-mode-string
 190                 (delq 'battery-mode-line-string global-mode-string))
 191         (add-to-list 'global-mode-string 'battery-mode-line-string t)
 192         (setq battery-update-timer (run-at-time nil battery-update-interval
 193                                                 'battery-update-handler))
 194         (battery-update))
 195     (message "Battery status not available")
 196     (setq display-battery-mode nil)))
 197
 198 (defun battery-update-handler ()
 199   (battery-update)
 200   (sit-for 0))
 201
 202 (defun battery-update ()
 203   "Update battery status information in the mode line."
 204   (let* ((data (and battery-status-function (funcall battery-status-function)))
 205          (percentage (car (read-from-string (cdr (assq ?p data))))))
 206     (setq battery-mode-line-string
 207           (propertize (if (and battery-mode-line-format
 208                                (numberp percentage)
 209                                (<= percentage battery-mode-line-limit))
 210                           (battery-format battery-mode-line-format data)
 211                         "")
 212                       'face
 213                       (and (numberp percentage)
 214                            (<= percentage battery-load-critical)
 215                            'error)
 216                       'help-echo "Battery status information")))
 217   (force-mode-line-update))
 218 \f
 219 ;;; `/proc/apm' interface for Linux.
 220
 221 (defconst battery-linux-proc-apm-regexp
 222   (concat "^\\([^ ]+\\)"                ; Driver version.
 223           " \\([^ ]+\\)"                ; APM BIOS version.
 224           " 0x\\([0-9a-f]+\\)"          ; APM BIOS flags.
 225           " 0x\\([0-9a-f]+\\)"          ; AC line status.
 226           " 0x\\([0-9a-f]+\\)"          ; Battery status.
 227           " 0x\\([0-9a-f]+\\)"          ; Battery flags.
 228           " \\(-?[0-9]+\\)%"            ; Load percentage.
 229           " \\(-?[0-9]+\\)"             ; Remaining time.
 230           " \\(.*\\)"                   ; Time unit.
 231           "$")
 232   "Regular expression matching contents of `/proc/apm'.")
 233
 234 (defun battery-linux-proc-apm ()
 235   "Get APM status information from Linux (the kernel).
 236 This function works only with the new `/proc/apm' format introduced
 237 in Linux version 1.3.58.
 238
 239 The following %-sequences are provided:
 240 %v Linux driver version
 241 %V APM BIOS version
 242 %I APM BIOS status (verbose)
 243 %L AC line status (verbose)
 244 %B Battery status (verbose)
 245 %b Battery status, empty means high, `-' means low,
 246    `!' means critical, and `+' means charging
 247 %p Battery load percentage
 248 %s Remaining time (to charge or discharge) in seconds
 249 %m Remaining time (to charge or discharge) in minutes
 250 %h Remaining time (to charge or discharge) in hours
 251 %t Remaining time (to charge or discharge) in the form `h:min'"
 252   (let (driver-version bios-version bios-interface line-status
 253         battery-status battery-status-symbol load-percentage
 254         seconds minutes hours remaining-time tem)
 255     (with-temp-buffer
 256       (ignore-errors (insert-file-contents "/proc/apm"))
 257       (when (re-search-forward battery-linux-proc-apm-regexp)
 258         (setq driver-version (match-string 1))
 259         (setq bios-version (match-string 2))
 260         (setq tem (string-to-number (match-string 3) 16))
 261         (if (not (logand tem 2))
 262             (setq bios-interface "not supported")
 263           (setq bios-interface "enabled")
 264           (cond ((logand tem 16) (setq bios-interface "disabled"))
 265                 ((logand tem 32) (setq bios-interface "disengaged")))
 266           (setq tem (string-to-number (match-string 4) 16))
 267           (cond ((= tem 0) (setq line-status "off-line"))
 268                 ((= tem 1) (setq line-status "on-line"))
 269                 ((= tem 2) (setq line-status "on backup")))
 270           (setq tem (string-to-number (match-string 6) 16))
 271           (if (= tem 255)
 272               (setq battery-status "N/A")
 273             (setq tem (string-to-number (match-string 5) 16))
 274             (cond ((= tem 0) (setq battery-status "high"
 275                                    battery-status-symbol ""))
 276                   ((= tem 1) (setq battery-status "low"
 277                                    battery-status-symbol "-"))
 278                   ((= tem 2) (setq battery-status "critical"
 279                                    battery-status-symbol "!"))
 280                   ((= tem 3) (setq battery-status "charging"
 281                                    battery-status-symbol "+")))
 282             (setq load-percentage (match-string 7))
 283             (setq seconds (string-to-number (match-string 8)))
 284             (and (string-equal (match-string 9) "min")
 285                  (setq seconds (* 60 seconds)))
 286             (setq minutes (/ seconds 60)
 287                   hours (/ seconds 3600))
 288             (setq remaining-time
 289                   (format "%d:%02d" hours (- minutes (* 60 hours))))))))
 290     (list (cons ?v (or driver-version "N/A"))
 291           (cons ?V (or bios-version "N/A"))
 292           (cons ?I (or bios-interface "N/A"))
 293           (cons ?L (or line-status "N/A"))
 294           (cons ?B (or battery-status "N/A"))
 295           (cons ?b (or battery-status-symbol ""))
 296           (cons ?p (or load-percentage "N/A"))
 297           (cons ?s (or (and seconds (number-to-string seconds)) "N/A"))
 298           (cons ?m (or (and minutes (number-to-string minutes)) "N/A"))
 299           (cons ?h (or (and hours (number-to-string hours)) "N/A"))
 300           (cons ?t (or remaining-time "N/A")))))
 301
 302 \f
 303 ;;; `/proc/acpi/' interface for Linux.
 304
 305 (defun battery-linux-proc-acpi ()
 306   "Get ACPI status information from Linux (the kernel).
 307 This function works only with the `/proc/acpi/' format introduced
 308 in Linux version 2.4.20 and 2.6.0.
 309
 310 The following %-sequences are provided:
 311 %c Current capacity (mAh)
 312 %r Current rate
 313 %B Battery status (verbose)
 314 %b Battery status, empty means high, `-' means low,
 315    `!' means critical, and `+' means charging
 316 %d Temperature (in degrees Celsius)
 317 %L AC line status (verbose)
 318 %p Battery load percentage
 319 %m Remaining time (to charge or discharge) in minutes
 320 %h Remaining time (to charge or discharge) in hours
 321 %t Remaining time (to charge or discharge) in the form `h:min'"
 322   (let ((design-capacity 0)
 323         (last-full-capacity 0)
 324         full-capacity
 325         (warn 0)
 326         (low 0)
 327         capacity rate rate-type charging-state minutes hours)
 328     ;; ACPI provides information about each battery present in the system in
 329     ;; a separate subdirectory.  We are going to merge the available
 330     ;; information together since displaying for a variable amount of
 331     ;; batteries seems overkill for format-strings.
 332     (with-temp-buffer
 333       (dolist (dir (ignore-errors (directory-files "/proc/acpi/battery/"
 334                                                    t "\\`[^.]")))
 335         (erase-buffer)
 336         (ignore-errors (insert-file-contents (expand-file-name "state" dir)))
 337         (when (re-search-forward "present: +yes$" nil t)
 338           (and (re-search-forward "charging state: +\\(.*\\)$" nil t)
 339                (member charging-state '("unknown" "charged" nil))
 340                ;; On most multi-battery systems, most of the time only one
 341                ;; battery is "charging"/"discharging", the others are
 342                ;; "unknown".
 343                (setq charging-state (match-string 1)))
 344           (when (re-search-forward "present rate: +\\([0-9]+\\) \\(m[AW]\\)$"
 345                                    nil t)
 346             (setq rate (+ (or rate 0) (string-to-number (match-string 1))))
 347             (when (> rate 0)
 348               (setq rate-type (or (and rate-type
 349                                      (if (string= rate-type (match-string 2))
 350                                          rate-type
 351                                        (error
 352                                         "Inconsistent rate types (%s vs. %s)"
 353                                         rate-type (match-string 2))))
 354                                   (match-string 2)))))
 355           (when (re-search-forward "remaining capacity: +\\([0-9]+\\) m[AW]h$"
 356                                    nil t)
 357             (setq capacity
 358                   (+ (or capacity 0) (string-to-number (match-string 1))))))
 359         (goto-char (point-max))
 360         (ignore-errors (insert-file-contents (expand-file-name "info" dir)))
 361         (when (re-search-forward "present: +yes$" nil t)
 362           (when (re-search-forward "design capacity: +\\([0-9]+\\) m[AW]h$"
 363                                    nil t)
 364             (cl-incf design-capacity (string-to-number (match-string 1))))
 365           (when (re-search-forward "last full capacity: +\\([0-9]+\\) m[AW]h$"
 366                                    nil t)
 367             (cl-incf last-full-capacity (string-to-number (match-string 1))))
 368           (when (re-search-forward
 369                  "design capacity warning: +\\([0-9]+\\) m[AW]h$" nil t)
 370             (cl-incf warn (string-to-number (match-string 1))))
 371           (when (re-search-forward "design capacity low: +\\([0-9]+\\) m[AW]h$"
 372                                    nil t)
 373             (cl-incf low (string-to-number (match-string 1)))))))
 374     (setq full-capacity (if (> last-full-capacity 0)
 375                             last-full-capacity design-capacity))
 376     (and capacity rate
 377          (setq minutes (if (zerop rate) 0
 378                          (floor (* (/ (float (if (string= charging-state
 379                                                           "charging")
 380                                                  (- full-capacity capacity)
 381                                                capacity))
 382                                       rate)
 383                                    60)))
 384                hours (/ minutes 60)))
 385     (list (cons ?c (or (and capacity (number-to-string capacity)) "N/A"))
 386           (cons ?L (or (battery-search-for-one-match-in-files
 387                         (mapcar (lambda (e) (concat e "/state"))
 388                                 (ignore-errors
 389                                   (directory-files "/proc/acpi/ac_adapter/"
 390                                                    t "\\`[^.]")))
 391                         "state: +\\(.*\\)$" 1)
 392
 393                        "N/A"))
 394           (cons ?d (or (battery-search-for-one-match-in-files
 395                         (mapcar (lambda (e) (concat e "/temperature"))
 396                                 (ignore-errors
 397                                   (directory-files "/proc/acpi/thermal_zone/"
 398                                                    t "\\`[^.]")))
 399                         "temperature: +\\([0-9]+\\) C$" 1)
 400
 401                        "N/A"))
 402           (cons ?r (or (and rate (concat (number-to-string rate) " "
 403                                          rate-type)) "N/A"))
 404           (cons ?B (or charging-state "N/A"))
 405           (cons ?b (or (and (string= charging-state "charging") "+")
 406                        (and capacity (< capacity low) "!")
 407                        (and capacity (< capacity warn) "-")
 408                        ""))
 409           (cons ?h (or (and hours (number-to-string hours)) "N/A"))
 410           (cons ?m (or (and minutes (number-to-string minutes)) "N/A"))
 411           (cons ?t (or (and minutes
 412                             (format "%d:%02d" hours (- minutes (* 60 hours))))
 413                        "N/A"))
 414           (cons ?p (or (and full-capacity capacity
 415                             (> full-capacity 0)
 416                             (number-to-string
 417                              (floor (/ capacity
 418                                        (/ (float full-capacity) 100)))))
 419                        "N/A")))))
 420
 421 \f
 422 ;;; `/sys/class/power_supply/BATN' interface for Linux.
 423
 424 (defun battery-linux-sysfs ()
 425   "Get ACPI status information from Linux kernel.
 426 This function works only with the new `/sys/class/power_supply/'
 427 format introduced in Linux version 2.4.25.
 428
 429 The following %-sequences are provided:
 430 %c Current capacity (mAh or mWh)
 431 %r Current rate
 432 %B Battery status (verbose)
 433 %d Temperature (in degrees Celsius)
 434 %p Battery load percentage
 435 %L AC line status (verbose)
 436 %m Remaining time (to charge or discharge) in minutes
 437 %h Remaining time (to charge or discharge) in hours
 438 %t Remaining time (to charge or discharge) in the form `h:min'"
 439   (let (charging-state rate temperature hours
 440         (charge-full 0.0)
 441         (charge-now 0.0)
 442         (energy-full 0.0)
 443         (energy-now 0.0))
 444     ;; SysFS provides information about each battery present in the
 445     ;; system in a separate subdirectory.  We are going to merge the
 446     ;; available information together.
 447     (with-temp-buffer
 448       (dolist (dir (ignore-errors
 449                     (directory-files
 450                      "/sys/class/power_supply/" t
 451                      battery--linux-sysfs-regexp)))
 452         (erase-buffer)
 453         (ignore-errors (insert-file-contents
 454                         (expand-file-name "uevent" dir)))
 455         (when (re-search-forward "POWER_SUPPLY_PRESENT=1$" nil t)
 456           (goto-char (point-min))
 457           (and (re-search-forward "POWER_SUPPLY_STATUS=\\(.*\\)$" nil t)
 458                (member charging-state '("Unknown" "Full" nil))
 459                (setq charging-state (match-string 1)))
 460           (goto-char (point-min))
 461           (when (re-search-forward
 462                  "POWER_SUPPLY_\\(CURRENT\\|POWER\\)_NOW=\\([0-9]*\\)$"
 463                  nil t)
 464             (setq rate (float (string-to-number (match-string 2)))))
 465           (goto-char (point-min))
 466           (when (re-search-forward "POWER_SUPPLY_TEMP=\\([0-9]*\\)$" nil t)
 467             (setq temperature (match-string 1)))
 468           (goto-char (point-min))
 469           (let (full-string now-string)
 470             ;; Sysfs may list either charge (mAh) or energy (mWh).
 471             ;; Keep track of both, and choose which to report later.
 472             (cond ((and (re-search-forward
 473                          "POWER_SUPPLY_CHARGE_FULL=\\([0-9]*\\)$" nil t)
 474                         (setq full-string (match-string 1))
 475                         (re-search-forward
 476                          "POWER_SUPPLY_CHARGE_NOW=\\([0-9]*\\)$" nil t)
 477                         (setq now-string (match-string 1)))
 478                    (setq charge-full (+ charge-full
 479                                         (string-to-number full-string))
 480                          charge-now  (+ charge-now
 481                                         (string-to-number now-string))))
 482                   ((and (progn (goto-char (point-min)) t)
 483                         (re-search-forward
 484                          "POWER_SUPPLY_ENERGY_FULL=\\([0-9]*\\)$" nil t)
 485                         (setq full-string (match-string 1))
 486                         (re-search-forward
 487                          "POWER_SUPPLY_ENERGY_NOW=\\([0-9]*\\)$" nil t)
 488                         (setq now-string (match-string 1)))
 489                    (setq energy-full (+ energy-full
 490                                         (string-to-number full-string))
 491                          energy-now  (+ energy-now
 492                                         (string-to-number now-string))))))
 493           (goto-char (point-min))
 494           (when (and energy-now rate (not (zerop rate))
 495                      (re-search-forward
 496                       "POWER_SUPPLY_VOLTAGE_NOW=\\([0-9]*\\)$" nil t))
 497             (let ((remaining (if (string= charging-state "Discharging")
 498                                  energy-now
 499                                (- energy-full energy-now))))
 500               (setq hours (/ (/ (* remaining (string-to-number
 501                                               (match-string 1)))
 502                                 rate)
 503                              10000000.0)))))))
 504     (list (cons ?c (cond ((or (> charge-full 0) (> charge-now 0))
 505                           (number-to-string charge-now))
 506                          ((or (> energy-full 0) (> energy-now 0))
 507                           (number-to-string energy-now))
 508                          (t "N/A")))
 509           (cons ?r (if rate (format "%.1f" (/ rate 1000000.0)) "N/A"))
 510           (cons ?m (if hours (format "%d" (* hours 60)) "N/A"))
 511           (cons ?h (if hours (format "%d" hours) "N/A"))
 512           (cons ?t (if hours
 513                        (format "%d:%02d" hours (* (- hours (floor hours)) 60))
 514                      "N/A"))
 515           (cons ?d (or temperature "N/A"))
 516           (cons ?B (or charging-state "N/A"))
 517           (cons ?p (cond ((and (> charge-full 0) (> charge-now 0))
 518                           (format "%.1f"
 519                                   (/ (* 100 charge-now) charge-full)))
 520                          ((> energy-full 0)
 521                           (format "%.1f"
 522                                   (/ (* 100 energy-now) energy-full)))
 523                          (t "N/A")))
 524           (cons ?L (if (file-readable-p "/sys/class/power_supply/AC/online")
 525                        (if (battery-search-for-one-match-in-files
 526                             (list "/sys/class/power_supply/AC/online"
 527                                   "/sys/class/power_supply/ACAD/online")
 528                             "1" 0)
 529                            "AC"
 530                          "BAT")
 531                      "N/A")))))
 532
 533 \f
 534 ;;; `apm' interface for BSD.
 535 (defun battery-bsd-apm ()
 536   "Get APM status information from BSD apm binary.
 537 The following %-sequences are provided:
 538 %L AC line status (verbose)
 539 %B Battery status (verbose)
 540 %b Battery status, empty means high, `-' means low,
 541  `!' means critical, and `+' means charging
 542 %P Advanced power saving mode state (verbose)
 543 %p Battery charge percentage
 544 %s Remaining battery charge time in seconds
 545 %m Remaining battery charge time in minutes
 546 %h Remaining battery charge time in hours
 547 %t Remaining battery charge time in the form `h:min'"
 548   (let* ((os-name (car (split-string
 549                         (shell-command-to-string "/usr/bin/uname"))))
 550          (apm-flag (if (equal os-name "OpenBSD") "P" "s"))
 551          (apm-cmd (concat "/usr/sbin/apm -ablm" apm-flag))
 552          (apm-output (split-string (shell-command-to-string apm-cmd)))
 553          ;; Battery status
 554          (battery-status
 555           (let ((stat (string-to-number (nth 0 apm-output))))
 556             (cond ((eq stat 0) '("high" . ""))
 557                   ((eq stat 1) '("low" . "-"))
 558                   ((eq stat 2) '("critical" . "!"))
 559                   ((eq stat 3) '("charging" . "+"))
 560                   ((eq stat 4) '("absent" . nil)))))
 561          ;; Battery percentage
 562          (battery-percentage (nth 1 apm-output))
 563          ;; Battery life
 564          (battery-life (nth 2 apm-output))
 565          ;; AC status
 566          (line-status
 567           (let ((ac (string-to-number (nth 3 apm-output))))
 568             (cond ((eq ac 0) "disconnected")
 569                   ((eq ac 1) "connected")
 570                   ((eq ac 2) "backup power"))))
 571          ;; Advanced power savings mode
 572          (apm-mode
 573           (let ((apm (string-to-number (nth 4 apm-output))))
 574             (if (string= os-name "OpenBSD")
 575                 (cond ((eq apm 0) "manual")
 576                       ((eq apm 1) "automatic")
 577                       ((eq apm 2) "cool running"))
 578               (if (eq apm 1) "on" "off"))))
 579          seconds minutes hours remaining-time)
 580     (unless (member battery-life '("unknown" "-1"))
 581       (if (member os-name '("OpenBSD" "NetBSD"))
 582           (setq minutes (string-to-number battery-life)
 583                 seconds (* 60 minutes))
 584         (setq seconds (string-to-number battery-life)
 585               minutes (truncate (/ seconds 60))))
 586       (setq hours (truncate (/ minutes 60))
 587             remaining-time (format "%d:%02d" hours
 588                                    (- minutes (* 60 hours)))))
 589     (list (cons ?L (or line-status "N/A"))
 590           (cons ?B (or (car battery-status) "N/A"))
 591           (cons ?b (or (cdr battery-status) "N/A"))
 592           (cons ?p (if (string= battery-percentage "255")
 593                        "N/A"
 594                      battery-percentage))
 595           (cons ?P (or apm-mode "N/A"))
 596           (cons ?s (or (and seconds (number-to-string seconds)) "N/A"))
 597           (cons ?m (or (and minutes (number-to-string minutes)) "N/A"))
 598           (cons ?h (or (and hours (number-to-string hours)) "N/A"))
 599           (cons ?t (or remaining-time "N/A")))))
 600
 601 \f
 602 ;;; `pmset' interface for Darwin (OS X).
 603
 604 (defun battery-pmset ()
 605   "Get battery status information using `pmset'.
 606
 607 The following %-sequences are provided:
 608 %L Power source (verbose)
 609 %B Battery status (verbose)
 610 %b Battery status, empty means high, `-' means low,
 611    `!' means critical, and `+' means charging
 612 %p Battery load percentage
 613 %h Remaining time in hours
 614 %m Remaining time in minutes
 615 %t Remaining time in the form `h:min'"
 616   (let (power-source load-percentage battery-status battery-status-symbol
 617         remaining-time hours minutes)
 618     (with-temp-buffer
 619       (ignore-errors (call-process "pmset" nil t nil "-g" "ps"))
 620       (goto-char (point-min))
 621       (when (re-search-forward "\\(?:Currentl?y\\|Now\\) drawing from '\\(AC\\|Battery\\) Power'" nil t)
 622         (setq power-source (match-string 1))
 623         (when (re-search-forward "^ -InternalBattery-0[ \t]+" nil t)
 624           (when (looking-at "\\([0-9]\\{1,3\\}\\)%")
 625             (setq load-percentage (match-string 1))
 626             (goto-char (match-end 0))
 627             (cond ((looking-at "; charging")
 628                    (setq battery-status "charging"
 629                          battery-status-symbol "+"))
 630                   ((< (string-to-number load-percentage) battery-load-low)
 631                    (setq battery-status "low"
 632                          battery-status-symbol "-"))
 633                   ((< (string-to-number load-percentage) battery-load-critical)
 634                    (setq battery-status "critical"
 635                          battery-status-symbol "!"))
 636                   (t
 637                    (setq battery-status "high"
 638                          battery-status-symbol "")))
 639             (when (re-search-forward "\\(\\([0-9]+\\):\\([0-9]+\\)\\) remaining"  nil t)
 640               (setq remaining-time (match-string 1))
 641               (let ((h (string-to-number (match-string 2)))
 642                     (m (string-to-number (match-string 3))))
 643                 (setq hours (number-to-string (+ h (if (< m 30) 0 1)))
 644                       minutes (number-to-string (+ (* h 60) m)))))))))
 645     (list (cons ?L (or power-source "N/A"))
 646           (cons ?p (or load-percentage "N/A"))
 647           (cons ?B (or battery-status "N/A"))
 648           (cons ?b (or battery-status-symbol ""))
 649           (cons ?h (or hours "N/A"))
 650           (cons ?m (or minutes "N/A"))
 651           (cons ?t (or remaining-time "N/A")))))
 652
 653 \f
 654 ;;; Private functions.
 655
 656 (defun battery-format (format alist)
 657   "Substitute %-sequences in FORMAT."
 658   (replace-regexp-in-string
 659    "%."
 660    (lambda (str)
 661      (let ((char (aref str 1)))
 662        (if (eq char ?%) "%"
 663          (or (cdr (assoc char alist)) ""))))
 664    format t t))
 665
 666 (defun battery-search-for-one-match-in-files (files regexp match-num)
 667   "Search REGEXP in the content of the files listed in FILES.
 668 If a match occurred, return the parenthesized expression numbered by
 669 MATCH-NUM in the match.  Otherwise, return nil."
 670   (with-temp-buffer
 671     (catch 'found
 672       (dolist (file files)
 673         (and (ignore-errors (insert-file-contents file nil nil nil 'replace))
 674              (re-search-forward regexp nil t)
 675              (throw 'found (match-string match-num)))))))
 676
 677 \f
 678 (provide 'battery)
 679
 680 ;;; battery.el ends here