lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality
   2
   3 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   8 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   9 ;; Keywords: dired extensions files
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  29 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  30 ;; been removed or renamed in order to work properly with dired of GNU
  31 ;; Emacs.  All suggestions or comments are most welcomed.
  32
  33 ;;
  34 ;; Please, PLEASE, *PLEASE* see the info pages.
  35 ;;
  36
  37 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  38
  39 ;; INSTALLATION: In your ~/.emacs,
  40 ;;
  41 ;; (add-hook 'dired-load-hook
  42 ;;           (function (lambda ()
  43 ;;                       (load "dired-x")
  44 ;;                       ;; Set global variables here.  For example:
  45 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  46 ;;                       )))
  47 ;; (add-hook 'dired-mode-hook
  48 ;;           (function (lambda ()
  49 ;;                       ;; Set buffer-local variables here.  For example:
  50 ;;                       ;; (dired-omit-mode 1)
  51 ;;                       )))
  52 ;;
  53 ;; At load time dired-x.el will install itself, redefine some functions, and
  54 ;; bind some dired keys.  *Please* see the info pages for more details.
  55
  56 ;; *Please* see the info pages for more details.
  57
  58 ;; User defined variables:
  59 ;;
  60 ;;      dired-bind-vm
  61 ;;      dired-vm-read-only-folders
  62 ;;      dired-bind-jump
  63 ;;      dired-bind-info
  64 ;;      dired-bind-man
  65 ;;      dired-x-hands-off-my-keys
  66 ;;      dired-find-subdir
  67 ;;      dired-enable-local-variables
  68 ;;      dired-local-variables-file
  69 ;;      dired-guess-shell-gnutar
  70 ;;      dired-guess-shell-gzip-quiet
  71 ;;      dired-guess-shell-znew-switches
  72 ;;      dired-guess-shell-alist-user
  73 ;;      dired-clean-up-buffers-too
  74 ;;      dired-omit-mode
  75 ;;      dired-omit-files
  76 ;;      dired-omit-extensions
  77 ;;      dired-omit-size-limit
  78 ;;
  79 ;; To find out more about these variables, load this file, put your cursor at
  80 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  81 ;; the info pages for more details.
  82
  83 ;; When loaded this code redefines the following functions of GNU Emacs
  84 ;;
  85 ;;   Function                         Found in this file of GNU Emacs
  86 ;;   --------                         -------------------------------
  87 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  88 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  89 ;;   dired-initial-position           ../lisp/dired.el
  90 ;;
  91 ;;   dired-add-entry                  ../lisp/dired-aux.el
  92 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  93
  94 \f
  95 ;;; Code:
  96
  97 ;; LOAD.
  98
  99 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 100 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 101 ;; (instead of autoloading to dired as is suggested in the info-pages).
 102
 103 (require 'dired)
 104
 105 ;; We will redefine some functions and also need some macros so we need to
 106 ;; load dired stuff of GNU Emacs.
 107
 108 (require 'dired-aux)
 109
 110 (defvar vm-folder-directory)
 111 (eval-when-compile (require 'man))
 112
 113 ;;; User-defined variables.
 114
 115 (defgroup dired-x nil
 116   "Extended directory editing (dired-x)."
 117   :group 'dired)
 118
 119 (defgroup dired-keys nil
 120   "Dired keys customizations."
 121   :prefix "dired-"
 122   :group 'dired-x)
 123
 124 (defcustom dired-bind-vm nil
 125   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 126
 127 RMAIL files in the old Babyl format (used before before Emacs 23.1)
 128 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
 129 will run `rmail' on these files.  New RMAIL files use the standard
 130 mbox format, and so cannot be distinguished in this way."
 131   :type 'boolean
 132   :group 'dired-keys)
 133
 134 (defcustom dired-bind-jump t
 135   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 136   :type 'boolean
 137   :group 'dired-keys)
 138
 139 (defcustom dired-bind-man t
 140   "Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 141   :type 'boolean
 142   :group 'dired-keys)
 143
 144 (defcustom dired-bind-info t
 145   "Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 146   :type 'boolean
 147   :group 'dired-keys)
 148
 149 (defcustom dired-vm-read-only-folders nil
 150   "If non-nil, \\[dired-vm] will visit all folders read-only.
 151 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 152 files not writable by you are visited read-only.
 153
 154 Read-only folders only work in VM 5, not in VM 4."
 155   :type '(choice (const :tag "off" nil)
 156                  (const :tag "on" t)
 157                  (other :tag "non-writable only" if-file-read-only))
 158   :group 'dired-x)
 159
 160 (define-minor-mode dired-omit-mode
 161   "Toggle Dired-Omit mode.
 162 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 163 otherwise.  Enabling and disabling is buffer-local.
 164 If enabled, \"uninteresting\" files are not listed.
 165 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 166 plus those ending with extensions in `dired-omit-extensions'.
 167
 168 To enable omitting in every Dired buffer, you can put in your ~/.emacs
 169
 170   (add-hook 'dired-mode-hook (lambda () (dired-omit-mode 1)))
 171
 172 See Info node `(dired-x) Omitting Variables' for more information."
 173   :group 'dired-x
 174   (if dired-omit-mode
 175       ;; This will mention how many lines were omitted:
 176       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 177     (revert-buffer)))
 178
 179 ;; For backward compatibility
 180 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 181
 182 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 183   "Filenames matching this regexp will not be displayed.
 184 This only has effect when `dired-omit-mode' is t.  See interactive function
 185 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 186 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 187 files and lock files."
 188   :type 'regexp
 189   :group 'dired-x)
 190
 191 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 192   "If non-nil, Dired always finds a directory in a buffer of its own.
 193 If nil, Dired finds the directory as a subdirectory in some other buffer
 194 if it is present as one.
 195
 196 If there are several dired buffers for a directory, the most recently
 197 used is chosen.
 198
 199 Dired avoids switching to the current buffer, so that if you have
 200 a normal and a wildcard buffer for the same directory, \\[dired] will
 201 toggle between those two."
 202   :type 'boolean
 203   :group 'dired-x)
 204
 205 (defcustom dired-omit-size-limit 30000
 206   "Maximum size for the \"omitting\" feature.
 207 If nil, there is no maximum size."
 208   :type '(choice (const :tag "no maximum" nil) integer)
 209   :group 'dired-x)
 210
 211 (defcustom dired-enable-local-variables t
 212   "Control use of local-variables lists in Dired.
 213 The value can be t, nil or something else.
 214 A value of t means local-variables lists are obeyed;
 215 nil means they are ignored; anything else means query.
 216
 217 This temporarily overrides the value of `enable-local-variables' when
 218 listing a directory.  See also `dired-local-variables-file'."
 219   :type 'boolean
 220   :group 'dired-x)
 221
 222 (defcustom dired-guess-shell-gnutar (when (or (eq system-type 'gnu)
 223                                               (eq system-type 'gnu/linux))
 224                                       "tar")
 225   "If non-nil, name of GNU tar executable.
 226 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 227 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 228 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 229   :type '(choice (const :tag "Not GNU tar" nil)
 230                  (string :tag "Command name"))
 231   :group 'dired-x)
 232
 233 (defcustom dired-guess-shell-gzip-quiet t
 234   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 235   :type 'boolean
 236   :group 'dired-x)
 237
 238 (defcustom dired-guess-shell-znew-switches nil
 239   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 240   :type '(choice (const :tag "None" nil)
 241                  (string :tag "Switches"))
 242   :group 'dired-x)
 243
 244 (defcustom dired-clean-up-buffers-too t
 245   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 246   :type 'boolean
 247   :group 'dired-x)
 248
 249 ;;; KEY BINDINGS.
 250
 251 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 252 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 253 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 254 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 255 (define-key dired-mode-map "*." 'dired-mark-extension)
 256 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 257 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 258 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 259 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 260 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 261 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 262 (define-key dired-mode-map "V" 'dired-do-run-mail)
 263
 264 (if dired-bind-man
 265     (define-key dired-mode-map "N" 'dired-man))
 266
 267 (if dired-bind-info
 268     (define-key dired-mode-map "I" 'dired-info))
 269
 270 ;;; MENU BINDINGS
 271
 272 (let ((menu-bar (lookup-key dired-mode-map [menu-bar])))
 273   (let ((menu (lookup-key menu-bar [operate])))
 274     (define-key-after
 275       menu
 276       [find-files]
 277       '(menu-item
 278         "Find files"
 279         dired-do-find-marked-files
 280         :help "Find current or marked files")
 281       'delete)
 282     (define-key-after
 283       menu
 284       [relsymlink]
 285       '(menu-item
 286         "Relative symlink to..."
 287         dired-do-relsymlink
 288         :visible (fboundp 'make-symbolic-link)
 289         :help "Make relative symbolic links for current or marked files")
 290       'symlink))
 291   (let ((menu (lookup-key menu-bar [mark])))
 292     (define-key-after
 293       menu
 294       [flag-extension]
 295       '(menu-item
 296         "Flag extension..."
 297         dired-flag-extension
 298         :help "Flag files with a certain extension for deletion")
 299       'garbage-files)
 300     (define-key-after
 301       menu
 302       [mark-extension]
 303       '(menu-item
 304         "Mark extension..."
 305         dired-mark-extension
 306         :help "Mark files with a certain extension")
 307       'symlinks)
 308     (define-key-after
 309       menu
 310       [mark-omitted]
 311       '(menu-item
 312         "Mark omitted"
 313         dired-mark-omitted
 314         :help "Mark files matching `dired-omit-files' and `dired-omit-extensions'")
 315       'mark-extension))
 316   (let ((menu (lookup-key menu-bar [regexp])))
 317     (define-key-after
 318       menu
 319       [relsymlink-regexp]
 320       '(menu-item
 321         "Relative symlink..."
 322         dired-do-relsymlink-regexp
 323         :visible (fboundp 'make-symbolic-link)
 324         :help "Make relative symbolic links for files matching regexp")
 325       'symlink))
 326   (let ((menu (lookup-key menu-bar [immediate])))
 327     (define-key-after
 328       menu
 329       [omit-mode]
 330       '(menu-item
 331         "Omit mode" dired-omit-mode
 332         :button (:toggle . dired-omit-mode)
 333         :help "Enable or disable omitting \"uninteresting\" files")
 334       'dashes)))
 335
 336 ;;; GLOBAL BINDING.
 337 (if dired-bind-jump
 338     (progn
 339       (define-key global-map "\C-x\C-j" 'dired-jump)
 340       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 341
 342 \f
 343 ;; Install into appropriate hooks.
 344
 345 (add-hook 'dired-mode-hook 'dired-extra-startup)
 346 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 347
 348 (defun dired-extra-startup ()
 349   "Automatically put on `dired-mode-hook' to get extra Dired features:
 350 \\<dired-mode-map>
 351   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 352   \\[dired-info]\t-- run info on file
 353   \\[dired-man]\t-- run man on file
 354   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 355   \\[dired-omit-mode]\t-- toggle omitting of files
 356   \\[dired-mark-sexp]\t-- mark by Lisp expression
 357   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 358   \t   you can feed it to other commands using \\[yank]
 359
 360 For more features, see variables
 361
 362   `dired-bind-vm'
 363   `dired-bind-jump'
 364   `dired-bind-info'
 365   `dired-bind-man'
 366   `dired-vm-read-only-folders'
 367   `dired-omit-mode'
 368   `dired-omit-files'
 369   `dired-omit-extensions'
 370   `dired-omit-size-limit'
 371   `dired-find-subdir'
 372   `dired-enable-local-variables'
 373   `dired-local-variables-file'
 374   `dired-guess-shell-gnutar'
 375   `dired-guess-shell-gzip-quiet'
 376   `dired-guess-shell-znew-switches'
 377   `dired-guess-shell-alist-user'
 378   `dired-clean-up-buffers-too'
 379
 380 See also functions
 381
 382   `dired-flag-extension'
 383   `dired-virtual'
 384   `dired-jump'
 385   `dired-man'
 386   `dired-vm'
 387   `dired-rmail'
 388   `dired-info'
 389   `dired-do-find-marked-files'"
 390   (interactive)
 391
 392   ;; These must be done in each new dired buffer.
 393   (dired-hack-local-variables)
 394   (dired-omit-startup))
 395
 396 \f
 397 ;;; BUFFER CLEANING.
 398
 399 ;; REDEFINE.
 400 (defun dired-clean-up-after-deletion (fn)
 401   "Clean up after a deleted file or directory FN.
 402 Remove expanded subdir of deleted dir, if any."
 403   (save-excursion (and (cdr dired-subdir-alist)
 404                        (dired-goto-subdir fn)
 405                        (dired-kill-subdir)))
 406
 407   ;; Offer to kill buffer of deleted file FN.
 408   (if dired-clean-up-buffers-too
 409       (progn
 410         (let ((buf (get-file-buffer fn)))
 411           (and buf
 412                (funcall (function y-or-n-p)
 413                         (format "Kill buffer of %s, too? "
 414                                 (file-name-nondirectory fn)))
 415                (save-excursion ; you never know where kill-buffer leaves you
 416                  (kill-buffer buf))))
 417         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 418               (buf nil))
 419           (and buf-list
 420                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 421                                  (dired-plural-s (length buf-list))
 422                                  (file-name-nondirectory fn)))
 423                (while buf-list
 424                  (save-excursion (kill-buffer (car buf-list)))
 425                  (setq buf-list (cdr buf-list)))))))
 426   ;; Anything else?
 427   )
 428
 429 \f
 430 ;;; EXTENSION MARKING FUNCTIONS.
 431
 432 ;; Mark files with some extension.
 433 (defun dired-mark-extension (extension &optional marker-char)
 434   "Mark all files with a certain EXTENSION for use in later commands.
 435 A `.' is *not* automatically prepended to the string entered."
 436   ;; EXTENSION may also be a list of extensions instead of a single one.
 437   ;; Optional MARKER-CHAR is marker to use.
 438   (interactive "sMarking extension: \nP")
 439   (or (listp extension)
 440       (setq extension (list extension)))
 441   (dired-mark-files-regexp
 442    (concat ".";; don't match names with nothing but an extension
 443            "\\("
 444            (mapconcat 'regexp-quote extension "\\|")
 445            "\\)$")
 446    marker-char))
 447
 448 (defun dired-flag-extension (extension)
 449   "In dired, flag all files with a certain EXTENSION for deletion.
 450 A `.' is *not* automatically prepended to the string entered."
 451   (interactive "sFlagging extension: ")
 452   (dired-mark-extension extension dired-del-marker))
 453
 454 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 455
 456 (defvar dired-patch-unclean-extensions
 457   '(".rej" ".orig")
 458   "List of extensions of dispensable files created by the `patch' program.")
 459
 460 (defvar dired-tex-unclean-extensions
 461   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 462   "List of extensions of dispensable files created by TeX.")
 463
 464 (defvar dired-latex-unclean-extensions
 465   '(".idx" ".lof" ".lot" ".glo")
 466   "List of extensions of dispensable files created by LaTeX.")
 467
 468 (defvar dired-bibtex-unclean-extensions
 469   '(".blg" ".bbl")
 470   "List of extensions of dispensable files created by BibTeX.")
 471
 472 (defvar dired-texinfo-unclean-extensions
 473   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 474     ".tp" ".tps" ".vr" ".vrs")
 475   "List of extensions of dispensable files created by texinfo.")
 476
 477 (defun dired-clean-patch ()
 478   "Flag dispensable files created by patch for deletion.
 479 See variable `dired-patch-unclean-extensions'."
 480   (interactive)
 481   (dired-flag-extension dired-patch-unclean-extensions))
 482
 483 (defun dired-clean-tex ()
 484   "Flag dispensable files created by [La]TeX etc. for deletion.
 485 See variables `dired-tex-unclean-extensions',
 486 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 487 `dired-texinfo-unclean-extensions'."
 488   (interactive)
 489   (dired-flag-extension (append dired-texinfo-unclean-extensions
 490                                 dired-latex-unclean-extensions
 491                                 dired-bibtex-unclean-extensions
 492                                 dired-tex-unclean-extensions)))
 493
 494 (defun dired-very-clean-tex ()
 495   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 496 See variables `dired-texinfo-unclean-extensions',
 497 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 498 `dired-texinfo-unclean-extensions'."
 499   (interactive)
 500   (dired-flag-extension (append dired-texinfo-unclean-extensions
 501                                 dired-latex-unclean-extensions
 502                                 dired-bibtex-unclean-extensions
 503                                 dired-tex-unclean-extensions
 504                                 (list ".dvi"))))
 505 \f
 506 ;;; JUMP.
 507
 508 ;;;###autoload
 509 (defun dired-jump (&optional other-window file-name)
 510   "Jump to dired buffer corresponding to current buffer.
 511 If in a file, dired the current directory and move to file's line.
 512 If in Dired already, pop up a level and goto old directory's line.
 513 In case the proper dired file line cannot be found, refresh the dired
 514 buffer and try again.
 515 When OTHER-WINDOW is non-nil, jump to dired buffer in other window.
 516 Interactively with prefix argument, read FILE-NAME and
 517 move to its line in dired."
 518   (interactive
 519    (list nil (and current-prefix-arg
 520                   (read-file-name "Jump to dired file: "))))
 521   (let* ((file (or file-name buffer-file-name))
 522          (dir (if file (file-name-directory file) default-directory)))
 523     (if (and (eq major-mode 'dired-mode) (null file-name))
 524         (progn
 525           (setq dir (dired-current-directory))
 526           (dired-up-directory other-window)
 527           (or (dired-goto-file dir)
 528               ;; refresh and try again
 529               (progn
 530                 (dired-insert-subdir (file-name-directory dir))
 531                 (dired-goto-file dir))))
 532       (if other-window
 533           (dired-other-window dir)
 534         (dired dir))
 535       (if file
 536           (or (dired-goto-file file)
 537               ;; refresh and try again
 538               (progn
 539                 (dired-insert-subdir (file-name-directory file))
 540                 (dired-goto-file file))
 541               ;; Toggle omitting, if it is on, and try again.
 542               (if dired-omit-mode
 543                   (progn
 544                     (dired-omit-mode)
 545                     (dired-goto-file file))))))))
 546
 547 (defun dired-jump-other-window (&optional file-name)
 548   "Like \\[dired-jump] (`dired-jump') but in other window."
 549   (interactive
 550    (list (and current-prefix-arg
 551               (read-file-name "Jump to dired file: "))))
 552   (dired-jump t file-name))
 553 \f
 554 ;;; OMITTING.
 555
 556 ;; Enhanced omitting of lines from directory listings.
 557 ;; Marked files are never omitted.
 558
 559 ;; should probably get rid of this and always use 'no-dir.
 560 ;; sk 28-Aug-1991 09:37
 561 (defvar dired-omit-localp 'no-dir
 562   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 563 If it is `no-dir', omitting is much faster, but you can only match
 564 against the non-directory part of the file name.  Set it to nil if you
 565 need to match the entire file name.")
 566
 567 ;; \017=^O for Omit - other packages can chose other control characters.
 568 (defvar dired-omit-marker-char ?\017
 569   "Temporary marker used by Dired-Omit.
 570 Should never be used as marker by the user or other packages.")
 571
 572 (defun dired-omit-startup ()
 573   (or (assq 'dired-omit-mode minor-mode-alist)
 574       (setq minor-mode-alist
 575             (append '((dired-omit-mode
 576                        (:eval (if (eq major-mode 'dired-mode)
 577                                   " Omit" ""))))
 578                     minor-mode-alist))))
 579
 580 (defun dired-mark-omitted ()
 581   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 582   (interactive)
 583   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 584   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 585
 586 (defvar dired-omit-extensions
 587   (append completion-ignored-extensions
 588           dired-latex-unclean-extensions
 589           dired-bibtex-unclean-extensions
 590           dired-texinfo-unclean-extensions)
 591   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 592 Defaults to elements of `completion-ignored-extensions',
 593 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 594 `dired-texinfo-unclean-extensions'.
 595
 596 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 597 variables `dired-omit-mode' and `dired-omit-files'.")
 598
 599 (defun dired-omit-expunge (&optional regexp)
 600   "Erases all unmarked files matching REGEXP.
 601 Does nothing if global variable `dired-omit-mode' is nil, or if called
 602   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 603 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 604   filenames ending in `dired-omit-extensions'.
 605 If REGEXP is the empty string, this function is a no-op.
 606
 607 This functions works by temporarily binding `dired-marker-char' to
 608 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 609   (interactive "sOmit files (regexp): ")
 610   (if (and dired-omit-mode
 611            (or (called-interactively-p 'interactive)
 612                (not dired-omit-size-limit)
 613                (< (buffer-size) dired-omit-size-limit)
 614                (progn
 615                  (message "Not omitting: directory larger than %d characters."
 616                           dired-omit-size-limit)
 617                  (setq dired-omit-mode nil)
 618                  nil)))
 619       (let ((omit-re (or regexp (dired-omit-regexp)))
 620             (old-modified-p (buffer-modified-p))
 621             count)
 622         (or (string= omit-re "")
 623             (let ((dired-marker-char dired-omit-marker-char))
 624               (message "Omitting...")
 625               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 626                   (progn
 627                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 628                     (force-mode-line-update))
 629                 (message "(Nothing to omit)"))))
 630         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 631         ;; in mode-line of omitted buffers.
 632         (set-buffer-modified-p (and old-modified-p
 633                                     (save-excursion
 634                                       (goto-char (point-min))
 635                                       (re-search-forward dired-re-mark nil t))))
 636         count)))
 637
 638 (defun dired-omit-regexp ()
 639   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 640           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 641           (if dired-omit-extensions
 642               (concat ".";; a non-extension part should exist
 643                       "\\("
 644                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 645                       "\\)$")
 646             "")))
 647
 648 ;; Returns t if any work was done, nil otherwise.
 649 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 650   "Mark unmarked files matching REGEXP, displaying MSG.
 651 REGEXP is matched against the entire file name.
 652 Does not re-mark files which already have a mark.
 653 With prefix argument, unflag all those files.
 654 Optional fourth argument LOCALP is as in `dired-get-filename'."
 655   (interactive "P")
 656   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 657     (dired-mark-if
 658      (and
 659       ;; not already marked
 660       (looking-at " ")
 661       ;; uninteresting
 662       (let ((fn (dired-get-filename localp t)))
 663         (and fn (string-match regexp fn))))
 664      msg)))
 665
 666 ;; Compiler does not get fset.
 667 (declare-function dired-omit-old-add-entry "dired-x")
 668
 669 ;; REDEFINE.
 670 ;; Redefine dired-aux.el's version of `dired-add-entry'
 671 ;; Save old defun if not already done:
 672 (or (fboundp 'dired-omit-old-add-entry)
 673     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 674
 675 ;; REDEFINE.
 676 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 677   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 678   ;; files that are going to be omitted anyway.
 679   (if dired-omit-mode
 680       ;; perhaps return t without calling ls
 681       (let ((omit-re (dired-omit-regexp)))
 682         (if (or (string= omit-re "")
 683                 (not
 684                  (string-match omit-re
 685                                (cond
 686                                 ((eq 'no-dir dired-omit-localp)
 687                                  filename)
 688                                 ((eq t dired-omit-localp)
 689                                  (dired-make-relative filename))
 690                                 (t
 691                                  (dired-make-absolute
 692                                   filename
 693                                   (file-name-directory filename)))))))
 694             ;; if it didn't match, go ahead and add the entry
 695             (dired-omit-old-add-entry filename marker-char relative)
 696           ;; dired-add-entry returns t for success, perhaps we should
 697           ;; return file-exists-p
 698           t))
 699     ;; omitting is not turned on at all
 700     (dired-omit-old-add-entry filename marker-char relative)))
 701
 702 ;; Redefine it.
 703 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 704
 705 \f
 706 ;;; VIRTUAL DIRED MODE.
 707
 708 ;; For browsing `ls -lR' listings in a dired-like fashion.
 709
 710 (defalias 'virtual-dired 'dired-virtual)
 711 (defun dired-virtual (dirname &optional switches)
 712   "Put this buffer into Virtual Dired mode.
 713
 714 In Virtual Dired mode, all commands that do not actually consult the
 715 filesystem will work.
 716
 717 This is useful if you want to peruse and move around in an ls -lR
 718 output file, for example one you got from an ftp server.  With
 719 ange-ftp, you can even dired a directory containing an ls-lR file,
 720 visit that file and turn on virtual dired mode.  But don't try to save
 721 this file, as dired-virtual indents the listing and thus changes the
 722 buffer.
 723
 724 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 725 resume it in a later session.
 726
 727 Type \\<dired-mode-map>\\[revert-buffer] \
 728 in the Virtual Dired buffer and answer `y' to convert
 729 the virtual to a real dired buffer again.  You don't have to do this, though:
 730 you can relist single subdirs using \\[dired-do-redisplay]."
 731
 732   ;; DIRNAME is the top level directory of the buffer.  It will become
 733   ;; its `default-directory'.  If nil, the old value of
 734   ;; default-directory is used.
 735
 736   ;; Optional SWITCHES are the ls switches to use.
 737
 738   ;; Shell wildcards will be used if there already is a `wildcard'
 739   ;; line in the buffer (thus it is a saved Dired buffer), but there
 740   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 741   ;; hand if you want them.
 742
 743   (interactive
 744    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 745   (goto-char (point-min))
 746   (or (looking-at "  ")
 747       ;; if not already indented, do it now:
 748       (indent-region (point-min) (point-max) 2))
 749   (or dirname (setq dirname default-directory))
 750   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 751   (setq default-directory dirname)      ; contains no wildcards
 752   (let ((wildcard (save-excursion
 753                     (goto-char (point-min))
 754                     (forward-line 1)
 755                     (and (looking-at "^  wildcard ")
 756                          (buffer-substring (match-end 0)
 757                                            (progn (end-of-line) (point)))))))
 758   (if wildcard
 759         (setq dirname (expand-file-name wildcard default-directory))))
 760   ;; If raw ls listing (not a saved old dired buffer), give it a
 761   ;; decent subdir headerline:
 762   (goto-char (point-min))
 763   (or (looking-at dired-subdir-regexp)
 764       (insert "  "
 765               (directory-file-name (file-name-directory default-directory))
 766               ":\n"))
 767   (dired-mode dirname (or switches dired-listing-switches))
 768   (setq mode-name "Virtual Dired"
 769         revert-buffer-function 'dired-virtual-revert)
 770   (set (make-local-variable 'dired-subdir-alist) nil)
 771   (dired-build-subdir-alist)
 772   (goto-char (point-min))
 773   (dired-initial-position dirname))
 774
 775 (defun dired-virtual-guess-dir ()
 776   "Guess and return appropriate working directory of this buffer.
 777 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 778 based upon buffer contents.  If nothing could be guessed, returns
 779 nil."
 780
 781   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 782         (subexpr 2))
 783     (goto-char (point-min))
 784     (cond ((looking-at regexp)
 785            ;; If a saved dired buffer, look to which dir and
 786            ;; perhaps wildcard it belongs:
 787            (let ((dir (buffer-substring (match-beginning subexpr)
 788                                         (match-end subexpr))))
 789              (file-name-as-directory dir)))
 790           ;; Else no match for headerline found.  It's a raw ls listing.
 791           ;; In raw ls listings the directory does not have a headerline
 792           ;; try parent of first subdir, if any
 793           ((re-search-forward regexp nil t)
 794            (file-name-directory
 795             (directory-file-name
 796              (file-name-as-directory
 797               (buffer-substring (match-beginning subexpr)
 798                                 (match-end subexpr))))))
 799           (t                            ; if all else fails
 800            nil))))
 801
 802
 803 (defun dired-virtual-revert (&optional arg noconfirm)
 804   (if (not
 805        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 806       (error "Cannot revert a Virtual Dired buffer")
 807     (setq mode-name "Dired"
 808           revert-buffer-function 'dired-revert)
 809     (revert-buffer)))
 810
 811 ;; A zero-arg version of dired-virtual.
 812 (defun dired-virtual-mode ()
 813   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 814 Useful on `magic-mode-alist' with the regexp
 815
 816   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 817
 818 to put saved dired buffers automatically into Virtual Dired mode.
 819
 820 Also useful for `auto-mode-alist' like this:
 821
 822   (add-to-list 'auto-mode-alist
 823                '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))"
 824   (interactive)
 825   (dired-virtual (dired-virtual-guess-dir)))
 826
 827 \f
 828 ;;; SMART SHELL.
 829
 830 ;; An Emacs buffer can have but one working directory, stored in the
 831 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 832 ;; several subdirectories inserted, but still has but one working directory:
 833 ;; that of the top level Dired directory in that buffer.  For some commands
 834 ;; it is appropriate that they use the current Dired directory instead of
 835 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 836 ;; mechanism is provided for special handling of the working directory in
 837 ;; special major modes.
 838
 839 ;; It's easier to add to this alist than redefine function
 840 ;; default-directory while keeping the old information.
 841 (defconst default-directory-alist
 842   '((dired-mode . (if (fboundp 'dired-current-directory)
 843                       (dired-current-directory)
 844                     default-directory)))
 845   "Alist of major modes and their opinion on `default-directory'.
 846 This is given as a Lisp expression to evaluate.  A resulting value of
 847 nil is ignored in favor of `default-directory'.")
 848
 849 (defun dired-default-directory ()
 850   "Usage like variable `default-directory'.
 851 Knows about the special cases in variable `default-directory-alist'."
 852   (or (eval (cdr (assq major-mode default-directory-alist)))
 853       default-directory))
 854
 855 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 856   "Like function `shell-command', but in the current Virtual Dired directory."
 857   (interactive
 858    (list
 859     (read-shell-command "Shell command: " nil nil
 860                         (cond
 861                          (buffer-file-name (file-relative-name buffer-file-name))
 862                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 863     current-prefix-arg
 864     shell-command-default-error-buffer))
 865   (let ((default-directory (dired-default-directory)))
 866     (shell-command command output-buffer error-buffer)))
 867
 868 \f
 869 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 870
 871 ;; Brief Description:
 872 ;;;
 873 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 874 ;;;
 875 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 876 ;;;
 877 ;; * `dired-hack-local-variables' checks the value of
 878 ;;;   `dired-local-variables-file'
 879 ;;;
 880 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 881 ;;;   filename found in the directory of the Dired Buffer being created.
 882 ;;;
 883 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 884 ;;;   include it in the Dired Buffer at the bottom.
 885 ;;;
 886 ;; * Set `enable-local-variables' temporarily to the user variable
 887 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 888 ;;;   Dired Buffer.
 889
 890 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 891   "Filename, as string, containing local dired buffer variables to be hacked.
 892 If this file found in current directory, then it will be inserted into dired
 893 buffer and `hack-local-variables' will be run.  See Info node
 894 `(emacs)File Variables' for more information on local variables.
 895 See also `dired-enable-local-variables'.")
 896
 897 (defun dired-hack-local-variables ()
 898   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 899   (if (and dired-local-variables-file
 900            (stringp dired-local-variables-file)
 901            (file-exists-p dired-local-variables-file))
 902       (let ((opoint (point-max))
 903             buffer-read-only
 904             ;; In case user has `enable-local-variables' set to nil we
 905             ;; override it locally with dired's variable.
 906             (enable-local-variables dired-enable-local-variables))
 907         ;; Insert 'em.
 908         (save-excursion
 909           (goto-char opoint)
 910           (insert "\^L\n")
 911           (insert-file-contents dired-local-variables-file))
 912         ;; Hack 'em.
 913         (let ((buffer-file-name dired-local-variables-file))
 914           (hack-local-variables))
 915         ;; Make sure that the modeline shows the proper information.
 916         (dired-sort-set-modeline)
 917         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 918         (delete-region opoint (point-max)))))
 919
 920 (defun dired-omit-here-always ()
 921   "Create `dired-local-variables-file' for omitting and reverts directory.
 922 Sets `dired-omit-mode' to t in a local variables file that is readable by
 923 dired."
 924   (interactive)
 925   (if (file-exists-p dired-local-variables-file)
 926       (message "File `./%s' already exists." dired-local-variables-file)
 927
 928     ;; Create `dired-local-variables-file'.
 929     (with-current-buffer (get-buffer-create " *dot-dired*")
 930       (erase-buffer)
 931       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 932       (write-file dired-local-variables-file)
 933       (kill-buffer (current-buffer)))
 934
 935     ;; Run extra-hooks and revert directory.
 936     (dired-extra-startup)
 937     (dired-revert)))
 938
 939 \f
 940 ;;; GUESS SHELL COMMAND.
 941
 942 ;; Brief Description:
 943 ;;;
 944 ;; `dired-do-shell-command' is bound to `!' by dired.el.
 945 ;;;
 946 ;; * Redefine `dired-read-shell-command' so it calls
 947 ;;;   `dired-guess-shell-command'.
 948 ;;;
 949 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 950 ;;;    marked files.
 951 ;;;
 952 ;; * Parse `dired-guess-shell-alist-user' and
 953 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 954 ;;;   that matches the first file in the file list.
 955 ;;;
 956 ;; * If the REGEXP matches all the entries of the file list then evaluate
 957 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 958 ;;;   string.  COMMAND may be a list of commands.
 959 ;;;
 960 ;; * Return this command to `dired-guess-shell-command' which prompts user
 961 ;;;   with it.  The list of commands is put into the list of default values.
 962 ;;;   If a command is used successfully then it is stored permanently in
 963 ;;;   `dired-shell-command-history'.
 964
 965 ;; Guess what shell command to apply to a file.
 966 (defvar dired-shell-command-history nil
 967   "History list for commands that read dired-shell commands.")
 968
 969 ;; Default list of shell commands.
 970
 971 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 972 ;; install GNU zip's version of zcat.
 973
 974 (defvar dired-guess-shell-alist-default
 975   (list
 976    (list "\\.tar$"
 977          '(if dired-guess-shell-gnutar
 978               (concat dired-guess-shell-gnutar " xvf")
 979             "tar xvf")
 980          ;; Extract files into a separate subdirectory
 981          '(if dired-guess-shell-gnutar
 982               (concat "mkdir " (file-name-sans-extension file)
 983                       "; " dired-guess-shell-gnutar " -C "
 984                       (file-name-sans-extension file) " -xvf")
 985             (concat "mkdir " (file-name-sans-extension file)
 986                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 987          ;; List archive contents.
 988          '(if dired-guess-shell-gnutar
 989               (concat dired-guess-shell-gnutar " tvf")
 990             "tar tvf"))
 991
 992    ;; REGEXPS for compressed archives must come before the .Z rule to
 993    ;; be recognized:
 994    (list "\\.tar\\.Z$"
 995          ;; Untar it.
 996          '(if dired-guess-shell-gnutar
 997               (concat dired-guess-shell-gnutar " zxvf")
 998             (concat "zcat * | tar xvf -"))
 999          ;; Optional conversion to gzip format.
1000          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1001                   " " dired-guess-shell-znew-switches))
1002
1003    ;; gzip'ed archives
1004    (list "\\.t\\(ar\\.\\)?gz$"
1005          '(if dired-guess-shell-gnutar
1006               (concat dired-guess-shell-gnutar " zxvf")
1007             (concat "gunzip -qc * | tar xvf -"))
1008          ;; Extract files into a separate subdirectory
1009          '(if dired-guess-shell-gnutar
1010               (concat "mkdir " (file-name-sans-extension file)
1011                       "; " dired-guess-shell-gnutar " -C "
1012                       (file-name-sans-extension file) " -zxvf")
1013             (concat "mkdir " (file-name-sans-extension file)
1014                     "; gunzip -qc * | tar -C "
1015                     (file-name-sans-extension file) " -xvf -"))
1016          ;; Optional decompression.
1017          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
1018          ;; List archive contents.
1019          '(if dired-guess-shell-gnutar
1020               (concat dired-guess-shell-gnutar " ztvf")
1021             (concat "gunzip -qc * | tar tvf -")))
1022
1023    ;; bzip2'ed archives
1024    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
1025          "bunzip2 -c * | tar xvf -"
1026          ;; Extract files into a separate subdirectory
1027          '(concat "mkdir " (file-name-sans-extension file)
1028                   "; bunzip2 -c * | tar -C "
1029                   (file-name-sans-extension file) " -xvf -")
1030          ;; Optional decompression.
1031          "bunzip2")
1032
1033    ;; xz'ed archives
1034    (list "\\.t\\(ar\\.\\)?xz$"
1035          "unxz -c * | tar xvf -"
1036          ;; Extract files into a separate subdirectory
1037          '(concat "mkdir " (file-name-sans-extension file)
1038                   "; unxz -c * | tar -C "
1039                   (file-name-sans-extension file) " -xvf -")
1040          ;; Optional decompression.
1041          "unxz")
1042
1043    '("\\.shar\\.Z$" "zcat * | unshar")
1044    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
1045
1046    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
1047    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
1048          ;; Optional decompression.
1049          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1050    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
1051          ;; Optional conversion to gzip format.
1052          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1053                   " " dired-guess-shell-znew-switches))
1054
1055    '("\\.patch$" "cat * | patch")
1056    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
1057          ;; Optional decompression.
1058          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1059    (list "\\.patch\\.Z$" "zcat * | patch"
1060          ;; Optional conversion to gzip format.
1061          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1062                   " " dired-guess-shell-znew-switches))
1063
1064    ;; The following four extensions are useful with dired-man ("N" key)
1065    (list "\\.\\(?:[0-9]\\|man\\)$" '(progn (require 'man)
1066                                            (if (Man-support-local-filenames)
1067                                                "man -l"
1068                                              "cat * | tbl | nroff -man -h")))
1069    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z$" '(progn (require 'man)
1070                                                  (if (Man-support-local-filenames)
1071                                                      "man -l"
1072                                                    "gunzip -qc * | tbl | nroff -man -h"))
1073          ;; Optional decompression.
1074          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1075    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
1076                                  (if (Man-support-local-filenames)
1077                                      "man -l"
1078                                    "zcat * | tbl | nroff -man -h"))
1079          ;; Optional conversion to gzip format.
1080          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1081                   " " dired-guess-shell-znew-switches))
1082    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
1083
1084    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
1085    '("\\.au$" "play")                   ; play Sun audiofiles
1086    '("\\.mpe?g$\\|\\.avi$" "xine -p")
1087    '("\\.ogg$" "ogg123")
1088    '("\\.mp3$" "mpg123")
1089    '("\\.wav$" "play")
1090    '("\\.uu$" "uudecode")               ; for uudecoded files
1091    '("\\.hqx$" "mcvert")
1092    '("\\.sh$" "sh")                     ; execute shell scripts
1093    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
1094    '("\\.gp$" "gnuplot")
1095    '("\\.p[bgpn]m$" "xloadimage")
1096    '("\\.gif$" "xloadimage")            ; view gif pictures
1097    '("\\.tif$" "xloadimage")
1098    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
1099    '("\\.jpe?g$" "xloadimage")
1100    '("\\.fig$" "xfig")                  ; edit fig pictures
1101    '("\\.out$" "xgraph")                ; for plotting purposes.
1102    '("\\.tex$" "latex" "tex")
1103    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
1104    '("\\.pdf$" "xpdf")
1105    '("\\.doc$" "antiword" "strings")
1106    '("\\.rpm$" "rpm -qilp" "rpm -ivh")
1107    '("\\.dia$" "dia")
1108    '("\\.mgp$" "mgp")
1109
1110    ;; Some other popular archivers.
1111    (list "\\.zip$" "unzip" "unzip -l"
1112          ;; Extract files into a separate subdirectory
1113          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1114                   " -d " (file-name-sans-extension file)))
1115    '("\\.zoo$" "zoo x//")
1116    '("\\.lzh$" "lharc x")
1117    '("\\.arc$" "arc x")
1118    '("\\.shar$" "unshar")
1119
1120    ;; Compression.
1121    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1122    (list "\\.dz$" "dictunzip")
1123    (list "\\.bz2$" "bunzip2")
1124    (list "\\.xz$" "unxz")
1125    (list "\\.Z$" "uncompress"
1126          ;; Optional conversion to gzip format.
1127          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1128                   " " dired-guess-shell-znew-switches))
1129
1130    '("\\.sign?$" "gpg --verify"))
1131
1132   "Default alist used for shell command guessing.
1133 See `dired-guess-shell-alist-user'.")
1134
1135 (defcustom dired-guess-shell-alist-user nil
1136   "User-defined alist of rules for suggested commands.
1137 These rules take precedence over the predefined rules in the variable
1138 `dired-guess-shell-alist-default' (to which they are prepended).
1139
1140 Each element of this list looks like
1141
1142     \(REGEXP COMMAND...\)
1143
1144 where each COMMAND can either be a string or a Lisp expression that evaluates
1145 to a string.  If several COMMANDs are given, the first one will be the default
1146 and the rest will be added temporarily to the history and can be retrieved
1147 with \\[previous-history-element] (M-p) .
1148
1149 The variable `dired-guess-shell-case-fold-search' controls whether
1150 REGEXP is matched case-sensitively.
1151
1152 You can set this variable in your ~/.emacs.  For example, to add rules for
1153 `.foo' and `.bar' files, write
1154
1155  \(setq dired-guess-shell-alist-user
1156        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1157               ;; possibly more rules ...
1158               (list \"\\\\.bar\\\\'\";; rule with condition test
1159                     '(if condition
1160                           \"BAR-COMMAND-1\"
1161                         \"BAR-COMMAND-2\")))\)"
1162   :group 'dired-x
1163   :type '(alist :key-type regexp :value-type (repeat sexp)))
1164
1165 (defcustom dired-guess-shell-case-fold-search t
1166   "If non-nil, `dired-guess-shell-alist-default' and
1167 `dired-guess-shell-alist-user' are matched case-insensitively."
1168   :group 'dired-x
1169   :type 'boolean)
1170
1171 (defun dired-guess-default (files)
1172   "Guess a shell commands for FILES.  Return command or list of commands.
1173 See `dired-guess-shell-alist-user'."
1174
1175   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1176          ;; Prepend the user's alist to the default alist.
1177          (alist (append dired-guess-shell-alist-user
1178                         dired-guess-shell-alist-default))
1179          (file (car files))
1180          (flist (cdr files))
1181          elt regexp cmds)
1182
1183     ;; Find the first match in the alist for first file in FILES.
1184     (while alist
1185       (setq elt (car alist)
1186             regexp (car elt)
1187             alist (cdr alist))
1188       (if (string-match regexp file)
1189           (setq cmds (cdr elt)
1190                 alist nil)))
1191
1192     ;; If more than one file, see if all of FILES match regular expression.
1193     (while (and flist
1194                 (string-match regexp (car flist)))
1195       (setq flist (cdr flist)))
1196
1197     ;; If flist is still non-nil, then do not guess since this means that not
1198     ;; all the files in FILES were matched by the regexp.
1199     (setq cmds (and (not flist) cmds))
1200
1201     ;; Return commands or nil if flist is still non-nil.
1202     ;; Evaluate the commands in order that any logical testing will be done.
1203     (cond ((not (cdr cmds))
1204            (eval (car cmds))) ; single command
1205           (t
1206            (mapcar (function eval) cmds)))))
1207
1208 (defun dired-guess-shell-command (prompt files)
1209   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1210   (let ((default (dired-guess-default files))
1211         default-list val)
1212     (if (null default)
1213         ;; Nothing to guess
1214         (read-shell-command prompt nil 'dired-shell-command-history)
1215       (if (listp default)
1216           ;; More than one guess
1217           (setq default-list default
1218                 default (car default)
1219                 prompt (concat
1220                         prompt
1221                         (format "{%d guesses} " (length default-list))))
1222         ;; Just one guess
1223         (setq default-list (list default)))
1224       ;; Put the first guess in the prompt but not in the initial value.
1225       (setq prompt (concat prompt (format "[%s] " default)))
1226       ;; All guesses can be retrieved with M-n
1227       (setq val (read-shell-command prompt nil
1228                                     'dired-shell-command-history
1229                                     default-list))
1230       ;; If we got a return, then return default.
1231       (if (equal val "") default val))))
1232
1233 ;; REDEFINE.
1234 ;; Redefine dired-aux.el's version:
1235 (defun dired-read-shell-command (prompt arg files)
1236   "Read a dired shell command prompting with PROMPT (using `read-shell-command').
1237 ARG is the prefix arg and may be used to indicate in the prompt which
1238 FILES are affected.
1239 This is an extra function so that you can redefine it."
1240   (minibuffer-with-setup-hook
1241       (lambda ()
1242         (set (make-local-variable 'minibuffer-default-add-function)
1243              'minibuffer-default-add-dired-shell-commands))
1244     (dired-mark-pop-up
1245      nil 'shell files
1246      'dired-guess-shell-command
1247      (format prompt (dired-mark-prompt arg files)) ; PROMPT
1248      files)))                                      ; FILES
1249
1250 \f
1251 ;;; RELATIVE SYMBOLIC LINKS.
1252
1253 (declare-function make-symbolic-link "fileio.c")
1254
1255 (defvar dired-keep-marker-relsymlink ?S
1256   "See variable `dired-keep-marker-move'.")
1257
1258 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1259   "Make a symbolic link (pointing to FILE1) in FILE2.
1260 The link is relative (if possible), for example
1261
1262     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1263
1264 results in
1265
1266     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1267   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1268   (let (name1 name2 len1 len2 (index 0) sub)
1269     (setq file1 (expand-file-name file1)
1270           file2 (expand-file-name file2)
1271           len1 (length file1)
1272           len2 (length file2))
1273     ;; Find common initial file name components:
1274     (let (next)
1275       (while (and (setq next (string-match "/" file1 index))
1276                   (setq next (1+ next))
1277                   (< next (min len1 len2))
1278                   ;; For the comparison, both substrings must end in
1279                   ;; `/', so NEXT is *one plus* the result of the
1280                   ;; string-match.
1281                   ;; E.g., consider the case of linking "/tmp/a/abc"
1282                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1283                   ;; of "/tmp/" as common initial component
1284                   (string-equal (substring file1 0 next)
1285                                 (substring file2 0 next)))
1286         (setq index next))
1287       (setq name2 file2
1288             sub (substring file1 0 index)
1289             name1 (substring file1 index)))
1290     (if (string-equal sub "/")
1291         ;; No common initial file name found
1292         (setq name1 file1)
1293       ;; Else they have a common parent directory
1294       (let ((tem (substring file2 index))
1295             (start 0)
1296             (count 0))
1297         ;; Count number of slashes we must compensate for ...
1298         (while (setq start (string-match "/" tem start))
1299           (setq count (1+ count)
1300                 start (1+ start)))
1301         ;; ... and prepend a "../" for each slash found:
1302         (while (> count 0)
1303           (setq count (1- count)
1304                 name1 (concat "../" name1)))))
1305     (make-symbolic-link
1306      (directory-file-name name1)        ; must not link to foo/
1307                                         ; (trailing slash!)
1308      name2 ok-if-already-exists)))
1309
1310 ;;;###autoload
1311 (defun dired-do-relsymlink (&optional arg)
1312    "Relative symlink all marked (or next ARG) files into a directory.
1313 Otherwise make a relative symbolic link to the current file.
1314 This creates relative symbolic links like
1315
1316     foo -> ../bar/foo
1317
1318 not absolute ones like
1319
1320     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1321
1322 For absolute symlinks, use \\[dired-do-symlink]."
1323   (interactive "P")
1324   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1325                            "RelSymLink" arg dired-keep-marker-relsymlink))
1326
1327 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1328   "RelSymlink all marked files containing REGEXP to NEWNAME.
1329 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1330 for more info."
1331   (interactive (dired-mark-read-regexp "RelSymLink"))
1332   (dired-do-create-files-regexp
1333    (function dired-make-relative-symlink)
1334    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1335
1336 \f
1337 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1338
1339 ;; Brief Description:
1340 ;;;
1341 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1342 ;;;
1343 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1344 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1345 ;;;
1346 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1347 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1348 ;;;
1349 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1350 ;;;   list each time.
1351 ;;;
1352 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1353 ;;;   element of FILE-LIST.
1354 ;;;
1355 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1356 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1357 ;;;   cognizant of the window-configuration.
1358 ;;;
1359 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1360 ;;;   of FILE-LIST giving each a window of height `size'.
1361
1362 (defun dired-do-find-marked-files (&optional noselect)
1363   "Find all marked files displaying all of them simultaneously.
1364 With optional NOSELECT just find files but do not select them.
1365
1366 The current window is split across all files marked, as evenly as possible.
1367 Remaining lines go to bottom-most window.  The number of files that can be
1368 displayed this way is restricted by the height of the current window and
1369 `window-min-height'.
1370
1371 To keep dired buffer displayed, type \\[split-window-vertically] first.
1372 To display just marked files, type \\[delete-other-windows] first."
1373
1374   (interactive "P")
1375   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1376
1377 (defun dired-simultaneous-find-file (file-list noselect)
1378
1379   "Visit all files in FILE-LIST and display them simultaneously.
1380 The current window is split across all files in FILE-LIST, as evenly as
1381 possible.  Remaining lines go to the bottom-most window.  The number of
1382 files that can be displayed this way is restricted by the height of the
1383 current window and the variable `window-min-height'.  With non-nil
1384 NOSELECT the files are merely found but not selected."
1385
1386   ;; We don't make this function interactive because it is usually too clumsy
1387   ;; to specify FILE-LIST interactively unless via dired.
1388
1389   (let (size)
1390
1391     (if noselect
1392         ;; Do not select the buffer.
1393         (find-file-noselect (car file-list))
1394
1395       ;; We will have to select the buffer.  Calculate and check window size.
1396       (setq size (/ (window-height) (length file-list)))
1397       (or (<= window-min-height size)
1398           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1399       (find-file (car file-list)))
1400
1401     ;; Decrement.
1402     (setq file-list (cdr file-list))
1403
1404     (while file-list
1405
1406       (if noselect
1407           ;; Do not select the buffer.
1408           (find-file-noselect (car file-list))
1409
1410         ;; Vertically split off a window of desired size.  Upper window will
1411         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1412         (select-window (split-window nil size))
1413         (find-file (car file-list)))
1414
1415       ;; Decrement.
1416       (setq file-list (cdr file-list)))))
1417
1418 \f
1419 ;;; MISCELLANEOUS COMMANDS.
1420
1421 ;; Run man on files.
1422
1423 (defun dired-man ()
1424   "Run man on this file.  Display old buffer if buffer name matches filename.
1425 Uses `man.el' of \\[manual-entry] fame."
1426   (interactive)
1427   (require 'man)
1428   (let* ((file (dired-get-filename))
1429          (manual-program (replace-regexp-in-string "\\*" "%s"
1430                           (dired-guess-shell-command
1431                            "Man command: " (list file)))))
1432     (Man-getpage-in-background file)))
1433
1434 ;; Run Info on files.
1435
1436 (defun dired-info ()
1437   "Run info on this file."
1438   (interactive)
1439   (info (dired-get-filename)))
1440
1441 ;; Run mail on mail folders.
1442
1443 ;; Avoid compiler warning.
1444 (eval-when-compile
1445   (when (not (fboundp 'vm-visit-folder))
1446     (defun vm-visit-folder (file &optional arg)
1447       nil)))
1448
1449 (defun dired-vm (&optional read-only)
1450   "Run VM on this file.
1451 With prefix arg, visit folder read-only (this requires at least VM 5).
1452 See also variable `dired-vm-read-only-folders'."
1453   (interactive "P")
1454   (let ((dir (dired-current-directory))
1455         (fil (dired-get-filename)))
1456     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1457     (cond (read-only (vm-visit-folder fil t))
1458           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1459           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1460           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1461     ;; so that pressing `v' inside VM does prompt within current directory:
1462     (set (make-local-variable 'vm-folder-directory) dir)))
1463
1464 (defun dired-rmail ()
1465   "Run RMAIL on this file."
1466   (interactive)
1467   (rmail (dired-get-filename)))
1468
1469 (defun dired-do-run-mail ()
1470   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1471   (interactive)
1472   (if dired-bind-vm
1473       ;; Read mail folder using vm.
1474       (dired-vm)
1475     ;; Read mail folder using rmail.
1476     (dired-rmail)))
1477
1478 \f
1479 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1480
1481 (declare-function dired-old-find-buffer-nocreate "dired-x")
1482
1483 (or (fboundp 'dired-old-find-buffer-nocreate)
1484     (fset 'dired-old-find-buffer-nocreate
1485           (symbol-function 'dired-find-buffer-nocreate)))
1486
1487 ;; REDEFINE.
1488 ;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1489 (defun dired-find-buffer-nocreate (dirname &optional mode)
1490   (if (and dired-find-subdir
1491            ;; don't try to find a wildcard as a subdirectory
1492            (string-equal dirname (file-name-directory dirname)))
1493       (let* ((cur-buf (current-buffer))
1494              (buffers (nreverse
1495                        (dired-buffers-for-dir (expand-file-name dirname))))
1496              (cur-buf-matches (and (memq cur-buf buffers)
1497                                    ;; wildcards must match, too:
1498                                    (equal dired-directory dirname))))
1499         ;; We don't want to switch to the same buffer---
1500         (setq buffers (delq cur-buf buffers));;need setq with delq
1501         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1502             ;; ---unless it's the only possibility:
1503             (and cur-buf-matches cur-buf)))
1504     (dired-old-find-buffer-nocreate dirname mode)))
1505
1506 ;; This should be a builtin
1507 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1508   "Return t if BUFFER1 is more recently used than BUFFER2."
1509   (if (equal buffer1 buffer2)
1510       nil
1511     (let ((more-recent nil)
1512           (list (buffer-list)))
1513       (while (and list
1514                   (not (setq more-recent (equal buffer1 (car list))))
1515                   (not (equal buffer2 (car list))))
1516         (setq list (cdr list)))
1517       more-recent)))
1518
1519 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1520 ;; (defun dired-buffers-for-dir-exact (dir)
1521 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1522 ;; ;; at top level, or as subdirectory.
1523 ;; ;; Top level matches must match the wildcard part too, if any.
1524 ;; ;; The list is in reverse order of buffer creation, most recent last.
1525 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1526 ;; ;; dired-buffers.
1527 ;;   (let ((alist dired-buffers) result elt)
1528 ;;     (while alist
1529 ;;       (setq elt (car alist)
1530 ;;             alist (cdr alist))
1531 ;;       (let ((buf (cdr elt)))
1532 ;;         (if (buffer-name buf)
1533 ;;             ;; Top level must match exactly against dired-directory in
1534 ;;             ;; case one of them is a wildcard.
1535 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1536 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1537 ;;                 (setq result (cons buf result)))
1538 ;;           ;; else buffer is killed - clean up:
1539 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1540 ;;     result))
1541
1542 ;; REDEFINE.
1543 ;; Redefines dired.el's version of `dired-initial-position'
1544 (defun dired-initial-position (dirname)
1545   "Where point should go in a new listing of DIRNAME.
1546 Point assumed at beginning of new subdir line.
1547 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1548   (end-of-line)
1549   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1550   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1551
1552 \f
1553 ;; Does anyone use this? - lrd 6/29/93.
1554 ;; Apparently people do use it. - lrd 12/22/97.
1555 (defun dired-mark-sexp (predicate &optional unflag-p)
1556   "Mark files for which PREDICATE returns non-nil.
1557 With a prefix arg, unflag those files instead.
1558
1559 PREDICATE is a lisp expression that can refer to the following symbols:
1560
1561     inode  [integer] the inode of the file (only for ls -i output)
1562     s      [integer] the size of the file for ls -s output
1563                      (usually in blocks or, with -k, in KByte)
1564     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1565     nlink  [integer] number of links to file
1566     uid    [string]  owner
1567     gid    [string]  group  (If the gid is not displayed by ls,
1568                      this will still be set (to the same as uid))
1569     size   [integer] file size in bytes
1570     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1571     name   [string]  the name of the file
1572     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1573
1574 For example, use
1575
1576         (equal 0 size)
1577
1578 to mark all zero length files."
1579   ;; Using sym="" instead of nil avoids the trap of
1580   ;; (string-match "foo" sym) into which a user would soon fall.
1581   ;; Give `equal' instead of `=' in the example, as this works on
1582   ;; integers and strings.
1583   (interactive "xMark if (lisp expr): \nP")
1584   (message "%s" predicate)
1585   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1586         inode s mode nlink uid gid size time name sym)
1587     (dired-mark-if
1588      (save-excursion
1589        (and
1590         ;; Sets vars
1591         ;;                inode s mode nlink uid gid size time name sym
1592
1593         ;; according to current file line.  Returns t for success, nil if
1594         ;; there is no file line.  Upon success, all variables are set, either
1595         ;; to nil or the appropriate value, so they need not be initialized.
1596         ;; Moves point within the current line.
1597         (if (dired-move-to-filename)
1598             (let (pos
1599                   (mode-len 10) ; length of mode string
1600                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1601                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1602               (beginning-of-line)
1603               (forward-char 2)
1604               (if (looking-at dired-re-inode-size)
1605                   (progn
1606                     (goto-char (match-end 0))
1607                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1608                                                                     (match-end 1)))
1609                           s (string-to-number (buffer-substring (match-beginning 2)
1610                                                                 (match-end 2)))))
1611                 (setq inode nil
1612                       s nil))
1613               (setq mode (buffer-substring (point) (+ mode-len (point))))
1614               (forward-char mode-len)
1615               (setq nlink (read (current-buffer)))
1616               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1617               (setq uid (buffer-substring (+ (point) 1)
1618                                           (progn (forward-word 1) (point))))
1619               (re-search-forward directory-listing-before-filename-regexp)
1620               (goto-char (match-beginning 1))
1621               (forward-char -1)
1622               (setq size (string-to-number (buffer-substring (save-excursion
1623                                                                (backward-word 1)
1624                                                                (setq pos (point)))
1625                                                              (point))))
1626               (goto-char pos)
1627               (backward-word 1)
1628               ;; if no gid is displayed, gid will be set to uid
1629               ;; but user will then not reference it anyway in PREDICATE.
1630               (setq gid (buffer-substring (save-excursion
1631                                             (forward-word 1) (point))
1632                                           (point))
1633                     time (buffer-substring (match-beginning 1)
1634                                            (1- (dired-move-to-filename)))
1635                     name (buffer-substring (point)
1636                                            (or
1637                                             (dired-move-to-end-of-filename t)
1638                                             (point)))
1639                     sym  (progn
1640                            (if (looking-at " -> ")
1641                                (buffer-substring
1642                                 (progn (forward-char 4) (point))
1643                                 (progn (end-of-line) (point)))
1644                              "")))
1645               t)
1646           nil)
1647                       (eval predicate)))
1648      (format "'%s file" predicate))))
1649
1650 \f
1651 ;;; FIND FILE AT POINT.
1652
1653 (defvar dired-x-hands-off-my-keys t
1654   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1655 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1656 If you change this variable after `dired-x.el' is loaded then do
1657 \\[dired-x-bind-find-file].")
1658
1659 ;; Bind `dired-x-find-file{-other-window}' over wherever
1660 ;; `find-file{-other-window}' is bound?
1661 (defun dired-x-bind-find-file ()
1662   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1663 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1664 Binding direction based on `dired-x-hands-off-my-keys'.
1665 This function is part of `after-init-hook'."
1666   (interactive)
1667   (if (called-interactively-p 'interactive)
1668       (setq dired-x-hands-off-my-keys
1669             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1670   (cond ((not dired-x-hands-off-my-keys)
1671          (substitute-key-definition 'find-file
1672                                     'dired-x-find-file
1673                                     (current-global-map))
1674          (substitute-key-definition 'find-file-other-window
1675                                     'dired-x-find-file-other-window
1676                                     (current-global-map)))
1677         (t
1678          (substitute-key-definition 'dired-x-find-file
1679                                     'find-file
1680                                     (current-global-map))
1681          (substitute-key-definition 'dired-x-find-file-other-window
1682                                     'find-file-other-window
1683                                     (current-global-map))))
1684   ;; Clear mini-buffer.
1685   (message nil))
1686
1687 ;; Now call it so binding is correct and put on `after-init-hook' in case
1688 ;; user changes binding.
1689 (dired-x-bind-find-file)
1690 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1691
1692 (defun dired-x-find-file (filename)
1693   "Edit file FILENAME.
1694 May create a new window, or reuse an existing one.
1695 See the function `display-buffer'.
1696
1697 Identical to `find-file' except when called interactively, with a prefix arg
1698 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1699 Useful for editing file mentioned in buffer you are viewing,
1700 or to test if that file exists.  Use minibuffer after snatching filename."
1701   (interactive (list (read-filename-at-point "Find file: ")))
1702   (find-file (expand-file-name filename)))
1703
1704 (defun dired-x-find-file-other-window (filename)
1705   "Edit file FILENAME, in another window.
1706 May create a new window, or reuse an existing one.
1707 See the function `display-buffer'.
1708
1709 Identical to `find-file-other-window' except when called interactively, with
1710 a prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1711 Useful for editing file mentioned in buffer you are viewing,
1712 or to test if that file exists.  Use minibuffer after snatching filename."
1713   (interactive (list (read-filename-at-point "Find file: ")))
1714   (find-file-other-window (expand-file-name filename)))
1715
1716 ;;; Internal functions.
1717
1718 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1719 (defun dired-filename-at-point ()
1720   "Get the filename closest to point, but do not change position.
1721 Has a preference for looking backward when not directly on a symbol.
1722 Not perfect - point must be in middle of or end of filename."
1723
1724   (let ((filename-chars "-.[:alnum:]_/:$+@")
1725         start end filename prefix)
1726
1727     (save-excursion
1728       ;; First see if just past a filename.
1729       (if (not (eobp))
1730           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1731               (progn
1732                 (skip-chars-backward " \n\t\r({[]})")
1733                 (if (not (bobp))
1734                     (backward-char 1)))))
1735
1736       (if (string-match (concat "[" filename-chars "]")
1737                         (char-to-string (following-char)))
1738           (progn
1739             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1740                 (forward-char)
1741               (goto-char (point-min)))
1742             (setq start (point))
1743             (setq prefix
1744                   (and (string-match
1745                         "^\\w+@"
1746                         (buffer-substring start (line-beginning-position)))
1747                        "/"))
1748             (goto-char start)
1749             (if (string-match "[/~]" (char-to-string (preceding-char)))
1750                 (setq start (1- start)))
1751             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1752
1753         (error "No file found around point!"))
1754
1755       ;; Return string.
1756       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1757
1758 (defun read-filename-at-point (prompt)
1759   "Return filename prompting with PROMPT with completion.
1760 If `current-prefix-arg' is non-nil, uses name at point as guess."
1761   (if current-prefix-arg
1762       (let ((guess (dired-filename-at-point)))
1763         (read-file-name prompt
1764                         (file-name-directory guess)
1765                         guess
1766                         nil (file-name-nondirectory guess)))
1767     (read-file-name prompt default-directory)))
1768 \f
1769 ;;; BUG REPORTS
1770
1771 ;; Fixme: get rid of this later.
1772
1773 ;; This section is provided for reports.  It uses Barry A. Warsaw's
1774 ;; reporter.el which is bundled with GNU Emacs v19.
1775
1776 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1777   "Address(es) accepting submission of reports on dired-x.el.")
1778
1779 (defconst dired-x-variable-list
1780   (list
1781    'dired-bind-vm
1782    'dired-vm-read-only-folders
1783    'dired-bind-jump
1784    'dired-bind-info
1785    'dired-bind-man
1786    'dired-find-subdir
1787    'dired-enable-local-variables
1788    'dired-local-variables-file
1789    'dired-guess-shell-gnutar
1790    'dired-guess-shell-gzip-quiet
1791    'dired-guess-shell-znew-switches
1792    'dired-guess-shell-alist-user
1793    'dired-clean-up-buffers-too
1794    'dired-omit-mode
1795    'dired-omit-files
1796    'dired-omit-extensions
1797    )
1798   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1799
1800 (defun dired-x-submit-report ()
1801   "Submit via `reporter.el' a bug report on program.
1802 Send report on `dired-x-file' version `dired-x-version', to
1803 `dired-x-maintainer' at address `dired-x-help-address' listing
1804 variables `dired-x-variable-list' in the message."
1805   (interactive)
1806
1807   (reporter-submit-bug-report
1808    dired-x-help-address                 ; address
1809    "dired-x"                            ; pkgname
1810    dired-x-variable-list                ; varlist
1811    nil nil                              ; pre-/post-hooks
1812    ""))
1813
1814 \f
1815 ;; As Barry Warsaw would say: "This might be useful..."
1816 (provide 'dired-x)
1817
1818 ;; Local Variables:
1819 ;; byte-compile-dynamic: t
1820 ;; generated-autoload-file: "dired.el"
1821 ;; End:
1822
1823 ;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1824 ;;; dired-x.el ends here