lisp/find-dired.el

   1 ;;; find-dired.el --- run a `find' command and dired the output
   2
   3 ;; Copyright (C) 1992, 1994, 1995, 2000, 2002 Free Software Foundation, Inc.
   4
   5 ;; Author: Roland McGrath <roland@gnu.org>,
   6 ;;         Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;; Maintainer: FSF
   8 ;; Keywords: unix
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (require 'dired)
  32
  33 (defgroup find-dired nil
  34   "Run a `find' command and dired the output."
  35   :group 'dired
  36   :prefix "find-")
  37
  38 (defcustom find-dired-find-program "find"
  39   "Program used to find files."
  40   :group 'dired
  41   :type 'file)
  42
  43 ;; find's -ls corresponds to these switches.
  44 ;; Note -b, at least GNU find quotes spaces etc. in filenames
  45 ;;;###autoload
  46 (defcustom find-ls-option
  47   (if (eq system-type 'berkeley-unix) '("-ls" . "-gilsb")
  48     '("-exec ls -ld {} \\;" . "-ld"))
  49   "*Description of the option to `find' to produce an `ls -l'-type listing.
  50 This is a cons of two strings (FIND-OPTION . LS-SWITCHES).  FIND-OPTION
  51 gives the option (or options) to `find' that produce the desired output.
  52 LS-SWITCHES is a list of `ls' switches to tell dired how to parse the output."
  53   :type '(cons (string :tag "Find Option")
  54                (string :tag "Ls Switches"))
  55   :group 'find-dired)
  56
  57 ;;;###autoload
  58 (defcustom find-grep-options
  59   (if (or (eq system-type 'berkeley-unix)
  60           (string-match "solaris2" system-configuration)
  61           (string-match "irix" system-configuration))
  62       "-s" "-q")
  63   "*Option to grep to be as silent as possible.
  64 On Berkeley systems, this is `-s'; on Posix, and with GNU grep, `-q' does it.
  65 On other systems, the closest you can come is to use `-l'."
  66   :type 'string
  67   :group 'find-dired)
  68
  69 (defvar find-args nil
  70   "Last arguments given to `find' by \\[find-dired].")
  71
  72 ;; History of find-args values entered in the minibuffer.
  73 (defvar find-args-history nil)
  74
  75 (defvar dired-sort-inhibit)
  76
  77 ;;;###autoload
  78 (defun find-dired (dir args)
  79   "Run `find' and go into Dired mode on a buffer of the output.
  80 The command run (after changing into DIR) is
  81
  82     find . \\( ARGS \\) -ls
  83
  84 except that the variable `find-ls-option' specifies what to use
  85 as the final argument."
  86   (interactive (list (read-file-name "Run find in directory: " nil "" t)
  87                      (read-string "Run find (with args): " find-args
  88                                   '(find-args-history . 1))))
  89   (let ((dired-buffers dired-buffers))
  90     ;; Expand DIR ("" means default-directory), and make sure it has a
  91     ;; trailing slash.
  92     (setq dir (abbreviate-file-name
  93                (file-name-as-directory (expand-file-name dir))))
  94     ;; Check that it's really a directory.
  95     (or (file-directory-p dir)
  96         (error "find-dired needs a directory: %s" dir))
  97     (switch-to-buffer (get-buffer-create "*Find*"))
  98
  99     ;; See if there's still a `find' running, and offer to kill
 100     ;; it first, if it is.
 101     (let ((find (get-buffer-process (current-buffer))))
 102       (when find
 103         (if (or (not (eq (process-status find) 'run))
 104                 (yes-or-no-p "A `find' process is running; kill it? "))
 105             (condition-case nil
 106                 (progn
 107                   (interrupt-process find)
 108                   (sit-for 1)
 109                   (delete-process find))
 110               (error nil))
 111           (error "Cannot have two processes in `%s' at once" (buffer-name)))))
 112
 113     (widen)
 114     (kill-all-local-variables)
 115     (setq buffer-read-only nil)
 116     (erase-buffer)
 117     (setq default-directory dir
 118           find-args args                ; save for next interactive call
 119           args (concat find-dired-find-program " . "
 120                        (if (string= args "")
 121                            ""
 122                          (concat "\\( " args " \\) "))
 123                        (car find-ls-option)))
 124     ;; Start the find process.
 125     (shell-command (concat args "&") (current-buffer))
 126     ;; The next statement will bomb in classic dired (no optional arg allowed)
 127     (dired-mode dir (cdr find-ls-option))
 128     (let ((map (make-sparse-keymap)))
 129       (set-keymap-parent map (current-local-map))
 130       (define-key map "\C-c\C-k" 'kill-find)
 131       (use-local-map map))
 132     (make-local-variable 'dired-sort-inhibit)
 133     (setq dired-sort-inhibit t)
 134     (set (make-local-variable 'revert-buffer-function)
 135          `(lambda (ignore-auto noconfirm)
 136             (find-dired ,dir ,find-args)))
 137     ;; Set subdir-alist so that Tree Dired will work:
 138     (if (fboundp 'dired-simple-subdir-alist)
 139         ;; will work even with nested dired format (dired-nstd.el,v 1.15
 140         ;; and later)
 141         (dired-simple-subdir-alist)
 142       ;; else we have an ancient tree dired (or classic dired, where
 143       ;; this does no harm)
 144       (set (make-local-variable 'dired-subdir-alist)
 145            (list (cons default-directory (point-min-marker)))))
 146     (setq buffer-read-only nil)
 147     ;; Subdir headlerline must come first because the first marker in
 148     ;; subdir-alist points there.
 149     (insert "  " dir ":\n")
 150     ;; Make second line a ``find'' line in analogy to the ``total'' or
 151     ;; ``wildcard'' line.
 152     (insert "  " args "\n")
 153     (setq buffer-read-only t)
 154     (let ((proc (get-buffer-process (current-buffer))))
 155       (set-process-filter proc (function find-dired-filter))
 156       (set-process-sentinel proc (function find-dired-sentinel))
 157       ;; Initialize the process marker; it is used by the filter.
 158       (move-marker (process-mark proc) 1 (current-buffer)))
 159     (setq mode-line-process '(":%s"))))
 160
 161 (defun kill-find ()
 162   "Kill the `find' process running in the current buffer."
 163   (interactive)
 164   (let ((find (get-buffer-process (current-buffer))))
 165     (and find (eq (process-status find) 'run)
 166          (eq (process-filter find) (function find-dired-filter))
 167          (condition-case nil
 168              (delete-process find)
 169            (error nil)))))
 170
 171 ;;;###autoload
 172 (defun find-name-dired (dir pattern)
 173   "Search DIR recursively for files matching the globbing pattern PATTERN,
 174 and run dired on those files.
 175 PATTERN is a shell wildcard (not an Emacs regexp) and need not be quoted.
 176 The command run (after changing into DIR) is
 177
 178     find . -name 'PATTERN' -ls"
 179   (interactive
 180    "DFind-name (directory): \nsFind-name (filename wildcard): ")
 181   (find-dired dir (concat "-name " (shell-quote-argument pattern))))
 182
 183 ;; This functionality suggested by
 184 ;; From: oblanc@watcgl.waterloo.edu (Olivier Blanc)
 185 ;; Subject: find-dired, lookfor-dired
 186 ;; Date: 10 May 91 17:50:00 GMT
 187 ;; Organization: University of Waterloo
 188
 189 (defalias 'lookfor-dired 'find-grep-dired)
 190 ;;;###autoload
 191 (defun find-grep-dired (dir regexp)
 192   "Find files in DIR containing a regexp REGEXP and start Dired on output.
 193 The command run (after changing into DIR) is
 194
 195     find . -exec grep -s -e REGEXP {} \\\; -ls
 196
 197 Thus ARG can also contain additional grep options."
 198   (interactive "DFind-grep (directory): \nsFind-grep (grep regexp): ")
 199   ;; find -exec doesn't allow shell i/o redirections in the command,
 200   ;; or we could use `grep -l >/dev/null'
 201   ;; We use -type f, not ! -type d, to avoid getting screwed
 202   ;; by FIFOs and devices.  I'm not sure what's best to do
 203   ;; about symlinks, so as far as I know this is not wrong.
 204   (find-dired dir
 205               (concat "-type f -exec grep " find-grep-options " -e "
 206                       (shell-quote-argument regexp)
 207                       " {} \\\; ")))
 208
 209 (defun find-dired-filter (proc string)
 210   ;; Filter for \\[find-dired] processes.
 211   (let ((buf (process-buffer proc))
 212         (inhibit-read-only t))
 213     (if (buffer-name buf)               ; not killed?
 214         (save-excursion
 215           (set-buffer buf)
 216           (save-restriction
 217             (widen)
 218             (save-excursion
 219               (let ((buffer-read-only nil)
 220                     (end (point-max)))
 221                 (goto-char end)
 222                 (insert string)
 223                 (goto-char end)
 224                 (or (looking-at "^")
 225                     (forward-line 1))
 226                 (while (looking-at "^")
 227                   (insert "  ")
 228                   (forward-line 1))
 229                 ;; Convert ` ./FILE' to ` FILE'
 230                 ;; This would lose if the current chunk of output
 231                 ;; starts or ends within the ` ./', so back up a bit:
 232                 (goto-char (- end 3))   ; no error if < 0
 233                 (while (search-forward " ./" nil t)
 234                   (delete-region (point) (- (point) 2)))
 235                 ;; Find all the complete lines in the unprocessed
 236                 ;; output and process it to add text properties.
 237                 (goto-char end)
 238                 (if (search-backward "\n" (process-mark proc) t)
 239                     (progn
 240                       (dired-insert-set-properties (process-mark proc)
 241                                                    (1+ (point)))
 242                       (move-marker (process-mark proc) (1+ (point)))))
 243                 ))))
 244       ;; The buffer has been killed.
 245       (delete-process proc))))
 246
 247 (defun find-dired-sentinel (proc state)
 248   ;; Sentinel for \\[find-dired] processes.
 249   (let ((buf (process-buffer proc))
 250         (inhibit-read-only t))
 251     (if (buffer-name buf)
 252         (save-excursion
 253           (set-buffer buf)
 254           (let ((buffer-read-only nil))
 255             (save-excursion
 256               (goto-char (point-max))
 257               (insert "\n  find " state)
 258               (forward-char -1)         ;Back up before \n at end of STATE.
 259               (insert " at " (substring (current-time-string) 0 19))
 260               (forward-char 1)
 261               (setq mode-line-process
 262                     (concat ":"
 263                             (symbol-name (process-status proc))))
 264               ;; Since the buffer and mode line will show that the
 265               ;; process is dead, we can delete it now.  Otherwise it
 266               ;; will stay around until M-x list-processes.
 267               (delete-process proc)
 268               (force-mode-line-update)))
 269           (message "find-dired %s finished." (current-buffer))))))
 270 \f
 271 (provide 'find-dired)
 272
 273 ;;; arch-tag: 8edece95-af00-4221-bc74-a4bd2f75f9b0
 274 ;;; find-dired.el ends here