configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002
   7 dnl  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 2, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 dnl  Boston, MA 02111-1307, USA.
  25
  26 AC_PREREQ(2.8)dnl
  27 AC_INIT(src/lisp.h)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29
  30 lispdir='${datadir}/emacs/${version}/lisp'
  31 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  32 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
  33 lisppath='${locallisppath}:${lispdir}'
  34 etcdir='${datadir}/emacs/${version}/etc'
  35 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  36 docdir='${datadir}/emacs/${version}/etc'
  37
  38 AC_ARG_WITH(gcc,
  39 [  --without-gcc           don't use GCC to compile Emacs if GCC is found])
  40 AC_ARG_WITH(pop,
  41 [  --without-pop           don't support POP mail retrieval with movemail],
  42 [if test "$withval" = yes; then
  43    AC_DEFINE(MAIL_USE_POP)
  44 else :
  45 fi],
  46 AC_DEFINE(MAIL_USE_POP))
  47 AC_ARG_WITH(kerberos,
  48 [  --with-kerberos         support Kerberos-authenticated POP],
  49 [AC_DEFINE(KERBEROS)])
  50 AC_ARG_WITH(kerberos5,
  51 [  --with-kerberos5        support Kerberos version 5 authenticated POP],
  52 [if test "${with_kerberos5+set}" = set; then
  53   if test "${with_kerberos+set}" != set; then
  54     with_kerberos=yes
  55     AC_DEFINE(KERBEROS)
  56   fi
  57 fi
  58 AC_DEFINE(KERBEROS5)])
  59 AC_ARG_WITH(hesiod,
  60 [  --with-hesiod           support Hesiod to get the POP server host],
  61 [AC_DEFINE(HESIOD)])
  62 dnl This should be the last --with option, because --with-x is
  63 dnl added later on when we find the path of X, and it's best to
  64 dnl keep them together visually.
  65 AC_ARG_WITH(x-toolkit,
  66 [  --with-x-toolkit=KIT    use an X toolkit (KIT = yes/lucid/athena/motif/no)],
  67 [         case "${withval}" in
  68             y | ye | yes )      val=athena ;;
  69             n | no )            val=no  ;;
  70             l | lu | luc | luci | lucid )       val=lucid ;;
  71             a | at | ath | athe | athen | athena )      val=athena ;;
  72             m | mo | mot | moti | motif )       val=motif ;;
  73 dnl These don't currently work.
  74 dnl         o | op | ope | open | open- | open-l | open-lo \
  75 dnl             | open-loo | open-look )        val=open-look ;;
  76             * )
  77 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  78 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  79 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
  80 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
  81 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  82             ;;
  83           esac
  84           with_x_toolkit=$val
  85 ])
  86 AC_ARG_WITH(xpm,
  87 [  --with-xpm              use -lXpm for displaying XPM images])
  88 AC_ARG_WITH(jpeg,
  89 [  --with-jpeg             use -ljpeg for displaying JPEG images])
  90 AC_ARG_WITH(tiff,
  91 [  --with-tiff             use -ltiff for displaying TIFF images])
  92 AC_ARG_WITH(gif,
  93 [  --with-gif              use -lungif for displaying GIF images])
  94 AC_ARG_WITH(png,
  95 [  --with-png              use -lpng for displaying PNG images])
  96 AC_ARG_WITH(toolkit-scroll-bars,
  97 [  --without-toolkit-scroll-bars
  98                           don't use Motif or Xaw3d scroll bars])
  99 AC_ARG_WITH(xim,
 100 [  --without-xim           don't use X11 XIM])
 101
 102 #### Make srcdir absolute, if it isn't already.  It's important to
 103 #### avoid running the path through pwd unnecessarily, since pwd can
 104 #### give you automounter prefixes, which can go away.  We do all this
 105 #### so Emacs can find its files when run uninstalled.
 106 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 107 unset CDPATH
 108 case "${srcdir}" in
 109   /* ) ;;
 110   . )
 111     ## We may be able to use the $PWD environment variable to make this
 112     ## absolute.  But sometimes PWD is inaccurate.
 113     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".${PWD}"  ;
 114     then
 115       srcdir="$PWD"
 116     else
 117       srcdir="`(cd ${srcdir}; pwd)`"
 118     fi
 119   ;;
 120   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 121 esac
 122
 123 #### Check if the source directory already has a configured system in it.
 124 if test `pwd` != `(cd ${srcdir} && pwd)` \
 125    && test -f "${srcdir}/src/config.h" ; then
 126   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
 127    as a build directory right now; it has been configured in its own
 128    right.  To configure in another directory as well, you MUST
 129    use GNU make.  If you do not have GNU make, then you must
 130    now do \`make distclean' in ${srcdir},
 131    and then run $0 again.])
 132
 133 changequote(, )dnl
 134   extrasub='/^VPATH[     ]*=/c\
 135 changequote([, ])dnl
 136 vpath %.c $(srcdir)\
 137 vpath %.h $(srcdir)\
 138 vpath %.y $(srcdir)\
 139 vpath %.l $(srcdir)\
 140 vpath %.s $(srcdir)\
 141 vpath %.in $(srcdir)\
 142 vpath %.texi $(srcdir)'
 143 fi
 144
 145 #### Given the configuration name, set machfile and opsysfile to the
 146 #### names of the m/*.h and s/*.h files we should use.
 147
 148 ### Canonicalize the configuration name.
 149
 150 AC_CANONICAL_HOST
 151 canonical=$host
 152 configuration=$host_alias
 153
 154 changequote(, )dnl
 155
 156 ### If you add support for a new configuration, add code to this
 157 ### switch statement to recognize your configuration name and select
 158 ### the appropriate operating system and machine description files.
 159
 160 ### You would hope that you could choose an m/*.h file pretty much
 161 ### based on the machine portion of the configuration name, and an s-
 162 ### file based on the operating system portion.  However, it turns out
 163 ### that each m/*.h file is pretty manufacturer-specific - for
 164 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 165 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 166 ### machines.  So we basically have to have a special case for each
 167 ### configuration name.
 168 ###
 169 ### As far as handling version numbers on operating systems is
 170 ### concerned, make sure things will fail in a fixable way.  If
 171 ### /etc/MACHINES doesn't say anything about version numbers, be
 172 ### prepared to handle anything reasonably.  If version numbers
 173 ### matter, be sure /etc/MACHINES says something about it.
 174 ###
 175 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 176 ### "System V Release 4"; he writes, "The old convention encouraged
 177 ### confusion between `system' and `release' levels'."
 178
 179 machine='' opsys='' unported=no
 180 case "${canonical}" in
 181
 182   ## NetBSD ports
 183   *-*-netbsd* )
 184     opsys=netbsd
 185     case "${canonical}" in
 186       alpha*-*-netbsd*) machine=alpha ;;
 187       i[3456]86-*-netbsd*) machine=intel386 ;;
 188       m68k-*-netbsd*)
 189                         # This is somewhat bogus.
 190                         machine=hp9000s300 ;;
 191       powerpc-apple-netbsd*) machine=macppc ;;
 192       mips-*-netbsd*)   machine=pmax ;;
 193       mipsel-*-netbsd*) machine=pmax ;;
 194       ns32k-*-netbsd*)  machine=ns32000 ;;
 195       powerpc-*-netbsd*) machine=macppc ;;
 196       sparc*-*-netbsd*) machine=sparc ;;
 197       vax-*-netbsd*)    machine=vax ;;
 198       arm-*-netbsd*)    machine=arm ;;
 199     esac
 200   ;;
 201
 202   ## OpenBSD ports
 203   *-*-openbsd* )
 204     opsys=openbsd
 205     case "${canonical}" in
 206       alpha*-*-openbsd*)        machine=alpha ;;
 207       i386-*-openbsd*)  machine=intel386 ;;
 208       m68k-*-openbsd*)  machine=hp9000s300 ;;
 209       mipsel-*-openbsd*) machine=pmax ;;
 210       ns32k-*-openbsd*) machine=ns32000 ;;
 211       sparc-*-openbsd*) machine=sparc ;;
 212       vax-*-openbsd*)   machine=vax ;;
 213     esac
 214   ;;
 215
 216   ## Acorn RISCiX:
 217   arm-acorn-riscix1.1* )
 218     machine=acorn opsys=riscix1-1
 219   ;;
 220   arm-acorn-riscix1.2* | arm-acorn-riscix )
 221     ## This name is riscix12 instead of riscix1.2
 222     ## to avoid a file name conflict on MSDOS.
 223     machine=acorn opsys=riscix12
 224   ;;
 225
 226   ## BSDI ports
 227   *-*-bsdi* )
 228     opsys=bsdi
 229     case "${canonical}" in
 230       i[345]86-*-bsdi*) machine=intel386 ;;
 231       sparc-*-bsdi*)  machine=sparc ;;
 232       powerpc-*-bsdi*)  machine=macppc ;;
 233     esac
 234     case "${canonical}" in
 235       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 236       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 237       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 238       *-*-bsdi3* )              opsys=bsdos3 ;;
 239       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 240     esac
 241   ;;
 242
 243   ## Alliant machines
 244   ## Strictly speaking, we need the version of the alliant operating
 245   ## system to choose the right machine file, but currently the
 246   ## configuration name doesn't tell us enough to choose the right
 247   ## one; we need to give alliants their own operating system name to
 248   ## do this right.  When someone cares, they can help us.
 249   fx80-alliant-* )
 250     machine=alliant4 opsys=bsd4-2
 251   ;;
 252   i860-alliant-* )
 253     machine=alliant-2800 opsys=bsd4-3
 254   ;;
 255
 256   ## Alpha (DEC) machines.
 257   alpha*-dec-osf* )
 258     machine=alpha opsys=osf1
 259     # This is needed to find X11R6.1 libraries for certain tests.
 260     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 261     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 262     # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
 263     # due to non-traditional preprocessing with the current compiler
 264     # defaults.  OSF 4 can also have that compiler version, and there
 265     # seems always to have been a usable /usr/bin/cpp.
 266     NON_GNU_CPP=/usr/bin/cpp
 267     case "${canonical}" in
 268     alpha*-dec-osf[5-9]*)
 269       opsys=osf5-0 ;;
 270     esac
 271   ;;
 272
 273   alpha*-*-linux-gnu* )
 274     machine=alpha opsys=gnu-linux
 275   ;;
 276
 277   arm*-*-linux-gnu* )
 278     machine=arm opsys=gnu-linux
 279   ;;
 280
 281   ppc-*-linux | \
 282   powerpc-*-linux* )
 283     machine=macppc opsys=gnu-linux
 284   ;;
 285
 286   ## Altos 3068
 287   m68*-altos-sysv* )
 288     machine=altos opsys=usg5-2
 289   ;;
 290
 291   ## Amdahl UTS
 292   580-amdahl-sysv* )
 293     machine=amdahl opsys=usg5-2-2
 294   ;;
 295
 296   ## Apollo, Domain/OS
 297   m68*-apollo-* )
 298     machine=apollo opsys=bsd4-3
 299   ;;
 300
 301   ## AT&T 3b2, 3b5, 3b15, 3b20
 302   we32k-att-sysv* )
 303     machine=att3b opsys=usg5-2-2
 304   ;;
 305
 306   ## AT&T 3b1 - The Mighty Unix PC!
 307   m68*-att-sysv* )
 308     machine=7300 opsys=usg5-2-2
 309   ;;
 310
 311   ## Bull dpx20
 312   rs6000-bull-bosx* )
 313     machine=ibmrs6000 opsys=aix3-2
 314   ;;
 315
 316   ## Bull dpx2
 317   m68*-bull-sysv3* )
 318     machine=dpx2 opsys=usg5-3
 319   ;;
 320
 321   ## Bull sps7
 322   m68*-bull-sysv2* )
 323     machine=sps7 opsys=usg5-2
 324   ;;
 325
 326   ## CCI 5/32, 6/32 -- see "Tahoe".
 327
 328   ## Celerity
 329   ## I don't know what configuration name to use for this; config.sub
 330   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 331   ## in touch with us!
 332   celerity-celerity-bsd* )
 333     machine=celerity opsys=bsd4-2
 334   ;;
 335
 336   ## Clipper
 337   ## What operating systems does this chip run that Emacs has been
 338   ## tested on?
 339   clipper-* )
 340     machine=clipper
 341     ## We'll use the catch-all code at the bottom to guess the
 342     ## operating system.
 343   ;;
 344
 345   ## Convex
 346   *-convex-bsd* | *-convex-convexos* )
 347     machine=convex opsys=bsd4-3
 348     ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
 349     NON_GNU_CPP="cc -E -P"
 350   ;;
 351
 352   ## Cubix QBx/386
 353   i[3456]86-cubix-sysv* )
 354     machine=intel386 opsys=usg5-3
 355   ;;
 356
 357   ## Cydra 5
 358   cydra*-cydrome-sysv* )
 359     machine=cydra5 opsys=usg5-3
 360   ;;
 361
 362   ## Data General AViiON Machines
 363   ## DG changed naming conventions with the release of 5.4.4.10, they
 364   ## dropped the initial 5.4 but left the intervening R.  Because of the
 365   ## R this shouldn't conflict with older versions of the OS (which I
 366   ## think were named like dgux4.*). In addition, DG new AViiONs series
 367   ## uses either Motorola M88k or Intel Pentium CPUs.
 368   m88k-dg-dguxR4.* | m88k-dg-dgux4* )
 369     machine=aviion opsys=dgux4
 370   ;;
 371   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 372     ## This name is dgux5-4-3 instead of dgux5-4r3
 373     ## to avoid a file name conflict on MSDOS.
 374     machine=aviion opsys=dgux5-4-3
 375   ;;
 376   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 377     machine=aviion opsys=dgux5-4r2
 378   ;;
 379   m88k-dg-dgux* )
 380     machine=aviion opsys=dgux
 381   ;;
 382
 383   ## Data General AViiON Intel (x86) Machines
 384   ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
 385   ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
 386   i[345]86-dg-dguxR4* )
 387     machine=aviion-intel opsys=dgux4
 388   ;;
 389
 390   ## DECstations
 391   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 392     machine=pmax opsys=bsd4-2
 393   ;;
 394   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 395     machine=pmax opsys=bsd4-3
 396   ;;
 397   mips-dec-ultrix* )
 398     machine=pmax opsys=ultrix4-3
 399   ;;
 400   mips-dec-osf* )
 401     machine=pmax opsys=osf1
 402   ;;
 403   mips-dec-mach_bsd4.3* )
 404     machine=pmax opsys=mach-bsd4-3
 405   ;;
 406
 407   ## Motorola Delta machines
 408   m68k-motorola-sysv* | m68000-motorola-sysv* )
 409     machine=delta opsys=usg5-3
 410     if test -z "`type gnucc | grep 'not found'`"
 411     then
 412       if test -s /etc/167config
 413       then CC="gnucc -m68040"
 414       else CC="gnucc -m68881"
 415       fi
 416     else
 417       if test -z "`type gcc | grep 'not found'`"
 418       then CC=gcc
 419       else CC=cc
 420       fi
 421     fi
 422   ;;
 423   m88k-motorola-sysv4* )
 424     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 425     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 426     # I hope there are not other 4.0 versions for this machine
 427     # which really need usg5-4 instead.
 428     machine=delta88k opsys=usg5-4-2
 429   ;;
 430   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 431     machine=delta88k opsys=usg5-3
 432   ;;
 433
 434   ## Dual machines
 435   m68*-dual-sysv* )
 436     machine=dual opsys=usg5-2
 437   ;;
 438   m68*-dual-uniplus* )
 439     machine=dual opsys=unipl5-2
 440   ;;
 441
 442   ## Elxsi 6400
 443   elxsi-elxsi-sysv* )
 444     machine=elxsi opsys=usg5-2
 445   ;;
 446
 447   ## Encore machines
 448   ns16k-encore-bsd* )
 449     machine=ns16000 opsys=umax
 450   ;;
 451
 452   ## The GEC 63 - apparently, this port isn't really finished yet.
 453   #  I'm sure we finished off the last of the machines, though.  -- fx
 454
 455   ## Gould Power Node and NP1
 456   pn-gould-bsd4.2* )
 457     machine=gould opsys=bsd4-2
 458   ;;
 459   pn-gould-bsd4.3* )
 460     machine=gould opsys=bsd4-3
 461   ;;
 462   np1-gould-bsd* )
 463     machine=gould-np1 opsys=bsd4-3
 464   ;;
 465
 466   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 467   ## as far as Emacs is concerned).
 468   m88k-harris-cxux* )
 469     # Build needs to be different on 7.0 and later releases
 470     case "`uname -r`" in
 471        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 472        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 473     esac
 474     NON_GNU_CPP="/lib/cpp"
 475   ;;
 476   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 477   m68k-harris-cxux* )
 478     machine=nh3000 opsys=cxux
 479   ;;
 480   ## Harris power pc NightHawk running Power UNIX (Series 6000)
 481   powerpc-harris-powerunix )
 482     machine=nh6000 opsys=powerunix
 483     NON_GNU_CPP="cc -Xo -E -P"
 484   ;;
 485   ## SR2001/SR2201 running HI-UX/MPP
 486   hppa1.1-hitachi-hiuxmpp* )
 487     machine=sr2k opsys=hiuxmpp
 488   ;;
 489   hppa1.1-hitachi-hiuxwe2* )
 490     machine=sr2k opsys=hiuxwe2
 491   ;;
 492   ## Honeywell XPS100
 493   xps*-honeywell-sysv* )
 494     machine=xps100 opsys=usg5-2
 495   ;;
 496
 497   ## HP 9000 series 200 or 300
 498   m68*-hp-bsd* )
 499     machine=hp9000s300 opsys=bsd4-3
 500   ;;
 501   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 502   m68*-hp-hpux* )
 503     case "`uname -r`" in
 504       ## Someone's system reports A.B8.05 for this.
 505       ## I wonder what other possibilities there are.
 506       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 507       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 508       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 509       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 510       *) machine=hp9000s300 opsys=hpux ;;
 511     esac
 512   ;;
 513
 514   ## HP 9000 series 700 and 800, running HP/UX
 515   hppa*-hp-hpux7* )
 516     machine=hp800 opsys=hpux
 517   ;;
 518   hppa*-hp-hpux8* )
 519     machine=hp800 opsys=hpux8
 520   ;;
 521   hppa*-hp-hpux9shr* )
 522     machine=hp800 opsys=hpux9shr
 523   ;;
 524   hppa*-hp-hpux9* )
 525     machine=hp800 opsys=hpux9
 526   ;;
 527
 528   hppa*-hp-hpux10* )
 529     machine=hp800 opsys=hpux10
 530   ;;
 531   hppa*-hp-hpux1[1-9]* )
 532     machine=hp800 opsys=hpux11
 533   ;;
 534
 535   ## HP 9000 series 700 and 800, running HP/UX
 536   hppa*-hp-hpux* )
 537     ## Cross-compilation?  Nah!
 538     case "`uname -r`" in
 539       ## Someone's system reports A.B8.05 for this.
 540       ## I wonder what other possibilities there are.
 541       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 542       *.08.* ) machine=hp800 opsys=hpux8 ;;
 543       *.09.* ) machine=hp800 opsys=hpux9 ;;
 544       *) machine=hp800 opsys=hpux10 ;;
 545     esac
 546   ;;
 547   hppa*-*-nextstep* )
 548     machine=hp800 opsys=nextstep
 549   ;;
 550
 551   ## Orion machines
 552   orion-orion-bsd* )
 553     machine=orion opsys=bsd4-2
 554   ;;
 555   clipper-orion-bsd* )
 556     machine=orion105 opsys=bsd4-2
 557   ;;
 558
 559   ## IBM machines
 560   i[3456]86-ibm-aix1.1* )
 561     machine=ibmps2-aix opsys=usg5-2-2
 562   ;;
 563   i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
 564     machine=ibmps2-aix opsys=usg5-3
 565   ;;
 566   i370-ibm-aix*)
 567     machine=ibm370aix opsys=usg5-3
 568   ;;
 569   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 570     machine=ibmrs6000 opsys=aix3-1
 571   ;;
 572   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 573     machine=ibmrs6000 opsys=aix3-2-5
 574   ;;
 575   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 576     machine=ibmrs6000 opsys=aix4-1
 577   ;;
 578   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 579     machine=ibmrs6000 opsys=aix4-2
 580   ;;
 581   rs6000-ibm-aix5.1* | powerpc-ibm-aix5.1*  )
 582     machine=ibmrs6000 opsys=aix4-2
 583   ;;
 584   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 585     machine=ibmrs6000 opsys=aix4
 586   ;;
 587   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 588     machine=ibmrs6000 opsys=aix4-1
 589   ;;
 590   rs6000-ibm-aix* | powerpc-ibm-aix* )
 591     machine=ibmrs6000 opsys=aix3-2
 592   ;;
 593   romp-ibm-bsd4.3* )
 594     machine=ibmrt opsys=bsd4-3
 595   ;;
 596   romp-ibm-bsd4.2* )
 597     machine=ibmrt opsys=bsd4-2
 598   ;;
 599   romp-ibm-aos4.3* )
 600     machine=ibmrt opsys=bsd4-3
 601   ;;
 602   romp-ibm-aos4.2* )
 603     machine=ibmrt opsys=bsd4-2
 604   ;;
 605   romp-ibm-aos* )
 606     machine=ibmrt opsys=bsd4-3
 607   ;;
 608   romp-ibm-bsd* )
 609     machine=ibmrt opsys=bsd4-3
 610   ;;
 611   romp-ibm-aix* )
 612     machine=ibmrt-aix opsys=usg5-2-2
 613   ;;
 614
 615   ## Integrated Solutions `Optimum V'
 616   m68*-isi-bsd4.2* )
 617     machine=isi-ov opsys=bsd4-2
 618   ;;
 619   m68*-isi-bsd4.3* )
 620     machine=isi-ov opsys=bsd4-3
 621   ;;
 622
 623   ## Intel 386 machines where we do care about the manufacturer
 624   i[3456]86-intsys-sysv* )
 625     machine=is386 opsys=usg5-2-2
 626   ;;
 627
 628   ## Prime EXL
 629   i[3456]86-prime-sysv* )
 630     machine=i386 opsys=usg5-3
 631   ;;
 632
 633   ## Sequent Symmetry running Dynix
 634   i[3456]86-sequent-bsd* )
 635     machine=symmetry opsys=bsd4-3
 636   ;;
 637
 638   ## Sequent Symmetry running ptx 4, which is a modified SVR4.
 639   i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
 640     machine=sequent-ptx opsys=ptx4
 641     NON_GNU_CPP=/lib/cpp
 642   ;;
 643
 644   ## Sequent Symmetry running DYNIX/ptx
 645   ## Use the old cpp rather than the newer ANSI one.
 646   i[3456]86-sequent-ptx* )
 647     machine=sequent-ptx opsys=ptx
 648     NON_GNU_CPP="/lib/cpp"
 649   ;;
 650
 651   ## ncr machine running svr4.3.
 652   i[3456]86-ncr-sysv4.3 )
 653     machine=ncr386 opsys=usg5-4-3
 654   ;;
 655
 656   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 657   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 658   i[3456]86-ncr-sysv* )
 659     machine=ncr386 opsys=usg5-4-2
 660   ;;
 661
 662   ## Intel Paragon OSF/1
 663   i860-intel-osf1* )
 664     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 665   ;;
 666
 667   ## Intel 860
 668   i860-*-sysv4* )
 669     machine=i860 opsys=usg5-4
 670     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 671     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 672   ;;
 673
 674   ## Macintosh PowerPC
 675   powerpc*-*-linux-gnu* )
 676     machine=macppc opsys=gnu-linux
 677   ;;
 678
 679   ## Masscomp machines
 680   m68*-masscomp-rtu* )
 681     machine=masscomp opsys=rtu
 682   ;;
 683
 684   ## Megatest machines
 685   m68*-megatest-bsd* )
 686     machine=mega68 opsys=bsd4-2
 687   ;;
 688
 689   ## Workstations sold by MIPS
 690   ## This is not necessarily all workstations using the MIPS processor -
 691   ## Irises are produced by SGI, and DECstations by DEC.
 692
 693   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 694   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 695   ## it gives for choosing between the alternatives seems to be "Use
 696   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 697   ## the BSD world."  I'll assume that these are instructions for
 698   ## handling two odd situations, and that every other situation
 699   ## should use mips.h and usg5-2-2, they being listed first.
 700   mips-mips-usg* )
 701     machine=mips4
 702     ## Fall through to the general code at the bottom to decide on the OS.
 703   ;;
 704   mips-mips-riscos4* )
 705     machine=mips4 opsys=bsd4-3
 706     NON_GNU_CC="cc -systype bsd43"
 707     NON_GNU_CPP="cc -systype bsd43 -E"
 708   ;;
 709   mips-mips-riscos5* )
 710     machine=mips4 opsys=riscos5
 711     NON_GNU_CC="cc -systype bsd43"
 712     NON_GNU_CPP="cc -systype bsd43 -E"
 713   ;;
 714   mips-mips-bsd* )
 715     machine=mips opsys=bsd4-3
 716   ;;
 717   mips-mips-* )
 718     machine=mips opsys=usg5-2-2
 719   ;;
 720
 721   ## NeXT
 722   m68*-next-* | m68k-*-nextstep* )
 723     machine=m68k opsys=nextstep
 724   ;;
 725
 726   ## The complete machine from National Semiconductor
 727   ns32k-ns-genix* )
 728     machine=ns32000 opsys=usg5-2
 729   ;;
 730
 731   ## NCR machines
 732   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 733     machine=tower32 opsys=usg5-2-2
 734   ;;
 735   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 736     machine=tower32v3 opsys=usg5-3
 737   ;;
 738
 739   ## NEC EWS4800
 740   mips-nec-sysv4*)
 741   machine=ews4800 opsys=ux4800
 742   ;;
 743
 744   ## Nixdorf Targon 31
 745   m68*-nixdorf-sysv* )
 746     machine=targon31 opsys=usg5-2-2
 747   ;;
 748
 749   ## Nu (TI or LMI)
 750   m68*-nu-sysv* )
 751     machine=nu opsys=usg5-2
 752   ;;
 753
 754   ## Plexus
 755   m68*-plexus-sysv* )
 756     machine=plexus opsys=usg5-2
 757   ;;
 758
 759   ## PowerPC reference platform
 760   powerpcle-*-solaris2* )
 761     machine=prep
 762     opsys=sol2-5
 763   ;;
 764
 765   ## Pyramid machines
 766   ## I don't really have any idea what sort of processor the Pyramid has,
 767   ## so I'm assuming it is its own architecture.
 768   pyramid-pyramid-bsd* )
 769     machine=pyramid opsys=bsd4-2
 770   ;;
 771
 772   ## Sequent Balance
 773   ns32k-sequent-bsd4.2* )
 774     machine=sequent opsys=bsd4-2
 775   ;;
 776   ns32k-sequent-bsd4.3* )
 777     machine=sequent opsys=bsd4-3
 778   ;;
 779
 780   ## Siemens Nixdorf
 781   mips-siemens-sysv* | mips-sni-sysv*)
 782     machine=mips-siemens opsys=usg5-4
 783     NON_GNU_CC=/usr/ccs/bin/cc
 784     NON_GNU_CPP=/usr/ccs/lib/cpp
 785   ;;
 786
 787   ## Silicon Graphics machines
 788   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 789   m68*-sgi-iris3.5* )
 790     machine=irist opsys=iris3-5
 791   ;;
 792   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 793     machine=irist opsys=iris3-6
 794   ;;
 795   ## Iris 4D
 796   mips-sgi-irix3* )
 797     machine=iris4d opsys=irix3-3
 798   ;;
 799   mips-sgi-irix4* )
 800     machine=iris4d opsys=irix4-0
 801   ;;
 802   mips-sgi-irix6.5 )
 803     machine=iris4d opsys=irix6-5
 804     # Without defining _LANGUAGE_C, things get masked out in the headers
 805     # so that, for instance, grepping for `free' in stdlib.h fails and
 806     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 807     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 808     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 809   ;;
 810   mips-sgi-irix6* )
 811     machine=iris4d opsys=irix6-0
 812     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 813     # but presumably it does no harm.
 814     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 815     # -32 probably isn't necessary in later v.6s -- anyone know which?
 816     NON_GCC_TEST_OPTIONS=-32
 817   ;;
 818   mips-sgi-irix5.[01]* )
 819     machine=iris4d opsys=irix5-0
 820   ;;
 821   mips-sgi-irix5* | mips-sgi-irix* )
 822     machine=iris4d opsys=irix5-2
 823   ;;
 824
 825   ## SONY machines
 826   m68*-sony-bsd4.2* )
 827     machine=news opsys=bsd4-2
 828   ;;
 829   m68*-sony-bsd4.3* )
 830     machine=news opsys=bsd4-3
 831   ;;
 832   m68*-sony-newsos3* | m68*-sony-news3*)
 833     machine=news opsys=bsd4-3
 834   ;;
 835   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 836     machine=news-risc opsys=bsd4-3
 837   ;;
 838   mips-sony-newsos6* )
 839     machine=news-r6 opsys=newsos6
 840   ;;
 841   mips-sony-news* )
 842     machine=news-risc opsys=newsos5
 843   ;;
 844
 845   ## Stride
 846   m68*-stride-sysv* )
 847     machine=stride opsys=usg5-2
 848   ;;
 849
 850   ## Suns
 851   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 852     machine=sparc opsys=gnu-linux
 853   ;;
 854
 855   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 856     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 857     | rs6000-*-solaris2*)
 858     case "${canonical}" in
 859       m68*-sunos1* )    machine=sun1 ;;
 860       m68*-sunos2* )    machine=sun2 ;;
 861       m68* )            machine=sun3 ;;
 862       i[3456]86-sun-sunos[34]* )        machine=sun386 ;;
 863       i[3456]86-*-* )     machine=intel386 ;;
 864       powerpcle* )      machine=powerpcle ;;
 865       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 866       sparc* )          machine=sparc ;;
 867       * )               unported=yes ;;
 868     esac
 869     case "${canonical}" in
 870       ## The Sun386 didn't get past 4.0.
 871       i[3456]86-*-sunos4          ) opsys=sunos4-0 ;;
 872       *-sunos4.0*         ) opsys=sunos4-0 ;;
 873       *-sunos4.1.[3-9]*noshare )
 874                 ## This name is sunos413 instead of sunos4-1-3
 875                 ## to avoid a file name conflict on MSDOS.
 876                 opsys=sunos413
 877                 NON_GNU_CPP=/usr/lib/cpp
 878                 NON_GCC_TEST_OPTIONS=-Bstatic
 879                 GCC_TEST_OPTIONS=-static
 880                 ;;
 881       *-sunos4.1.[3-9]* | *-sunos4shr*)
 882                 opsys=sunos4shr
 883                 NON_GNU_CPP=/usr/lib/cpp
 884                 ;;
 885       *-sunos4* | *-sunos )
 886                 opsys=sunos4-1
 887                 NON_GCC_TEST_OPTIONS=-Bstatic
 888                 GCC_TEST_OPTIONS=-static
 889                 ;;
 890       *-sunos5.3* | *-solaris2.3* )
 891                 opsys=sol2-3
 892                 NON_GNU_CPP=/usr/ccs/lib/cpp
 893                 ;;
 894       *-sunos5.4* | *-solaris2.4* )
 895                 opsys=sol2-4
 896                 NON_GNU_CPP=/usr/ccs/lib/cpp
 897                 RANLIB="ar -ts"
 898                 ;;
 899       *-sunos5.5* | *-solaris2.5* )
 900                 opsys=sol2-5
 901                 NON_GNU_CPP=/usr/ccs/lib/cpp
 902                 RANLIB="ar -ts"
 903                 ;;
 904       *-sunos5.8* | *-solaris2.8* )
 905                 opsys=sol2-8
 906                 NON_GNU_CPP=/usr/ccs/lib/cpp
 907                 RANLIB="ar -ts"
 908                 ;;
 909       *-sunos5* | *-solaris* )
 910                 opsys=sol2-5
 911                 NON_GNU_CPP=/usr/ccs/lib/cpp
 912                 ;;
 913       *                   ) opsys=bsd4-2   ;;
 914     esac
 915     ## Watch out for a compiler that we know will not work.
 916     case "${canonical}" in
 917      *-solaris* | *-sunos5* )
 918                 if [ "x$CC" = x/usr/ucb/cc ]; then
 919                   ## /usr/ucb/cc doesn't work;
 920                   ## we should find some other compiler that does work.
 921                   unset CC
 922                 fi
 923                 ;;
 924       *) ;;
 925     esac
 926   ;;
 927   sparc-*-nextstep* )
 928     machine=sparc opsys=nextstep
 929   ;;
 930
 931   ## Tadpole 68k
 932   m68*-tadpole-sysv* )
 933     machine=tad68k opsys=usg5-3
 934   ;;
 935
 936   ## Tahoe machines
 937   tahoe-tahoe-bsd4.2* )
 938     machine=tahoe opsys=bsd4-2
 939   ;;
 940   tahoe-tahoe-bsd4.3* )
 941     machine=tahoe opsys=bsd4-3
 942   ;;
 943
 944   ## Tandem Integrity S2
 945   mips-tandem-sysv* )
 946     machine=tandem-s2 opsys=usg5-3
 947   ;;
 948
 949   ## Tektronix XD88
 950   m88k-tektronix-sysv3* )
 951   machine=tekxd88 opsys=usg5-3
 952   ;;
 953
 954   ## Tektronix 16000 box (6130?)
 955   ns16k-tektronix-bsd* )
 956     machine=ns16000 opsys=bsd4-2
 957   ;;
 958   ## Tektronix 4300
 959   ## src/m/tek4300.h hints that this is a m68k machine.
 960   m68*-tektronix-bsd* )
 961     machine=tek4300 opsys=bsd4-3
 962   ;;
 963
 964   ## Titan P2 or P3
 965   ## We seem to have lost the machine-description file titan.h!
 966   titan-titan-sysv* )
 967     machine=titan opsys=usg5-3
 968   ;;
 969
 970   ## Ustation E30 (SS5E)
 971   m68*-unisys-uniplus* )
 972     machine=ustation opsystem=unipl5-2
 973   ;;
 974
 975   ## Vaxen.
 976   vax-dec-* )
 977     machine=vax
 978     case "${canonical}" in
 979       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 980       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 981       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 982       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 983       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 984       *-vms* )                                          opsys=vms ;;
 985       * )                                               unported=yes
 986     esac
 987   ;;
 988
 989   ## Whitechapel MG1
 990   ns16k-whitechapel-* )
 991     machine=mg1
 992     ## We don't know what sort of OS runs on these; we'll let the
 993     ## operating system guessing code below try.
 994   ;;
 995
 996   ## Wicat
 997   m68*-wicat-sysv* )
 998     machine=wicat opsys=usg5-2
 999   ;;
1000
1001   ## IA-64
1002   ia64*-*-linux* )
1003     machine=ia64 opsys=gnu-linux
1004   ;;
1005
1006   ## Intel 386 machines where we don't care about the manufacturer
1007   i[3456]86-*-* )
1008     machine=intel386
1009     case "${canonical}" in
1010       *-lynxos* )               opsys=lynxos ;;
1011       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1012       *-isc2.2* )               opsys=isc2-2 ;;
1013       *-isc4.0* )               opsys=isc4-0 ;;
1014       *-isc4.* )                opsys=isc4-1
1015                                 GCC_TEST_OPTIONS=-posix
1016                                 NON_GCC_TEST_OPTIONS=-Xp
1017                                 ;;
1018       *-isc* )                  opsys=isc3-0 ;;
1019       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1020       *-esix* )                 opsys=esix ;;
1021       *-xenix* )                opsys=xenix ;;
1022       *-linux-gnu* )            opsys=gnu-linux ;;
1023       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
1024       *-sco3.2v5* )             opsys=sco5
1025                                 NON_GNU_CPP=/lib/cpp
1026                                 # Prevent -belf from being passed to $CPP.
1027                                 # /lib/cpp does not accept it.
1028                                 OVERRIDE_CPPFLAGS=" "
1029                                 ;;
1030       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1031       *-386bsd* )               opsys=386bsd ;;
1032       *-freebsd* )              opsys=freebsd ;;
1033       *-nextstep* )             opsys=nextstep ;;
1034       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1035     esac
1036   ;;
1037
1038   ## m68k Linux-based GNU system
1039   m68k-*-linux-gnu* )
1040     machine=m68k opsys=gnu-linux
1041   ;;
1042
1043   ## Mips Linux-based GNU system
1044   mips-*-linux-gnu* )
1045     machine=mips opsys=gnu-linux
1046   ;;
1047
1048   ## UXP/DS
1049   sparc-fujitsu-sysv4* )
1050     machine=sparc opsys=uxpds
1051     NON_GNU_CPP=/usr/ccs/lib/cpp
1052     RANLIB="ar -ts"
1053   ;;
1054
1055   ## UXP/V
1056   f301-fujitsu-uxpv4.1)
1057     machine=f301 opsys=uxpv
1058   ;;
1059
1060   * )
1061     unported=yes
1062   ;;
1063 esac
1064
1065 ### If the code above didn't choose an operating system, just choose
1066 ### an operating system based on the configuration name.  You really
1067 ### only want to use this when you have no idea what the right
1068 ### operating system is; if you know what operating systems a machine
1069 ### runs, it's cleaner to make it explicit in the case statement
1070 ### above.
1071 if test x"${opsys}" = x; then
1072   case "${canonical}" in
1073     *-gnu* )                            opsys=gnu ;;
1074     *-bsd4.[01] )                       opsys=bsd4-1 ;;
1075     *-bsd4.2 )                          opsys=bsd4-2 ;;
1076     *-bsd4.3 )                          opsys=bsd4-3 ;;
1077     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
1078     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
1079     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
1080     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
1081     *-sysv4.2uw* )                      opsys=unixware ;;
1082     *-sysv4.1* | *-sysvr4.1* )
1083         NON_GNU_CPP=/usr/lib/cpp
1084         opsys=usg5-4 ;;
1085     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1086         if [ x$NON_GNU_CPP = x ]; then
1087           if [ -f /usr/ccs/lib/cpp ]; then
1088             NON_GNU_CPP=/usr/ccs/lib/cpp
1089           else
1090             NON_GNU_CPP=/lib/cpp
1091           fi
1092         fi
1093         opsys=usg5-4-2 ;;
1094     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
1095     * )
1096       unported=yes
1097     ;;
1098   esac
1099 fi
1100
1101 changequote([, ])dnl
1102
1103 if test $unported = yes; then
1104   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1105 Check \`etc/MACHINES' for recognized configuration names.])
1106 fi
1107
1108 machfile="m/${machine}.h"
1109 opsysfile="s/${opsys}.h"
1110
1111
1112 #### Choose a compiler.
1113 test -n "$CC" && cc_specified=yes
1114
1115 # Save the value of CFLAGS that the user specified.
1116 SPECIFIED_CFLAGS="$CFLAGS"
1117
1118 case ${with_gcc} in
1119   "yes" ) CC="gcc" GCC=yes ;;
1120   "no"  ) : ${CC=cc} ;;
1121   * ) AC_PROG_CC
1122 esac
1123
1124 # On Suns, sometimes $CPP names a directory.
1125 if test -n "$CPP" && test -d "$CPP"; then
1126   CPP=
1127 fi
1128
1129 #### Some systems specify a CPP to use unless we are using GCC.
1130 #### Now that we know whether we are using GCC, we can decide whether
1131 #### to use that one.
1132 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1133 then
1134   CPP="$NON_GNU_CPP"
1135 fi
1136
1137 #### Some systems specify a CC to use unless we are using GCC.
1138 #### Now that we know whether we are using GCC, we can decide whether
1139 #### to use that one.
1140 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1141   test x$cc_specified != xyes
1142 then
1143   CC="$NON_GNU_CC"
1144 fi
1145
1146 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1147 then
1148   CC="$CC $GCC_TEST_OPTIONS"
1149 fi
1150
1151 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1152 then
1153   CC="$CC $NON_GCC_TEST_OPTIONS"
1154 fi
1155
1156 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1157 then
1158   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1159 fi
1160
1161 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1162 then
1163   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1164 fi
1165
1166 #### Some other nice autoconf tests.  If you add a test here which
1167 #### should make an entry in src/config.h, don't forget to add an
1168 #### #undef clause to src/config.h.in for autoconf to modify.
1169
1170 dnl checks for programs
1171 AC_PROG_LN_S
1172 AC_PROG_CPP
1173 AC_PROG_INSTALL
1174 AC_PROG_YACC
1175 if test "x$RANLIB" = x; then
1176   AC_PROG_RANLIB
1177 fi
1178
1179 dnl checks for Unix variants
1180 AC_AIX
1181
1182 #### Extract some information from the operating system and machine files.
1183
1184 AC_CHECKING([the machine- and system-dependent files to find out
1185  - which libraries the lib-src programs will want, and
1186  - whether the GNU malloc routines are usable])
1187
1188 ### First figure out CFLAGS (which we use for running the compiler here)
1189 ### and REAL_CFLAGS (which we use for real compilation).
1190 ### The two are the same except on a few systems, where they are made
1191 ### different to work around various lossages.  For example,
1192 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1193 ### as implying static linking.
1194
1195 ### If the CFLAGS env var is specified, we use that value
1196 ### instead of the default.
1197
1198 ### It's not important that this name contain the PID; you can't run
1199 ### two configures in the same directory and have anything work
1200 ### anyway.
1201 tempcname="conftest.c"
1202
1203 echo '
1204 #include "'${srcdir}'/src/'${opsysfile}'"
1205 #include "'${srcdir}'/src/'${machfile}'"
1206 #ifndef LIBS_MACHINE
1207 #define LIBS_MACHINE
1208 #endif
1209 #ifndef LIBS_SYSTEM
1210 #define LIBS_SYSTEM
1211 #endif
1212 #ifndef C_SWITCH_SYSTEM
1213 #define C_SWITCH_SYSTEM
1214 #endif
1215 #ifndef C_SWITCH_MACHINE
1216 #define C_SWITCH_MACHINE
1217 #endif
1218 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1219 configure___ c_switch_system=C_SWITCH_SYSTEM
1220 configure___ c_switch_machine=C_SWITCH_MACHINE
1221
1222 #ifndef LIB_X11_LIB
1223 #define LIB_X11_LIB -lX11
1224 #endif
1225
1226 #ifndef LIBX11_MACHINE
1227 #define LIBX11_MACHINE
1228 #endif
1229
1230 #ifndef LIBX11_SYSTEM
1231 #define LIBX11_SYSTEM
1232 #endif
1233 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1234
1235 #ifdef UNEXEC
1236 configure___ unexec=UNEXEC
1237 #else
1238 configure___ unexec=unexec.o
1239 #endif
1240
1241 #ifdef SYSTEM_MALLOC
1242 configure___ system_malloc=yes
1243 #else
1244 configure___ system_malloc=no
1245 #endif
1246
1247 #ifdef USE_MMAP_FOR_BUFFERS
1248 configure___ use_mmap_for_buffers=yes
1249 #else
1250 configure___ use_mmap_for_buffers=no
1251 #endif
1252
1253 #ifndef C_DEBUG_SWITCH
1254 #define C_DEBUG_SWITCH -g
1255 #endif
1256
1257 #ifndef C_OPTIMIZE_SWITCH
1258 #ifdef __GNUC__
1259 #define C_OPTIMIZE_SWITCH -O2
1260 #else
1261 #define C_OPTIMIZE_SWITCH -O
1262 #endif
1263 #endif
1264
1265 #ifndef LD_SWITCH_MACHINE
1266 #define LD_SWITCH_MACHINE
1267 #endif
1268
1269 #ifndef LD_SWITCH_SYSTEM
1270 #define LD_SWITCH_SYSTEM
1271 #endif
1272
1273 #ifndef LD_SWITCH_X_SITE_AUX
1274 #define LD_SWITCH_X_SITE_AUX
1275 #endif
1276
1277 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1278 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1279
1280 #ifdef THIS_IS_CONFIGURE
1281
1282 /* Get the CFLAGS for tests in configure.  */
1283 #ifdef __GNUC__
1284 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1285 #else
1286 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1287 #endif
1288
1289 #else /* not THIS_IS_CONFIGURE */
1290
1291 /* Get the CFLAGS for real compilation.  */
1292 #ifdef __GNUC__
1293 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1294 #else
1295 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1296 #endif
1297
1298 #endif /* not THIS_IS_CONFIGURE */
1299 ' > ${tempcname}
1300
1301 # The value of CPP is a quoted variable reference, so we need to do this
1302 # to get its actual value...
1303 CPP=`eval "echo $CPP"`
1304 changequote(, )dnl
1305 eval `${CPP} -Isrc ${tempcname} \
1306        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1307 if test "x$SPECIFIED_CFLAGS" = x; then
1308   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1309          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1310 else
1311   REAL_CFLAGS="$CFLAGS"
1312 fi
1313 changequote([, ])dnl
1314 rm ${tempcname}
1315
1316 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1317
1318 ### Make sure subsequent tests use flags consistent with the build flags.
1319
1320 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1321   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1322 else
1323   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1324 fi
1325
1326 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1327 AC_SYS_LARGEFILE
1328
1329 # Sound support for GNU/Linux and the free BSDs.
1330 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1331 # Emulation library used on NetBSD.
1332 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1333 AC_SUBST(LIBSOUND)
1334
1335 dnl checks for header files
1336 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1337   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1338   termcap.h stdio_ext.h fcntl.h term.h strings.h)
1339 AC_HEADER_STDC
1340 AC_HEADER_TIME
1341 AC_DECL_SYS_SIGLIST
1342 AC_HEADER_SYS_WAIT
1343
1344 dnl Some systems have utime.h but don't declare the struct anyplace.
1345 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1346 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1347 #include <sys/time.h>
1348 #include <time.h>
1349 #else
1350 #ifdef HAVE_SYS_TIME_H
1351 #include <sys/time.h>
1352 #else
1353 #include <time.h>
1354 #endif
1355 #endif
1356 #ifdef HAVE_UTIME_H
1357 #include <utime.h>
1358 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1359   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1360 if test $emacs_cv_struct_utimbuf = yes; then
1361   AC_DEFINE(HAVE_STRUCT_UTIMBUF)
1362 fi
1363
1364 dnl checks for typedefs
1365 AC_TYPE_SIGNAL
1366
1367 dnl Check for speed_t typedef.
1368 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1369 AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1370   emacs_cv_speed_t=yes, emacs_cv_speed_t=no))
1371 if test $emacs_cv_speed_t = yes; then
1372   AC_DEFINE(HAVE_SPEED_T)
1373 fi
1374
1375 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1376 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1377 #include <sys/time.h>
1378 #include <time.h>
1379 #else
1380 #ifdef HAVE_SYS_TIME_H
1381 #include <sys/time.h>
1382 #else
1383 #include <time.h>
1384 #endif
1385 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1386   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1387 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1388 if test $emacs_cv_struct_timeval = yes; then
1389   AC_DEFINE(HAVE_TIMEVAL)
1390 fi
1391
1392 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1393 AC_TRY_COMPILE([#include <math.h>],
1394 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1395   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1396 HAVE_EXCEPTION=$emacs_cv_struct_exception
1397 if test $emacs_cv_struct_exception != yes; then
1398   AC_DEFINE(NO_MATHERR)
1399 fi
1400
1401 dnl checks for structure members
1402 AC_STRUCT_TM
1403 AC_STRUCT_TIMEZONE
1404 AC_CACHE_CHECK(for tm_gmtoff in struct tm, emacs_cv_tm_gmtoff,
1405 AC_TRY_LINK([#include <time.h>], [struct tm t; t.tm_gmtoff = 0],
1406   emacs_cv_tm_gmtoff=yes,
1407   emacs_cv_tm_gmtoff=no))
1408 if test $emacs_cv_tm_gmtoff = yes; then
1409   AC_DEFINE(HAVE_TM_GMTOFF)
1410 fi
1411
1412 dnl checks for compiler characteristics
1413
1414 dnl Testing __STDC__ to determine prototype support isn't good enough.
1415 dnl DEC C, for instance, doesn't define it with default options, and
1416 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1417 dnl and void *.
1418 AC_C_PROTOTYPES
1419 AC_C_VOLATILE
1420 AC_C_CONST
1421 dnl This isn't useful because we can't turn on use of `inline' unless
1422 dnl the compiler groks `extern inline'.
1423 dnl AC_C_INLINE
1424 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1425   [AC_TRY_COMPILE(, [void * foo;],
1426                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1427 if test $emacs_cv_void_star = yes; then
1428   AC_DEFINE(POINTER_TYPE, void)
1429 else
1430   AC_DEFINE(POINTER_TYPE, char)
1431 fi
1432
1433 dnl check for Make feature
1434 AC_PROG_MAKE_SET
1435
1436 dnl checks for operating system services
1437 AC_SYS_LONG_FILE_NAMES
1438
1439 #### Choose a window system.
1440
1441 AC_PATH_X
1442 if test "$no_x" = yes; then
1443   window_system=none
1444 else
1445   window_system=x11
1446 fi
1447
1448 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1449   LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1450   LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1451   x_default_search_path=""
1452   for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1453     x_search_path="\
1454 ${x_library}/X11/%L/%T/%N%C%S:\
1455 ${x_library}/X11/%l/%T/%N%C%S:\
1456 ${x_library}/X11/%T/%N%C%S:\
1457 ${x_library}/X11/%L/%T/%N%S:\
1458 ${x_library}/X11/%l/%T/%N%S:\
1459 ${x_library}/X11/%T/%N%S"
1460     if test x"${x_default_search_path}" = x; then
1461       x_default_search_path=${x_search_path}
1462     else
1463       x_default_search_path="${x_search_path}:${x_default_search_path}"
1464     fi
1465   done
1466 fi
1467 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1468   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1469 fi
1470
1471 if test x"${x_includes}" = x; then
1472   bitmapdir=/usr/include/X11/bitmaps
1473 else
1474   # accumulate include directories that have X11 bitmap subdirectories
1475   bmd_acc="dummyval"
1476   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1477     if test -d "${bmd}/X11/bitmaps"; then
1478       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1479     fi
1480     if test -d "${bmd}/bitmaps"; then
1481       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1482     fi
1483   done
1484   if test ${bmd_acc} != "dummyval"; then
1485     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1486   fi
1487 fi
1488
1489 case "${window_system}" in
1490   x11 )
1491     HAVE_X_WINDOWS=yes
1492     HAVE_X11=yes
1493     case "${with_x_toolkit}" in
1494       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1495       motif ) USE_X_TOOLKIT=MOTIF ;;
1496 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1497       no ) USE_X_TOOLKIT=none ;;
1498 dnl If user did not say whether to use a toolkit,
1499 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1500       * ) USE_X_TOOLKIT=maybe ;;
1501     esac
1502   ;;
1503   none )
1504     HAVE_X_WINDOWS=no
1505     HAVE_X11=no
1506     USE_X_TOOLKIT=none
1507   ;;
1508 esac
1509
1510 ### If we're using X11, we should use the X menu package.
1511 HAVE_MENUS=no
1512 case ${HAVE_X11} in
1513   yes ) HAVE_MENUS=yes ;;
1514 esac
1515
1516 if test "${opsys}" = "hpux9"; then
1517   case "${x_libraries}" in
1518     *X11R4* )
1519       opsysfile="s/hpux9-x11r4.h"
1520       ;;
1521   esac
1522 fi
1523
1524 if test "${opsys}" = "hpux9shr"; then
1525   case "${x_libraries}" in
1526     *X11R4* )
1527       opsysfile="s/hpux9shxr4.h"
1528       ;;
1529   esac
1530 fi
1531
1532 ### Compute the unexec source name from the object name.
1533 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1534
1535 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1536 # Assume not, until told otherwise.
1537 GNU_MALLOC=yes
1538 doug_lea_malloc=yes
1539 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1540 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1541 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1542                emacs_cv_var___after_morecore_hook,
1543 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1544   emacs_cv_var___after_morecore_hook=yes,
1545   emacs_cv_var___after_morecore_hook=no))
1546 if test $emacs_cv_var___after_morecore_hook = no; then
1547   doug_lea_malloc=no
1548 fi
1549 if test "${system_malloc}" = "yes"; then
1550   GNU_MALLOC=no
1551   GNU_MALLOC_reason="
1552     (The GNU allocators don't work with this system configuration.)"
1553 fi
1554 if test "$doug_lea_malloc" = "yes" ; then
1555   if test "$GNU_MALLOC" = yes ; then
1556     GNU_MALLOC_reason="
1557       (Using Doug Lea's new malloc from the GNU C Library.)"
1558   fi
1559   AC_DEFINE(DOUG_LEA_MALLOC)
1560 fi
1561
1562 if test x"${REL_ALLOC}" = x; then
1563   REL_ALLOC=${GNU_MALLOC}
1564 fi
1565
1566 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1567 dnl the system configuration file (s/*.h) to turn the use of mmap
1568 dnl in the relocating allocator on.
1569
1570 AC_FUNC_MMAP
1571 if test $use_mmap_for_buffers = yes; then
1572   REL_ALLOC=no
1573 fi
1574
1575 LIBS="$libsrc_libs $LIBS"
1576
1577 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1578 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1579 AC_CHECK_LIB(dnet, dnet_ntoa)
1580 dnl This causes -lresolv to get used in subsequent tests,
1581 dnl which causes failures on some systems such as HPUX 9.
1582 dnl AC_CHECK_LIB(resolv, gethostbyname)
1583
1584 dnl FIXME replace main with a function we actually want from this library.
1585 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1586
1587 AC_CHECK_LIB(pthreads, cma_open)
1588
1589 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1590 if test -d /usr/X386/include; then
1591   HAVE_XFREE386=yes
1592   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1593 else
1594   HAVE_XFREE386=no
1595 fi
1596 AC_MSG_RESULT($HAVE_XFREE386)
1597
1598 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1599 # for the tests that follow.  We set it back to REAL_CFLAGS later on.
1600
1601 REAL_CPPFLAGS="$CPPFLAGS"
1602
1603 if test "${HAVE_X11}" = "yes"; then
1604   DEFS="$C_SWITCH_X_SITE $DEFS"
1605   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1606   LIBS="$LIBX $LIBS"
1607   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1608   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1609
1610   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1611   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1612   # but it's more convenient here to set LD_RUN_PATH
1613   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1614   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1615     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1616     export LD_RUN_PATH
1617   fi
1618
1619   if test "${opsys}" = "gnu-linux"; then
1620     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1621     AC_TRY_LINK([],
1622      [XOpenDisplay ("foo");],
1623      [xlinux_first_failure=no],
1624      [xlinux_first_failure=yes])
1625     if test "${xlinux_first_failure}" = "yes"; then
1626       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1627       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1628       OLD_CPPFLAGS="$CPPFLAGS"
1629       OLD_LIBS="$LIBS"
1630       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1631       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1632       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1633       LIBS="$LIBS -b i486-linuxaout"
1634       AC_TRY_LINK([],
1635        [XOpenDisplay ("foo");],
1636        [xlinux_second_failure=no],
1637        [xlinux_second_failure=yes])
1638       if test "${xlinux_second_failure}" = "yes"; then
1639         # If we get the same failure with -b, there is no use adding -b.
1640         # So take it out.  This plays safe.
1641         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1642         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1643         CPPFLAGS="$OLD_CPPFLAGS"
1644         LIBS="$OLD_LIBS"
1645         AC_MSG_RESULT(no)
1646       else
1647         AC_MSG_RESULT(yes)
1648       fi
1649     else
1650       AC_MSG_RESULT(no)
1651     fi
1652   fi
1653
1654   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1655   # header files included from there.
1656   AC_MSG_CHECKING(for Xkb)
1657   AC_TRY_LINK([#include <X11/Xlib.h>
1658 #include <X11/XKBlib.h>],
1659         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1660         emacs_xkb=yes, emacs_xkb=no)
1661   AC_MSG_RESULT($emacs_xkb)
1662   if test $emacs_xkb = yes; then
1663     AC_DEFINE(HAVE_XKBGETKEYBOARD)
1664   fi
1665
1666   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1667 XScreenNumberOfScreen XSetWMProtocols)
1668 fi
1669
1670 if test "${window_system}" = "x11"; then
1671   AC_MSG_CHECKING(X11 version 6)
1672   AC_CACHE_VAL(emacs_cv_x11_version_6,
1673   AC_TRY_LINK([#include <X11/Xlib.h>],
1674 [#if XlibSpecificationRelease < 6
1675 fail;
1676 #endif
1677 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no))
1678   if test $emacs_cv_x11_version_6 = yes; then
1679     AC_MSG_RESULT(6 or newer)
1680     AC_DEFINE(HAVE_X11R6)
1681   else
1682     AC_MSG_RESULT(before 6)
1683   fi
1684 fi
1685
1686 if test "${window_system}" = "x11"; then
1687   AC_MSG_CHECKING(X11 version 5)
1688   AC_CACHE_VAL(emacs_cv_x11_version_5,
1689   AC_TRY_LINK([#include <X11/Xlib.h>],
1690 [#if XlibSpecificationRelease < 5
1691 fail;
1692 #endif
1693 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no))
1694   if test $emacs_cv_x11_version_5 = yes; then
1695     AC_MSG_RESULT(5 or newer)
1696     HAVE_X11R5=yes
1697     AC_DEFINE(HAVE_X11R5)
1698   else
1699     HAVE_X11R5=no
1700     AC_MSG_RESULT(before 5)
1701   fi
1702 fi
1703
1704 dnl Do not put whitespace before the #include statements below.
1705 dnl Older compilers (eg sunos4 cc) choke on it.
1706 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1707   if test x"${HAVE_X11R5}" = xyes; then
1708     AC_MSG_CHECKING(X11 version 5 with Xaw)
1709     AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1710     AC_TRY_LINK([
1711 #include <X11/Intrinsic.h>
1712 #include <X11/Xaw/Simple.h>],
1713       [],
1714       emacs_cv_x11_version_5_with_xaw=yes,
1715       emacs_cv_x11_version_5_with_xaw=no))
1716     if test $emacs_cv_x11_version_5_with_xaw = yes; then
1717       AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1718       USE_X_TOOLKIT=LUCID
1719     else
1720       AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1721       USE_X_TOOLKIT=none
1722     fi
1723   else
1724     USE_X_TOOLKIT=none
1725   fi
1726 fi
1727
1728 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1729
1730 if test "${USE_X_TOOLKIT}" != "none"; then
1731   AC_MSG_CHECKING(X11 toolkit version)
1732   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1733   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1734 [#if XtSpecificationRelease < 6
1735 fail;
1736 #endif
1737 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no))
1738   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1739   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1740     AC_MSG_RESULT(6 or newer)
1741     AC_DEFINE(HAVE_X11XTR6)
1742   else
1743     AC_MSG_RESULT(before 6)
1744   fi
1745
1746 dnl If using toolkit, check whether libXmu.a exists.
1747 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1748   OLDLIBS="$LIBS"
1749   if test x$HAVE_X11XTR6 = xyes; then
1750     LIBS="-lXt -lSM -lICE $LIBS"
1751   else
1752     LIBS="-lXt $LIBS"
1753   fi
1754   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1755   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1756 fi
1757
1758 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1759 if test "${HAVE_X11}" = "yes"; then
1760   if test "${USE_X_TOOLKIT}" != "none"; then
1761     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1762   fi
1763 fi
1764
1765 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1766   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1767   AC_TRY_COMPILE([#include <Xm/Xm.h>],
1768     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1769 int x = 5;
1770 #else
1771 Motif version prior to 2.1.
1772 #endif],
1773     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no))
1774   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1775   if test $emacs_cv_motif_version_2_1 = yes; then
1776     HAVE_LIBXP=no
1777     AC_DEFINE(HAVE_MOTIF_2_1)
1778     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1779     if test ${HAVE_LIBXP} = yes; then
1780       AC_DEFINE(HAVE_LIBXP)
1781     fi
1782   fi
1783 fi
1784
1785 ### Is -lXaw3d available?
1786 HAVE_XAW3D=no
1787 if test "${HAVE_X11}" = "yes"; then
1788   if test "${USE_X_TOOLKIT}" != "none"; then
1789     AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1790         AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes))
1791     if test "${HAVE_XAW3D}" = "yes"; then
1792         AC_DEFINE(HAVE_XAW3D)
1793     fi
1794   fi
1795 fi
1796
1797 dnl Use toolkit scroll bars if configured for X toolkit and either
1798 dnl using Motif or Xaw3d is available, and unless
1799 dnl --with-toolkit-scroll-bars=no was specified.
1800
1801 USE_TOOLKIT_SCROLL_BARS=no
1802 if test "${with_toolkit_scroll_bars}" != "no"; then
1803   if test "${USE_X_TOOLKIT}" != "none"; then
1804     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1805       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1806       HAVE_XAW3D=no
1807       USE_TOOLKIT_SCROLL_BARS=yes
1808     elif test "${HAVE_XAW3D}" = "yes"; then
1809       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1810       USE_TOOLKIT_SCROLL_BARS=yes
1811     fi
1812   fi
1813 fi
1814
1815 dnl Don't use X11 input methods if user specifies he doesn't want it
1816 dnl with `--with-xim=no'.
1817
1818 if test "${with_xim}" != "no"; then
1819   AC_DEFINE(USE_XIM)
1820 fi
1821
1822 ### Use -lXpm if available, unless `--with-xpm=no'.
1823 HAVE_XPM=no
1824 if test "${HAVE_X11}" = "yes"; then
1825   if test "${with_xpm}" != "no"; then
1826     AC_CHECK_HEADER(X11/xpm.h,
1827       AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
1828     if test "${HAVE_XPM}" = "yes"; then
1829       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1830       AC_EGREP_CPP(no_return_alloc_pixels,
1831       [#include "X11/xpm.h"
1832 #ifndef XpmReturnAllocPixels
1833 no_return_alloc_pixels
1834 #endif
1835       ], HAVE_XPM=no, HAVE_XPM=yes)
1836
1837       if test "${HAVE_XPM}" = "yes"; then
1838         AC_MSG_RESULT(yes)
1839       else
1840         AC_MSG_RESULT(no)
1841       fi
1842     fi
1843   fi
1844
1845   if test "${HAVE_XPM}" = "yes"; then
1846     AC_DEFINE(HAVE_XPM)
1847   fi
1848 fi
1849
1850 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1851 HAVE_JPEG=no
1852 if test "${HAVE_X11}" = "yes"; then
1853   if test "${with_jpeg}" != "no"; then
1854     dnl Checking for jpeglib.h can lose becsue of a redefinition of
1855     dnl  HAVE_STDLIB_H.
1856     AC_CHECK_HEADER(jerror.h,
1857       AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
1858   fi
1859
1860   if test "${HAVE_JPEG}" = "yes"; then
1861     AC_DEFINE(HAVE_JPEG)
1862     AC_EGREP_CPP(
1863 changequote({, })dnl avoid leadingspace on the next line
1864 {version= *(6[2-9]|[7-9][0-9])},
1865 changequote([, ])dnl
1866         [#include <jpeglib.h>
1867          version=JPEG_LIB_VERSION
1868 ],
1869         AC_DEFINE(HAVE_JPEG),
1870         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1871         HAVE_JPEG=no])
1872   fi
1873 fi
1874
1875 ### Use -lpng if available, unless `--with-png=no'.
1876 HAVE_PNG=no
1877 if test "${HAVE_X11}" = "yes"; then
1878   if test "${with_png}" != "no"; then
1879     AC_CHECK_HEADER(png.h,
1880       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm))
1881   fi
1882
1883   if test "${HAVE_PNG}" = "yes"; then
1884     AC_DEFINE(HAVE_PNG)
1885   fi
1886 fi
1887
1888 ### Use -ltiff if available, unless `--with-tiff=no'.
1889 HAVE_TIFF=no
1890 if test "${HAVE_X11}" = "yes"; then
1891   if test "${with_tiff}" != "no"; then
1892     AC_CHECK_HEADER(tiffio.h,
1893       tifflibs="-lz -lm"
1894       # At least one tiff package requires the jpeg library.
1895       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1896       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
1897   fi
1898
1899   if test "${HAVE_TIFF}" = "yes"; then
1900     AC_DEFINE(HAVE_TIFF)
1901   fi
1902 fi
1903
1904 ### Use -lgif if available, unless `--with-gif=no'.
1905 HAVE_GIF=no
1906 if test "${HAVE_X11}" = "yes"; then
1907   if test "${with_gif}" != "no"; then
1908     AC_CHECK_HEADER(gif_lib.h,
1909 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
1910 # Earlier versions can crash Emacs.
1911       AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
1912   fi
1913
1914   if test "${HAVE_GIF}" = "yes"; then
1915     AC_DEFINE(HAVE_GIF)
1916   fi
1917 fi
1918
1919 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1920 AC_CACHE_CHECK(whether netdb declares h_errno,
1921                emacs_cv_netdb_declares_h_errno,
1922 AC_TRY_LINK([#include <netdb.h>],
1923   [return h_errno;],
1924   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no))
1925 if test $emacs_cv_netdb_declares_h_errno = yes; then
1926   AC_DEFINE(HAVE_H_ERRNO)
1927 fi
1928
1929 AC_FUNC_ALLOCA
1930
1931 # fmod, logb, and frexp are found in -lm on most systems.
1932 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1933 AC_CHECK_LIB(m, sqrt)
1934
1935 # Check for mail-locking functions in a "mail" library
1936 AC_CHECK_LIB(mail, maillock)
1937 dnl Debian, at least:
1938 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
1939 AC_CHECK_LIB(lockfile, maillock)
1940 # If we have the shared liblockfile, assume we must use it for mail
1941 # locking (e.g. Debian).  If we couldn't link against liblockfile
1942 # (no liblockfile.a installed), ensure that we don't need to.
1943 if test "$ac_cv_lib_lockfile_maillock" = no; then
1944   dnl This works for files generally, not just executables.
1945   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
1946   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
1947                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
1948   if test $ac_cv_prog_liblockfile = yes; then
1949     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
1950 This probably means that movemail could lose mail.
1951 There may be a \`development' package to install containing liblockfile.])
1952   else AC_DEFINE(LIBMAIL, -llockfile)
1953   fi
1954   else :
1955 fi
1956 AC_CHECK_FUNCS(touchlock)
1957 AC_CHECK_HEADERS(maillock.h)
1958
1959 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
1960 rename closedir mkdir rmdir sysinfo \
1961 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
1962 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
1963 utimes setrlimit setpgid getcwd getwd shutdown strftime getaddrinfo \
1964 __fpending mblen mbrlen strsignal setitimer ualarm index rindex \
1965 gai_strerror mkstemp)
1966
1967 AC_FUNC_MKTIME
1968 if test "$ac_cv_func_working_mktime" = no; then
1969   AC_DEFINE(BROKEN_MKTIME)
1970 fi
1971
1972 AC_FUNC_GETLOADAVG
1973
1974 AC_FUNC_FSEEKO
1975
1976 # UNIX98 PTYs.
1977 AC_CHECK_FUNCS(grantpt)
1978
1979 # PTY-related GNU extensions.
1980 AC_CHECK_FUNCS(getpt)
1981
1982 # Check this now, so that we will NOT find the above functions in ncurses.
1983 # That is because we have not set up to link ncurses in lib-src.
1984 # It's better to believe a function is not available
1985 # than to expect to find it in ncurses.
1986 AC_CHECK_LIB(ncurses, tparm)
1987
1988 # Do we need the Hesiod library to provide the support routines?
1989 if test "$with_hesiod" = yes ; then
1990   # Don't set $LIBS here -- see comments above.
1991   resolv=no
1992   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
1993      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
1994                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
1995   if test "$resolv" = yes ; then
1996     RESOLVLIB=-lresolv
1997     AC_DEFINE(HAVE_LIBRESOLV)
1998   else
1999     RESOLVLIB=
2000   fi
2001   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2002         AC_DEFINE(HAVE_LIBHESIOD), :, $RESOLVLIB)])
2003 fi
2004
2005 # These tell us which Kerberos-related libraries to use.
2006 if test "${with_kerberos+set}" = set; then
2007   AC_CHECK_LIB(com_err, com_err)
2008   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2009   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2010   AC_CHECK_LIB(krb5, krb5_init_context)
2011   if test "${with_kerberos5+set}" != set; then
2012     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2013                  AC_CHECK_LIB(des, des_cbc_encrypt))
2014     AC_CHECK_LIB(krb4, krb_get_cred,,
2015                  AC_CHECK_LIB(krb, krb_get_cred))
2016   fi
2017
2018   if test "${with_kerberos5+set}" = set; then
2019     AC_CHECK_HEADERS(krb5.h)
2020   else
2021     AC_CHECK_HEADERS(des.h,,
2022                      AC_CHECK_HEADERS(kerberosIV/des.h,,
2023                                       AC_CHECK_HEADERS(kerberos/des.h)))
2024     AC_CHECK_HEADERS(krb.h,,
2025                      AC_CHECK_HEADERS(kerberosIV/krb.h,,
2026                                       AC_CHECK_HEADERS(kerberos/krb.h)))
2027   fi
2028   AC_CHECK_HEADERS(com_err.h)
2029 fi
2030
2031 # Solaris requires -lintl if you want strerror (which calls dgettext)
2032 # to return localized messages.
2033 AC_CHECK_LIB(intl, dgettext)
2034
2035 AC_MSG_CHECKING(whether localtime caches TZ)
2036 AC_CACHE_VAL(emacs_cv_localtime_cache,
2037 [if test x$ac_cv_func_tzset = xyes; then
2038 AC_TRY_RUN([#include <time.h>
2039 extern char **environ;
2040 unset_TZ ()
2041 {
2042   char **from, **to;
2043   for (to = from = environ; (*to = *from); from++)
2044     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2045       to++;
2046 }
2047 char TZ_GMT0[] = "TZ=GMT0";
2048 char TZ_PST8[] = "TZ=PST8";
2049 main()
2050 {
2051   time_t now = time ((time_t *) 0);
2052   int hour_GMT0, hour_unset;
2053   if (putenv (TZ_GMT0) != 0)
2054     exit (1);
2055   hour_GMT0 = localtime (&now)->tm_hour;
2056   unset_TZ ();
2057   hour_unset = localtime (&now)->tm_hour;
2058   if (putenv (TZ_PST8) != 0)
2059     exit (1);
2060   if (localtime (&now)->tm_hour == hour_GMT0)
2061     exit (1);
2062   unset_TZ ();
2063   if (localtime (&now)->tm_hour != hour_unset)
2064     exit (1);
2065   exit (0);
2066 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2067 [# If we have tzset, assume the worst when cross-compiling.
2068 emacs_cv_localtime_cache=yes])
2069 else
2070         # If we lack tzset, report that localtime does not cache TZ,
2071         # since we can't invalidate the cache if we don't have tzset.
2072         emacs_cv_localtime_cache=no
2073 fi])dnl
2074 AC_MSG_RESULT($emacs_cv_localtime_cache)
2075 if test $emacs_cv_localtime_cache = yes; then
2076   AC_DEFINE(LOCALTIME_CACHE)
2077 fi
2078
2079 if test "x$HAVE_TIMEVAL" = xyes; then
2080   AC_CHECK_FUNCS(gettimeofday)
2081   AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2082                  emacs_cv_gettimeofday_two_arguments,
2083   AC_TRY_COMPILE([
2084 #ifdef TIME_WITH_SYS_TIME
2085 #include <sys/time.h>
2086 #include <time.h>
2087 #else
2088 #ifdef HAVE_SYS_TIME_H
2089 #include <sys/time.h>
2090 #else
2091 #include <time.h>
2092 #endif
2093 #endif],
2094     [struct timeval time;
2095      gettimeofday (&time, 0);],
2096     emacs_cv_gettimeofday_two_arguments=yes,
2097     emacs_cv_gettimeofday_two_arguments=no))
2098   if test $emacs_cv_gettimeofday_two_arguments = no; then
2099     AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)
2100   fi
2101 fi
2102
2103 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2104 if test "$ac_cv_func_gettimeofday" = yes; then
2105   AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2106     [AC_TRY_COMPILE([#include <sys/time.h>],
2107     [struct timezone tz;],
2108     dnl It may be that we can't call gettimeofday with a non-null pointer,
2109     dnl even though we have struct timezone (e.g. HPUX).  In that case
2110     dnl we'll lie about struct timezone.
2111     [AC_TRY_RUN([
2112 #ifdef TIME_WITH_SYS_TIME
2113 #include <sys/time.h>
2114 #include <time.h>
2115 #else
2116 #ifdef HAVE_SYS_TIME_H
2117 #include <sys/time.h>
2118 #else
2119 #include <time.h>
2120 #endif
2121 #endif
2122 main () {
2123   struct timeval time;
2124   struct timezone dummy;
2125   exit (gettimeofday (&time, &dummy));
2126 }],
2127       emacs_cv_struct_timezone=yes,
2128       emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2129     emacs_cv_struct_timezone=no)])
2130 fi
2131
2132 ok_so_far=yes
2133 AC_CHECK_FUNC(socket, , ok_so_far=no)
2134 if test $ok_so_far = yes; then
2135   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2136 fi
2137 if test $ok_so_far = yes; then
2138   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2139 fi
2140 if test $ok_so_far = yes; then
2141   AC_DEFINE(HAVE_INET_SOCKETS)
2142 fi
2143
2144 if test -f /usr/lpp/X11/bin/smt.exp; then
2145   AC_DEFINE(HAVE_AIX_SMT_EXP)
2146 fi
2147
2148 AC_MSG_CHECKING(whether system supports dynamic ptys)
2149 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2150   AC_MSG_RESULT(yes)
2151   AC_DEFINE(HAVE_DEV_PTMX)
2152 else
2153   AC_MSG_RESULT(no)
2154 fi
2155
2156 AC_FUNC_VFORK
2157
2158 # Fixme: This should be replaced when we have autoconf 2.14.
2159 AC_SIZE_T
2160
2161 # Set up the CFLAGS for real compilation, so we can substitute it.
2162 CFLAGS="$REAL_CFLAGS"
2163 CPPFLAGS="$REAL_CPPFLAGS"
2164
2165 changequote(, )dnl
2166 #### Find out which version of Emacs this is.
2167 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
2168          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
2169 changequote([, ])dnl
2170 if test x"${version}" = x; then
2171   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
2172 fi
2173
2174 ### Specify what sort of things we'll be editing into Makefile and config.h.
2175 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2176 AC_SUBST(version)
2177 AC_SUBST(configuration)
2178 AC_SUBST(canonical)
2179 AC_SUBST(srcdir)
2180 AC_SUBST(prefix)
2181 AC_SUBST(exec_prefix)
2182 AC_SUBST(bindir)
2183 AC_SUBST(datadir)
2184 AC_SUBST(sharedstatedir)
2185 AC_SUBST(libexecdir)
2186 AC_SUBST(mandir)
2187 AC_SUBST(infodir)
2188 AC_SUBST(lispdir)
2189 AC_SUBST(locallisppath)
2190 AC_SUBST(lisppath)
2191 AC_SUBST(x_default_search_path)
2192 AC_SUBST(etcdir)
2193 AC_SUBST(archlibdir)
2194 AC_SUBST(docdir)
2195 AC_SUBST(bitmapdir)
2196 AC_SUBST(c_switch_system)
2197 AC_SUBST(c_switch_machine)
2198 AC_SUBST(LD_SWITCH_X_SITE)
2199 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2200 AC_SUBST(C_SWITCH_X_SITE)
2201 AC_SUBST(CFLAGS)
2202 AC_SUBST(X_TOOLKIT_TYPE)
2203 AC_SUBST(machfile)
2204 AC_SUBST(opsysfile)
2205 AC_SUBST(GETLOADAVG_LIBS)
2206
2207 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
2208 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
2209 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
2210 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
2211 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
2212 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
2213 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
2214 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
2215
2216 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2217   AC_DEFINE(HAVE_X_WINDOWS)
2218 fi
2219 if test "${USE_X_TOOLKIT}" != "none" ; then
2220   AC_DEFINE(USE_X_TOOLKIT)
2221 fi
2222 if test "${HAVE_X11}" = "yes" ; then
2223   AC_DEFINE(HAVE_X11)
2224 fi
2225 if test "${HAVE_XFREE386}" = "yes" ; then
2226   AC_DEFINE(HAVE_XFREE386)
2227 fi
2228 if test "${HAVE_MENUS}" = "yes" ; then
2229   AC_DEFINE(HAVE_MENUS)
2230 fi
2231 if test "${GNU_MALLOC}" = "yes" ; then
2232   AC_DEFINE(GNU_MALLOC)
2233 fi
2234 if test "${REL_ALLOC}" = "yes" ; then
2235   AC_DEFINE(REL_ALLOC)
2236 fi
2237
2238 #### Report on what we decided to do.
2239 echo "
2240 Configured for \`${canonical}'.
2241
2242   Where should the build process find the source code?    ${srcdir}
2243   What operating system and machine description files should Emacs use?
2244         \`${opsysfile}' and \`${machfile}'
2245   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2246   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2247   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2248   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2249   What window system should Emacs use?                    ${window_system}
2250   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2251
2252 if test -n "${x_includes}"; then
2253 echo "  Where do we find X Windows header files?                ${x_includes}"
2254 else
2255 echo "  Where do we find X Windows header files?                Standard dirs"
2256 fi
2257 if test -n "${x_libraries}"; then
2258 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2259 else
2260 echo "  Where do we find X Windows libraries?                   Standard dirs"
2261 fi
2262
2263 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2264 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2265 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2266 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2267 echo "  Does Emacs use -lungif?                                 ${HAVE_GIF}"
2268 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2269 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
2270 echo
2271
2272 # Remove any trailing slashes in these variables.
2273 changequote(, )dnl
2274 test "${prefix}" != NONE &&
2275   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2276 test "${exec_prefix}" != NONE &&
2277   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
2278 changequote([, ])dnl
2279
2280 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2281 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2282 ## from Makefile.c can correctly provide the arg `-traditional' to the
2283 ## C preprocessor.
2284
2285 AC_EGREP_CPP(yes..yes,
2286         [yes..yes],
2287         CPP_NEED_TRADITIONAL=no,
2288         CPP_NEED_TRADITIONAL=yes)
2289
2290 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2291         man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2292         lisp/Makefile leim/Makefile, [
2293
2294 ### Make the necessary directories, if they don't exist.
2295 for dir in etc lisp ; do
2296   test -d ${dir} || mkdir ${dir}
2297 done
2298
2299 # Build src/Makefile from ${srcdir}/src/Makefile.c
2300 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2301 # This must be done after src/config.h is built, since we rely on that file.
2302
2303 changequote(, )dnl The horror, the horror.
2304 # Now get this: Some word that is part of the ${srcdir} directory name
2305 # or the ${configuration} value might, just might, happen to be an
2306 # identifier like `sun4' or `i386' or something, and be predefined by
2307 # the C preprocessor to some helpful value like 1, or maybe the empty
2308 # string.  Needless to say consequent macro substitutions are less
2309 # than conducive to the makefile finding the correct directory.
2310 undefs="`echo $top_srcdir $configuration $canonical |
2311 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2312     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2313 `"
2314 changequote([, ])dnl
2315
2316 echo creating src/epaths.h
2317 ${MAKE-make} epaths-force
2318
2319 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2320 # `..' to `. .'  unless invoked with -traditional
2321
2322 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2323   CPPFLAGS="$CPPFLAGS -traditional"
2324 fi
2325
2326 echo creating lib-src/Makefile
2327 ( cd lib-src
2328   rm -f junk.c junk1.c junk2.c
2329   sed -e '/start of cpp stuff/q' \
2330       < Makefile.c > junk1.c
2331   sed -e '1,/start of cpp stuff/d'\
2332       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2333       < Makefile.c > junk.c
2334   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2335       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2336   cat junk1.c junk2.c > Makefile.new
2337   rm -f junk.c junk1.c junk2.c
2338   chmod 444 Makefile.new
2339   mv -f Makefile.new Makefile
2340 )
2341
2342 echo creating src/Makefile
2343 ( cd src
2344   rm -f junk.c junk1.c junk2.c
2345   sed -e '/start of cpp stuff/q' \
2346       < Makefile.c > junk1.c
2347   sed -e '1,/start of cpp stuff/d'\
2348       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2349       < Makefile.c > junk.c
2350   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2351       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2352   cat junk1.c junk2.c > Makefile.new
2353   rm -f junk.c junk1.c junk2.c
2354   chmod 444 Makefile.new
2355   mv -f Makefile.new Makefile
2356 )
2357
2358 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
2359   echo creating src/.gdbinit
2360   echo source $top_srcdir/src/.gdbinit > src/.gdbinit
2361 fi
2362
2363 # This is how we know whether to re-run configure in certain cases.
2364 touch src/config.stamp
2365
2366 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
2367