lisp/browse-url.el

   1 ;;; browse-url.el --- ask a WWW browser to load a URL
   2
   3 ;; Copyright 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Denis Howe <dbh@doc.ic.ac.uk>
   6 ;; Maintainer: Denis Howe <dbh@doc.ic.ac.uk>
   7 ;; Created: 03 Apr 1995
   8 ;; Keywords: hypertext
   9 ;; X-Home page: http://wombat.doc.ic.ac.uk/
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; The latest version of this package should be available from
  31 ;; <URL:http://wombat.doc.ic.ac.uk/emacs/browse-url.el>.
  32
  33 ;; This package provides functions which read a URL (Uniform Resource
  34 ;; Locator) from the minibuffer, defaulting to the URL around point,
  35 ;; and ask a World-Wide Web browser to load it.  It can also load the
  36 ;; URL associated with the current buffer.  Different browsers use
  37 ;; different methods of remote control so there is one function for
  38 ;; each supported browser.  If the chosen browser is not running, it
  39 ;; is started.  Currently there is support for:
  40
  41 ;; Function              Browser     Earliest version
  42 ;; browse-url-netscape   Netscape    1.1b1
  43 ;; browse-url-mosaic     XMosaic     <= 2.4
  44 ;; browse-url-cci        XMosaic     2.5
  45 ;; browse-url-w3         w3          0
  46 ;; browse-url-iximosaic  IXI Mosaic  ?
  47
  48 ;; Note that versions of Netscape before 1.1b1 did not have remote
  49 ;; control.  <URL:http://home.netscape.com/newsref/std/x-remote.html>
  50 ;; and <URL:http://home.netscape.com/info/APIs/>.
  51
  52 ;; Netscape can cache Web pages so it may be necessary to tell it to
  53 ;; reload the current page if it has changed (eg. if you have edited
  54 ;; it).  There is currently no perfect automatic solution to this.
  55
  56 ;; Netscape allows you to specify the id of the window you want to
  57 ;; control but which window DO you want to control and how do you
  58 ;; discover its id?
  59
  60 ;; If using XMosaic before version 2.5, check the definition of
  61 ;; browse-url-usr1-signal below.
  62 ;; <URL:http://www.ncsa.uiuc.edu/SDG/Software/XMosaic/remote-control.html>
  63
  64 ;; XMosaic version 2.5 introduced Common Client Interface allowing you
  65 ;; to control mosaic through Unix sockets.
  66 ;; <URL:http://www.ncsa.uiuc.edu/SDG/Software/XMosaic/CCI/cci-spec.html>
  67
  68 ;; William M. Perry's excellent "w3" WWW browser for
  69 ;; Emacs <URL:ftp://cs.indiana.edu/pub/elisp/w3/>
  70 ;; has a function w3-follow-url-at-point, but that
  71 ;; doesn't let you edit the URL like browse-url.
  72
  73 ;; I recommend Nelson Minar <nelson@santafe.edu>'s excellent
  74 ;; html-helper-mode.el for editing HTML and thank Nelson for
  75 ;; his many useful comments on this code.
  76 ;; <URL:http://www.santafe.edu/~nelson/hhm-beta/>
  77
  78 ;; This package generalises function html-previewer-process in Marc
  79 ;; Andreessen <marca@ncsa.uiuc.edu>'s html-mode (LCD
  80 ;; modes/html-mode.el.Z) and provides better versions of the URL
  81 ;; functions in Michelangelo Grigni <mic@cs.ucsd.edu>'s ffap.el
  82 ;; (find-file-at-point) <URL:ftp://cs.ucsd.edu:/pub/mic/>.  The huge
  83 ;; hyperbole package also contains similar functions.
  84
  85 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  86 ;; Help!
  87
  88 ;; Can you write and test some code for the Macintrash and Windoze
  89 ;; Netscape remote control APIs?  (See the URL above).
  90
  91 ;; Do any other browsers have remote control?
  92
  93 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  94 ;; Usage
  95
  96 ;; To display the URL at or before point:
  97 ;; M-x browse-url-at-point RET
  98
  99 ;; To display a URL by shift-clicking on it, put this in your ~/.emacs
 100 ;; file:
 101 ;;      (global-set-key [S-mouse-2] 'browse-url-at-mouse)
 102 ;; (Note that using Shift-mouse-1 is not desirable because
 103 ;; that event has a standard meaning in Emacs.)
 104
 105 ;; To display the current buffer in a web browser:
 106 ;; M-x browse-url-of-buffer RET
 107
 108 ;; In Dired, to display the file named on the current line:
 109 ;; M-x browse-url-of-dired-file RET
 110
 111 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 112 ;; Customisation (~/.emacs)
 113
 114 ;; To see what variables are available for customization, type `M-x
 115 ;; set-variable browse-url TAB'.
 116
 117 ;; To bind the browse-url commands to keys with the `C-c u' prefix:
 118 ;;      (global-set-key "\C-cu." 'browse-url-at-point)
 119 ;;      (global-set-key "\C-cub" 'browse-url-of-buffer)
 120 ;;      (global-set-key "\C-cuf" 'browse-url-of-file)
 121 ;;      (add-hook 'dired-mode-hook
 122 ;;                (lambda ()
 123 ;;                  (local-set-key "\C-cuf" 'browse-url-of-dired-file))))
 124 ;;      (if (boundp 'browse-url-browser-function)
 125 ;;          (global-set-key "\C-cuu" browse-url-browser-function)
 126 ;;        (eval-after-load
 127 ;;         "browse-url"
 128 ;;         '(global-set-key "\C-cuu" browse-url-browser-function)))
 129
 130 ;; To use the Emacs w3 browser when not running under X11:
 131 ;;      (if (not (eq window-system 'x))
 132 ;;          (setq browse-url-browser-function 'browse-url-w3))
 133
 134 ;; To always save modified buffers before displaying the file in a browser:
 135 ;;      (setq browse-url-save-file t)
 136
 137 ;; To get round the Netscape caching problem, you could try either of
 138 ;; the following (but not both).  EITHER write-file in
 139 ;; html-helper-mode makes Netscape reload document:
 140 ;;
 141 ;;      (autoload 'browse-url-netscape-reload "browse-url"
 142 ;;        "Ask a WWW browser to redisplay the current file." t)
 143 ;;      (add-hook 'html-helper-mode-hook
 144 ;;                (function (lambda ()
 145 ;;                   (add-hook 'local-write-file-hooks
 146 ;;                             (function (lambda ()
 147 ;;                                (let ((local-write-file-hooks))
 148 ;;                                  (save-buffer))
 149 ;;                                (browse-url-netscape-reload)
 150 ;;                                t))                   ; => file written by hook
 151 ;;                             t))))                    ; append to l-w-f-hooks
 152 ;;
 153 ;; [Does this work for html-mode too?]
 154 ;;
 155 ;; OR browse-url-of-file ask Netscape to load and then reload the
 156 ;; file:
 157 ;;
 158 ;;      (add-hook 'browse-url-of-file-hook 'browse-url-netscape-reload)
 159
 160 ;; You may also want to customise browse-url-netscape-arguments, eg.
 161 ;;
 162 ;;      (setq browse-url-netscape-arguments '("-install"))
 163 ;;
 164 ;; or similarly for the other browsers.
 165
 166 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 167 ;;; Change Log:
 168
 169 ;; 0.00 03 Apr 1995 Denis Howe <dbh@doc.ic.ac.uk>
 170 ;;      Created.
 171
 172 ;; 0.01 04 Apr 1995
 173 ;;      All names start with "browse-url-".  Added provide.
 174
 175 ;; 0.02 05 Apr 1995
 176 ;;      Save file at start of browse-url-of-file.
 177 ;;      Use start-process instead of start-process-shell-command.
 178
 179 ;; 0.03 06 Apr 1995
 180 ;;      Add browse-url-netscape-reload, browse-url-netscape-command.
 181 ;;      browse-url-of-file save file option.
 182
 183 ;; 0.04 08 Apr 1995
 184 ;;      b-u-file-url separate function.  Change b-u-filename-alist
 185 ;;      default.
 186
 187 ;; 0.05 09 Apr 1995
 188 ;;      Added b-u-of-file-hook.
 189
 190 ;; 0.06 11 Apr 1995
 191 ;;      Improved .emacs suggestions and documentation.
 192
 193 ;; 0.07 13 Apr 1995
 194 ;;      Added browse-url-interactive-arg optional prompt.
 195
 196 ;; 0.08 18 Apr 1995
 197 ;;      Exclude final "." from browse-url-regexp.
 198
 199 ;; 0.09 21 Apr 1995
 200 ;;      Added mouse-set-point to browse-url-interactive-arg.
 201
 202 ;; 0.10 24 Apr 1995
 203 ;;      Added Mosaic signal sending variations.
 204 ;;      Thanks Brian K Servis <servis@ecn.purdue.edu>.
 205 ;;      Don't use xprop for Netscape.
 206
 207 ;; 0.11 25 Apr 1995
 208 ;;      Fix reading of ~/.mosaicpid.  Thanks Dag.H.Wanvik@kvatro.no.
 209
 210 ;; 0.12 27 Apr 1995
 211 ;;      Interactive prefix arg => URL *after* point.
 212 ;;      Thanks Michelangelo Grigni <mic@cs.ucsd.edu>.
 213 ;;      Added IXI Mosaic support.
 214 ;;      Thanks David Karr <dkarr@nmo.gtegsc.com>.
 215
 216 ;; 0.13 28 Apr 1995
 217 ;;      Exclude final [,;] from browse-url-regexp.
 218
 219 ;; 0.14 02 May 1995
 220 ;;      Provide browser argument variables.
 221
 222 ;; 0.15 07 May 1995
 223 ;;      More Netscape options.  Thanks Peter Arius
 224 ;;      <arius@immd2.informatik.uni-erlangen.de>.
 225
 226 ;; 0.16 17 May 1995
 227 ;;      Added browse-url-at-mouse.
 228 ;;      Thanks Wayne Mesard <wmesard@sgi.com>
 229
 230 ;; 0.17 27 Jun 1995
 231 ;;      Renamed browse-url-at-point to browse-url-url-at-point.
 232 ;;      Added browse-url-at-point.
 233 ;;      Thanks Jonathan Cano <cano@patch.tandem.com>.
 234
 235 ;; 0.18 16 Aug 1995
 236 ;;      Fixed call to browse-url-url-at-point in browse-url-at-point.
 237 ;;      Thanks Eric Ding <ericding@San-Jose.ate.slb.com>.
 238
 239 ;; 0.19 24 Aug 1995
 240 ;;      Improved documentation.
 241 ;;      Thanks Kevin Rodgers <kevin.rodgers@ihs.com>.
 242
 243 ;; 0.20 31 Aug 1995
 244 ;;      browse-url-of-buffer to handle file-less buffers.
 245 ;;      browse-url-of-dired-file browses current file in dired.
 246 ;;      Thanks Kevin Rodgers <kevin.rodgers@ihs.com>.
 247
 248 ;; 0.21 09 Sep 1995
 249 ;;      XMosaic CCI functions.
 250 ;;      Thanks Marc Furrer <Marc.Furrer@di.epfl.ch>.
 251
 252 ;; 0.22 13 Sep 1995
 253 ;;      Fixed new-window documentation and added to browse-url-cci.
 254 ;;      Thanks Dilip Sequeira <djs@dcs.ed.ac.uk>.
 255
 256 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 257 ;;; Code:
 258
 259 (defvar browse-url-regexp
 260   "\\(https?://\\|ftp://\\|gopher://\\|telnet://\\|wais://\\|file:/\\|s?news:\\|mailto:\\)[^]\t\n \"'()<>[^`{}]*[^]\t\n \"'()<>[^`{}.,;]+"
 261   "A regular expression probably matching a URL.")
 262
 263 (defvar browse-url-browser-function
 264   'browse-url-netscape
 265   "*Function to display the current buffer in a WWW browser.
 266 Used by the `browse-url-at-point', `browse-url-at-mouse', and
 267 `browse-url-of-file' commands.")
 268
 269 (defvar browse-url-netscape-arguments nil
 270   "*A list of strings to pass to Netscape as arguments.")
 271
 272 (defvar browse-url-new-window-p nil
 273   "*If non-nil, always open a new browser window.
 274 Passing an interactive argument to \\[browse-url-netscape] or
 275 \\[browse-url-cci] reverses the effect of this variable.  Requires
 276 Netscape version 1.1N or later or XMosaic version 2.5 or later.")
 277
 278 (defvar browse-url-mosaic-arguments nil
 279   "*A list of strings to pass to Mosaic as arguments.")
 280
 281 (defvar browse-url-filename-alist
 282   '(("^/+" . "file:/"))
 283   "An alist of (REGEXP . STRING) pairs.
 284 Any substring of a filename matching one of the REGEXPs is replaced by
 285 the corresponding STRING.  All pairs are applied in the order given.
 286 Used by the `browse-url-of-file' command.")
 287
 288 (defvar browse-url-save-file nil
 289   "If non-nil, save the buffer before displaying its file.
 290 Used by the `browse-url-of-file' command.")
 291
 292 (defvar browse-url-of-file-hook nil
 293   "A hook to be run with run-hook after `browse-url-of-file' has asked
 294 a browser to load a file.
 295
 296 Set this to `browse-url-netscape-reload' to force Netscape to load the
 297 file rather than displaying a cached copy.")
 298
 299 (defvar browse-url-usr1-signal
 300   (if (and (boundp 'emacs-major-version)
 301            (or (> emacs-major-version 19) (>= emacs-minor-version 29)))
 302       'SIGUSR1
 303     30)                                 ; Check /usr/include/signal.h.
 304   "The argument to `signal-process' for sending SIGUSR1 to XMosaic.
 305 Emacs 19.29 accepts 'SIGUSR1, earlier versions require an integer
 306 which is 30 on SunOS and 16 on HP-UX and Solaris.")
 307
 308 (defvar browse-url-CCI-port 3003
 309   "Port to access XMosaic via CCI.
 310 This can be any number between 1024 and 65535 but must correspond to
 311 the value set in the browser.")
 312
 313 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 314 ;; URL input
 315
 316 ;; thingatpt.el doesn't work for complex regexps.
 317
 318 (defun browse-url-url-at-point ()
 319   "Return the URL around or before point.
 320 Then search backwards for the start of a URL.  If no URL found, return
 321 the empty string."
 322   (if (or (looking-at browse-url-regexp)        ; Already at start
 323           (let ((eol (save-excursion (end-of-line) (point))))
 324             ;; Search forwards for the next URL or end of line in case
 325             ;; we're in the middle of one.
 326             (and (re-search-forward browse-url-regexp eol 'lim)
 327                  (goto-char (match-beginning 0)))
 328             ;; Now back to where we started or earlier.
 329             (re-search-backward browse-url-regexp nil t)))
 330       (buffer-substring (match-beginning 0) (match-end 0))
 331     ""))                                ; No match
 332
 333 ;; Todo: restrict to around or immediately before point.  Expand bare
 334 ;; hostname to URL.
 335
 336 (defun browse-url-interactive-arg (&optional prompt)
 337   "Read a URL from the minibuffer, optionally prompting with PROMPT.
 338 Default to the URL at or before point.  If bound to a mouse button,
 339 set point to the position clicked.  Return the result as a list for
 340 use in `interactive'."
 341   (let ((event (elt (this-command-keys) 0)))
 342     (and (listp event) (mouse-set-point event)))
 343   (list (read-string (or prompt "URL: ") (browse-url-url-at-point))))
 344
 345 ;;;###autoload
 346 (defun browse-url-at-point ()
 347   "Ask a WWW browser to load the URL at or before point.
 348 The URL is loaded according to the value of `browse-url-browser-function'."
 349   (interactive)
 350   (funcall browse-url-browser-function (browse-url-url-at-point)))
 351
 352 ;;;###autoload
 353 (defun browse-url-at-mouse (event)
 354   "Ask a WWW browser to load a URL clicked with the mouse.
 355 The URL is the one around or before the position of the mouse click
 356 but point is not changed.  The URL is loaded according to the value of
 357 `browse-url-browser-function'."
 358   (interactive "e")
 359   (save-excursion
 360     (let ((posn (event-start event)))
 361       (set-buffer (window-buffer (posn-window posn)))
 362       (goto-char (posn-point posn))
 363       (let ((url (browse-url-url-at-point)))
 364         (if (string-equal url "")
 365             (error "No URL found"))
 366         (funcall browse-url-browser-function url)))))
 367
 368 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 369 ;; Browse current buffer
 370
 371 ;;;###autoload
 372 (defun browse-url-of-file (&optional file)
 373   "Ask a WWW browser to display FILE.
 374 Display the current buffer's file if FILE is nil or if called
 375 interactively.  Turn the filename into a URL by performing
 376 replacements given in variable `browse-url-filename-alist'.  Pass the
 377 URL to a browser using variable `browse-url-browser-function' then run
 378 `browse-url-of-file-hook'."
 379   (interactive)
 380   (setq file
 381         (or file
 382             (buffer-file-name)
 383             (error "Current buffer has no file")))
 384   (let ((buf (get-file-buffer file)))
 385     (if buf
 386         (save-excursion
 387           (set-buffer buf)
 388           (cond ((not (buffer-modified-p)))
 389                 (browse-url-save-file (save-buffer))
 390                 (t (message "%s modified since last save" file))))))
 391   (funcall browse-url-browser-function (browse-url-file-url file))
 392   (run-hooks 'browse-url-of-file-hook))
 393
 394 (defun browse-url-file-url (file)
 395   "Return the URL corresponding to FILE.
 396 Uses variable `browse-url-filename-alist' to map filenames to URLs."
 397   (let ((maps browse-url-filename-alist))
 398     (while maps
 399       (let* ((map (car maps))
 400              (from-re (car map))
 401              (to-string (cdr map)))
 402         (setq maps (cdr maps))
 403         (if (string-match from-re file)
 404             (setq file (concat (substring file 0 (match-beginning 0))
 405                                to-string
 406                                (substring file (match-end 0))))))))
 407   file)
 408
 409 (defvar browse-url-temp-file-name nil)
 410 (make-variable-buffer-local 'browse-url-temp-file-name)
 411
 412 (defvar browse-url-temp-file-list '())
 413
 414 ;;;###autoload
 415 (defun browse-url-of-buffer (&optional buffer)
 416   "Ask a WWW browser to display BUFFER.
 417 Display the current buffer if BUFFER is nil."
 418   (interactive)
 419   (save-excursion
 420     (set-buffer (or buffer (current-buffer)))
 421     (let ((file-name
 422            (or buffer-file-name
 423                (and (boundp 'dired-directory) dired-directory))))
 424       (if (null file-name)
 425           (progn
 426             (if (null browse-url-temp-file-name)
 427                 (progn
 428                   (setq browse-url-temp-file-name
 429                         (make-temp-name
 430                          (expand-file-name (buffer-name)
 431                                            (or (getenv "TMPDIR") "/tmp"))))
 432                   (setq browse-url-temp-file-list
 433                         (cons browse-url-temp-file-name
 434                               browse-url-temp-file-list))))
 435             (write-region (point-min) (point-max) browse-url-temp-file-name
 436                           nil 'no-message)))
 437       (browse-url-of-file (or file-name browse-url-temp-file-name)))))
 438
 439 (defun browse-url-delete-temp-file (&optional temp-file-name)
 440   ;; Delete browse-url-temp-file-name from the file system and from
 441   ;; browse-url-temp-file-list.  If optional arg TEMP-FILE-NAME is
 442   ;; non-nil, delete it instead, but only from the file system --
 443   ;; browse-url-temp-file-list is not affected.
 444   (let ((file-name (or temp-file-name browse-url-temp-file-name)))
 445     (if (and file-name (file-exists-p file-name))
 446         (progn
 447           (delete-file file-name)
 448           (if (null temp-file-name)
 449               (setq browse-url-temp-file-list
 450                     (delete browse-url-temp-file-name
 451                             browse-url-temp-file-list)))))))
 452
 453 (defun browse-url-delete-temp-file-list ()
 454   ;; Delete all elements of browse-url-temp-file-list.
 455   (while browse-url-temp-file-list
 456     (browse-url-delete-temp-file (car browse-url-temp-file-list))
 457     (setq browse-url-temp-file-list
 458           (cdr browse-url-temp-file-list))))
 459
 460 (add-hook 'kill-buffer-hook 'browse-url-delete-temp-file)
 461 (add-hook 'kill-emacs-hook 'browse-url-delete-temp-file-list)
 462
 463 ;;;###autoload
 464 (defun browse-url-of-dired-file ()
 465   "In Dired, ask a WWW browser to display the file named on this line."
 466   (interactive)
 467   (browse-url-of-file (dired-get-filename)))
 468
 469 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 470 ;; Browser-specific functions
 471
 472 (defun browse-url-netscape (url &optional new-window)
 473   "Ask the Netscape WWW browser to load URL.
 474
 475 Default to the URL around or before point.  The strings in variable
 476 `browse-url-netscape-arguments' are also passed to Netscape.
 477
 478 When called interactively, if variable `browse-url-new-window-p' is
 479 non-nil, load the document in a new Netscape window, otherwise use a
 480 random existing one.  A non-nil interactive prefix argument reverses
 481 the effect of browse-url-new-window-p.
 482
 483 When called non-interactively, optional second argument NEW-WINDOW is
 484 used instead of browse-url-new-window-p."
 485
 486   (interactive (append (browse-url-interactive-arg "Netscape URL: ")
 487                        (list (not (eq (null browse-url-new-window-p)
 488                                       (null current-prefix-arg))))))
 489   (let ((res
 490          (apply 'call-process "netscape" nil nil nil
 491                 (append browse-url-netscape-arguments
 492                         (if new-window '("-noraise"))
 493                         (list "-remote"
 494                               (concat "openURL(" url
 495                                       (if new-window ",new-window")
 496                                       ")"))))
 497          ))
 498     (if (stringp res)
 499         (error "netscape got signal: %s" res)
 500       (or (zerop res)
 501           (progn                        ; Netscape not running - start it
 502             (message "Starting Netscape...")
 503             (apply 'start-process "netscape" nil "netscape"
 504                    (append browse-url-netscape-arguments (list url))))))))
 505
 506 (defun browse-url-netscape-reload ()
 507   "Ask Netscape to reload its current document."
 508   (interactive)
 509   (browse-url-netscape-command "reload"))
 510
 511 (defun browse-url-netscape-command (command)
 512   "Send a remote control command to Netscape."
 513   (apply 'start-process "netscape" nil "netscape"
 514          (append browse-url-netscape-arguments
 515                  (list "-remote" command))))
 516
 517 (defun browse-url-mosaic (url)
 518   "Ask the XMosaic WWW browser to load URL.
 519 Default to the URL around or before point."
 520   (interactive (browse-url-interactive-arg "Mosaic URL: "))
 521   (let ((pidfile (expand-file-name "~/.mosaicpid"))
 522         pid pidbuf)
 523     (if (file-readable-p pidfile)
 524         (save-excursion
 525           (find-file pidfile)
 526           (goto-char (point-min))
 527           (setq pid (read (current-buffer)))
 528           (kill-buffer nil)))
 529     (if (and pid (zerop (signal-process pid 0))) ; Mosaic running
 530         (save-excursion
 531           (find-file (format "/tmp/Mosaic.%d" pid))
 532           (erase-buffer)
 533           (insert "goto\n" url "\n")
 534           (save-buffer)
 535           (kill-buffer nil)
 536           ;; Send signal SIGUSR to Mosaic
 537           (signal-process pid browse-url-usr1-signal)
 538           (message "Signal sent to Mosaic")
 539           ;; Or you could try:
 540           ;; (call-process "kill" nil 0 nil "-USR1" (int-to-string pid))
 541           )
 542       ;; Mosaic not running - start it
 543       (message "Starting Mosaic...")
 544       (apply 'start-process "xmosaic" nil "xmosaic"
 545              (append browse-url-mosaic-arguments (list url)))
 546       (message "Starting Mosaic...done"))))
 547
 548 (defun browse-url-cci (url &optional new-window)
 549   "Ask the XMosaic WWW browser to load URL.
 550 Default to the URL around or before point.
 551
 552 This function only works for XMosaic version 2.5 or later.  You must
 553 select `CCI' from XMosaic's File menu, set the CCI Port Address to the
 554 value of variable `browse-url-CCI-port', and enable `Accept requests'.
 555
 556 When called interactively, if variable `browse-url-new-window-p' is
 557 non-nil, load the document in a new browser window, otherwise use a
 558 random existing one.  A non-nil interactive prefix argument reverses
 559 the effect of browse-url-new-window-p.
 560
 561 When called non-interactively, optional second argument NEW-WINDOW is
 562 used instead of browse-url-new-window-p."
 563   (interactive (append (browse-url-interactive-arg "Mosaic URL: ")
 564                        (list (not (eq (null browse-url-new-window-p)
 565                                       (null current-prefix-arg))))))
 566   (open-network-stream "browse-url" " *browse-url*"
 567                        "localhost" browse-url-CCI-port)
 568   ;; Todo: start browser if fails
 569   (process-send-string "browse-url"
 570                        (concat "get url (" url ") output "
 571                                (if new-window "new" "current") "\r\n"))
 572   (process-send-string "browse-url" "disconnect\r\n")
 573   (delete-process "browse-url"))
 574
 575 (defun browse-url-iximosaic (url)
 576   "Ask the IXIMosaic WWW browser to load URL.
 577 Default to the URL around or before point."
 578   (interactive (browse-url-interactive-arg "IXI Mosaic URL: "))
 579   (start-process "tellw3b" nil "tellw3b"
 580                  "-service WWW_BROWSER ixi_showurl " url))
 581
 582 (defun browse-url-w3 (url)
 583   "Ask the w3 WWW browser to load URL.
 584 Default to the URL around or before point."
 585   (interactive (browse-url-interactive-arg "W3 URL: "))
 586   (w3-fetch url))
 587
 588 (provide 'browse-url)
 589
 590 ;;; browse-url.el ends here