lisp/saveplace.el

   1 ;;; saveplace.el --- automatically save place in files
   2
   3 ;; Copyright (C) 1993-1994, 2001-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Karl Fogel <kfogel@red-bean.com>
   6 ;; Maintainer: FSF
   7 ;; Created: July, 1993
   8 ;; Keywords: bookmarks, placeholders
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Automatically save place in files, so that visiting them later
  28 ;; (even during a different Emacs session) automatically moves point
  29 ;; to the saved position, when the file is first found.  Uses the
  30 ;; value of buffer-local variable save-place to determine whether to
  31 ;; save position or not.
  32 ;;
  33 ;; Thanks to Stefan Schoef, who sent a patch with the
  34 ;; `save-place-version-control' stuff in it.
  35
  36 ;;; Code:
  37
  38 ;; this is what I was using during testing:
  39 ;; (define-key ctl-x-map "p" 'toggle-save-place-globally)
  40
  41 (defgroup save-place nil
  42   "Automatically save place in files."
  43   :group 'data)
  44
  45
  46 (defvar save-place-alist nil
  47   "Alist of saved places to go back to when revisiting files.
  48 Each element looks like (FILENAME . POSITION);
  49 visiting file FILENAME goes automatically to position POSITION
  50 rather than the beginning of the buffer.
  51 This alist is saved between Emacs sessions.")
  52
  53 (defcustom save-place nil
  54   "Non-nil means automatically save place in each file.
  55 This means when you visit a file, point goes to the last place
  56 where it was when you previously visited the same file.
  57 This variable is automatically buffer-local.
  58
  59 If you wish your place in any file to always be automatically
  60 saved, set this to t using the Customize facility, or put the
  61 following code in your init file:
  62
  63 \(setq-default save-place t)
  64 \(require 'saveplace)"
  65   :type 'boolean
  66   :require 'saveplace
  67   :group 'save-place)
  68
  69 (make-variable-buffer-local 'save-place)
  70
  71 (defcustom save-place-file (locate-user-emacs-file "places" ".emacs-places")
  72   "Name of the file that records `save-place-alist' value."
  73   :type 'file
  74   :group 'save-place)
  75
  76 (defcustom save-place-version-control nil
  77   "Controls whether to make numbered backups of master save-place file.
  78 It can have four values: t, nil, `never', and `nospecial'.  The first
  79 three have the same meaning that they do for the variable
  80 `version-control', and the final value `nospecial' means just use the
  81 value of `version-control'."
  82   :type '(radio (const :tag "Unconditionally" t)
  83                 (const :tag "For VC Files" nil)
  84                 (const never)
  85                 (const :tag "Use value of `version-control'" nospecial))
  86   :group 'save-place)
  87
  88 (defvar save-place-loaded nil
  89   "Non-nil means that the `save-place-file' has been loaded.")
  90
  91 (defcustom save-place-limit 400
  92   "Maximum number of entries to retain in the list; nil means no limit."
  93   :version "24.1"                       ; nil -> 400
  94   :type '(choice (integer :tag "Entries" :value 1)
  95                  (const :tag "No Limit" nil))
  96   :group 'save-place)
  97
  98 (defcustom save-place-forget-unreadable-files t
  99   "Non-nil means forget place in unreadable files.
 100
 101 The filenames in `save-place-alist' that do not match
 102 `save-place-skip-check-regexp' are filtered through
 103 `file-readable-p'. if nil, their alist entries are removed.
 104
 105 You may do this anytime by calling the complementary function,
 106 `save-place-forget-unreadable-files'.  When this option is turned on,
 107 this happens automatically before saving `save-place-alist' to
 108 `save-place-file'."
 109   :type 'boolean :group 'save-place)
 110
 111 (defcustom save-place-save-skipped t
 112   "If non-nil, remember files matching `save-place-skip-check-regexp'.
 113
 114 When filtering `save-place-alist' for unreadable files, some will not
 115 be checked, based on said regexp, and instead saved or forgotten based
 116 on this flag."
 117   :type 'boolean :group 'save-place)
 118
 119 (defcustom save-place-skip-check-regexp
 120   ;; thanks to ange-ftp-name-format
 121   "\\`/\\(?:cdrom\\|floppy\\|mnt\\|\\(?:[^@/:]*@\\)?[^@/:]*[^@/:.]:\\)"
 122   "Regexp whose file names shall not be checked for readability.
 123
 124 When forgetting unreadable files, file names matching this regular
 125 expression shall not be checked for readability, but instead be
 126 subject to `save-place-save-skipped'.
 127
 128 Files for which such a check may be inconvenient include those on
 129 removable and network volumes."
 130   :type 'regexp :group 'save-place)
 131
 132 (defcustom save-place-ignore-files-regexp
 133   "\\(?:COMMIT_EDITMSG\\|hg-editor-[[:alnum:]]+\\.txt\\|svn-commit\\.tmp\\|bzr_log\\.[[:alnum:]]+\\)$"
 134   "Regexp matching files for which no position should be recorded.
 135 Useful for temporary file such as commit message files that are
 136 automatically created by the VCS.  If set to nil, this feature is
 137 disabled, i.e., the position is recorded for all files."
 138   :version "24.1"
 139   :type 'regexp :group 'save-place)
 140
 141 (defun toggle-save-place (&optional parg)
 142   "Toggle whether to save your place in this file between sessions.
 143 If this mode is enabled, point is recorded when you kill the buffer
 144 or exit Emacs.  Visiting this file again will go to that position,
 145 even in a later Emacs session.
 146
 147 If called with a prefix arg, the mode is enabled if and only if
 148 the argument is positive.
 149
 150 To save places automatically in all files, put this in your init
 151 file:
 152
 153 \(setq-default save-place t\)"
 154   (interactive "P")
 155   (if (not buffer-file-name)
 156       (message "Buffer `%s' not visiting a file" (buffer-name))
 157     (if (and save-place (or (not parg) (<= parg 0)))
 158         (progn
 159           (message "No place will be saved in this file")
 160           (setq save-place nil))
 161       (message "Place will be saved")
 162       (setq save-place t))))
 163
 164 (defun save-place-to-alist ()
 165   ;; put filename and point in a cons box and then cons that onto the
 166   ;; front of the save-place-alist, if save-place is non-nil.
 167   ;; Otherwise, just delete that file from the alist.
 168   ;; first check to make sure alist has been loaded in from the master
 169   ;; file.  If not, do so, then feel free to modify the alist.  It
 170   ;; will be saved again when Emacs is killed.
 171   (or save-place-loaded (load-save-place-alist-from-file))
 172   (when (and buffer-file-name
 173              (or (not save-place-ignore-files-regexp)
 174                  (not (string-match save-place-ignore-files-regexp
 175                                     buffer-file-name))))
 176     (let ((cell (assoc buffer-file-name save-place-alist))
 177           (position (if (not (eq major-mode 'hexl-mode))
 178                         (point)
 179                       (with-no-warnings
 180                         (1+ (hexl-current-address))))))
 181       (if cell
 182           (setq save-place-alist (delq cell save-place-alist)))
 183       (if (and save-place
 184                (not (= position 1)))  ;; Optimize out the degenerate case.
 185           (setq save-place-alist
 186                 (cons (cons buffer-file-name position)
 187                       save-place-alist))))))
 188
 189 (defun save-place-forget-unreadable-files ()
 190   "Remove unreadable files from `save-place-alist'.
 191 For each entry in the alist, if `file-readable-p' returns nil for the
 192 filename, remove the entry.  Save the new alist \(as the first pair
 193 may have changed\) back to `save-place-alist'."
 194   (interactive)
 195   ;; the following was adapted from an in-place filtering function,
 196   ;; `filter-mod', used in the original.
 197   (unless (null save-place-alist)       ;says it better than `when'
 198     ;; first, check all except first
 199     (let ((fmprev save-place-alist) (fmcur (cdr save-place-alist)))
 200       (while fmcur                      ;not null
 201         ;; a value is only saved when it becomes FMPREV.
 202         (if (if (string-match save-place-skip-check-regexp (caar fmcur))
 203                 save-place-save-skipped
 204               (file-readable-p (caar fmcur)))
 205             (setq fmprev fmcur)
 206           (setcdr fmprev (cdr fmcur)))
 207         (setq fmcur (cdr fmcur))))
 208     ;; test first pair, keep it if OK, otherwise 2nd element, which
 209     ;; may be '()
 210     (unless (if (string-match save-place-skip-check-regexp
 211                               (caar save-place-alist))
 212                 save-place-save-skipped
 213               (file-readable-p (caar save-place-alist)))
 214       (setq save-place-alist (cdr save-place-alist)))))
 215
 216 (defun save-place-alist-to-file ()
 217   (let ((file (expand-file-name save-place-file))
 218         (coding-system-for-write 'utf-8))
 219     (with-current-buffer (get-buffer-create " *Saved Places*")
 220       (delete-region (point-min) (point-max))
 221       (when save-place-forget-unreadable-files
 222         (save-place-forget-unreadable-files))
 223       (insert (format ";;; -*- coding: %s -*-\n"
 224                       (symbol-name coding-system-for-write)))
 225       (let ((print-length nil)
 226             (print-level nil))
 227         (pp save-place-alist (current-buffer)))
 228       (let ((version-control
 229              (cond
 230               ((null save-place-version-control) nil)
 231               ((eq 'never save-place-version-control) 'never)
 232               ((eq 'nospecial save-place-version-control) version-control)
 233               (t
 234                t))))
 235         (condition-case nil
 236             ;; Don't use write-file; we don't want this buffer to visit it.
 237             (write-region (point-min) (point-max) file)
 238           (file-error (message "Saving places: can't write %s" file)))
 239         (kill-buffer (current-buffer))))))
 240
 241 (defun load-save-place-alist-from-file ()
 242   (if (not save-place-loaded)
 243       (progn
 244         (setq save-place-loaded t)
 245         (let ((file (expand-file-name save-place-file)))
 246           ;; make sure that the alist does not get overwritten, and then
 247           ;; load it if it exists:
 248           (if (file-readable-p file)
 249               ;; don't want to use find-file because we have been
 250               ;; adding hooks to it.
 251               (with-current-buffer (get-buffer-create " *Saved Places*")
 252                 (delete-region (point-min) (point-max))
 253                 (insert-file-contents file)
 254                 (goto-char (point-min))
 255                 (setq save-place-alist
 256                       (car (read-from-string
 257                             (buffer-substring (point-min) (point-max)))))
 258
 259                 ;; If there is a limit, and we're over it, then we'll
 260                 ;; have to truncate the end of the list:
 261                 (if save-place-limit
 262                     (if (<= save-place-limit 0)
 263                         ;; Zero gets special cased.  I'm not thrilled
 264                         ;; with this, but the loop for >= 1 is tight.
 265                         (setq save-place-alist nil)
 266                       ;; Else the limit is >= 1, so enforce it by
 267                       ;; counting and then `setcdr'ing.
 268                       (let ((s save-place-alist)
 269                             (count 1))
 270                         (while s
 271                           (if (>= count save-place-limit)
 272                               (setcdr s nil)
 273                             (setq count (1+ count)))
 274                           (setq s (cdr s))))))
 275
 276                 (kill-buffer (current-buffer))))
 277           nil))))
 278
 279 (defun save-places-to-alist ()
 280   ;; go through buffer-list, saving places to alist if save-place is
 281   ;; non-nil, deleting them from alist if it is nil.
 282   (let ((buf-list (buffer-list)))
 283     (while buf-list
 284       ;; put this into a save-excursion in case someone is counting on
 285       ;; another function in kill-emacs-hook to act on the last buffer
 286       ;; they were in:
 287       (with-current-buffer (car buf-list)
 288         ;; save-place checks buffer-file-name too, but we can avoid
 289         ;; overhead of function call by checking here too.
 290         (and buffer-file-name (save-place-to-alist))
 291         (setq buf-list (cdr buf-list))))))
 292
 293 (defun save-place-find-file-hook ()
 294   (or save-place-loaded (load-save-place-alist-from-file))
 295   (let ((cell (assoc buffer-file-name save-place-alist)))
 296     (if cell
 297         (progn
 298           (or revert-buffer-in-progress-p
 299               (goto-char (cdr cell)))
 300           ;; and make sure it will be saved again for later
 301           (setq save-place t)))))
 302
 303 (defun save-place-kill-emacs-hook ()
 304   ;; First update the alist.  This loads the old save-place-file if nec.
 305   (save-places-to-alist)
 306   ;; Now save the alist in the file, if we have ever loaded the file
 307   ;; (including just now).
 308   (if save-place-loaded
 309       (save-place-alist-to-file)))
 310
 311 (add-hook 'find-file-hook 'save-place-find-file-hook t)
 312
 313 (unless noninteractive
 314   (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook))
 315
 316 (add-hook 'kill-buffer-hook 'save-place-to-alist)
 317
 318 (provide 'saveplace) ; why not...
 319
 320 ;;; saveplace.el ends here