lisp/tar-mode.el

   1 ;;; tar-mode.el --- simple editing of tar files from GNU emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2000, 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Jamie Zawinski <jwz@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 04 Apr 1990
   9 ;; Keywords: unix
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package attempts to make dealing with Unix 'tar' archives easier.
  31 ;; When this code is loaded, visiting a file whose name ends in '.tar' will
  32 ;; cause the contents of that archive file to be displayed in a Dired-like
  33 ;; listing.  It is then possible to use the customary Dired keybindings to
  34 ;; extract sub-files from that archive, either by reading them into their own
  35 ;; editor buffers, or by copying them directly to arbitrary files on disk.
  36 ;; It is also possible to delete sub-files from within the tar file and write
  37 ;; the modified archive back to disk, or to edit sub-files within the archive
  38 ;; and re-insert the modified files into the archive.  See the documentation
  39 ;; string of tar-mode for more info.
  40
  41 ;; This code now understands the extra fields that GNU tar adds to tar files.
  42
  43 ;; This interacts correctly with "uncompress.el" in the Emacs library,
  44 ;; which you get with
  45 ;;
  46 ;;  (autoload 'uncompress-while-visiting "uncompress")
  47 ;;  (setq auto-mode-alist (cons '("\\.Z$" . uncompress-while-visiting)
  48 ;;                         auto-mode-alist))
  49 ;;
  50 ;; Do not attempt to use tar-mode.el with crypt.el, you will lose.
  51
  52 ;;    ***************   TO DO   ***************
  53 ;;
  54 ;; o  chmod should understand "a+x,og-w".
  55 ;;
  56 ;; o  It's not possible to add a NEW file to a tar archive; not that
  57 ;;    important, but still...
  58 ;;
  59 ;; o  The code is less efficient that it could be - in a lot of places, I
  60 ;;    pull a 512-character string out of the buffer and parse it, when I could
  61 ;;    be parsing it in place, not garbaging a string.  Should redo that.
  62 ;;
  63 ;; o  I'd like a command that searches for a string/regexp in every subfile
  64 ;;    of an archive, where <esc> would leave you in a subfile-edit buffer.
  65 ;;    (Like the Meta-R command of the Zmacs mail reader.)
  66 ;;
  67 ;; o  Sometimes (but not always) reverting the tar-file buffer does not
  68 ;;    re-grind the listing, and you are staring at the binary tar data.
  69 ;;    Typing 'g' again immediately after that will always revert and re-grind
  70 ;;    it, though.  I have no idea why this happens.
  71 ;;
  72 ;; o  Tar-mode interacts poorly with crypt.el and zcat.el because the tar
  73 ;;    write-file-hook actually writes the file.  Instead it should remove the
  74 ;;    header (and conspire to put it back afterwards) so that other write-file
  75 ;;    hooks which frob the buffer have a chance to do their dirty work.  There
  76 ;;    might be a problem if the tar write-file-hook does not come *first* on
  77 ;;    the list.
  78 ;;
  79 ;; o  Block files, sparse files, continuation files, and the various header
  80 ;;    types aren't editable.  Actually I don't know that they work at all.
  81
  82 ;; Rationale:
  83
  84 ;; Why does tar-mode edit the file itself instead of using tar?
  85
  86 ;; That means that you can edit tar files which you don't have room for
  87 ;; on your local disk.
  88
  89 ;; I don't know about recent features in gnu tar, but old versions of tar
  90 ;; can't replace a file in the middle of a tar file with a new version.
  91 ;; Tar-mode can.  I don't think tar can do things like chmod the subfiles.
  92 ;; An implementation which involved unpacking and repacking the file into
  93 ;; some scratch directory would be very wasteful, and wouldn't be able to
  94 ;; preserve the file owners.
  95
  96 ;;; Code:
  97
  98 (defgroup tar nil
  99   "Simple editing of tar files."
 100   :prefix "tar-"
 101   :group 'data)
 102
 103 (defcustom tar-anal-blocksize 20
 104   "*The blocksize of tar files written by Emacs, or nil, meaning don't care.
 105 The blocksize of a tar file is not really the size of the blocks; rather, it is
 106 the number of blocks written with one system call.  When tarring to a tape,
 107 this is the size of the *tape* blocks, but when writing to a file, it doesn't
 108 matter much.  The only noticeable difference is that if a tar file does not
 109 have a blocksize of 20, tar will tell you that; all this really controls is
 110 how many null padding bytes go on the end of the tar file."
 111   :type '(choice integer (const nil))
 112   :group 'tar)
 113
 114 (defcustom tar-update-datestamp nil
 115   "*Non-nil means Tar mode should play fast and loose with sub-file datestamps.
 116 If this is true, then editing and saving a tar file entry back into its
 117 tar file will update its datestamp.  If false, the datestamp is unchanged.
 118 You may or may not want this - it is good in that you can tell when a file
 119 in a tar archive has been changed, but it is bad for the same reason that
 120 editing a file in the tar archive at all is bad - the changed version of
 121 the file never exists on disk."
 122   :type 'boolean
 123   :group 'tar)
 124
 125 (defcustom tar-mode-show-date nil
 126   "*Non-nil means Tar mode should show the date/time of each subfile.
 127 This information is useful, but it takes screen space away from file names."
 128   :type 'boolean
 129   :group 'tar)
 130
 131 (defvar tar-parse-info nil)
 132 ;; Be sure that this variable holds byte position, not char position.
 133 (defvar tar-header-offset nil)
 134 (defvar tar-superior-buffer nil)
 135 (defvar tar-superior-descriptor nil)
 136 (defvar tar-subfile-mode nil)
 137
 138 (put 'tar-parse-info 'permanent-local t)
 139 (put 'tar-header-offset 'permanent-local t)
 140 (put 'tar-superior-buffer 'permanent-local t)
 141 (put 'tar-superior-descriptor 'permanent-local t)
 142 \f
 143 (defmacro tar-setf (form val)
 144   "A mind-numbingly simple implementation of setf."
 145   (let ((mform (macroexpand form (and (boundp 'byte-compile-macro-environment)
 146                                       byte-compile-macro-environment))))
 147     (cond ((symbolp mform) (list 'setq mform val))
 148           ((not (consp mform)) (error "can't setf %s" form))
 149           ((eq (car mform) 'aref)
 150            (list 'aset (nth 1 mform) (nth 2 mform) val))
 151           ((eq (car mform) 'car)
 152            (list 'setcar (nth 1 mform) val))
 153           ((eq (car mform) 'cdr)
 154            (list 'setcdr (nth 1 mform) val))
 155           (t (error "don't know how to setf %s" form)))))
 156 \f
 157 ;;; down to business.
 158
 159 (defmacro make-tar-header (name mode uid git size date ck lt ln
 160                            magic uname gname devmaj devmin)
 161   (list 'vector name mode uid git size date ck lt ln
 162         magic uname gname devmaj devmin))
 163
 164 (defmacro tar-header-name (x) (list 'aref x 0))
 165 (defmacro tar-header-mode (x) (list 'aref x 1))
 166 (defmacro tar-header-uid  (x) (list 'aref x 2))
 167 (defmacro tar-header-gid  (x) (list 'aref x 3))
 168 (defmacro tar-header-size (x) (list 'aref x 4))
 169 (defmacro tar-header-date (x) (list 'aref x 5))
 170 (defmacro tar-header-checksum  (x) (list 'aref x 6))
 171 (defmacro tar-header-link-type (x) (list 'aref x 7))
 172 (defmacro tar-header-link-name (x) (list 'aref x 8))
 173 (defmacro tar-header-magic (x) (list 'aref x 9))
 174 (defmacro tar-header-uname (x) (list 'aref x 10))
 175 (defmacro tar-header-gname (x) (list 'aref x 11))
 176 (defmacro tar-header-dmaj (x) (list 'aref x 12))
 177 (defmacro tar-header-dmin (x) (list 'aref x 13))
 178
 179 (defmacro make-tar-desc (data-start tokens)
 180   (list 'cons data-start tokens))
 181
 182 (defmacro tar-desc-data-start (x) (list 'car x))
 183 (defmacro tar-desc-tokens     (x) (list 'cdr x))
 184
 185 (defconst tar-name-offset 0)
 186 (defconst tar-mode-offset (+ tar-name-offset 100))
 187 (defconst tar-uid-offset  (+ tar-mode-offset 8))
 188 (defconst tar-gid-offset  (+ tar-uid-offset 8))
 189 (defconst tar-size-offset (+ tar-gid-offset 8))
 190 (defconst tar-time-offset (+ tar-size-offset 12))
 191 (defconst tar-chk-offset  (+ tar-time-offset 12))
 192 (defconst tar-linkp-offset (+ tar-chk-offset 8))
 193 (defconst tar-link-offset (+ tar-linkp-offset 1))
 194 ;;; GNU-tar specific slots.
 195 (defconst tar-magic-offset (+ tar-link-offset 100))
 196 (defconst tar-uname-offset (+ tar-magic-offset 8))
 197 (defconst tar-gname-offset (+ tar-uname-offset 32))
 198 (defconst tar-dmaj-offset (+ tar-gname-offset 32))
 199 (defconst tar-dmin-offset (+ tar-dmaj-offset 8))
 200 (defconst tar-end-offset (+ tar-dmin-offset 8))
 201
 202 (defun tar-header-block-tokenize (string)
 203   "Return a `tar-header' structure.
 204 This is a list of name, mode, uid, gid, size,
 205 write-date, checksum, link-type, and link-name."
 206   (cond ((< (length string) 512) nil)
 207         (;(some 'plusp string)           ; <-- oops, massive cycle hog!
 208          (or (not (= 0 (aref string 0))) ; This will do.
 209              (not (= 0 (aref string 101))))
 210          (let* ((name-end (1- tar-mode-offset))
 211                 (link-end (1- tar-magic-offset))
 212                 (uname-end (1- tar-gname-offset))
 213                 (gname-end (1- tar-dmaj-offset))
 214                 (link-p (aref string tar-linkp-offset))
 215                 (magic-str (substring string tar-magic-offset (1- tar-uname-offset)))
 216                 (uname-valid-p (or (string= "ustar  " magic-str) (string= "GNUtar " magic-str)))
 217                 name linkname
 218                 (nulsexp   "[^\000]*\000"))
 219            (when (string-match nulsexp string tar-name-offset)
 220              (setq name-end (min name-end (1- (match-end 0)))))
 221            (when (string-match nulsexp string tar-link-offset)
 222              (setq link-end (min link-end (1- (match-end 0)))))
 223            (when (string-match nulsexp string tar-uname-offset)
 224              (setq uname-end (min uname-end (1- (match-end 0)))))
 225            (when (string-match nulsexp string tar-gname-offset)
 226              (setq gname-end (min gname-end (1- (match-end 0)))))
 227            (setq name (substring string tar-name-offset name-end)
 228                  link-p (if (or (= link-p 0) (= link-p ?0))
 229                             nil
 230                           (- link-p ?0)))
 231            (setq linkname (substring string tar-link-offset link-end))
 232            (if default-enable-multibyte-characters
 233                (setq name
 234                      (decode-coding-string name (or file-name-coding-system
 235                                                     'undecided))
 236                      linkname
 237                      (decode-coding-string linkname (or file-name-coding-system
 238                                                         'undecided))))
 239            (if (and (null link-p) (string-match "/$" name)) (setq link-p 5)) ; directory
 240            (make-tar-header
 241              name
 242              (tar-parse-octal-integer string tar-mode-offset tar-uid-offset)
 243              (tar-parse-octal-integer string tar-uid-offset tar-gid-offset)
 244              (tar-parse-octal-integer string tar-gid-offset tar-size-offset)
 245              (tar-parse-octal-integer string tar-size-offset tar-time-offset)
 246              (tar-parse-octal-long-integer string tar-time-offset tar-chk-offset)
 247              (tar-parse-octal-integer string tar-chk-offset tar-linkp-offset)
 248              link-p
 249              linkname
 250              uname-valid-p
 251              (and uname-valid-p (substring string tar-uname-offset uname-end))
 252              (and uname-valid-p (substring string tar-gname-offset gname-end))
 253              (tar-parse-octal-integer string tar-dmaj-offset tar-dmin-offset)
 254              (tar-parse-octal-integer string tar-dmin-offset tar-end-offset)
 255              )))
 256         (t 'empty-tar-block)))
 257
 258
 259 (defun tar-parse-octal-integer (string &optional start end)
 260   (if (null start) (setq start 0))
 261   (if (null end) (setq end (length string)))
 262   (if (= (aref string start) 0)
 263       0
 264     (let ((n 0))
 265       (while (< start end)
 266         (setq n (if (< (aref string start) ?0) n
 267                   (+ (* n 8) (- (aref string start) ?0)))
 268               start (1+ start)))
 269       n)))
 270
 271 (defun tar-parse-octal-long-integer (string &optional start end)
 272   (if (null start) (setq start 0))
 273   (if (null end) (setq end (length string)))
 274   (if (= (aref string start) 0)
 275       (list 0 0)
 276     (let ((lo 0)
 277           (hi 0))
 278       (while (< start end)
 279         (if (>= (aref string start) ?0)
 280             (setq lo (+ (* lo 8) (- (aref string start) ?0))
 281                   hi (+ (* hi 8) (ash lo -16))
 282                   lo (logand lo 65535)))
 283         (setq start (1+ start)))
 284       (list hi lo))))
 285
 286 (defun tar-parse-octal-integer-safe (string)
 287   (let ((L (length string)))
 288     (if (= L 0) (error "empty string"))
 289     (dotimes (i L)
 290        (if (or (< (aref string i) ?0)
 291                (> (aref string i) ?7))
 292            (error "`%c' is not an octal digit" (aref string i)))))
 293   (tar-parse-octal-integer string))
 294
 295
 296 (defun tar-header-block-checksum (string)
 297   "Compute and return a tar-acceptable checksum for this block."
 298   (let* ((chk-field-start tar-chk-offset)
 299          (chk-field-end (+ chk-field-start 8))
 300          (sum 0)
 301          (i 0))
 302     ;; Add up all of the characters except the ones in the checksum field.
 303     ;; Add that field as if it were filled with spaces.
 304     (while (< i chk-field-start)
 305       (setq sum (+ sum (aref string i))
 306             i (1+ i)))
 307     (setq i chk-field-end)
 308     (while (< i 512)
 309       (setq sum (+ sum (aref string i))
 310             i (1+ i)))
 311     (+ sum (* 32 8))))
 312
 313 (defun tar-header-block-check-checksum (hblock desired-checksum file-name)
 314   "Beep and print a warning if the checksum doesn't match."
 315   (if (not (= desired-checksum (tar-header-block-checksum hblock)))
 316       (progn (beep) (message "Invalid checksum for file %s!" file-name))))
 317
 318 (defun tar-clip-time-string (time)
 319   (let ((str (current-time-string time)))
 320     (concat " " (substring str 4 16) (substring str 19 24))))
 321
 322 (defun tar-grind-file-mode (mode)
 323   "Construct a `-rw--r--r--' string indicating MODE.
 324 MODE should be an integer which is a file mode value."
 325   (string
 326    (if (zerop (logand 256 mode)) ?- ?r)
 327    (if (zerop (logand 128 mode)) ?- ?w)
 328    (if (zerop (logand 1024 mode)) (if (zerop (logand  64 mode)) ?- ?x) ?s)
 329    (if (zerop (logand  32 mode)) ?- ?r)
 330    (if (zerop (logand  16 mode)) ?- ?w)
 331    (if (zerop (logand 2048 mode)) (if (zerop (logand   8 mode)) ?- ?x) ?s)
 332    (if (zerop (logand   4 mode)) ?- ?r)
 333    (if (zerop (logand   2 mode)) ?- ?w)
 334    (if (zerop (logand   1 mode)) ?- ?x)))
 335
 336 (defun tar-header-block-summarize (tar-hblock &optional mod-p)
 337   "Return a line similar to the output of `tar -vtf'."
 338   (let ((name (tar-header-name tar-hblock))
 339         (mode (tar-header-mode tar-hblock))
 340         (uid (tar-header-uid tar-hblock))
 341         (gid (tar-header-gid tar-hblock))
 342         (uname (tar-header-uname tar-hblock))
 343         (gname (tar-header-gname tar-hblock))
 344         (size (tar-header-size tar-hblock))
 345         (time (tar-header-date tar-hblock))
 346         (ck (tar-header-checksum tar-hblock))
 347         (type (tar-header-link-type tar-hblock))
 348         (link-name (tar-header-link-name tar-hblock)))
 349     (format "%c%c%s%8s/%-8s%7s%s %s%s"
 350             (if mod-p ?* ? )
 351             (cond ((or (eq type nil) (eq type 0)) ?-)
 352                   ((eq type 1) ?h)      ; link
 353                   ((eq type 2) ?l)      ; symlink
 354                   ((eq type 3) ?c)      ; char special
 355                   ((eq type 4) ?b)      ; block special
 356                   ((eq type 5) ?d)      ; directory
 357                   ((eq type 6) ?p)      ; FIFO/pipe
 358                   ((eq type 20) ?*)     ; directory listing
 359                   ((eq type 28) ?L)     ; next has longname
 360                   ((eq type 29) ?M)     ; multivolume continuation
 361                   ((eq type 35) ?S)     ; sparse
 362                   ((eq type 38) ?V)     ; volume header
 363                   (t ?\ )
 364                   )
 365             (tar-grind-file-mode mode)
 366             (if (= 0 (length uname)) uid uname)
 367             (if (= 0 (length gname)) gid gname)
 368             size
 369             (if tar-mode-show-date (tar-clip-time-string time) "")
 370             (propertize name
 371                         'mouse-face 'highlight
 372                         'help-echo "mouse-2: extract this file into a buffer")
 373             (if (or (eq type 1) (eq type 2))
 374                 (concat (if (= type 1) " ==> " " --> ") link-name)
 375               ""))))
 376
 377 (defun tar-untar-buffer ()
 378   "Extract all archive members in the tar-file into the current directory."
 379   (interactive)
 380   (let ((multibyte enable-multibyte-characters))
 381     (unwind-protect
 382         (save-restriction
 383           (widen)
 384           (set-buffer-multibyte nil)
 385           (dolist (descriptor tar-parse-info)
 386             (let* ((tokens (tar-desc-tokens descriptor))
 387                    (name (tar-header-name tokens))
 388                    (dir (file-name-directory name))
 389                    (start (+ (tar-desc-data-start descriptor)
 390                              (- tar-header-offset (point-min))))
 391                    (end (+ start (tar-header-size tokens))))
 392               (unless (file-directory-p name)
 393                 (message "Extracting %s" name)
 394                 (if (and dir (not (file-exists-p dir)))
 395                     (make-directory dir t))
 396                 (unless (file-directory-p name)
 397                   (write-region start end name))
 398                 (set-file-modes name (tar-header-mode tokens))))))
 399       (set-buffer-multibyte multibyte))))
 400
 401 (defun tar-summarize-buffer ()
 402   "Parse the contents of the tar file in the current buffer.
 403 Place a dired-like listing on the front;
 404 then narrow to it, so that only that listing
 405 is visible (and the real data of the buffer is hidden)."
 406   (set-buffer-multibyte nil)
 407   (let* ((result '())
 408          (pos (point-min))
 409          (progress-reporter
 410           (make-progress-reporter "Parsing tar file..."
 411                                   (point-min) (max 1 (- (buffer-size) 1024))))
 412          tokens)
 413     (while (and (<= (+ pos 512) (point-max))
 414                 (not (eq 'empty-tar-block
 415                          (setq tokens
 416                                (tar-header-block-tokenize
 417                                 (buffer-substring pos (+ pos 512)))))))
 418       (setq pos (+ pos 512))
 419       (progress-reporter-update progress-reporter pos)
 420       (if (eq (tar-header-link-type tokens) 20)
 421           ;; Foo.  There's an extra empty block after these.
 422           (setq pos (+ pos 512)))
 423       (let ((size (tar-header-size tokens)))
 424         (if (< size 0)
 425             (error "%s has size %s - corrupted"
 426                    (tar-header-name tokens) size))
 427         ;
 428         ; This is just too slow.  Don't really need it anyway....
 429         ;(tar-header-block-check-checksum
 430         ;  hblock (tar-header-block-checksum hblock)
 431         ;  (tar-header-name tokens))
 432
 433         (setq result (cons (make-tar-desc pos tokens) result))
 434
 435         (and (null (tar-header-link-type tokens))
 436              (> size 0)
 437              (setq pos
 438                    (+ pos 512 (ash (ash (1- size) -9) 9))        ; this works
 439                    ;(+ pos (+ size (- 512 (rem (1- size) 512)))) ; this doesn't
 440                    ))))
 441     (make-local-variable 'tar-parse-info)
 442     (setq tar-parse-info (nreverse result))
 443     ;; A tar file should end with a block or two of nulls,
 444     ;; but let's not get a fatal error if it doesn't.
 445     (if (eq tokens 'empty-tar-block)
 446         (progress-reporter-done progress-reporter)
 447       (message "Warning: premature EOF parsing tar file")))
 448   (save-excursion
 449     (goto-char (point-min))
 450     (let ((buffer-read-only nil)
 451           (summaries nil))
 452       ;; Collect summary lines and insert them all at once since tar files
 453       ;; can be pretty big.
 454       (dolist (tar-desc (reverse tar-parse-info))
 455         (setq summaries
 456               (cons (tar-header-block-summarize (tar-desc-tokens tar-desc))
 457                     (cons "\n"
 458                           summaries))))
 459       (let ((total-summaries (apply 'concat summaries)))
 460         (if (multibyte-string-p total-summaries)
 461             (set-buffer-multibyte t))
 462         (insert total-summaries))
 463       (make-local-variable 'tar-header-offset)
 464       (setq tar-header-offset (point))
 465       (narrow-to-region (point-min) tar-header-offset)
 466       (if enable-multibyte-characters
 467           (setq tar-header-offset (position-bytes tar-header-offset)))
 468       (set-buffer-modified-p nil))))
 469 \f
 470 (defvar tar-mode-map nil "*Local keymap for Tar mode listings.")
 471
 472 (if tar-mode-map
 473     nil
 474   (setq tar-mode-map (make-keymap))
 475   (suppress-keymap tar-mode-map)
 476   (define-key tar-mode-map " " 'tar-next-line)
 477   (define-key tar-mode-map "C" 'tar-copy)
 478   (define-key tar-mode-map "d" 'tar-flag-deleted)
 479   (define-key tar-mode-map "\^D" 'tar-flag-deleted)
 480   (define-key tar-mode-map "e" 'tar-extract)
 481   (define-key tar-mode-map "f" 'tar-extract)
 482   (define-key tar-mode-map "\C-m" 'tar-extract)
 483   (define-key tar-mode-map [mouse-2] 'tar-mouse-extract)
 484   (define-key tar-mode-map "g" 'revert-buffer)
 485   (define-key tar-mode-map "h" 'describe-mode)
 486   (define-key tar-mode-map "n" 'tar-next-line)
 487   (define-key tar-mode-map "\^N" 'tar-next-line)
 488   (define-key tar-mode-map [down] 'tar-next-line)
 489   (define-key tar-mode-map "o" 'tar-extract-other-window)
 490   (define-key tar-mode-map "p" 'tar-previous-line)
 491   (define-key tar-mode-map "q" 'quit-window)
 492   (define-key tar-mode-map "\^P" 'tar-previous-line)
 493   (define-key tar-mode-map [up] 'tar-previous-line)
 494   (define-key tar-mode-map "R" 'tar-rename-entry)
 495   (define-key tar-mode-map "u" 'tar-unflag)
 496   (define-key tar-mode-map "v" 'tar-view)
 497   (define-key tar-mode-map "x" 'tar-expunge)
 498   (define-key tar-mode-map "\177" 'tar-unflag-backwards)
 499   (define-key tar-mode-map "E" 'tar-extract-other-window)
 500   (define-key tar-mode-map "M" 'tar-chmod-entry)
 501   (define-key tar-mode-map "G" 'tar-chgrp-entry)
 502   (define-key tar-mode-map "O" 'tar-chown-entry)
 503   )
 504 \f
 505 ;; Make menu bar items.
 506
 507 ;; Get rid of the Edit menu bar item to save space.
 508 (define-key tar-mode-map [menu-bar edit] 'undefined)
 509
 510 (define-key tar-mode-map [menu-bar immediate]
 511   (cons "Immediate" (make-sparse-keymap "Immediate")))
 512
 513 (define-key tar-mode-map [menu-bar immediate view]
 514   '("View This File" . tar-view))
 515 (define-key tar-mode-map [menu-bar immediate display]
 516   '("Display in Other Window" . tar-display-other-window))
 517 (define-key tar-mode-map [menu-bar immediate find-file-other-window]
 518   '("Find in Other Window" . tar-extract-other-window))
 519 (define-key tar-mode-map [menu-bar immediate find-file]
 520   '("Find This File" . tar-extract))
 521
 522 (define-key tar-mode-map [menu-bar mark]
 523   (cons "Mark" (make-sparse-keymap "Mark")))
 524
 525 (define-key tar-mode-map [menu-bar mark unmark-all]
 526   '("Unmark All" . tar-clear-modification-flags))
 527 (define-key tar-mode-map [menu-bar mark deletion]
 528   '("Flag" . tar-flag-deleted))
 529 (define-key tar-mode-map [menu-bar mark unmark]
 530   '("Unflag" . tar-unflag))
 531
 532 (define-key tar-mode-map [menu-bar operate]
 533   (cons "Operate" (make-sparse-keymap "Operate")))
 534
 535 (define-key tar-mode-map [menu-bar operate chown]
 536   '("Change Owner..." . tar-chown-entry))
 537 (define-key tar-mode-map [menu-bar operate chgrp]
 538   '("Change Group..." . tar-chgrp-entry))
 539 (define-key tar-mode-map [menu-bar operate chmod]
 540   '("Change Mode..." . tar-chmod-entry))
 541 (define-key tar-mode-map [menu-bar operate rename]
 542   '("Rename to..." . tar-rename-entry))
 543 (define-key tar-mode-map [menu-bar operate copy]
 544   '("Copy to..." . tar-copy))
 545 (define-key tar-mode-map [menu-bar operate expunge]
 546   '("Expunge Marked Files" . tar-expunge))
 547 \f
 548 ;; tar mode is suitable only for specially formatted data.
 549 (put 'tar-mode 'mode-class 'special)
 550 (put 'tar-subfile-mode 'mode-class 'special)
 551
 552 ;;;###autoload
 553 (define-derived-mode tar-mode nil "Tar"
 554   "Major mode for viewing a tar file as a dired-like listing of its contents.
 555 You can move around using the usual cursor motion commands.
 556 Letters no longer insert themselves.
 557 Type `e' to pull a file out of the tar file and into its own buffer;
 558 or click mouse-2 on the file's line in the Tar mode buffer.
 559 Type `c' to copy an entry from the tar file into another file on disk.
 560
 561 If you edit a sub-file of this archive (as with the `e' command) and
 562 save it with Control-x Control-s, the contents of that buffer will be
 563 saved back into the tar-file buffer; in this way you can edit a file
 564 inside of a tar archive without extracting it and re-archiving it.
 565
 566 See also: variables `tar-update-datestamp' and `tar-anal-blocksize'.
 567 \\{tar-mode-map}"
 568   ;; this is not interactive because you shouldn't be turning this
 569   ;; mode on and off.  You can corrupt things that way.
 570   ;; rms: with permanent locals, it should now be possible to make this work
 571   ;; interactively in some reasonable fashion.
 572   (make-local-variable 'tar-header-offset)
 573   (make-local-variable 'tar-parse-info)
 574   (set (make-local-variable 'require-final-newline) nil) ; binary data, dude...
 575   (set (make-local-variable 'revert-buffer-function) 'tar-mode-revert)
 576   (set (make-local-variable 'local-enable-local-variables) nil)
 577   (set (make-local-variable 'next-line-add-newlines) nil)
 578   ;; Prevent loss of data when saving the file.
 579   (set (make-local-variable 'file-precious-flag) t)
 580   (auto-save-mode 0)
 581   (set (make-local-variable 'write-contents-functions) '(tar-mode-write-file))
 582   (buffer-disable-undo)
 583   (widen)
 584   (if (and (boundp 'tar-header-offset) tar-header-offset)
 585       (narrow-to-region (point-min) (byte-to-position tar-header-offset))
 586     (tar-summarize-buffer)
 587     (tar-next-line 0)))
 588
 589
 590 (defun tar-subfile-mode (p)
 591   "Minor mode for editing an element of a tar-file.
 592 This mode arranges for \"saving\" this buffer to write the data
 593 into the tar-file buffer that it came from.  The changes will actually
 594 appear on disk when you save the tar-file's buffer."
 595   (interactive "P")
 596   (or (and (boundp 'tar-superior-buffer) tar-superior-buffer)
 597       (error "This buffer is not an element of a tar file"))
 598   ;; Don't do this, because it is redundant and wastes mode line space.
 599   ;;  (or (assq 'tar-subfile-mode minor-mode-alist)
 600   ;;      (setq minor-mode-alist (append minor-mode-alist
 601   ;;                                 (list '(tar-subfile-mode " TarFile")))))
 602   (make-local-variable 'tar-subfile-mode)
 603   (setq tar-subfile-mode
 604         (if (null p)
 605             (not tar-subfile-mode)
 606             (> (prefix-numeric-value p) 0)))
 607   (cond (tar-subfile-mode
 608          (add-hook 'write-file-functions 'tar-subfile-save-buffer nil t)
 609          ;; turn off auto-save.
 610          (auto-save-mode -1)
 611          (setq buffer-auto-save-file-name nil)
 612          (run-hooks 'tar-subfile-mode-hook))
 613         (t
 614          (remove-hook 'write-file-functions 'tar-subfile-save-buffer t))))
 615
 616
 617 ;; Revert the buffer and recompute the dired-like listing.
 618 (defun tar-mode-revert (&optional no-auto-save no-confirm)
 619   (let ((revert-buffer-function nil)
 620         (old-offset tar-header-offset)
 621         success)
 622     (setq tar-header-offset nil)
 623     (unwind-protect
 624         (and (revert-buffer t no-confirm)
 625              (progn (widen)
 626                     (setq success t)
 627                     (tar-mode)))
 628       ;; If the revert was canceled,
 629       ;; put back the old value of tar-header-offset.
 630       (or success
 631           (setq tar-header-offset old-offset)))))
 632
 633
 634 (defun tar-next-line (arg)
 635   "Move cursor vertically down ARG lines and to the start of the filename."
 636   (interactive "p")
 637   (forward-line arg)
 638   (if (eobp) nil (forward-char (if tar-mode-show-date 54 36))))
 639
 640 (defun tar-previous-line (arg)
 641   "Move cursor vertically up ARG lines and to the start of the filename."
 642   (interactive "p")
 643   (tar-next-line (- arg)))
 644
 645 (defun tar-current-descriptor (&optional noerror)
 646   "Return the tar-descriptor of the current line, or signals an error."
 647   ;; I wish lines had plists, like in ZMACS...
 648   (or (nth (count-lines (point-min)
 649                         (save-excursion (beginning-of-line) (point)))
 650            tar-parse-info)
 651       (if noerror
 652           nil
 653           (error "This line does not describe a tar-file entry"))))
 654
 655 (defun tar-get-descriptor ()
 656   (let* ((descriptor (tar-current-descriptor))
 657          (tokens (tar-desc-tokens descriptor))
 658          (size (tar-header-size tokens))
 659          (link-p (tar-header-link-type tokens)))
 660     (if link-p
 661         (error "This is a %s, not a real file"
 662                (cond ((eq link-p 5) "directory")
 663                      ((eq link-p 20) "tar directory header")
 664                      ((eq link-p 28) "next has longname")
 665                      ((eq link-p 29) "multivolume-continuation")
 666                      ((eq link-p 35) "sparse entry")
 667                      ((eq link-p 38) "volume header")
 668                      (t "link"))))
 669     (if (zerop size) (error "This is a zero-length file"))
 670     descriptor))
 671
 672 (defun tar-mouse-extract (event)
 673   "Extract a file whose tar directory line you click on."
 674   (interactive "e")
 675   (save-excursion
 676     (set-buffer (window-buffer (posn-window (event-end event))))
 677     (save-excursion
 678       (goto-char (posn-point (event-end event)))
 679       ;; Just make sure this doesn't get an error.
 680       (tar-get-descriptor)))
 681   (select-window (posn-window (event-end event)))
 682   (goto-char (posn-point (event-end event)))
 683   (tar-extract))
 684
 685 (defun tar-extract (&optional other-window-p)
 686   "In Tar mode, extract this entry of the tar file into its own buffer."
 687   (interactive)
 688   (let* ((view-p (eq other-window-p 'view))
 689          (descriptor (tar-get-descriptor))
 690          (tokens (tar-desc-tokens descriptor))
 691          (name (tar-header-name tokens))
 692          (size (tar-header-size tokens))
 693          (start (+ (tar-desc-data-start descriptor)
 694                    (- tar-header-offset (point-min))))
 695          (end (+ start size)))
 696     (let* ((tar-buffer (current-buffer))
 697            (tar-buffer-multibyte enable-multibyte-characters)
 698            (tarname (buffer-name))
 699            (bufname (concat (file-name-nondirectory name)
 700                             " ("
 701                              tarname
 702                              ")"))
 703            (read-only-p (or buffer-read-only view-p))
 704            (new-buffer-file-name (expand-file-name
 705                                   ;; `:' is not allowed on Windows
 706                                   (concat tarname "!" name)))
 707            (buffer (get-file-buffer new-buffer-file-name))
 708            (just-created nil))
 709       (unless buffer
 710         (setq buffer (generate-new-buffer bufname))
 711         (setq bufname (buffer-name buffer))
 712         (setq just-created t)
 713         (unwind-protect
 714             (progn
 715               (widen)
 716               (set-buffer-multibyte nil)
 717               (save-excursion
 718                 (set-buffer buffer)
 719                 (let ((buffer-undo-list t))
 720                   (if enable-multibyte-characters
 721                       (progn
 722                         ;; We must avoid unibyte->multibyte conversion.
 723                         (set-buffer-multibyte nil)
 724                         (insert-buffer-substring tar-buffer start end)
 725                         (set-buffer-multibyte t))
 726                     (insert-buffer-substring tar-buffer start end))
 727                   (goto-char (point-min))
 728                   (setq buffer-file-name new-buffer-file-name)
 729                   (setq buffer-file-truename
 730                         (abbreviate-file-name buffer-file-name))
 731                   ;; We need to mimic the parts of insert-file-contents
 732                   ;; which determine the coding-system and decode the text.
 733                   (let ((coding
 734                          (or coding-system-for-read
 735                              (and set-auto-coding-function
 736                                   (save-excursion
 737                                     (funcall set-auto-coding-function
 738                                              name (- (point-max) (point)))))
 739                              (car (find-operation-coding-system
 740                                    'insert-file-contents name t))))
 741                         (multibyte enable-multibyte-characters)
 742                         (detected (detect-coding-region
 743                                    (point-min)
 744                                    (min (+ (point-min) 16384) (point-max)) t)))
 745                     (if coding
 746                         (or (numberp (coding-system-eol-type coding))
 747                             (vectorp (coding-system-eol-type detected))
 748                             (setq coding (coding-system-change-eol-conversion
 749                                           coding
 750                                           (coding-system-eol-type detected))))
 751                       (setq coding
 752                             (find-new-buffer-file-coding-system detected)))
 753                     (if (or (eq coding 'no-conversion)
 754                             (eq (coding-system-type coding) 5))
 755                         (setq multibyte (set-buffer-multibyte nil)))
 756                     (or multibyte
 757                         (setq coding
 758                               (coding-system-change-text-conversion
 759                                coding 'raw-text)))
 760                     (decode-coding-region (point-min) (point-max) coding)
 761                     (set-buffer-file-coding-system coding))
 762                   ;; Set the default-directory to the dir of the
 763                   ;; superior buffer.
 764                   (setq default-directory
 765                         (save-excursion
 766                           (set-buffer tar-buffer)
 767                           default-directory))
 768                   (normal-mode)  ; pick a mode.
 769                   (rename-buffer bufname)
 770                   (make-local-variable 'tar-superior-buffer)
 771                   (make-local-variable 'tar-superior-descriptor)
 772                   (setq tar-superior-buffer tar-buffer)
 773                   (setq tar-superior-descriptor descriptor)
 774                   (setq buffer-read-only read-only-p)
 775                   (set-buffer-modified-p nil))
 776                 (tar-subfile-mode 1))
 777               (set-buffer tar-buffer))
 778           (narrow-to-region (point-min) tar-header-offset)
 779           (set-buffer-multibyte tar-buffer-multibyte)))
 780       (if view-p
 781           (view-buffer buffer (and just-created 'kill-buffer))
 782         (if (eq other-window-p 'display)
 783             (display-buffer buffer)
 784           (if other-window-p
 785               (switch-to-buffer-other-window buffer)
 786             (switch-to-buffer buffer)))))))
 787
 788
 789 (defun tar-extract-other-window ()
 790   "*In Tar mode, find this entry of the tar file in another window."
 791   (interactive)
 792   (tar-extract t))
 793
 794 (defun tar-display-other-window ()
 795   "*In Tar mode, display this entry of the tar file in another window."
 796   (interactive)
 797   (tar-extract 'display))
 798
 799 (defun tar-view ()
 800   "*In Tar mode, view the tar file entry on this line."
 801   (interactive)
 802   (tar-extract 'view))
 803
 804
 805 (defun tar-read-file-name (&optional prompt)
 806   "Read a file name with this line's entry as the default."
 807   (or prompt (setq prompt "Copy to: "))
 808   (let* ((default-file (expand-file-name
 809                         (tar-header-name (tar-desc-tokens
 810                                           (tar-current-descriptor)))))
 811          (target (expand-file-name
 812                   (read-file-name prompt
 813                                   (file-name-directory default-file)
 814                                   default-file nil))))
 815     (if (or (string= "" (file-name-nondirectory target))
 816             (file-directory-p target))
 817         (setq target (concat (if (string-match "/$" target)
 818                                  (substring target 0 (1- (match-end 0)))
 819                                  target)
 820                              "/"
 821                              (file-name-nondirectory default-file))))
 822     target))
 823
 824
 825 (defun tar-copy (&optional to-file)
 826   "*In Tar mode, extract this entry of the tar file into a file on disk.
 827 If TO-FILE is not supplied, it is prompted for, defaulting to the name of
 828 the current tar-entry."
 829   (interactive (list (tar-read-file-name)))
 830   (let* ((descriptor (tar-get-descriptor))
 831          (tokens (tar-desc-tokens descriptor))
 832          (name (tar-header-name tokens))
 833          (size (tar-header-size tokens))
 834          (start (+ (tar-desc-data-start descriptor)
 835                    (- tar-header-offset (point-min))))
 836          (end (+ start size))
 837          (multibyte enable-multibyte-characters)
 838          (inhibit-file-name-handlers inhibit-file-name-handlers)
 839          (inhibit-file-name-operation inhibit-file-name-operation))
 840     (save-restriction
 841       (widen)
 842       ;; Inhibit compressing a subfile again if *both* name and
 843       ;; to-file are handled by jka-compr
 844       (if (and (eq (find-file-name-handler name 'write-region) 'jka-compr-handler)
 845                (eq (find-file-name-handler to-file 'write-region) 'jka-compr-handler))
 846           (setq inhibit-file-name-handlers
 847                 (cons 'jka-compr-handler
 848                       (and (eq inhibit-file-name-operation 'write-region)
 849                            inhibit-file-name-handlers))
 850                 inhibit-file-name-operation 'write-region))
 851       (unwind-protect
 852           (let ((coding-system-for-write 'no-conversion))
 853             (set-buffer-multibyte nil)
 854             (write-region start end to-file nil nil nil t))
 855         (set-buffer-multibyte multibyte)))
 856     (message "Copied tar entry %s to %s" name to-file)))
 857
 858 (defun tar-flag-deleted (p &optional unflag)
 859   "*In Tar mode, mark this sub-file to be deleted from the tar file.
 860 With a prefix argument, mark that many files."
 861   (interactive "p")
 862   (beginning-of-line)
 863   (dotimes (i (if (< p 0) (- p) p))
 864     (if (tar-current-descriptor unflag) ; barf if we're not on an entry-line.
 865         (progn
 866           (delete-char 1)
 867           (insert (if unflag " " "D"))))
 868     (forward-line (if (< p 0) -1 1)))
 869   (if (eobp) nil (forward-char 36)))
 870
 871 (defun tar-unflag (p)
 872   "*In Tar mode, un-mark this sub-file if it is marked to be deleted.
 873 With a prefix argument, un-mark that many files forward."
 874   (interactive "p")
 875   (tar-flag-deleted p t))
 876
 877 (defun tar-unflag-backwards (p)
 878   "*In Tar mode, un-mark this sub-file if it is marked to be deleted.
 879 With a prefix argument, un-mark that many files backward."
 880   (interactive "p")
 881   (tar-flag-deleted (- p) t))
 882
 883
 884 ;; When this function is called, it is sure that the buffer is unibyte.
 885 (defun tar-expunge-internal ()
 886   "Expunge the tar-entry specified by the current line."
 887   (let* ((descriptor (tar-current-descriptor))
 888          (tokens (tar-desc-tokens descriptor))
 889          (line (tar-desc-data-start descriptor))
 890          (name (tar-header-name tokens))
 891          (size (tar-header-size tokens))
 892          (link-p (tar-header-link-type tokens))
 893          (start (tar-desc-data-start descriptor))
 894          (following-descs (cdr (memq descriptor tar-parse-info))))
 895     (if link-p (setq size 0)) ; size lies for hard-links.
 896     ;;
 897     ;; delete the current line...
 898     (beginning-of-line)
 899     (let ((line-start (point)))
 900       (end-of-line) (forward-char)
 901       (let ((line-len (- (point) line-start)))
 902         (delete-region line-start (point))
 903         ;;
 904         ;; decrement the header-pointer to be in sync...
 905         (setq tar-header-offset (- tar-header-offset line-len))))
 906     ;;
 907     ;; delete the data pointer...
 908     (setq tar-parse-info (delq descriptor tar-parse-info))
 909     ;;
 910     ;; delete the data from inside the file...
 911     (widen)
 912     (let* ((data-start (+ start tar-header-offset -513))
 913            (data-end (+ data-start 512 (ash (ash (+ size 511) -9) 9))))
 914       (delete-region data-start data-end)
 915       ;;
 916       ;; and finally, decrement the start-pointers of all following
 917       ;; entries in the archive.  This is a pig when deleting a bunch
 918       ;; of files at once - we could optimize this to only do the
 919       ;; iteration over the files that remain, or only iterate up to
 920       ;; the next file to be deleted.
 921       (let ((data-length (- data-end data-start)))
 922         (dolist (desc following-descs)
 923           (tar-setf (tar-desc-data-start desc)
 924                     (- (tar-desc-data-start desc) data-length))))
 925       ))
 926   (narrow-to-region (point-min) tar-header-offset))
 927
 928
 929 (defun tar-expunge (&optional noconfirm)
 930   "*In Tar mode, delete all the archived files flagged for deletion.
 931 This does not modify the disk image; you must save the tar file itself
 932 for this to be permanent."
 933   (interactive)
 934   (if (or noconfirm
 935           (y-or-n-p "Expunge files marked for deletion? "))
 936       (let ((n 0)
 937             (multibyte enable-multibyte-characters))
 938         (set-buffer-multibyte nil)
 939         (save-excursion
 940           (goto-char (point-min))
 941           (while (not (eobp))
 942             (if (looking-at "D")
 943                 (progn (tar-expunge-internal)
 944                        (setq n (1+ n)))
 945                 (forward-line 1)))
 946           ;; after doing the deletions, add any padding that may be necessary.
 947           (tar-pad-to-blocksize)
 948           (narrow-to-region (point-min) tar-header-offset))
 949         (set-buffer-multibyte multibyte)
 950         (if (zerop n)
 951             (message "Nothing to expunge.")
 952             (message "%s files expunged.  Be sure to save this buffer." n)))))
 953
 954
 955 (defun tar-clear-modification-flags ()
 956   "Remove the stars at the beginning of each line."
 957   (interactive)
 958   (save-excursion
 959     (goto-char (point-min))
 960     (while (< (position-bytes (point)) tar-header-offset)
 961       (if (not (eq (following-char) ?\ ))
 962           (progn (delete-char 1) (insert " ")))
 963       (forward-line 1))))
 964
 965
 966 (defun tar-chown-entry (new-uid)
 967   "*Change the user-id associated with this entry in the tar file.
 968 If this tar file was written by GNU tar, then you will be able to edit
 969 the user id as a string; otherwise, you must edit it as a number.
 970 You can force editing as a number by calling this with a prefix arg.
 971 This does not modify the disk image; you must save the tar file itself
 972 for this to be permanent."
 973   (interactive (list
 974                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
 975                    (if (or current-prefix-arg
 976                            (not (tar-header-magic tokens)))
 977                        (let (n)
 978                          (while (not (numberp (setq n (read-minibuffer
 979                                                         "New UID number: "
 980                                                         (format "%s" (tar-header-uid tokens)))))))
 981                          n)
 982                        (read-string "New UID string: " (tar-header-uname tokens))))))
 983   (cond ((stringp new-uid)
 984          (tar-setf (tar-header-uname (tar-desc-tokens (tar-current-descriptor)))
 985                    new-uid)
 986          (tar-alter-one-field tar-uname-offset (concat new-uid "\000")))
 987         (t
 988          (tar-setf (tar-header-uid (tar-desc-tokens (tar-current-descriptor)))
 989                    new-uid)
 990          (tar-alter-one-field tar-uid-offset
 991            (concat (substring (format "%6o" new-uid) 0 6) "\000 ")))))
 992
 993
 994 (defun tar-chgrp-entry (new-gid)
 995   "*Change the group-id associated with this entry in the tar file.
 996 If this tar file was written by GNU tar, then you will be able to edit
 997 the group id as a string; otherwise, you must edit it as a number.
 998 You can force editing as a number by calling this with a prefix arg.
 999 This does not modify the disk image; you must save the tar file itself
1000 for this to be permanent."
1001   (interactive (list
1002                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
1003                    (if (or current-prefix-arg
1004                            (not (tar-header-magic tokens)))
1005                        (let (n)
1006                          (while (not (numberp (setq n (read-minibuffer
1007                                                         "New GID number: "
1008                                                         (format "%s" (tar-header-gid tokens)))))))
1009                          n)
1010                        (read-string "New GID string: " (tar-header-gname tokens))))))
1011   (cond ((stringp new-gid)
1012          (tar-setf (tar-header-gname (tar-desc-tokens (tar-current-descriptor)))
1013                    new-gid)
1014          (tar-alter-one-field tar-gname-offset
1015            (concat new-gid "\000")))
1016         (t
1017          (tar-setf (tar-header-gid (tar-desc-tokens (tar-current-descriptor)))
1018                    new-gid)
1019          (tar-alter-one-field tar-gid-offset
1020            (concat (substring (format "%6o" new-gid) 0 6) "\000 ")))))
1021
1022 (defun tar-rename-entry (new-name)
1023   "*Change the name associated with this entry in the tar file.
1024 This does not modify the disk image; you must save the tar file itself
1025 for this to be permanent."
1026   (interactive
1027     (list (read-string "New name: "
1028             (tar-header-name (tar-desc-tokens (tar-current-descriptor))))))
1029   (if (string= "" new-name) (error "zero length name"))
1030   (if (> (length new-name) 98) (error "name too long"))
1031   (tar-setf (tar-header-name (tar-desc-tokens (tar-current-descriptor)))
1032             new-name)
1033   (tar-alter-one-field 0
1034     (substring (concat new-name (make-string 99 0)) 0 99)))
1035
1036
1037 (defun tar-chmod-entry (new-mode)
1038   "*Change the protection bits associated with this entry in the tar file.
1039 This does not modify the disk image; you must save the tar file itself
1040 for this to be permanent."
1041   (interactive (list (tar-parse-octal-integer-safe
1042                        (read-string "New protection (octal): "))))
1043   (tar-setf (tar-header-mode (tar-desc-tokens (tar-current-descriptor)))
1044             new-mode)
1045   (tar-alter-one-field tar-mode-offset
1046     (concat (substring (format "%6o" new-mode) 0 6) "\000 ")))
1047
1048
1049 (defun tar-alter-one-field (data-position new-data-string)
1050   (let* ((descriptor (tar-current-descriptor))
1051          (tokens (tar-desc-tokens descriptor))
1052          (multibyte enable-multibyte-characters))
1053     (unwind-protect
1054         (save-excursion
1055           ;;
1056           ;; update the header-line.
1057           (beginning-of-line)
1058           (let ((p (point)))
1059             (forward-line 1)
1060             (delete-region p (point))
1061             (insert (tar-header-block-summarize tokens) "\n")
1062             (setq tar-header-offset (position-bytes (point-max))))
1063
1064           (widen)
1065           (set-buffer-multibyte nil)
1066           (let* ((start (+ (tar-desc-data-start descriptor) tar-header-offset -513)))
1067             ;;
1068             ;; delete the old field and insert a new one.
1069             (goto-char (+ start data-position))
1070             (delete-region (point) (+ (point) (length new-data-string))) ; <--
1071             (insert new-data-string) ; <--
1072             ;;
1073             ;; compute a new checksum and insert it.
1074             (let ((chk (tar-header-block-checksum
1075                         (buffer-substring start (+ start 512)))))
1076               (goto-char (+ start tar-chk-offset))
1077               (delete-region (point) (+ (point) 8))
1078               (insert (format "%6o" chk))
1079               (insert 0)
1080               (insert ? )
1081               (tar-setf (tar-header-checksum tokens) chk)
1082               ;;
1083               ;; ok, make sure we didn't botch it.
1084               (tar-header-block-check-checksum
1085                 (buffer-substring start (+ start 512))
1086                 chk (tar-header-name tokens))
1087               )))
1088       (narrow-to-region (point-min) tar-header-offset)
1089       (set-buffer-multibyte multibyte)
1090       (tar-next-line 0))))
1091
1092
1093 (defun tar-octal-time (timeval)
1094   ;; Format a timestamp as 11 octal digits.  Ghod, I hope this works...
1095   (let ((hibits (car timeval)) (lobits (car (cdr timeval))))
1096     (format "%05o%01o%05o"
1097             (lsh hibits -2)
1098             (logior (lsh (logand 3 hibits) 1)
1099                     (if (> (logand lobits 32768) 0) 1 0))
1100             (logand 32767 lobits)
1101             )))
1102
1103 (defun tar-subfile-save-buffer ()
1104   "In tar subfile mode, save this buffer into its parent tar-file buffer.
1105 This doesn't write anything to disk; you must save the parent tar-file buffer
1106 to make your changes permanent."
1107   (interactive)
1108   (if (not (and (boundp 'tar-superior-buffer) tar-superior-buffer))
1109     (error "This buffer has no superior tar file buffer"))
1110   (if (not (and (boundp 'tar-superior-descriptor) tar-superior-descriptor))
1111     (error "This buffer doesn't have an index into its superior tar file!"))
1112   (save-excursion
1113   (let ((subfile (current-buffer))
1114         (subfile-multibyte enable-multibyte-characters)
1115         (coding buffer-file-coding-system)
1116         (descriptor tar-superior-descriptor)
1117         subfile-size)
1118     ;; We must make the current buffer unibyte temporarily to avoid
1119     ;; multibyte->unibyte conversion in `insert-buffer-substring'.
1120     (set-buffer-multibyte nil)
1121     (setq subfile-size (buffer-size))
1122     (set-buffer tar-superior-buffer)
1123     (let* ((tokens (tar-desc-tokens descriptor))
1124            (start (tar-desc-data-start descriptor))
1125            (name (tar-header-name tokens))
1126            (size (tar-header-size tokens))
1127            (size-pad (ash (ash (+ size 511) -9) 9))
1128            (head (memq descriptor tar-parse-info))
1129            (following-descs (cdr head))
1130            (tar-buffer-multibyte enable-multibyte-characters))
1131       (if (not head)
1132         (error "Can't find this tar file entry in its parent tar file!"))
1133       (unwind-protect
1134        (save-excursion
1135         (widen)
1136         (set-buffer-multibyte nil)
1137         ;; delete the old data...
1138         (let* ((data-start (+ start (- tar-header-offset (point-min))))
1139                (data-end (+ data-start (ash (ash (+ size 511) -9) 9))))
1140           (delete-region data-start data-end)
1141           ;; insert the new data...
1142           (goto-char data-start)
1143           (insert-buffer-substring subfile)
1144           (setq subfile-size
1145                 (encode-coding-region
1146                  data-start (+ data-start subfile-size) coding))
1147           ;;
1148           ;; pad the new data out to a multiple of 512...
1149           (let ((subfile-size-pad (ash (ash (+ subfile-size 511) -9) 9)))
1150             (goto-char (+ data-start subfile-size))
1151             (insert (make-string (- subfile-size-pad subfile-size) 0))
1152             ;;
1153             ;; update the data pointer of this and all following files...
1154             (tar-setf (tar-header-size tokens) subfile-size)
1155             (let ((difference (- subfile-size-pad size-pad)))
1156               (dolist (desc following-descs)
1157                 (tar-setf (tar-desc-data-start desc)
1158                           (+ (tar-desc-data-start desc) difference))))
1159             ;;
1160             ;; Update the size field in the header block.
1161             (let ((header-start (- data-start 512)))
1162               (goto-char (+ header-start tar-size-offset))
1163               (delete-region (point) (+ (point) 12))
1164               (insert (format "%11o" subfile-size))
1165               (insert ? )
1166               ;;
1167               ;; Maybe update the datestamp.
1168               (if (not tar-update-datestamp)
1169                   nil
1170                 (goto-char (+ header-start tar-time-offset))
1171                 (delete-region (point) (+ (point) 12))
1172                 (insert (tar-octal-time (current-time)))
1173                 (insert ? ))
1174               ;;
1175               ;; compute a new checksum and insert it.
1176               (let ((chk (tar-header-block-checksum
1177                           (buffer-substring header-start data-start))))
1178                 (goto-char (+ header-start tar-chk-offset))
1179                 (delete-region (point) (+ (point) 8))
1180                 (insert (format "%6o" chk))
1181                 (insert 0)
1182                 (insert ? )
1183                 (tar-setf (tar-header-checksum tokens) chk)))
1184             ;;
1185             ;; alter the descriptor-line...
1186             ;;
1187             (let ((position (- (length tar-parse-info) (length head))))
1188               (goto-char (point-min))
1189               (next-line position)
1190               (beginning-of-line)
1191               (let ((p (point))
1192                     after
1193                     (m (set-marker (make-marker) tar-header-offset)))
1194                 (forward-line 1)
1195                 (setq after (point))
1196                 ;; Insert the new text after the old, before deleting,
1197                 ;; to preserve the window start.
1198                 (let ((line (tar-header-block-summarize tokens t)))
1199                   (if (multibyte-string-p line)
1200                       (insert-before-markers (string-as-unibyte line) "\n")
1201                     (insert-before-markers line "\n")))
1202                 (delete-region p after)
1203                 (setq tar-header-offset (marker-position m)))
1204               )))
1205         ;; after doing the insertion, add any final padding that may be necessary.
1206         (tar-pad-to-blocksize))
1207        (narrow-to-region (point-min) tar-header-offset)
1208        (set-buffer-multibyte tar-buffer-multibyte)))
1209     (set-buffer-modified-p t)   ; mark the tar file as modified
1210     (tar-next-line 0)
1211     (set-buffer subfile)
1212     ;; Restore the buffer multibyteness.
1213     (set-buffer-multibyte subfile-multibyte)
1214     (set-buffer-modified-p nil) ; mark the tar subfile as unmodified
1215     (message "Saved into tar-buffer `%s'.  Be sure to save that buffer!"
1216              (buffer-name tar-superior-buffer))
1217     ;; Prevent basic-save-buffer from changing our coding-system.
1218     (setq last-coding-system-used buffer-file-coding-system)
1219     ;; Prevent ordinary saving from happening.
1220     t)))
1221
1222
1223 ;; When this function is called, it is sure that the buffer is unibyte.
1224 (defun tar-pad-to-blocksize ()
1225   "If we are being anal about tar file blocksizes, fix up the current buffer.
1226 Leaves the region wide."
1227   (if (null tar-anal-blocksize)
1228       nil
1229     (widen)
1230     (let* ((last-desc (nth (1- (length tar-parse-info)) tar-parse-info))
1231            (start (tar-desc-data-start last-desc))
1232            (tokens (tar-desc-tokens last-desc))
1233            (link-p (tar-header-link-type tokens))
1234            (size (if link-p 0 (tar-header-size tokens)))
1235            (data-end (+ start size))
1236            (bbytes (ash tar-anal-blocksize 9))
1237            (pad-to (+ bbytes (* bbytes (/ (1- data-end) bbytes))))
1238            (inhibit-read-only t) ; ##
1239            )
1240       ;; If the padding after the last data is too long, delete some;
1241       ;; else insert some until we are padded out to the right number of blocks.
1242       ;;
1243       (goto-char (+ (or tar-header-offset 0) data-end))
1244       (if (> (1+ (buffer-size)) (+ (or tar-header-offset 0) pad-to))
1245           (delete-region (+ (or tar-header-offset 0) pad-to) (1+ (buffer-size)))
1246           (insert (make-string (- (+ (or tar-header-offset 0) pad-to)
1247                                   (1+ (buffer-size)))
1248                                0)))
1249       )))
1250
1251
1252 ;; Used in write-file-hook to write tar-files out correctly.
1253 (defun tar-mode-write-file ()
1254   (unwind-protect
1255       (save-excursion
1256         (widen)
1257         ;; Doing this here confuses things - the region gets left too wide!
1258         ;; I suppose this is run in a context where changing the buffer is bad.
1259         ;; (tar-pad-to-blocksize)
1260         ;; tar-header-offset turns out to be null for files fetched with W3,
1261         ;; at least.
1262         (let ((coding-system-for-write 'no-conversion))
1263           (write-region (if tar-header-offset
1264                             (byte-to-position tar-header-offset)
1265                           (point-min))
1266                         (point-max)
1267                         buffer-file-name nil t))
1268         (tar-clear-modification-flags)
1269         (set-buffer-modified-p nil))
1270     (narrow-to-region (point-min) (byte-to-position tar-header-offset)))
1271   ;; Return t because we've written the file.
1272   t)
1273 \f
1274 (provide 'tar-mode)
1275
1276 ;;; arch-tag: 8a585a4a-340e-42c2-89e7-d3b1013a4b78
1277 ;;; tar-mode.el ends here