lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer
   2
   3 ;; Copyright (C) 1986, 1987, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Howie Kaye
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package provides the sorting facilities documented in the Emacs
  29 ;; user's manual.
  30
  31 ;;; Code:
  32
  33 (defgroup sort nil
  34   "Commands to sort text in an Emacs buffer."
  35   :group 'data)
  36
  37 (defcustom sort-fold-case nil
  38   "*Non-nil if the buffer sort functions should ignore case."
  39   :group 'sort
  40   :type 'boolean)
  41
  42 ;;;###autoload
  43 (defun sort-subr (reverse nextrecfun endrecfun &optional startkeyfun endkeyfun)
  44   "General text sorting routine to divide buffer into records and sort them.
  45 Arguments are REVERSE NEXTRECFUN ENDRECFUN &optional STARTKEYFUN ENDKEYFUN.
  46
  47 We divide the accessible portion of the buffer into disjoint pieces
  48 called sort records.  A portion of each sort record (perhaps all of
  49 it) is designated as the sort key.  The records are rearranged in the
  50 buffer in order by their sort keys.  The records may or may not be
  51 contiguous.
  52
  53 Usually the records are rearranged in order of ascending sort key.
  54 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  55 The variable `sort-fold-case' determines whether alphabetic case affects
  56 the sort order.
  57
  58 The next four arguments are functions to be called to move point
  59 across a sort record.  They will be called many times from within sort-subr.
  60
  61 NEXTRECFUN is called with point at the end of the previous record.
  62 It moves point to the start of the next record.
  63 It should move point to the end of the buffer if there are no more records.
  64 The first record is assumed to start at the position of point when sort-subr
  65 is called.
  66
  67 ENDRECFUN is called with point within the record.
  68 It should move point to the end of the record.
  69
  70 STARTKEYFUN moves from the start of the record to the start of the key.
  71 It may return either a non-nil value to be used as the key, or
  72 else the key is the substring between the values of point after
  73 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  74 starts at the beginning of the record.
  75
  76 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  77 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  78 same as ENDRECFUN."
  79   ;; Heuristically try to avoid messages if sorting a small amt of text.
  80   (let ((messages (> (- (point-max) (point-min)) 50000)))
  81     (save-excursion
  82       (if messages (message "Finding sort keys..."))
  83       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  84                                            startkeyfun endkeyfun))
  85              (old (reverse sort-lists))
  86              (case-fold-search sort-fold-case))
  87         (if (null sort-lists)
  88             ()
  89           (or reverse (setq sort-lists (nreverse sort-lists)))
  90           (if messages (message "Sorting records..."))
  91           (setq sort-lists
  92                 (if (fboundp 'sortcar)
  93                     (sortcar sort-lists
  94                              (cond ((numberp (car (car sort-lists)))
  95                                     ;; This handles both ints and floats.
  96                                     '<)
  97                                    ((consp (car (car sort-lists)))
  98                                     (function
  99                                      (lambda (a b)
 100                                        (> 0 (compare-buffer-substrings
 101                                              nil (car a) (cdr a)
 102                                              nil (car b) (cdr b))))))
 103                                    (t
 104                                     'string<)))
 105                   (sort sort-lists
 106                         (cond ((numberp (car (car sort-lists)))
 107                                'car-less-than-car)
 108                               ((consp (car (car sort-lists)))
 109                                (function
 110                                 (lambda (a b)
 111                                   (> 0 (compare-buffer-substrings
 112                                         nil (car (car a)) (cdr (car a))
 113                                         nil (car (car b)) (cdr (car b)))))))
 114                               (t
 115                                (function
 116                                 (lambda (a b)
 117                                   (string< (car a) (car b)))))))))
 118           (if reverse (setq sort-lists (nreverse sort-lists)))
 119           (if messages (message "Reordering buffer..."))
 120           (sort-reorder-buffer sort-lists old)))
 121       (if messages (message "Reordering buffer... Done"))))
 122   nil)
 123
 124 ;; Parse buffer into records using the arguments as Lisp expressions;
 125 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
 126 ;; where KEY is the sort key (a number or string),
 127 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
 128
 129 ;; The records appear in the list lastmost first!
 130
 131 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 132   (let ((sort-lists ())
 133         (start-rec nil)
 134         done key)
 135     ;; Loop over sort records.
 136     ;(goto-char (point-min)) -- it is the caller's responsibility to
 137     ;arrange this if necessary
 138     (while (not (eobp))
 139       (setq start-rec (point))          ;save record start
 140       (setq done nil)
 141       ;; Get key value, or move to start of key.
 142       (setq key (catch 'key
 143                   (or (and startkeyfun (funcall startkeyfun))
 144                       ;; If key was not returned as value,
 145                       ;; move to end of key and get key from the buffer.
 146                       (let ((start (point)))
 147                         (funcall (or endkeyfun
 148                                      (prog1 endrecfun (setq done t))))
 149                         (cons start (point))))))
 150       ;; Move to end of this record (start of next one, or end of buffer).
 151       (cond ((prog1 done (setq done nil)))
 152             (endrecfun (funcall endrecfun))
 153             (nextrecfun (funcall nextrecfun) (setq done t)))
 154       (if key (setq sort-lists (cons
 155                                  ;; consing optimization in case in which key
 156                                  ;; is same as record.
 157                                  (if (and (consp key)
 158                                           (equal (car key) start-rec)
 159                                           (equal (cdr key) (point)))
 160                                      (cons key key)
 161                                    (cons key (cons start-rec (point))))
 162                                  sort-lists)))
 163       (and (not done) nextrecfun (funcall nextrecfun)))
 164     sort-lists))
 165
 166 (defun sort-reorder-buffer (sort-lists old)
 167   (let ((last (point-min))
 168         (min (point-min)) (max (point-max))
 169         (old-buffer (current-buffer))
 170         temp-buffer)
 171     (with-temp-buffer
 172       ;; Record the temporary buffer.
 173       (setq temp-buffer (current-buffer))
 174
 175       ;; Copy the sorted text into the temporary buffer.
 176       (while sort-lists
 177         (goto-char (point-max))
 178         (insert-buffer-substring old-buffer
 179                                  last
 180                                  (nth 1 (car old)))
 181         (goto-char (point-max))
 182         (insert-buffer-substring old-buffer
 183                                  (nth 1 (car sort-lists))
 184                                  (cdr (cdr (car sort-lists))))
 185         (setq last (cdr (cdr (car old)))
 186               sort-lists (cdr sort-lists)
 187               old (cdr old)))
 188       (goto-char (point-max))
 189       (insert-buffer-substring old-buffer
 190                                last
 191                                max)
 192
 193       ;; Copy the reordered text from the temporary buffer
 194       ;; to the buffer we sorted (OLD-BUFFER).
 195       (set-buffer old-buffer)
 196       (let ((inhibit-quit t))
 197         ;; Make sure insertions done for reordering
 198         ;; do not go after any markers at the end of the sorted region,
 199         ;; by inserting a space to separate them.
 200         (goto-char max)
 201         (insert-before-markers " ")
 202         ;; Delete the original copy of the text.
 203         (delete-region min max)
 204         ;; Now replace the separator " " with the sorted text.
 205         (goto-char (point-max))
 206         (insert-buffer-substring temp-buffer 1 (1+ (- max min)))
 207         (delete-region min (1+ min))))))
 208
 209 ;;;###autoload
 210 (defun sort-lines (reverse beg end)
 211   "Sort lines in region alphabetically; argument means descending order.
 212 Called from a program, there are three arguments:
 213 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 214 The variable `sort-fold-case' determines whether alphabetic case affects
 215 the sort order."
 216   (interactive "P\nr")
 217   (save-excursion
 218     (save-restriction
 219       (narrow-to-region beg end)
 220       (goto-char (point-min))
 221       (sort-subr reverse 'forward-line 'end-of-line))))
 222
 223 ;;;###autoload
 224 (defun sort-paragraphs (reverse beg end)
 225   "Sort paragraphs in region alphabetically; argument means descending order.
 226 Called from a program, there are three arguments:
 227 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 228 The variable `sort-fold-case' determines whether alphabetic case affects
 229 the sort order."
 230   (interactive "P\nr")
 231   (save-excursion
 232     (save-restriction
 233       (narrow-to-region beg end)
 234       (goto-char (point-min))
 235       (sort-subr reverse
 236                  (function
 237                   (lambda ()
 238                     (while (and (not (eobp)) (looking-at paragraph-separate))
 239                       (forward-line 1))))
 240                  'forward-paragraph))))
 241
 242 ;;;###autoload
 243 (defun sort-pages (reverse beg end)
 244   "Sort pages in region alphabetically; argument means descending order.
 245 Called from a program, there are three arguments:
 246 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 247 The variable `sort-fold-case' determines whether alphabetic case affects
 248 the sort order."
 249   (interactive "P\nr")
 250   (save-excursion
 251     (save-restriction
 252       (narrow-to-region beg end)
 253       (goto-char (point-min))
 254       (sort-subr reverse
 255                  (function (lambda () (skip-chars-forward "\n")))
 256                  'forward-page))))
 257 \f
 258 (defvar sort-fields-syntax-table nil)
 259 (if sort-fields-syntax-table nil
 260   (let ((table (make-syntax-table))
 261         (i 0))
 262     (while (< i 256)
 263       (modify-syntax-entry i "w" table)
 264       (setq i (1+ i)))
 265     (modify-syntax-entry ?\  " " table)
 266     (modify-syntax-entry ?\t " " table)
 267     (modify-syntax-entry ?\n " " table)
 268     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 269     (setq sort-fields-syntax-table table)))
 270
 271 (defcustom sort-numeric-base 10
 272   "*The default base used by `sort-numeric-fields'."
 273   :group 'sort
 274   :type 'integer)
 275
 276 ;;;###autoload
 277 (defun sort-numeric-fields (field beg end)
 278   "Sort lines in region numerically by the ARGth field of each line.
 279 Fields are separated by whitespace and numbered from 1 up.
 280 Specified field must contain a number in each line of the region,
 281 which may begin with \"0x\" or \"0\" for hexadecimal and octal values.
 282 Otherwise, the number is interpreted according to sort-numeric-base.
 283 With a negative arg, sorts by the ARGth field counted from the right.
 284 Called from a program, there are three arguments:
 285 FIELD, BEG and END.  BEG and END specify region to sort."
 286   (interactive "p\nr")
 287   (sort-fields-1 field beg end
 288                  (lambda ()
 289                    (sort-skip-fields field)
 290                    (let* ((case-fold-search t)
 291                           (base
 292                            (if (looking-at "\\(0x\\)[0-9a-f]\\|\\(0\\)[0-7]")
 293                                (cond ((match-beginning 1)
 294                                       (goto-char (match-end 1))
 295                                       16)
 296                                      ((match-beginning 2)
 297                                       (goto-char (match-end 2))
 298                                       8)
 299                                      (t nil)))))
 300                      (string-to-number (buffer-substring (point)
 301                                                          (save-excursion
 302                                                            (forward-sexp 1)
 303                                                            (point)))
 304                                        (or base sort-numeric-base))))
 305                  nil))
 306
 307 ;;;;;###autoload
 308 ;;(defun sort-float-fields (field beg end)
 309 ;;  "Sort lines in region numerically by the ARGth field of each line.
 310 ;;Fields are separated by whitespace and numbered from 1 up.  Specified field
 311 ;;must contain a floating point number in each line of the region.  With a
 312 ;;negative arg, sorts by the ARGth field counted from the right.  Called from a
 313 ;;program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 314 ;;region to sort."
 315 ;;  (interactive "p\nr")
 316 ;;  (sort-fields-1 field beg end
 317 ;;               (function (lambda ()
 318 ;;                           (sort-skip-fields field)
 319 ;;                           (string-to-number
 320 ;;                            (buffer-substring
 321 ;;                             (point)
 322 ;;                             (save-excursion
 323 ;;                               (re-search-forward
 324 ;;                                "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 325 ;;                               (point))))))
 326 ;;               nil))
 327
 328 ;;;###autoload
 329 (defun sort-fields (field beg end)
 330   "Sort lines in region lexicographically by the ARGth field of each line.
 331 Fields are separated by whitespace and numbered from 1 up.
 332 With a negative arg, sorts by the ARGth field counted from the right.
 333 Called from a program, there are three arguments:
 334 FIELD, BEG and END.  BEG and END specify region to sort.
 335 The variable `sort-fold-case' determines whether alphabetic case affects
 336 the sort order."
 337   (interactive "p\nr")
 338   (sort-fields-1 field beg end
 339                  (function (lambda ()
 340                              (sort-skip-fields field)
 341                              nil))
 342                  (function (lambda () (skip-chars-forward "^ \t\n")))))
 343
 344 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 345   (let ((tbl (syntax-table)))
 346     (if (zerop field) (setq field 1))
 347     (unwind-protect
 348         (save-excursion
 349           (save-restriction
 350             (narrow-to-region beg end)
 351             (goto-char (point-min))
 352             (set-syntax-table sort-fields-syntax-table)
 353             (sort-subr nil
 354                        'forward-line 'end-of-line
 355                        startkeyfun endkeyfun)))
 356       (set-syntax-table tbl))))
 357
 358 ;; Position at the beginning of field N on the current line,
 359 ;; assuming point is initially at the beginning of the line.
 360 (defun sort-skip-fields (n)
 361   (if (> n 0)
 362       ;; Skip across N - 1 fields.
 363       (let ((i (1- n)))
 364         (while (> i 0)
 365           (skip-chars-forward " \t")
 366           (skip-chars-forward "^ \t\n")
 367           (setq i (1- i)))
 368         (skip-chars-forward " \t")
 369         (if (eolp)
 370             (error "Line has too few fields: %s"
 371                    (buffer-substring
 372                     (save-excursion (beginning-of-line) (point))
 373                     (save-excursion (end-of-line) (point))))))
 374     (end-of-line)
 375     ;; Skip back across - N - 1 fields.
 376     (let ((i (1- (- n))))
 377       (while (> i 0)
 378         (skip-chars-backward " \t")
 379         (skip-chars-backward "^ \t\n")
 380         (setq i (1- i)))
 381       (skip-chars-backward " \t"))
 382     (if (bolp)
 383         (error "Line has too few fields: %s"
 384                (buffer-substring
 385                 (save-excursion (beginning-of-line) (point))
 386                 (save-excursion (end-of-line) (point)))))
 387     ;; Position at the front of the field
 388     ;; even if moving backwards.
 389     (skip-chars-backward "^ \t\n")))
 390 \f
 391 (defvar sort-regexp-fields-regexp)
 392 (defvar sort-regexp-record-end)
 393
 394 ;; Move to the beginning of the next match for record-regexp,
 395 ;; and set sort-regexp-record-end to the end of that match.
 396 ;; If the next match is empty and does not advance point,
 397 ;; skip one character and try again.
 398 (defun sort-regexp-fields-next-record ()
 399   (let ((oldpos (point)))
 400     (and (re-search-forward sort-regexp-fields-regexp nil 'move)
 401          (setq sort-regexp-record-end (match-end 0))
 402          (if (= sort-regexp-record-end oldpos)
 403              (progn
 404                (forward-char 1)
 405                (re-search-forward sort-regexp-fields-regexp nil 'move)
 406                (setq sort-regexp-record-end (match-end 0)))
 407            t)
 408          (goto-char (match-beginning 0)))))
 409
 410 ;;;###autoload
 411 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 412   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
 413 RECORD-REGEXP specifies the textual units which should be sorted.
 414   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 415 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 416   is to be used for sorting.
 417   If it is \"\\\\digit\" then the digit'th \"\\\\(...\\\\)\" match field from
 418   RECORD-REGEXP is used.
 419   If it is \"\\\\&\" then the whole record is used.
 420   Otherwise, it is a regular-expression for which to search within the record.
 421 If a match for KEY is not found within a record then that record is ignored.
 422
 423 With a negative prefix arg sorts in reverse order.
 424
 425 The variable `sort-fold-case' determines whether alphabetic case affects
 426 the sort order.
 427
 428 For example: to sort lines in the region by the first word on each line
 429  starting with the letter \"f\",
 430  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\\\=\\<f\\\\w*\\\\>\""
 431   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 432   ;; other sort-.*fields functions but then again this was before, since it
 433   ;; didn't use the magnitude of the arg to specify anything.
 434   (interactive "P\nsRegexp specifying records to sort:
 435 sRegexp specifying key within record: \nr")
 436   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 437          (setq key-regexp 0))
 438         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 439          (setq key-regexp (- (aref key-regexp 1) ?0))))
 440   (save-excursion
 441     (save-restriction
 442       (narrow-to-region beg end)
 443       (goto-char (point-min))
 444       (let (sort-regexp-record-end
 445             (sort-regexp-fields-regexp record-regexp))
 446         (re-search-forward sort-regexp-fields-regexp)
 447         (setq sort-regexp-record-end (point))
 448         (goto-char (match-beginning 0))
 449         (sort-subr reverse
 450                    'sort-regexp-fields-next-record
 451                    (function (lambda ()
 452                                (goto-char sort-regexp-record-end)))
 453                    (function (lambda ()
 454                                (let ((n 0))
 455                                  (cond ((numberp key-regexp)
 456                                         (setq n key-regexp))
 457                                        ((re-search-forward
 458                                           key-regexp sort-regexp-record-end t)
 459                                         (setq n 0))
 460                                        (t (throw 'key nil)))
 461                                  (condition-case ()
 462                                      (cons (match-beginning n)
 463                                            (match-end n))
 464                                    ;; if there was no such register
 465                                    (error (throw 'key nil)))))))))))
 466
 467 \f
 468 (defvar sort-columns-subprocess t)
 469
 470 ;;;###autoload
 471 (defun sort-columns (reverse &optional beg end)
 472   "Sort lines in region alphabetically by a certain range of columns.
 473 For the purpose of this command, the region BEG...END includes
 474 the entire line that point is in and the entire line the mark is in.
 475 The column positions of point and mark bound the range of columns to sort on.
 476 A prefix argument means sort into REVERSE order.
 477 The variable `sort-fold-case' determines whether alphabetic case affects
 478 the sort order.
 479
 480 Note that `sort-columns' rejects text that contains tabs,
 481 because tabs could be split across the specified columns
 482 and it doesn't know how to handle that.  Also, when possible,
 483 it uses the `sort' utility program, which doesn't understand tabs.
 484 Use \\[untabify] to convert tabs to spaces before sorting."
 485   (interactive "P\nr")
 486   (save-excursion
 487     (let (beg1 end1 col-beg1 col-end1 col-start col-end)
 488       (goto-char (min beg end))
 489       (setq col-beg1 (current-column))
 490       (beginning-of-line)
 491       (setq beg1 (point))
 492       (goto-char (max beg end))
 493       (setq col-end1 (current-column))
 494       (forward-line)
 495       (setq end1 (point))
 496       (setq col-start (min col-beg1 col-end1))
 497       (setq col-end (max col-beg1 col-end1))
 498       (if (search-backward "\t" beg1 t)
 499           (error "sort-columns does not work with tabs -- use M-x untabify"))
 500       (if (not (or (eq system-type 'vax-vms)
 501                    (text-properties-at beg1)
 502                    (< (next-property-change beg1 nil end1) end1)))
 503           ;; Use the sort utility if we can; it is 4 times as fast.
 504           ;; Do not use it if there are any properties in the region,
 505           ;; since the sort utility would lose the properties.
 506           (let ((sort-args (list (if reverse "-rt\n" "-t\n")
 507                                  (concat "+0." (int-to-string col-start))
 508                                  (concat "-0." (int-to-string col-end)))))
 509             (when sort-fold-case
 510               (push "-f" sort-args))
 511             (apply #'call-process-region beg1 end1 "sort" t t nil sort-args))
 512         ;; On VMS, use Emacs's own facilities.
 513         (save-excursion
 514           (save-restriction
 515             (narrow-to-region beg1 end1)
 516             (goto-char beg1)
 517             (sort-subr reverse 'forward-line 'end-of-line
 518                        #'(lambda () (move-to-column col-start) nil)
 519                        #'(lambda () (move-to-column col-end) nil))))))))
 520
 521 ;;;###autoload
 522 (defun reverse-region (beg end)
 523   "Reverse the order of lines in a region.
 524 From a program takes two point or marker arguments, BEG and END."
 525   (interactive "r")
 526   (if (> beg end)
 527       (let (mid) (setq mid end end beg beg mid)))
 528   (save-excursion
 529     ;; put beg at the start of a line and end and the end of one --
 530     ;; the largest possible region which fits this criteria
 531     (goto-char beg)
 532     (or (bolp) (forward-line 1))
 533     (setq beg (point))
 534     (goto-char end)
 535     ;; the test for bolp is for those times when end is on an empty line;
 536     ;; it is probably not the case that the line should be included in the
 537     ;; reversal; it isn't difficult to add it afterward.
 538     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 539     (setq end (point-marker))
 540     ;; the real work.  this thing cranks through memory on large regions.
 541     (let (ll (do t))
 542       (while do
 543         (goto-char beg)
 544         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 545                        ll))
 546         (setq do (/= (point) end))
 547         (delete-region beg (if do (1+ (point)) (point))))
 548       (while (cdr ll)
 549         (insert (car ll) "\n")
 550         (setq ll (cdr ll)))
 551       (insert (car ll)))))
 552
 553 (provide 'sort)
 554
 555 ;;; sort.el ends here