lisp/textmodes/page.el

   1 ;;; page.el --- page motion commands for emacs.
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; This code provides the page-oriented movement and selection commands
  26 ;; documented in the Emacs manual.
  27
  28 ;;; Code:
  29
  30 (defun forward-page (&optional count)
  31   "Move forward to page boundary.  With arg, repeat, or go back if negative.
  32 A page boundary is any line whose beginning matches the regexp
  33 `page-delimiter'."
  34   (interactive "p")
  35   (or count (setq count 1))
  36   (while (and (> count 0) (not (eobp)))
  37     ;; In case the page-delimiter matches the null string,
  38     ;; don't find a match without moving.
  39     (if (bolp) (forward-char 1))
  40     (if (re-search-forward page-delimiter nil t)
  41         nil
  42       (goto-char (point-max)))
  43     (setq count (1- count)))
  44   (while (and (< count 0) (not (bobp)))
  45     (forward-char -1)
  46     (if (re-search-backward page-delimiter nil t)
  47         (goto-char (match-end 0))
  48       (goto-char (point-min)))
  49     (setq count (1+ count))))
  50
  51 (defun backward-page (&optional count)
  52   "Move backward to page boundary.  With arg, repeat, or go fwd if negative.
  53 A page boundary is any line whose beginning matches the regexp
  54 `page-delimiter'."
  55   (interactive "p")
  56   (or count (setq count 1))
  57   (forward-page (- count)))
  58
  59 (defun mark-page (&optional arg)
  60   "Put mark at end of page, point at beginning.
  61 A numeric arg specifies to move forward or backward by that many pages,
  62 thus marking a page other than the one point was originally in."
  63   (interactive "P")
  64   (setq arg (if arg (prefix-numeric-value arg) 0))
  65   (if (> arg 0)
  66       (forward-page arg)
  67     (if (< arg 0)
  68         (forward-page (1- arg))))
  69   (forward-page)
  70   (push-mark nil t t)
  71   (forward-page -1))
  72
  73 (defun narrow-to-page (&optional arg)
  74   "Make text outside current page invisible.
  75 A numeric arg specifies to move forward or backward by that many pages,
  76 thus showing a page other than the one point was originally in."
  77   (interactive "P")
  78   (setq arg (if arg (prefix-numeric-value arg) 0))
  79   (save-excursion
  80     (widen)
  81     (if (> arg 0)
  82         (forward-page arg)
  83       (if (< arg 0)
  84           (forward-page (1- arg))))
  85     ;; Find the end of the page.
  86     (forward-page)
  87     ;; If we stopped due to end of buffer, stay there.
  88     ;; If we stopped after a page delimiter, put end of restriction
  89     ;; at the beginning of that line.
  90     (if (save-excursion
  91           (goto-char (match-beginning 0)) ; was (beginning-of-line)
  92           (looking-at page-delimiter))
  93         (beginning-of-line))
  94     (narrow-to-region (point)
  95                       (progn
  96                         ;; Find the top of the page.
  97                         (forward-page -1)
  98                         ;; If we found beginning of buffer, stay there.
  99                         ;; If extra text follows page delimiter on same line,
 100                         ;; include it.
 101                         ;; Otherwise, show text starting with following line.
 102                         (if (and (eolp) (not (bobp)))
 103                             (forward-line 1))
 104                         (point)))))
 105 (put 'narrow-to-page 'disabled t)
 106
 107 (defun count-lines-page ()
 108   "Report number of lines on current page, and how many are before or after point."
 109   (interactive)
 110   (save-excursion
 111     (let ((opoint (point)) beg end
 112           total before after)
 113       (forward-page)
 114       (beginning-of-line)
 115       (or (looking-at page-delimiter)
 116           (end-of-line))
 117       (setq end (point))
 118       (backward-page)
 119       (setq beg (point))
 120       (setq total (count-lines beg end)
 121             before (count-lines beg opoint)
 122             after (count-lines opoint end))
 123       (message "Page has %d lines (%d + %d)" total before after))))
 124
 125 (defun what-page ()
 126   "Print page and line number of point."
 127   (interactive)
 128   (save-restriction
 129     (widen)
 130     (save-excursion
 131       (beginning-of-line)
 132       (let ((count 1)
 133             (opoint (point)))
 134         (goto-char 1)
 135         (while (re-search-forward page-delimiter opoint t)
 136           (setq count (1+ count)))
 137         (message "Page %d, line %d"
 138                  count
 139                  (1+ (count-lines (point) opoint)))))))
 140 \f
 141 ;;; Place `provide' at end of file.
 142 (provide 'page)
 143
 144 ;;; page.el ends here