lisp/vc-dir.el

   1 ;;; vc-dir.el --- Directory status display under VC
   2
   3 ;; Copyright (C) 2007, 2008, 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author:   Dan Nicolaescu <dann@ics.uci.edu>
   7 ;; Keywords: tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Credits:
  25
  26 ;; The original VC directory status implementation was based on dired.
  27 ;; This implementation was inspired by PCL-CVS.
  28 ;; Many people contributed comments, ideas and code to this
  29 ;; implementation.  These include:
  30 ;;
  31 ;;   Alexandre Julliard  <julliard@winehq.org>
  32 ;;   Stefan Monnier  <monnier@iro.umontreal.ca>
  33 ;;   Tom Tromey  <tromey@redhat.com>
  34
  35 ;;; Commentary:
  36 ;;
  37
  38 ;;; Todo:  see vc.el.
  39
  40 (require 'vc-hooks)
  41 (require 'vc)
  42 (require 'tool-bar)
  43 (require 'ewoc)
  44
  45 ;;; Code:
  46 (eval-when-compile
  47   (require 'cl))
  48
  49 (defcustom vc-dir-mode-hook nil
  50   "Normal hook run by `vc-dir-mode'.
  51 See `run-hooks'."
  52   :type 'hook
  53   :group 'vc)
  54
  55 ;; Used to store information for the files displayed in the directory buffer.
  56 ;; Each item displayed corresponds to one of these defstructs.
  57 (defstruct (vc-dir-fileinfo
  58             (:copier nil)
  59             (:type list)            ;So we can use `member' on lists of FIs.
  60             (:constructor
  61              ;; We could define it as an alias for `list'.
  62              vc-dir-create-fileinfo (name state &optional extra marked directory))
  63             (:conc-name vc-dir-fileinfo->))
  64   name                                  ;Keep it as first, for `member'.
  65   state
  66   ;; For storing backend specific information.
  67   extra
  68   marked
  69   ;; To keep track of not updated files during a global refresh
  70   needs-update
  71   ;; To distinguish files and directories.
  72   directory)
  73
  74 (defvar vc-ewoc nil)
  75
  76 (defvar vc-dir-process-buffer nil
  77   "The buffer used for the asynchronous call that computes status.")
  78
  79 (defvar vc-dir-backend nil
  80   "The backend used by the current *vc-dir* buffer.")
  81
  82 (defun vc-dir-move-to-goal-column ()
  83   ;; Used to keep the cursor on the file name column.
  84   (beginning-of-line)
  85   (unless (eolp)
  86     ;; Must be in sync with vc-default-dir-printer.
  87     (forward-char 25)))
  88
  89 (defun vc-dir-prepare-status-buffer (bname dir backend &optional create-new)
  90   "Find a buffer named BNAME showing DIR, or create a new one."
  91   (setq dir (file-name-as-directory (expand-file-name dir)))
  92   (let* ;; Look for another buffer name BNAME visiting the same directory.
  93       ((buf (save-excursion
  94               (unless create-new
  95                 (dolist (buffer vc-dir-buffers)
  96                   (when (buffer-live-p buffer)
  97                     (set-buffer buffer)
  98                     (when (and (derived-mode-p 'vc-dir-mode)
  99                                (eq vc-dir-backend backend)
 100                                (string= default-directory dir))
 101                       (return buffer))))))))
 102     (or buf
 103         ;; Create a new buffer named BNAME.
 104         ;; We pass a filename to create-file-buffer because it is what
 105         ;; the function expects, and also what uniquify needs (if active)
 106         (with-current-buffer (create-file-buffer (expand-file-name bname dir))
 107           (cd dir)
 108           (vc-setup-buffer (current-buffer))
 109           ;; Reset the vc-parent-buffer-name so that it does not appear
 110           ;; in the mode-line.
 111           (setq vc-parent-buffer-name nil)
 112           (current-buffer)))))
 113
 114 (defvar vc-dir-menu-map
 115   (let ((map (make-sparse-keymap "VC-dir")))
 116     (define-key map [quit]
 117       '(menu-item "Quit" quit-window
 118                   :help "Quit"))
 119     (define-key map [kill]
 120       '(menu-item "Kill Update Command" vc-dir-kill-dir-status-process
 121                   :enable (vc-dir-busy)
 122                   :help "Kill the command that updates the directory buffer"))
 123     (define-key map [refresh]
 124       '(menu-item "Refresh" revert-buffer
 125                   :enable (not (vc-dir-busy))
 126                   :help "Refresh the contents of the directory buffer"))
 127     (define-key map [remup]
 128       '(menu-item "Hide up-to-date" vc-dir-hide-up-to-date
 129                   :help "Hide up-to-date items from display"))
 130     ;; Movement.
 131     (define-key map [sepmv] '("--"))
 132     (define-key map [next-line]
 133       '(menu-item "Next line" vc-dir-next-line
 134                   :help "Go to the next line" :keys "n"))
 135     (define-key map [previous-line]
 136       '(menu-item "Previous line" vc-dir-previous-line
 137                   :help "Go to the previous line"))
 138     ;; Marking.
 139     (define-key map [sepmrk] '("--"))
 140     (define-key map [unmark-all]
 141       '(menu-item "Unmark All" vc-dir-unmark-all-files
 142                   :help "Unmark all files that are in the same state as the current file\
 143 \nWith prefix argument unmark all files"))
 144     (define-key map [unmark-previous]
 145       '(menu-item "Unmark previous " vc-dir-unmark-file-up
 146                   :help "Move to the previous line and unmark the file"))
 147
 148     (define-key map [mark-all]
 149       '(menu-item "Mark All" vc-dir-mark-all-files
 150                   :help "Mark all files that are in the same state as the current file\
 151 \nWith prefix argument mark all files"))
 152     (define-key map [unmark]
 153       '(menu-item "Unmark" vc-dir-unmark
 154                   :help "Unmark the current file or all files in the region"))
 155
 156     (define-key map [mark]
 157       '(menu-item "Mark" vc-dir-mark
 158                   :help "Mark the current file or all files in the region"))
 159
 160     (define-key map [sepopn] '("--"))
 161     (define-key map [qr]
 162       '(menu-item "Query Replace in Files..." vc-dir-query-replace-regexp
 163                   :help "Replace a string in the marked files"))
 164     (define-key map [se]
 165       '(menu-item "Search Files..." vc-dir-search
 166                   :help "Search a regexp in the marked files"))
 167     (define-key map [ires]
 168       '(menu-item "Isearch Regexp Files..." vc-dir-isearch-regexp
 169                   :help "Incremental search a regexp in the marked files"))
 170     (define-key map [ise]
 171       '(menu-item "Isearch Files..." vc-dir-isearch
 172                   :help "Incremental search a string in the marked files"))
 173     (define-key map [open-other]
 174       '(menu-item "Open in other window" vc-dir-find-file-other-window
 175                   :help "Find the file on the current line, in another window"))
 176     (define-key map [open]
 177       '(menu-item "Open file" vc-dir-find-file
 178                   :help "Find the file on the current line"))
 179     (define-key map [sepvcdet] '("--"))
 180     ;; FIXME: This needs a key binding.  And maybe a better name
 181     ;; ("Insert" like PCL-CVS uses does not sound that great either)...
 182     (define-key map [ins]
 183       '(menu-item "Show File" vc-dir-show-fileentry
 184                   :help "Show a file in the VC status listing even though it might be up to date"))
 185     (define-key map [annotate]
 186       '(menu-item "Annotate" vc-annotate
 187                   :help "Display the edit history of the current file using colors"))
 188     (define-key map [diff]
 189       '(menu-item "Compare with Base Version" vc-diff
 190                   :help "Compare file set with the base version"))
 191     (define-key map [logo]
 192       '(menu-item "Show Outgoing Log" vc-log-outgoing
 193                   :help "Show a log of changes that will be sent with a push operation"))
 194     (define-key map [logi]
 195       '(menu-item "Show Incoming Log" vc-log-incoming
 196                   :help "Show a log of changes that will be received with a pull operation"))
 197     (define-key map [log]
 198       '(menu-item "Show history" vc-print-log
 199                   :help "List the change log of the current file set in a window"))
 200     (define-key map [rlog]
 201       '(menu-item "Show Top of the Tree History " vc-print-root-log
 202                   :help "List the change log for the current tree in a window"))
 203     ;; VC commands.
 204     (define-key map [sepvccmd] '("--"))
 205     (define-key map [update]
 206       '(menu-item "Update to latest version" vc-update
 207                   :help "Update the current fileset's files to their tip revisions"))
 208     (define-key map [revert]
 209       '(menu-item "Revert to base version" vc-revert
 210                   :help "Revert working copies of the selected fileset to their repository contents."))
 211     (define-key map [next-action]
 212       ;; FIXME: This really really really needs a better name!
 213       ;; And a key binding too.
 214       '(menu-item "Check In/Out" vc-next-action
 215                   :help "Do the next logical version control operation on the current fileset"))
 216     (define-key map [register]
 217       '(menu-item "Register" vc-register
 218                   :help "Register file set into the version control system"))
 219     map)
 220   "Menu for VC dir.")
 221
 222 ;; VC backends can use this to add mode-specific menu items to
 223 ;; vc-dir-menu-map.
 224 (defun vc-dir-menu-map-filter (orig-binding)
 225   (when (and (symbolp orig-binding) (fboundp orig-binding))
 226     (setq orig-binding (indirect-function orig-binding)))
 227   (let ((ext-binding
 228          (when (derived-mode-p 'vc-dir-mode)
 229            (vc-call-backend vc-dir-backend 'extra-status-menu))))
 230     (if (null ext-binding)
 231         orig-binding
 232       (append orig-binding
 233               '("----")
 234               ext-binding))))
 235
 236 (defvar vc-dir-mode-map
 237   (let ((map (make-sparse-keymap)))
 238     ;; VC commands
 239     (define-key map "v" 'vc-next-action)   ;; C-x v v
 240     (define-key map "=" 'vc-diff)          ;; C-x v =
 241     (define-key map "i" 'vc-register)      ;; C-x v i
 242     (define-key map "+" 'vc-update)        ;; C-x v +
 243     (define-key map "l" 'vc-print-log)     ;; C-x v l
 244     ;; More confusing than helpful, probably
 245     ;;(define-key map "R" 'vc-revert) ;; u is taken by vc-dir-unmark.
 246     ;;(define-key map "A" 'vc-annotate) ;; g is taken by revert-buffer
 247     ;;                                     bound by `special-mode'.
 248     ;; Marking.
 249     (define-key map "m" 'vc-dir-mark)
 250     (define-key map "M" 'vc-dir-mark-all-files)
 251     (define-key map "u" 'vc-dir-unmark)
 252     (define-key map "U" 'vc-dir-unmark-all-files)
 253     (define-key map "\C-?" 'vc-dir-unmark-file-up)
 254     (define-key map "\M-\C-?" 'vc-dir-unmark-all-files)
 255     ;; Movement.
 256     (define-key map "n" 'vc-dir-next-line)
 257     (define-key map " " 'vc-dir-next-line)
 258     (define-key map "\t" 'vc-dir-next-directory)
 259     (define-key map "p" 'vc-dir-previous-line)
 260     (define-key map [backtab] 'vc-dir-previous-directory)
 261     ;;; Rebind paragraph-movement commands.
 262     (define-key map "\M-}" 'vc-dir-next-directory)
 263     (define-key map "\M-{" 'vc-dir-previous-directory)
 264     (define-key map [C-down] 'vc-dir-next-directory)
 265     (define-key map [C-up] 'vc-dir-previous-directory)
 266     ;; The remainder.
 267     (define-key map "f" 'vc-dir-find-file)
 268     (define-key map "\C-m" 'vc-dir-find-file)
 269     (define-key map "o" 'vc-dir-find-file-other-window)
 270     (define-key map "\C-c\C-c" 'vc-dir-kill-dir-status-process)
 271     (define-key map [down-mouse-3] 'vc-dir-menu)
 272     (define-key map [mouse-2] 'vc-dir-toggle-mark)
 273     (define-key map [follow-link] 'mouse-face)
 274     (define-key map "x" 'vc-dir-hide-up-to-date)
 275     (define-key map [?\C-k] 'vc-dir-kill-line)
 276     (define-key map "S" 'vc-dir-search) ;; FIXME: Maybe use A like dired?
 277     (define-key map "Q" 'vc-dir-query-replace-regexp)
 278     (define-key map (kbd "M-s a C-s")   'vc-dir-isearch)
 279     (define-key map (kbd "M-s a M-C-s") 'vc-dir-isearch-regexp)
 280
 281     ;; Hook up the menu.
 282     (define-key map [menu-bar vc-dir-mode]
 283       `(menu-item
 284         ;; VC backends can use this to add mode-specific menu items to
 285         ;; vc-dir-menu-map.
 286         "VC-dir" ,vc-dir-menu-map :filter vc-dir-menu-map-filter))
 287     map)
 288   "Keymap for directory buffer.")
 289
 290 (defmacro vc-dir-at-event (event &rest body)
 291   "Evaluate BODY with point located at event-start of EVENT.
 292 If BODY uses EVENT, it should be a variable,
 293  otherwise it will be evaluated twice."
 294   (let ((posn (make-symbol "vc-dir-at-event-posn")))
 295     `(save-excursion
 296        (unless (equal ,event '(tool-bar))
 297          (let ((,posn (event-start ,event)))
 298            (set-buffer (window-buffer (posn-window ,posn)))
 299            (goto-char (posn-point ,posn))))
 300        ,@body)))
 301
 302 (defun vc-dir-menu (e)
 303   "Popup the VC dir menu."
 304   (interactive "e")
 305   (vc-dir-at-event e (popup-menu vc-dir-menu-map e)))
 306
 307 (defvar vc-dir-tool-bar-map
 308   (let ((map (make-sparse-keymap)))
 309     (tool-bar-local-item-from-menu 'vc-dir-find-file "open"
 310                                    map vc-dir-mode-map)
 311     (tool-bar-local-item "bookmark_add"
 312                          'vc-dir-toggle-mark 'vc-dir-toggle-mark map
 313                          :help "Toggle mark on current item")
 314     (tool-bar-local-item-from-menu 'vc-dir-previous-line "left-arrow"
 315                                    map vc-dir-mode-map
 316                                    :rtl "right-arrow")
 317     (tool-bar-local-item-from-menu 'vc-dir-next-line "right-arrow"
 318                                    map vc-dir-mode-map
 319                                    :rtl "left-arrow")
 320     (tool-bar-local-item-from-menu 'vc-print-log "info"
 321                                    map vc-dir-mode-map)
 322     (tool-bar-local-item-from-menu 'revert-buffer "refresh"
 323                                    map vc-dir-mode-map)
 324     (tool-bar-local-item-from-menu 'nonincremental-search-forward
 325                                    "search" map)
 326     (tool-bar-local-item-from-menu 'vc-dir-query-replace-regexp
 327                                    "search-replace" map vc-dir-mode-map)
 328     (tool-bar-local-item-from-menu 'vc-dir-kill-dir-status-process "cancel"
 329                                    map vc-dir-mode-map)
 330     (tool-bar-local-item-from-menu 'quit-window "exit"
 331                                    map vc-dir-mode-map)
 332     map))
 333
 334 (defun vc-dir-node-directory (node)
 335   ;; Compute the directory for NODE.
 336   ;; If it's a directory node, get it from the node.
 337   (let ((data (ewoc-data node)))
 338     (or (vc-dir-fileinfo->directory data)
 339         ;; Otherwise compute it from the file name.
 340         (file-name-directory
 341          (directory-file-name
 342           (expand-file-name
 343            (vc-dir-fileinfo->name data)))))))
 344
 345 (defun vc-dir-update (entries buffer &optional noinsert)
 346   "Update BUFFER's ewoc from the list of ENTRIES.
 347 If NOINSERT, ignore elements on ENTRIES which are not in the ewoc."
 348   ;; Add ENTRIES to the vc-dir buffer BUFFER.
 349   (with-current-buffer buffer
 350     ;; Insert the entries sorted by name into the ewoc.
 351     ;; We assume the ewoc is sorted too, which should be the
 352     ;; case if we always add entries with vc-dir-update.
 353     (setq entries
 354           ;; Sort: first files and then subdirectories.
 355           ;; XXX: this is VERY inefficient, it computes the directory
 356           ;; names too many times
 357           (sort entries
 358                 (lambda (entry1 entry2)
 359                   (let ((dir1 (file-name-directory
 360                                 (directory-file-name (expand-file-name (car entry1)))))
 361                         (dir2 (file-name-directory
 362                                (directory-file-name (expand-file-name (car entry2))))))
 363                     (cond
 364                      ((string< dir1 dir2) t)
 365                      ((not (string= dir1 dir2)) nil)
 366                      ((string< (car entry1) (car entry2))))))))
 367     ;; Insert directory entries in the right places.
 368     (let ((entry (car entries))
 369           (node (ewoc-nth vc-ewoc 0))
 370           (to-remove nil)
 371           (dotname (file-relative-name default-directory)))
 372       ;; Insert . if it is not present.
 373       (unless node
 374         (ewoc-enter-last
 375          vc-ewoc (vc-dir-create-fileinfo
 376                   dotname nil nil nil default-directory))
 377         (setq node (ewoc-nth vc-ewoc 0)))
 378
 379       (while (and entry node)
 380         (let* ((entryfile (car entry))
 381                (entrydir (file-name-directory (directory-file-name
 382                                                (expand-file-name entryfile))))
 383                (nodedir (vc-dir-node-directory node)))
 384           (cond
 385            ;; First try to find the directory.
 386            ((string-lessp nodedir entrydir)
 387             (setq node (ewoc-next vc-ewoc node)))
 388            ((string-equal nodedir entrydir)
 389             ;; Found the directory, find the place for the file name.
 390             (let ((nodefile (vc-dir-fileinfo->name (ewoc-data node))))
 391               (cond
 392                ((string= nodefile dotname)
 393                 (setq node (ewoc-next vc-ewoc node)))
 394                ((string-lessp nodefile entryfile)
 395                 (setq node (ewoc-next vc-ewoc node)))
 396                ((string-equal nodefile entryfile)
 397                 (if (nth 1 entry)
 398                     (progn
 399                       (setf (vc-dir-fileinfo->state (ewoc-data node)) (nth 1 entry))
 400                       (setf (vc-dir-fileinfo->extra (ewoc-data node)) (nth 2 entry))
 401                       (setf (vc-dir-fileinfo->needs-update (ewoc-data node)) nil)
 402                       (ewoc-invalidate vc-ewoc node))
 403                   ;; If the state is nil, the file does not exist
 404                   ;; anymore, so remember the entry so we can remove
 405                   ;; it after we are done inserting all ENTRIES.
 406                   (push node to-remove))
 407                 (setq entries (cdr entries))
 408                 (setq entry (car entries))
 409                 (setq node (ewoc-next vc-ewoc node)))
 410                (t
 411                 (unless noinsert
 412                   (ewoc-enter-before vc-ewoc node
 413                                      (apply 'vc-dir-create-fileinfo entry)))
 414                 (setq entries (cdr entries))
 415                 (setq entry (car entries))))))
 416            (t
 417             (unless noinsert
 418               ;; We might need to insert a directory node if the
 419               ;; previous node was in a different directory.
 420               (let* ((rd (file-relative-name entrydir))
 421                      (prev-node (ewoc-prev vc-ewoc node))
 422                      (prev-dir (vc-dir-node-directory prev-node)))
 423                 (unless (string-equal entrydir prev-dir)
 424                   (ewoc-enter-before
 425                    vc-ewoc node (vc-dir-create-fileinfo rd nil nil nil entrydir))))
 426               ;; Now insert the node itself.
 427               (ewoc-enter-before vc-ewoc node
 428                                  (apply 'vc-dir-create-fileinfo entry)))
 429             (setq entries (cdr entries) entry (car entries))))))
 430       ;; We're past the last node, all remaining entries go to the end.
 431       (unless (or node noinsert)
 432         (let ((lastdir (vc-dir-node-directory (ewoc-nth vc-ewoc -1))))
 433           (dolist (entry entries)
 434             (let ((entrydir (file-name-directory
 435                              (directory-file-name (expand-file-name (car entry))))))
 436               ;; Insert a directory node if needed.
 437               (unless (string-equal lastdir entrydir)
 438                 (setq lastdir entrydir)
 439                 (let ((rd (file-relative-name entrydir)))
 440                   (ewoc-enter-last
 441                    vc-ewoc (vc-dir-create-fileinfo rd nil nil nil entrydir))))
 442               ;; Now insert the node itself.
 443               (ewoc-enter-last vc-ewoc
 444                                (apply 'vc-dir-create-fileinfo entry))))))
 445       (when to-remove
 446         (let ((inhibit-read-only t))
 447           (apply 'ewoc-delete vc-ewoc (nreverse to-remove)))))))
 448
 449 (defun vc-dir-busy ()
 450   (and (buffer-live-p vc-dir-process-buffer)
 451        (get-buffer-process vc-dir-process-buffer)))
 452
 453 (defun vc-dir-kill-dir-status-process ()
 454   "Kill the temporary buffer and associated process."
 455   (interactive)
 456   (when (buffer-live-p vc-dir-process-buffer)
 457     (let ((proc (get-buffer-process vc-dir-process-buffer)))
 458       (when proc (delete-process proc))
 459       (setq vc-dir-process-buffer nil)
 460       (setq mode-line-process nil))))
 461
 462 (defun vc-dir-kill-query ()
 463   ;; Make sure that when the status buffer is killed the update
 464   ;; process running in background is also killed.
 465   (if (vc-dir-busy)
 466     (when (y-or-n-p "Status update process running, really kill status buffer? ")
 467       (vc-dir-kill-dir-status-process)
 468       t)
 469     t))
 470
 471 (defun vc-dir-next-line (arg)
 472   "Go to the next line.
 473 If a prefix argument is given, move by that many lines."
 474   (interactive "p")
 475   (with-no-warnings
 476     (ewoc-goto-next vc-ewoc arg)
 477     (vc-dir-move-to-goal-column)))
 478
 479 (defun vc-dir-previous-line (arg)
 480   "Go to the previous line.
 481 If a prefix argument is given, move by that many lines."
 482   (interactive "p")
 483   (ewoc-goto-prev vc-ewoc arg)
 484   (vc-dir-move-to-goal-column))
 485
 486 (defun vc-dir-next-directory ()
 487   "Go to the next directory."
 488   (interactive)
 489   (let ((orig (point)))
 490     (if
 491         (catch 'foundit
 492           (while t
 493             (let* ((next (ewoc-next vc-ewoc (ewoc-locate vc-ewoc))))
 494               (cond ((not next)
 495                      (throw 'foundit t))
 496                     (t
 497                      (progn
 498                        (ewoc-goto-node vc-ewoc next)
 499                        (vc-dir-move-to-goal-column)
 500                        (if (vc-dir-fileinfo->directory (ewoc-data next))
 501                            (throw 'foundit nil))))))))
 502         (goto-char orig))))
 503
 504 (defun vc-dir-previous-directory ()
 505   "Go to the previous directory."
 506   (interactive)
 507   (let ((orig (point)))
 508     (if
 509         (catch 'foundit
 510           (while t
 511             (let* ((prev (ewoc-prev vc-ewoc (ewoc-locate vc-ewoc))))
 512               (cond ((not prev)
 513                      (throw 'foundit t))
 514                     (t
 515                      (progn
 516                        (ewoc-goto-node vc-ewoc prev)
 517                        (vc-dir-move-to-goal-column)
 518                        (if (vc-dir-fileinfo->directory (ewoc-data prev))
 519                            (throw 'foundit nil))))))))
 520         (goto-char orig))))
 521
 522 (defun vc-dir-mark-unmark (mark-unmark-function)
 523   (if (use-region-p)
 524       (let ((firstl (line-number-at-pos (region-beginning)))
 525             (lastl (line-number-at-pos (region-end))))
 526         (save-excursion
 527           (goto-char (region-beginning))
 528           (while (<= (line-number-at-pos) lastl)
 529             (funcall mark-unmark-function))))
 530     (funcall mark-unmark-function)))
 531
 532 (defun vc-dir-parent-marked-p (arg)
 533   ;; Return nil if none of the parent directories of arg is marked.
 534   (let* ((argdir (vc-dir-node-directory arg))
 535          (arglen (length argdir))
 536          (crt arg)
 537          data dir)
 538     ;; Go through the predecessors, checking if any directory that is
 539     ;; a parent is marked.
 540     (while (setq crt (ewoc-prev vc-ewoc crt))
 541       (setq data (ewoc-data crt))
 542       (setq dir (vc-dir-node-directory crt))
 543       (when (and (vc-dir-fileinfo->directory data)
 544                  (vc-string-prefix-p dir argdir))
 545         (when (vc-dir-fileinfo->marked data)
 546           (error "Cannot mark `%s', parent directory `%s' marked"
 547                  (vc-dir-fileinfo->name (ewoc-data arg))
 548                  (vc-dir-fileinfo->name data)))))
 549     nil))
 550
 551 (defun vc-dir-children-marked-p (arg)
 552   ;; Return nil if none of the children of arg is marked.
 553   (let* ((argdir-re (concat "\\`" (regexp-quote (vc-dir-node-directory arg))))
 554          (is-child t)
 555          (crt arg)
 556          data dir)
 557     (while (and is-child (setq crt (ewoc-next vc-ewoc crt)))
 558       (setq data (ewoc-data crt))
 559       (setq dir (vc-dir-node-directory crt))
 560       (if (string-match argdir-re dir)
 561           (when (vc-dir-fileinfo->marked data)
 562             (error "Cannot mark `%s', child `%s' marked"
 563                    (vc-dir-fileinfo->name (ewoc-data arg))
 564                    (vc-dir-fileinfo->name data)))
 565         ;; We are done, we got to an entry that is not a child of `arg'.
 566         (setq is-child nil)))
 567     nil))
 568
 569 (defun vc-dir-mark-file (&optional arg)
 570   ;; Mark ARG or the current file and move to the next line.
 571   (let* ((crt (or arg (ewoc-locate vc-ewoc)))
 572          (file (ewoc-data crt))
 573          (isdir (vc-dir-fileinfo->directory file)))
 574     (when (or (and isdir (not (vc-dir-children-marked-p crt)))
 575               (and (not isdir) (not (vc-dir-parent-marked-p crt))))
 576       (setf (vc-dir-fileinfo->marked file) t)
 577       (ewoc-invalidate vc-ewoc crt)
 578       (unless (or arg (mouse-event-p last-command-event))
 579         (vc-dir-next-line 1)))))
 580
 581 (defun vc-dir-mark ()
 582   "Mark the current file or all files in the region.
 583 If the region is active, mark all the files in the region.
 584 Otherwise mark the file on the current line and move to the next
 585 line."
 586   (interactive)
 587   (vc-dir-mark-unmark 'vc-dir-mark-file))
 588
 589 (defun vc-dir-mark-all-files (arg)
 590   "Mark all files with the same state as the current one.
 591 With a prefix argument mark all files.
 592 If the current entry is a directory, mark all child files.
 593
 594 The commands operate on files that are on the same state.
 595 This command is intended to make it easy to select all files that
 596 share the same state."
 597   (interactive "P")
 598   (if arg
 599       ;; Mark all files.
 600       (progn
 601         ;; First check that no directory is marked, we can't mark
 602         ;; files in that case.
 603         (ewoc-map
 604          (lambda (filearg)
 605            (when (and (vc-dir-fileinfo->directory filearg)
 606                       (vc-dir-fileinfo->marked filearg))
 607              (error "Cannot mark all files, directory `%s' marked"
 608                     (vc-dir-fileinfo->name filearg))))
 609          vc-ewoc)
 610         (ewoc-map
 611          (lambda (filearg)
 612            (unless (vc-dir-fileinfo->marked filearg)
 613              (setf (vc-dir-fileinfo->marked filearg) t)
 614              t))
 615          vc-ewoc))
 616     (let ((data (ewoc-data (ewoc-locate vc-ewoc))))
 617       (if (vc-dir-fileinfo->directory data)
 618           ;; It's a directory, mark child files.
 619           (let ((crt (ewoc-locate vc-ewoc)))
 620             (unless (vc-dir-children-marked-p crt)
 621               (while (setq crt (ewoc-next vc-ewoc crt))
 622                 (let ((crt-data (ewoc-data crt)))
 623                   (unless (vc-dir-fileinfo->directory crt-data)
 624                     (setf (vc-dir-fileinfo->marked crt-data) t)
 625                     (ewoc-invalidate vc-ewoc crt))))))
 626         ;; It's a file
 627         (let ((state (vc-dir-fileinfo->state data))
 628               (crt (ewoc-nth vc-ewoc 0)))
 629           (while crt
 630             (let ((crt-data (ewoc-data crt)))
 631               (when (and (not (vc-dir-fileinfo->marked crt-data))
 632                          (eq (vc-dir-fileinfo->state crt-data) state)
 633                          (not (vc-dir-fileinfo->directory crt-data)))
 634                 (vc-dir-mark-file crt)))
 635             (setq crt (ewoc-next vc-ewoc crt))))))))
 636
 637 (defun vc-dir-unmark-file ()
 638   ;; Unmark the current file and move to the next line.
 639   (let* ((crt (ewoc-locate vc-ewoc))
 640          (file (ewoc-data crt)))
 641     (setf (vc-dir-fileinfo->marked file) nil)
 642     (ewoc-invalidate vc-ewoc crt)
 643     (unless (mouse-event-p last-command-event)
 644       (vc-dir-next-line 1))))
 645
 646 (defun vc-dir-unmark ()
 647   "Unmark the current file or all files in the region.
 648 If the region is active, unmark all the files in the region.
 649 Otherwise mark the file on the current line and move to the next
 650 line."
 651   (interactive)
 652   (vc-dir-mark-unmark 'vc-dir-unmark-file))
 653
 654 (defun vc-dir-unmark-file-up ()
 655   "Move to the previous line and unmark the file."
 656   (interactive)
 657   ;; If we're on the first line, we won't move up, but we will still
 658   ;; remove the mark.  This seems a bit odd but it is what buffer-menu
 659   ;; does.
 660   (let* ((prev (ewoc-goto-prev vc-ewoc 1))
 661          (file (ewoc-data prev)))
 662     (setf (vc-dir-fileinfo->marked file) nil)
 663     (ewoc-invalidate vc-ewoc prev)
 664     (vc-dir-move-to-goal-column)))
 665
 666 (defun vc-dir-unmark-all-files (arg)
 667   "Unmark all files with the same state as the current one.
 668 With a prefix argument unmark all files.
 669 If the current entry is a directory, unmark all the child files.
 670
 671 The commands operate on files that are on the same state.
 672 This command is intended to make it easy to deselect all files
 673 that share the same state."
 674   (interactive "P")
 675   (if arg
 676       (ewoc-map
 677        (lambda (filearg)
 678          (when (vc-dir-fileinfo->marked filearg)
 679            (setf (vc-dir-fileinfo->marked filearg) nil)
 680            t))
 681        vc-ewoc)
 682     (let* ((crt (ewoc-locate vc-ewoc))
 683            (data (ewoc-data crt)))
 684       (if (vc-dir-fileinfo->directory data)
 685           ;; It's a directory, unmark child files.
 686           (while (setq crt (ewoc-next vc-ewoc crt))
 687             (let ((crt-data (ewoc-data crt)))
 688               (unless (vc-dir-fileinfo->directory crt-data)
 689                 (setf (vc-dir-fileinfo->marked crt-data) nil)
 690                 (ewoc-invalidate vc-ewoc crt))))
 691         ;; It's a file
 692         (let ((crt-state (vc-dir-fileinfo->state (ewoc-data crt))))
 693           (ewoc-map
 694            (lambda (filearg)
 695              (when (and (vc-dir-fileinfo->marked filearg)
 696                         (eq (vc-dir-fileinfo->state filearg) crt-state))
 697                (setf (vc-dir-fileinfo->marked filearg) nil)
 698                t))
 699            vc-ewoc))))))
 700
 701 (defun vc-dir-toggle-mark-file ()
 702   (let* ((crt (ewoc-locate vc-ewoc))
 703          (file (ewoc-data crt)))
 704     (if (vc-dir-fileinfo->marked file)
 705         (vc-dir-unmark-file)
 706       (vc-dir-mark-file))))
 707
 708 (defun vc-dir-toggle-mark (e)
 709   (interactive "e")
 710   (vc-dir-at-event e (vc-dir-mark-unmark 'vc-dir-toggle-mark-file)))
 711
 712 (defun vc-dir-delete-file ()
 713   "Delete the marked files, or the current file if no marks."
 714   (interactive)
 715   (mapc 'vc-delete-file (or (vc-dir-marked-files)
 716                             (list (vc-dir-current-file)))))
 717
 718 (defun vc-dir-find-file ()
 719   "Find the file on the current line."
 720   (interactive)
 721   (find-file (vc-dir-current-file)))
 722
 723 (defun vc-dir-find-file-other-window (&optional event)
 724   "Find the file on the current line, in another window."
 725   (interactive (list last-nonmenu-event))
 726   (if event (posn-set-point (event-end event)))
 727   (find-file-other-window (vc-dir-current-file)))
 728
 729 (defun vc-dir-isearch ()
 730   "Search for a string through all marked buffers using Isearch."
 731   (interactive)
 732   (multi-isearch-files
 733    (mapcar 'car (vc-dir-marked-only-files-and-states))))
 734
 735 (defun vc-dir-isearch-regexp ()
 736   "Search for a regexp through all marked buffers using Isearch."
 737   (interactive)
 738   (multi-isearch-files-regexp
 739    (mapcar 'car (vc-dir-marked-only-files-and-states))))
 740
 741 (defun vc-dir-search (regexp)
 742   "Search through all marked files for a match for REGEXP.
 743 For marked directories, use the files displayed from those directories.
 744 Stops when a match is found.
 745 To continue searching for next match, use command \\[tags-loop-continue]."
 746   (interactive "sSearch marked files (regexp): ")
 747   (tags-search regexp '(mapcar 'car (vc-dir-marked-only-files-and-states))))
 748
 749 (defun vc-dir-query-replace-regexp (from to &optional delimited)
 750   "Do `query-replace-regexp' of FROM with TO, on all marked files.
 751 For marked directories, use the files displayed from those directories.
 752 If a directory is marked, then use the files displayed for that directory.
 753 Third arg DELIMITED (prefix arg) means replace only word-delimited matches.
 754 If you exit (\\[keyboard-quit], RET or q), you can resume the query replace
 755 with the command \\[tags-loop-continue]."
 756   ;; FIXME: this is almost a copy of `dired-do-replace-regexp'.  This
 757   ;; should probably be made generic and used in both places instead of
 758   ;; duplicating it here.
 759   (interactive
 760    (let ((common
 761           (query-replace-read-args
 762            "Query replace regexp in marked files" t t)))
 763      (list (nth 0 common) (nth 1 common) (nth 2 common))))
 764   (dolist (file (mapcar 'car (vc-dir-marked-only-files-and-states)))
 765     (let ((buffer (get-file-buffer file)))
 766       (if (and buffer (with-current-buffer buffer
 767                         buffer-read-only))
 768           (error "File `%s' is visited read-only" file))))
 769   (tags-query-replace from to delimited
 770                       '(mapcar 'car (vc-dir-marked-only-files-and-states))))
 771
 772 (defun vc-dir-current-file ()
 773   (let ((node (ewoc-locate vc-ewoc)))
 774     (unless node
 775       (error "No file available"))
 776     (expand-file-name (vc-dir-fileinfo->name (ewoc-data node)))))
 777
 778 (defun vc-dir-marked-files ()
 779   "Return the list of marked files."
 780   (mapcar
 781    (lambda (elem) (expand-file-name (vc-dir-fileinfo->name elem)))
 782    (ewoc-collect vc-ewoc 'vc-dir-fileinfo->marked)))
 783
 784 (defun vc-dir-marked-only-files-and-states ()
 785   "Return the list of conses (FILE . STATE) for the marked files.
 786 For marked directories return the corresponding conses for the
 787 child files."
 788   (let ((crt (ewoc-nth vc-ewoc 0))
 789         result)
 790     (while crt
 791       (let ((crt-data (ewoc-data crt)))
 792         (if (vc-dir-fileinfo->marked crt-data)
 793             ;; FIXME: use vc-dir-child-files-and-states here instead of duplicating it.
 794             (if (vc-dir-fileinfo->directory crt-data)
 795                 (let* ((dir (vc-dir-fileinfo->directory crt-data))
 796                        (dirlen (length dir))
 797                        data)
 798                   (while
 799                       (and (setq crt (ewoc-next vc-ewoc crt))
 800                            (vc-string-prefix-p dir
 801                                                (progn
 802                                                  (setq data (ewoc-data crt))
 803                                                  (vc-dir-node-directory crt))))
 804                     (unless (vc-dir-fileinfo->directory data)
 805                       (push
 806                        (cons (expand-file-name (vc-dir-fileinfo->name data))
 807                              (vc-dir-fileinfo->state data))
 808                        result))))
 809               (push (cons (expand-file-name (vc-dir-fileinfo->name crt-data))
 810                           (vc-dir-fileinfo->state crt-data))
 811                     result)
 812               (setq crt (ewoc-next vc-ewoc crt)))
 813           (setq crt (ewoc-next vc-ewoc crt)))))
 814     (nreverse result)))
 815
 816 (defun vc-dir-child-files-and-states ()
 817   "Return the list of conses (FILE . STATE) for child files of the current entry if it's a directory.
 818 If it is a file, return the corresponding cons for the file itself."
 819   (let* ((crt (ewoc-locate vc-ewoc))
 820          (crt-data (ewoc-data crt))
 821          result)
 822     (if (vc-dir-fileinfo->directory crt-data)
 823         (let* ((dir (vc-dir-fileinfo->directory crt-data))
 824                (dirlen (length dir))
 825                data)
 826           (while
 827               (and (setq crt (ewoc-next vc-ewoc crt))
 828                    (vc-string-prefix-p dir (progn
 829                                              (setq data (ewoc-data crt))
 830                                              (vc-dir-node-directory crt))))
 831             (unless (vc-dir-fileinfo->directory data)
 832               (push
 833                (cons (expand-file-name (vc-dir-fileinfo->name data))
 834                      (vc-dir-fileinfo->state data))
 835                result))))
 836       (push
 837        (cons (expand-file-name (vc-dir-fileinfo->name crt-data))
 838              (vc-dir-fileinfo->state crt-data)) result))
 839     (nreverse result)))
 840
 841 (defun vc-dir-recompute-file-state (fname def-dir)
 842   (let* ((file-short (file-relative-name fname def-dir))
 843          (remove-me-when-CVS-works
 844           (when (eq vc-dir-backend 'CVS)
 845             ;; FIXME: Warning: UGLY HACK.  The CVS backend caches the state
 846             ;; info, this forces the backend to update it.
 847             (vc-call-backend vc-dir-backend 'registered fname)))
 848          (state (vc-call-backend vc-dir-backend 'state fname))
 849          (extra (vc-call-backend vc-dir-backend
 850                                  'status-fileinfo-extra fname)))
 851     (list file-short state extra)))
 852
 853 (defun vc-dir-find-child-files (dirname)
 854   ;; Give a DIRNAME string return the list of all child files shown in
 855   ;; the current *vc-dir* buffer.
 856   (let ((crt (ewoc-nth vc-ewoc 0))
 857         children
 858         dname)
 859     ;; Find DIR
 860     (while (and crt (not (vc-string-prefix-p
 861                           dirname (vc-dir-node-directory crt))))
 862       (setq crt (ewoc-next vc-ewoc crt)))
 863     (while (and crt (vc-string-prefix-p
 864                      dirname
 865                      (setq dname (vc-dir-node-directory crt))))
 866       (let ((data (ewoc-data crt)))
 867         (unless (vc-dir-fileinfo->directory data)
 868           (push (expand-file-name (vc-dir-fileinfo->name data)) children)))
 869       (setq crt (ewoc-next vc-ewoc crt)))
 870     children))
 871
 872 (defun vc-dir-resync-directory-files (dirname)
 873   ;; Update the entries for all the child files of DIRNAME shown in
 874   ;; the current *vc-dir* buffer.
 875   (let ((files (vc-dir-find-child-files dirname))
 876         (ddir default-directory)
 877         fileentries)
 878     (when files
 879       (dolist (crt files)
 880         (push (vc-dir-recompute-file-state crt ddir)
 881               fileentries))
 882       (vc-dir-update fileentries (current-buffer)))))
 883
 884 (defun vc-dir-resynch-file (&optional fname)
 885   "Update the entries for FNAME in any directory buffers that list it."
 886   (let ((file (or fname (expand-file-name buffer-file-name)))
 887         (drop '()))
 888     (save-current-buffer
 889       ;; look for a vc-dir buffer that might show this file.
 890       (dolist (status-buf vc-dir-buffers)
 891         (if (not (buffer-live-p status-buf))
 892             (push status-buf drop)
 893           (set-buffer status-buf)
 894           (if (not (derived-mode-p 'vc-dir-mode))
 895               (push status-buf drop)
 896             (let ((ddir default-directory))
 897               (when (vc-string-prefix-p ddir file)
 898                 (if (file-directory-p file)
 899                     (progn
 900                       (vc-dir-resync-directory-files file)
 901                       (ewoc-set-hf vc-ewoc
 902                                    (vc-dir-headers vc-dir-backend default-directory) ""))
 903                   (let* ((complete-state (vc-dir-recompute-file-state file ddir))
 904                          (state (cadr complete-state)))
 905                     (vc-dir-update
 906                      (list complete-state)
 907                      status-buf (or (not state)
 908                                     (eq state 'up-to-date)))))))))))
 909     ;; Remove out-of-date entries from vc-dir-buffers.
 910     (dolist (b drop) (setq vc-dir-buffers (delq b vc-dir-buffers)))))
 911
 912 (defvar use-vc-backend)  ;; dynamically bound
 913
 914 (define-derived-mode vc-dir-mode special-mode "VC dir"
 915   "Major mode for VC directory buffers.
 916 Marking/Unmarking key bindings and actions:
 917 m - mark a file/directory
 918   - if the region is active, mark all the files in region.
 919     Restrictions: - a file cannot be marked if any parent directory is marked
 920                   - a directory cannot be marked if any child file or
 921                     directory is marked
 922 u - unmark a file/directory
 923   - if the region is active, unmark all the files in region.
 924 M - if the cursor is on a file: mark all the files with the same state as
 925       the current file
 926   - if the cursor is on a directory: mark all child files
 927   - with a prefix argument: mark all files
 928 U - if the cursor is on a file: unmark all the files with the same state
 929       as the current file
 930   - if the cursor is on a directory: unmark all child files
 931   - with a prefix argument: unmark all files
 932 mouse-2  - toggles the mark state
 933
 934 VC commands
 935 VC commands in the `C-x v' prefix can be used.
 936 VC commands act on the marked entries.  If nothing is marked, VC
 937 commands act on the current entry.
 938
 939 Search & Replace
 940 S - searches the marked files
 941 Q - does a query replace on the marked files
 942 M-s a C-s - does an isearch on the marked files
 943 M-s a C-M-s - does a regexp isearch on the marked files
 944 If nothing is marked, these commands act on the current entry.
 945 When a directory is current or marked, the Search & Replace
 946 commands act on the child files of that directory that are displayed in
 947 the *vc-dir* buffer.
 948
 949 \\{vc-dir-mode-map}"
 950   (set (make-local-variable 'vc-dir-backend) use-vc-backend)
 951   (setq buffer-read-only t)
 952   (when (boundp 'tool-bar-map)
 953     (set (make-local-variable 'tool-bar-map) vc-dir-tool-bar-map))
 954   (let ((buffer-read-only nil))
 955     (erase-buffer)
 956     (set (make-local-variable 'vc-dir-process-buffer) nil)
 957     (set (make-local-variable 'vc-ewoc) (ewoc-create #'vc-dir-printer))
 958     (set (make-local-variable 'revert-buffer-function)
 959          'vc-dir-revert-buffer-function)
 960     (setq list-buffers-directory (expand-file-name "*vc-dir*" default-directory))
 961     (add-to-list 'vc-dir-buffers (current-buffer))
 962     ;; Make sure that if the directory buffer is killed, the update
 963     ;; process running in the background is also killed.
 964     (add-hook 'kill-buffer-query-functions 'vc-dir-kill-query nil t)
 965     (vc-dir-refresh)))
 966
 967 (defun vc-dir-headers (backend dir)
 968   "Display the headers in the *VC dir* buffer.
 969 It calls the `dir-extra-headers' backend method to display backend
 970 specific headers."
 971   (concat
 972    ;; First layout the common headers.
 973    (propertize "VC backend : " 'face 'font-lock-type-face)
 974    (propertize (format "%s\n" backend) 'face 'font-lock-variable-name-face)
 975    (propertize "Working dir: " 'face 'font-lock-type-face)
 976    (propertize (format "%s\n" (abbreviate-file-name dir))
 977                'face 'font-lock-variable-name-face)
 978    ;; Then the backend specific ones.
 979    (vc-call-backend backend 'dir-extra-headers dir)
 980    "\n"))
 981
 982 (defun vc-dir-refresh-files (files default-state)
 983   "Refresh some files in the *VC-dir* buffer."
 984   (let ((def-dir default-directory)
 985         (backend vc-dir-backend))
 986     (vc-set-mode-line-busy-indicator)
 987     ;; Call the `dir-status-file' backend function.
 988     ;; `dir-status-file' is supposed to be asynchronous.
 989     ;; It should compute the results, and then call the function
 990     ;; passed as an argument in order to update the vc-dir buffer
 991     ;; with the results.
 992     (unless (buffer-live-p vc-dir-process-buffer)
 993       (setq vc-dir-process-buffer
 994             (generate-new-buffer (format " *VC-%s* tmp status" backend))))
 995     (lexical-let ((buffer (current-buffer)))
 996       (with-current-buffer vc-dir-process-buffer
 997         (cd def-dir)
 998         (erase-buffer)
 999         (vc-call-backend
1000          backend 'dir-status-files def-dir files default-state
1001          (lambda (entries &optional more-to-come)
1002            ;; ENTRIES is a list of (FILE VC_STATE EXTRA) items.
1003            ;; If MORE-TO-COME is true, then more updates will come from
1004            ;; the asynchronous process.
1005            (with-current-buffer buffer
1006              (vc-dir-update entries buffer)
1007              (unless more-to-come
1008                (setq mode-line-process nil)
1009                ;; Remove the ones that haven't been updated at all.
1010                ;; Those not-updated are those whose state is nil because the
1011                ;; file/dir doesn't exist and isn't versioned.
1012                (ewoc-filter vc-ewoc
1013                             (lambda (info)
1014                               ;; The state for directory entries might
1015                               ;; have been changed to 'up-to-date,
1016                               ;; reset it, othewise it will be removed when doing 'x'
1017                               ;; next time.
1018                               ;; FIXME: There should be a more elegant way to do this.
1019                               (when (and (vc-dir-fileinfo->directory info)
1020                                          (eq (vc-dir-fileinfo->state info)
1021                                              'up-to-date))
1022                                 (setf (vc-dir-fileinfo->state info) nil))
1023
1024                               (not (vc-dir-fileinfo->needs-update info))))))))))))
1025
1026 (defun vc-dir-revert-buffer-function (&optional ignore-auto noconfirm)
1027   (vc-dir-refresh))
1028
1029 (defun vc-dir-refresh ()
1030   "Refresh the contents of the *VC-dir* buffer.
1031 Throw an error if another update process is in progress."
1032   (interactive)
1033   (if (vc-dir-busy)
1034       (error "Another update process is in progress, cannot run two at a time")
1035     (let ((def-dir default-directory)
1036           (backend vc-dir-backend))
1037       (vc-set-mode-line-busy-indicator)
1038       ;; Call the `dir-status' backend function.
1039       ;; `dir-status' is supposed to be asynchronous.
1040       ;; It should compute the results, and then call the function
1041       ;; passed as an argument in order to update the vc-dir buffer
1042       ;; with the results.
1043
1044       ;; Create a buffer that can be used by `dir-status' and call
1045       ;; `dir-status' with this buffer as the current buffer.  Use
1046       ;; `vc-dir-process-buffer' to remember this buffer, so that
1047       ;; it can be used later to kill the update process in case it
1048       ;; takes too long.
1049       (unless (buffer-live-p vc-dir-process-buffer)
1050         (setq vc-dir-process-buffer
1051               (generate-new-buffer (format " *VC-%s* tmp status" backend))))
1052       ;; set the needs-update flag on all non-directory entries
1053       (ewoc-map (lambda (info)
1054                   (unless (vc-dir-fileinfo->directory info)
1055                     (setf (vc-dir-fileinfo->needs-update info) t) nil))
1056                 vc-ewoc)
1057       (lexical-let ((buffer (current-buffer)))
1058         (with-current-buffer vc-dir-process-buffer
1059           (cd def-dir)
1060           (erase-buffer)
1061           (vc-call-backend
1062            backend 'dir-status def-dir
1063            (lambda (entries &optional more-to-come)
1064              ;; ENTRIES is a list of (FILE VC_STATE EXTRA) items.
1065              ;; If MORE-TO-COME is true, then more updates will come from
1066              ;; the asynchronous process.
1067              (with-current-buffer buffer
1068                (vc-dir-update entries buffer)
1069                (unless more-to-come
1070                  (let ((remaining
1071                         (ewoc-collect
1072                          vc-ewoc 'vc-dir-fileinfo->needs-update)))
1073                    (if remaining
1074                        (vc-dir-refresh-files
1075                         (mapcar 'vc-dir-fileinfo->name remaining)
1076                         'up-to-date)
1077                      (setq mode-line-process nil)))))))))
1078       (ewoc-set-hf vc-ewoc (vc-dir-headers backend def-dir) ""))))
1079
1080 (defun vc-dir-show-fileentry (file)
1081   "Insert an entry for a specific file into the current *VC-dir* listing.
1082 This is typically used if the file is up-to-date (or has been added
1083 outside of VC) and one wants to do some operation on it."
1084   (interactive "fShow file: ")
1085   (vc-dir-update (list (list (file-relative-name file) (vc-state file))) (current-buffer)))
1086
1087 (defun vc-dir-hide-up-to-date ()
1088   "Hide up-to-date items from display."
1089   (interactive)
1090   (let ((crt (ewoc-nth vc-ewoc -1))
1091         (first (ewoc-nth vc-ewoc 0)))
1092     ;; Go over from the last item to the first and remove the
1093     ;; up-to-date files and directories with no child files.
1094     (while (not (eq crt first))
1095       (let* ((data (ewoc-data crt))
1096              (dir (vc-dir-fileinfo->directory data))
1097              (next (ewoc-next vc-ewoc crt))
1098              (prev (ewoc-prev vc-ewoc crt))
1099              ;; ewoc-delete does not work without this...
1100              (inhibit-read-only t))
1101           (when (or
1102                  ;; Remove directories with no child files.
1103                  (and dir
1104                       (or
1105                        ;; Nothing follows this directory.
1106                        (not next)
1107                        ;; Next item is a directory.
1108                        (vc-dir-fileinfo->directory (ewoc-data next))))
1109                  ;; Remove files in the up-to-date state.
1110                  (eq (vc-dir-fileinfo->state data) 'up-to-date))
1111             (ewoc-delete vc-ewoc crt))
1112           (setq crt prev)))))
1113
1114 (defun vc-dir-kill-line ()
1115   "Remove the current line from display."
1116   (interactive)
1117   (let ((crt (ewoc-locate vc-ewoc))
1118         (inhibit-read-only t))
1119     (ewoc-delete vc-ewoc crt)))
1120
1121 (defun vc-dir-printer (fileentry)
1122   (vc-call-backend vc-dir-backend 'dir-printer fileentry))
1123
1124 (defun vc-dir-deduce-fileset (&optional state-model-only-files)
1125   (let ((marked (vc-dir-marked-files))
1126         files
1127         only-files-list
1128         state
1129         model)
1130     (if marked
1131         (progn
1132           (setq files marked)
1133           (when state-model-only-files
1134             (setq only-files-list (vc-dir-marked-only-files-and-states))))
1135       (let ((crt (vc-dir-current-file)))
1136         (setq files (list crt))
1137         (when state-model-only-files
1138           (setq only-files-list (vc-dir-child-files-and-states)))))
1139
1140     (when state-model-only-files
1141       (setq state (cdar only-files-list))
1142       ;; Check that all files are in a consistent state, since we use that
1143       ;; state to decide which operation to perform.
1144       (dolist (crt (cdr only-files-list))
1145         (unless (vc-compatible-state (cdr crt) state)
1146           (error "When applying VC operations to multiple files, the files are required\nto  be in similar VC states.\n%s in state %s clashes with %s in state %s"
1147                  (car crt) (cdr crt) (caar only-files-list) state)))
1148       (setq only-files-list (mapcar 'car only-files-list))
1149       (when (and state (not (eq state 'unregistered)))
1150         (setq model (vc-checkout-model vc-dir-backend only-files-list))))
1151     (list vc-dir-backend files only-files-list state model)))
1152
1153 ;;;###autoload
1154 (defun vc-dir (dir &optional backend)
1155   "Show the VC status for \"interesting\" files in and below DIR.
1156 This allows you to mark files and perform VC operations on them.
1157 The list omits files which are up to date, with no changes in your copy
1158 or the repository, if there is nothing in particular to say about them.
1159
1160 Preparing the list of file status takes time; when the buffer
1161 first appears, it has only the first few lines of summary information.
1162 The file lines appear later.
1163
1164 Optional second argument BACKEND specifies the VC backend to use.
1165 Interactively, a prefix argument means to ask for the backend.
1166
1167 These are the commands available for use in the file status buffer:
1168
1169 \\{vc-dir-mode-map}"
1170
1171   (interactive
1172    (list
1173     ;; When you hit C-x v d in a visited VC file,
1174     ;; the *vc-dir* buffer visits the directory under its truename;
1175     ;; therefore it makes sense to always do that.
1176     ;; Otherwise if you do C-x v d -> C-x C-f -> C-c v d
1177     ;; you may get a new *vc-dir* buffer, different from the original
1178     (file-truename (read-file-name "VC status for directory: "
1179                                    default-directory default-directory t
1180                                    nil #'file-directory-p))
1181     (if current-prefix-arg
1182         (intern
1183          (completing-read
1184           "Use VC backend: "
1185           (mapcar (lambda (b) (list (symbol-name b)))
1186                   vc-handled-backends)
1187           nil t nil nil)))))
1188   (unless backend
1189     (setq backend (vc-responsible-backend dir)))
1190   (let (pop-up-windows)               ; based on cvs-examine; bug#6204
1191     (pop-to-buffer (vc-dir-prepare-status-buffer "*vc-dir*" dir backend)))
1192   (if (derived-mode-p 'vc-dir-mode)
1193       (vc-dir-refresh)
1194     ;; FIXME: find a better way to pass the backend to `vc-dir-mode'.
1195     (let ((use-vc-backend backend))
1196       (vc-dir-mode))))
1197
1198 (defun vc-default-dir-extra-headers (backend dir)
1199   ;; Be loud by default to remind people to add code to display
1200   ;; backend specific headers.
1201   ;; XXX: change this to return nil before the release.
1202   (concat
1203    (propertize "Extra      : " 'face 'font-lock-type-face)
1204    (propertize "Please add backend specific headers here.  It's easy!"
1205                'face 'font-lock-warning-face)))
1206
1207 (defvar vc-dir-filename-mouse-map
1208    (let ((map (make-sparse-keymap)))
1209      (define-key map [mouse-2] 'vc-dir-find-file-other-window)
1210     map)
1211   "Local keymap for visiting a file.")
1212
1213 (defun vc-default-dir-printer (backend fileentry)
1214   "Pretty print FILEENTRY."
1215   ;; If you change the layout here, change vc-dir-move-to-goal-column.
1216   ;; VC backends can implement backend specific versions of this
1217   ;; function.  Changes here might need to be reflected in the
1218   ;; vc-BACKEND-dir-printer functions.
1219   (let* ((isdir (vc-dir-fileinfo->directory fileentry))
1220         (state (if isdir "" (vc-dir-fileinfo->state fileentry)))
1221         (filename (vc-dir-fileinfo->name fileentry)))
1222     (insert
1223      (propertize
1224       (format "%c" (if (vc-dir-fileinfo->marked fileentry) ?* ? ))
1225       'face 'font-lock-type-face)
1226      "   "
1227      (propertize
1228       (format "%-20s" state)
1229       'face (cond ((eq state 'up-to-date) 'font-lock-builtin-face)
1230                   ((memq state '(missing conflict)) 'font-lock-warning-face)
1231                   (t 'font-lock-variable-name-face))
1232       'mouse-face 'highlight)
1233      " "
1234      (propertize
1235       (format "%s" filename)
1236       'face
1237       (if isdir 'font-lock-comment-delimiter-face 'font-lock-function-name-face)
1238       'help-echo
1239       (if isdir
1240           "Directory\nVC operations can be applied to it\nmouse-3: Pop-up menu"
1241         "File\nmouse-3: Pop-up menu")
1242       'mouse-face 'highlight
1243       'keymap vc-dir-filename-mouse-map))))
1244
1245 (defun vc-default-extra-status-menu (backend)
1246   nil)
1247
1248 (defun vc-default-status-fileinfo-extra (backend file)
1249   "Default absence of extra information returned for a file."
1250   nil)
1251
1252 (provide 'vc-dir)
1253
1254 ;; arch-tag: 0274a2e3-e8e9-4b1a-a73c-e8b9129d5d15
1255 ;;; vc-dir.el ends here