lisp/help-mode.el

   1 ;;; help-mode.el --- `help-mode' used by *Help* buffers
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Defines `help-mode', which is the mode used by *Help* buffers, and
  28 ;; associated support machinery, such as adding hyperlinks, etc.,
  29
  30 ;;; Code:
  31
  32 (require 'button)
  33 (require 'view)
  34 (eval-when-compile (require 'easymenu))
  35
  36 (defvar help-mode-map (make-sparse-keymap)
  37   "Keymap for help mode.")
  38
  39 (set-keymap-parent help-mode-map button-buffer-map)
  40
  41 (define-key help-mode-map [mouse-2] 'help-follow-mouse)
  42 (define-key help-mode-map "\C-c\C-b" 'help-go-back)
  43 (define-key help-mode-map "\C-c\C-f" 'help-go-forward)
  44 (define-key help-mode-map "\C-c\C-c" 'help-follow-symbol)
  45 ;; Documentation only, since we use minor-mode-overriding-map-alist.
  46 (define-key help-mode-map "\r" 'help-follow)
  47
  48 (easy-menu-define help-mode-menu help-mode-map
  49   "Menu for Help Mode."
  50   '("Help-Mode"
  51     ["Show Help for Symbol" help-follow-symbol
  52      :help "Show the docs for the symbol at point"]
  53     ["Previous Topic" help-go-back
  54      :help "Go back to previous topic in this help buffer"]
  55     ["Next Topic" help-go-forward
  56      :help "Go back to next topic in this help buffer"]
  57     ["Move to Previous Button" backward-button
  58      :help "Move to the Next Button in the help buffer"]
  59     ["Move to Next Button" forward-button
  60       :help "Move to the Next Button in the help buffer"]))
  61
  62 (defvar help-xref-stack nil
  63   "A stack of ways by which to return to help buffers after following xrefs.
  64 Used by `help-follow' and `help-xref-go-back'.
  65 An element looks like (POSITION FUNCTION ARGS...).
  66 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  67 (put 'help-xref-stack 'permanent-local t)
  68 (make-variable-buffer-local 'help-xref-stack)
  69
  70 (defvar help-xref-forward-stack nil
  71   "A stack used to navigate help forwards after using the back button.
  72 Used by `help-follow' and `help-xref-go-forward'.
  73 An element looks like (POSITION FUNCTION ARGS...).
  74 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  75 (put 'help-xref-forward-stack 'permanent-local t)
  76 (make-variable-buffer-local 'help-xref-forward-stack)
  77
  78 (defvar help-xref-stack-item nil
  79   "An item for `help-follow' in this buffer to push onto `help-xref-stack'.
  80 The format is (FUNCTION ARGS...).")
  81 (put 'help-xref-stack-item 'permanent-local t)
  82 (make-variable-buffer-local 'help-xref-stack-item)
  83
  84 (defvar help-xref-stack-forward-item nil
  85   "An item for `help-go-back' to push onto `help-xref-forward-stack'.
  86 The format is (FUNCTION ARGS...).")
  87 (put 'help-xref-stack-forward-item 'permanent-local t)
  88 (make-variable-buffer-local 'help-xref-stack-forward-item)
  89
  90 (setq-default help-xref-stack nil help-xref-stack-item nil)
  91 (setq-default help-xref-forward-stack nil help-xref-forward-stack-item nil)
  92
  93 (defcustom help-mode-hook nil
  94   "Hook run by `help-mode'."
  95   :type 'hook
  96   :group 'help)
  97 \f
  98 ;; Button types used by help
  99
 100 (define-button-type 'help-xref
 101   'follow-link t
 102   'action #'help-button-action)
 103
 104 (defun help-button-action (button)
 105   "Call BUTTON's help function."
 106   (help-do-xref (button-start button)
 107                 (button-get button 'help-function)
 108                 (button-get button 'help-args)))
 109
 110 ;; These 6 calls to define-button-type were generated in a dolist
 111 ;; loop, but that is bad because it means these button types don't
 112 ;; have an easily found definition.
 113
 114 (define-button-type 'help-function
 115   :supertype 'help-xref
 116   'help-function 'describe-function
 117   'help-echo (purecopy "mouse-2, RET: describe this function"))
 118
 119 (define-button-type 'help-variable
 120   :supertype 'help-xref
 121   'help-function 'describe-variable
 122   'help-echo (purecopy "mouse-2, RET: describe this variable"))
 123
 124 (define-button-type 'help-face
 125   :supertype 'help-xref
 126   'help-function 'describe-face
 127   'help-echo (purecopy "mouse-2, RET: describe this face"))
 128
 129 (define-button-type 'help-coding-system
 130   :supertype 'help-xref
 131   'help-function 'describe-coding-system
 132   'help-echo (purecopy "mouse-2, RET: describe this coding system"))
 133
 134 (define-button-type 'help-input-method
 135   :supertype 'help-xref
 136   'help-function 'describe-input-method
 137   'help-echo (purecopy "mouse-2, RET: describe this input method"))
 138
 139 (define-button-type 'help-character-set
 140   :supertype 'help-xref
 141   'help-function 'describe-character-set
 142   'help-echo (purecopy "mouse-2, RET: describe this character set"))
 143
 144 ;; make some more ideosyncratic button types
 145
 146 (define-button-type 'help-symbol
 147   :supertype 'help-xref
 148   'help-function #'help-xref-interned
 149   'help-echo (purecopy "mouse-2, RET: describe this symbol"))
 150
 151 (define-button-type 'help-back
 152   :supertype 'help-xref
 153   'help-function #'help-xref-go-back
 154   'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
 155
 156 (define-button-type 'help-forward
 157   :supertype 'help-xref
 158   'help-function #'help-xref-go-forward
 159   'help-echo (purecopy "mouse-2, RET: move forward to next help buffer"))
 160
 161 (define-button-type 'help-info-variable
 162   :supertype 'help-xref
 163   ;; the name of the variable is put before the argument to Info
 164   'help-function (lambda (a v) (info v))
 165   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 166
 167 (define-button-type 'help-info
 168   :supertype 'help-xref
 169   'help-function #'info
 170   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 171
 172 (define-button-type 'help-url
 173   :supertype 'help-xref
 174   'help-function #'browse-url
 175   'help-echo (purecopy "mouse-2, RET: view this URL in a browser"))
 176
 177 (define-button-type 'help-customize-variable
 178   :supertype 'help-xref
 179   'help-function (lambda (v)
 180                    (customize-variable v))
 181   'help-echo (purecopy "mouse-2, RET: customize variable"))
 182
 183 (define-button-type 'help-customize-face
 184   :supertype 'help-xref
 185   'help-function (lambda (v)
 186                    (customize-face v))
 187   'help-echo (purecopy "mouse-2, RET: customize face"))
 188
 189 (define-button-type 'help-function-def
 190   :supertype 'help-xref
 191   'help-function (lambda (fun file)
 192                    (require 'find-func)
 193                    (when (eq file 'C-source)
 194                      (setq file
 195                            (help-C-file-name (indirect-function fun) 'fun)))
 196                    ;; Don't use find-function-noselect because it follows
 197                    ;; aliases (which fails for built-in functions).
 198                    (let ((location
 199                           (find-function-search-for-symbol fun nil file)))
 200                      (pop-to-buffer (car location))
 201                      (if (cdr location)
 202                          (goto-char (cdr location))
 203                        (message "Unable to find location in file"))))
 204   'help-echo (purecopy "mouse-2, RET: find function's definition"))
 205
 206 (define-button-type 'help-function-cmacro
 207   :supertype 'help-xref
 208   'help-function (lambda (fun file)
 209                    (setq file (locate-library file t))
 210                    (if (and file (file-readable-p file))
 211                        (progn
 212                          (pop-to-buffer (find-file-noselect file))
 213                          (goto-char (point-min))
 214                          (if (re-search-forward
 215                               (format "^[ \t]*(define-compiler-macro[ \t]+%s"
 216                                       (regexp-quote (symbol-name fun))) nil t)
 217                              (forward-line 0)
 218                            (message "Unable to find location in file")))
 219                      (message "Unable to find file")))
 220   'help-echo (purecopy "mouse-2, RET: find function's compiler macro"))
 221
 222 (define-button-type 'help-variable-def
 223   :supertype 'help-xref
 224   'help-function (lambda (var &optional file)
 225                    (when (eq file 'C-source)
 226                      (setq file (help-C-file-name var 'var)))
 227                    (let ((location (find-variable-noselect var file)))
 228                      (pop-to-buffer (car location))
 229                      (if (cdr location)
 230                        (goto-char (cdr location))
 231                        (message "Unable to find location in file"))))
 232   'help-echo (purecopy "mouse-2, RET: find variable's definition"))
 233
 234 (define-button-type 'help-face-def
 235   :supertype 'help-xref
 236   'help-function (lambda (fun file)
 237                    (require 'find-func)
 238                    ;; Don't use find-function-noselect because it follows
 239                    ;; aliases (which fails for built-in functions).
 240                    (let ((location
 241                           (find-function-search-for-symbol fun 'defface file)))
 242                      (pop-to-buffer (car location))
 243                      (if (cdr location)
 244                          (goto-char (cdr location))
 245                        (message "Unable to find location in file"))))
 246   'help-echo (purecopy "mouse-2, RET: find face's definition"))
 247
 248 (define-button-type 'help-package
 249   :supertype 'help-xref
 250   'help-function 'describe-package
 251   'help-echo (purecopy "mouse-2, RET: Describe package"))
 252
 253 (define-button-type 'help-package-def
 254   :supertype 'help-xref
 255   'help-function (lambda (file) (dired file))
 256   'help-echo (purecopy "mouse-2, RET: visit package directory"))
 257
 258 (define-button-type 'help-theme-def
 259   :supertype 'help-xref
 260   'help-function 'find-file
 261   'help-echo (purecopy "mouse-2, RET: visit theme file"))
 262
 263 (define-button-type 'help-theme-edit
 264   :supertype 'help-xref
 265   'help-function 'customize-create-theme
 266   'help-echo (purecopy "mouse-2, RET: edit this theme file"))
 267 \f
 268 ;;;###autoload
 269 (defun help-mode ()
 270   "Major mode for viewing help text and navigating references in it.
 271 Entry to this mode runs the normal hook `help-mode-hook'.
 272 Commands:
 273 \\{help-mode-map}"
 274   (interactive)
 275   (kill-all-local-variables)
 276   (use-local-map help-mode-map)
 277   (setq mode-name "Help")
 278   (setq major-mode 'help-mode)
 279
 280   (view-mode)
 281   (set (make-local-variable 'view-no-disable-on-exit) t)
 282   ;; With Emacs 22 `view-exit-action' could delete the selected window
 283   ;; disregarding whether the help buffer was shown in that window at
 284   ;; all.  Since `view-exit-action' is called with the help buffer as
 285   ;; argument it seems more appropriate to have it work on the buffer
 286   ;; only and leave it to `view-mode-exit' to delete any associated
 287   ;; window(s).
 288   (setq view-exit-action
 289         (lambda (buffer)
 290           ;; Use `with-current-buffer' to make sure that `bury-buffer'
 291           ;; also removes BUFFER from the selected window.
 292           (with-current-buffer buffer
 293             (bury-buffer))))
 294
 295   (set (make-local-variable 'revert-buffer-function)
 296        'help-mode-revert-buffer)
 297
 298   (run-mode-hooks 'help-mode-hook))
 299
 300 ;;;###autoload
 301 (defun help-mode-setup ()
 302   (help-mode)
 303   (setq buffer-read-only nil))
 304
 305 ;;;###autoload
 306 (defun help-mode-finish ()
 307   (when (eq major-mode 'help-mode)
 308     ;; View mode's read-only status of existing *Help* buffer is lost
 309     ;; by with-output-to-temp-buffer.
 310     (toggle-read-only 1)
 311     (help-make-xrefs (current-buffer))))
 312 \f
 313 ;; Grokking cross-reference information in doc strings and
 314 ;; hyperlinking it.
 315
 316 ;; This may have some scope for extension and the same or something
 317 ;; similar should be done for widget doc strings, which currently use
 318 ;; another mechanism.
 319
 320 (defvar help-back-label (purecopy "[back]")
 321   "Label to use by `help-make-xrefs' for the go-back reference.")
 322
 323 (defvar help-forward-label (purecopy "[forward]")
 324   "Label to use by `help-make-xrefs' for the go-forward reference.")
 325
 326 (defconst help-xref-symbol-regexp
 327   (purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|"  ; Link to var
 328                     "\\(function\\|command\\)\\|"          ; Link to function
 329                     "\\(face\\)\\|"                        ; Link to face
 330                     "\\(symbol\\|program\\|property\\)\\|" ; Don't link
 331                     "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
 332                     "[ \t\n]+\\)?"
 333                     ;; Note starting with word-syntax character:
 334                     "`\\(\\sw\\(\\sw\\|\\s_\\)+\\)'"))
 335   "Regexp matching doc string references to symbols.
 336
 337 The words preceding the quoted symbol can be used in doc strings to
 338 distinguish references to variables, functions and symbols.")
 339
 340 (defvar help-xref-mule-regexp nil
 341   "Regexp matching doc string references to MULE-related keywords.
 342
 343 It is usually nil, and is temporarily bound to an appropriate regexp
 344 when help commands related to multilingual environment (e.g.,
 345 `describe-coding-system') are invoked.")
 346
 347
 348 (defconst help-xref-info-regexp
 349   (purecopy "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+`\\([^']+\\)'")
 350   "Regexp matching doc string references to an Info node.")
 351
 352 (defconst help-xref-url-regexp
 353   (purecopy "\\<[Uu][Rr][Ll][ \t\n]+`\\([^']+\\)'")
 354   "Regexp matching doc string references to a URL.")
 355
 356 ;;;###autoload
 357 (defun help-setup-xref (item interactive-p)
 358   "Invoked from commands using the \"*Help*\" buffer to install some xref info.
 359
 360 ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
 361 buffer after following a reference.  INTERACTIVE-P is non-nil if the
 362 calling command was invoked interactively.  In this case the stack of
 363 items for help buffer \"back\" buttons is cleared.
 364
 365 This should be called very early, before the output buffer is cleared,
 366 because we want to record the \"previous\" position of point so we can
 367 restore it properly when going back."
 368   (with-current-buffer (help-buffer)
 369     (when help-xref-stack-item
 370       (push (cons (point) help-xref-stack-item) help-xref-stack)
 371       (setq help-xref-forward-stack nil))
 372     (when interactive-p
 373       (let ((tail (nthcdr 10 help-xref-stack)))
 374         ;; Truncate the stack.
 375         (if tail (setcdr tail nil))))
 376     (setq help-xref-stack-item item)))
 377
 378 (defvar help-xref-following nil
 379   "Non-nil when following a help cross-reference.")
 380
 381 ;;;###autoload
 382 (defun help-buffer ()
 383   "Return the name of a buffer for inserting help.
 384 If `help-xref-following' is non-nil, this is the name of the
 385 current buffer.
 386 Otherwise, it is *Help*; if no buffer with that name currently
 387 exists, it is created."
 388   (buffer-name                          ;for with-output-to-temp-buffer
 389    (if help-xref-following
 390        (current-buffer)
 391      (get-buffer-create "*Help*"))))
 392
 393 (defvar help-xref-override-view-map
 394   (let ((map (make-sparse-keymap)))
 395     (set-keymap-parent map view-mode-map)
 396     (define-key map "\r" nil)
 397     map)
 398   "Replacement keymap for `view-mode' in help buffers.")
 399
 400 ;;;###autoload
 401 (defun help-make-xrefs (&optional buffer)
 402   "Parse and hyperlink documentation cross-references in the given BUFFER.
 403
 404 Find cross-reference information in a buffer and activate such cross
 405 references for selection with `help-follow'.  Cross-references have
 406 the canonical form `...'  and the type of reference may be
 407 disambiguated by the preceding word(s) used in
 408 `help-xref-symbol-regexp'.  Faces only get cross-referenced if
 409 preceded or followed by the word `face'.  Variables without
 410 variable documentation do not get cross-referenced, unless
 411 preceded by the word `variable' or `option'.
 412
 413 If the variable `help-xref-mule-regexp' is non-nil, find also
 414 cross-reference information related to multilingual environment
 415 \(e.g., coding-systems).  This variable is also used to disambiguate
 416 the type of reference as the same way as `help-xref-symbol-regexp'.
 417
 418 A special reference `back' is made to return back through a stack of
 419 help buffers.  Variable `help-back-label' specifies the text for
 420 that."
 421   (interactive "b")
 422   (with-current-buffer (or buffer (current-buffer))
 423     (save-excursion
 424       (goto-char (point-min))
 425       ;; Skip the header-type info, though it might be useful to parse
 426       ;; it at some stage (e.g. "function in `library'").
 427       (forward-paragraph)
 428       (let ((old-modified (buffer-modified-p)))
 429         (let ((stab (syntax-table))
 430               (case-fold-search t)
 431               (inhibit-read-only t))
 432           (set-syntax-table emacs-lisp-mode-syntax-table)
 433           ;; The following should probably be abstracted out.
 434           (unwind-protect
 435               (progn
 436                 ;; Info references
 437                 (save-excursion
 438                   (while (re-search-forward help-xref-info-regexp nil t)
 439                     (let ((data (match-string 2)))
 440                       (save-match-data
 441                         (unless (string-match "^([^)]+)" data)
 442                           (setq data (concat "(emacs)" data)))
 443                         (setq data ;; possible newlines if para filled
 444                               (replace-regexp-in-string "[ \t\n]+" " " data t t)))
 445                       (help-xref-button 2 'help-info data))))
 446                 ;; URLs
 447                 (save-excursion
 448                   (while (re-search-forward help-xref-url-regexp nil t)
 449                     (let ((data (match-string 1)))
 450                       (help-xref-button 1 'help-url data))))
 451                 ;; Mule related keywords.  Do this before trying
 452                 ;; `help-xref-symbol-regexp' because some of Mule
 453                 ;; keywords have variable or function definitions.
 454                 (if help-xref-mule-regexp
 455                     (save-excursion
 456                       (while (re-search-forward help-xref-mule-regexp nil t)
 457                         (let* ((data (match-string 7))
 458                                (sym (intern-soft data)))
 459                           (cond
 460                            ((match-string 3) ; coding system
 461                             (and sym (coding-system-p sym)
 462                                  (help-xref-button 6 'help-coding-system sym)))
 463                            ((match-string 4) ; input method
 464                             (and (assoc data input-method-alist)
 465                                  (help-xref-button 7 'help-input-method data)))
 466                            ((or (match-string 5) (match-string 6)) ; charset
 467                             (and sym (charsetp sym)
 468                                  (help-xref-button 7 'help-character-set sym)))
 469                            ((assoc data input-method-alist)
 470                             (help-xref-button 7 'help-character-set data))
 471                            ((and sym (coding-system-p sym))
 472                             (help-xref-button 7 'help-coding-system sym))
 473                            ((and sym (charsetp sym))
 474                             (help-xref-button 7 'help-character-set sym)))))))
 475                 ;; Quoted symbols
 476                 (save-excursion
 477                   (while (re-search-forward help-xref-symbol-regexp nil t)
 478                     (let* ((data (match-string 8))
 479                            (sym (intern-soft data)))
 480                       (if sym
 481                           (cond
 482                            ((match-string 3) ; `variable' &c
 483                             (and (or (boundp sym) ; `variable' doesn't ensure
 484                                         ; it's actually bound
 485                                      (get sym 'variable-documentation))
 486                                  (help-xref-button 8 'help-variable sym)))
 487                            ((match-string 4) ; `function' &c
 488                             (and (fboundp sym) ; similarly
 489                                  (help-xref-button 8 'help-function sym)))
 490                            ((match-string 5) ; `face'
 491                             (and (facep sym)
 492                                  (help-xref-button 8 'help-face sym)))
 493                            ((match-string 6)) ; nothing for `symbol'
 494                            ((match-string 7)
 495                             ;; this used:
 496                             ;; #'(lambda (arg)
 497                             ;;     (let ((location
 498                             ;;            (find-function-noselect arg)))
 499                             ;;       (pop-to-buffer (car location))
 500                             ;;  (goto-char (cdr location))))
 501                             (help-xref-button 8 'help-function-def sym))
 502                            ((and
 503                              (facep sym)
 504                              (save-match-data (looking-at "[ \t\n]+face\\W")))
 505                             (help-xref-button 8 'help-face sym))
 506                            ((and (or (boundp sym)
 507                                      (get sym 'variable-documentation))
 508                                  (fboundp sym))
 509                             ;; We can't intuit whether to use the
 510                             ;; variable or function doc -- supply both.
 511                             (help-xref-button 8 'help-symbol sym))
 512                            ((and
 513                              (or (boundp sym)
 514                                  (get sym 'variable-documentation))
 515                              (or
 516                               (documentation-property
 517                                sym 'variable-documentation)
 518                               (condition-case nil
 519                                   (documentation-property
 520                                    (indirect-variable sym)
 521                                    'variable-documentation)
 522                                 (cyclic-variable-indirection nil))))
 523                             (help-xref-button 8 'help-variable sym))
 524                            ((fboundp sym)
 525                             (help-xref-button 8 'help-function sym)))))))
 526                 ;; An obvious case of a key substitution:
 527                 (save-excursion
 528                   (while (re-search-forward
 529                           ;; Assume command name is only word and symbol
 530                           ;; characters to get things like `use M-x foo->bar'.
 531                           ;; Command required to end with word constituent
 532                           ;; to avoid `.' at end of a sentence.
 533                           "\\<M-x\\s-+\\(\\sw\\(\\sw\\|\\s_\\)*\\sw\\)" nil t)
 534                     (let ((sym (intern-soft (match-string 1))))
 535                       (if (fboundp sym)
 536                           (help-xref-button 1 'help-function sym)))))
 537                 ;; Look for commands in whole keymap substitutions:
 538                 (save-excursion
 539                   ;; Make sure to find the first keymap.
 540                   (goto-char (point-min))
 541                   ;; Find a header and the column at which the command
 542                   ;; name will be found.
 543
 544                   ;; If the keymap substitution isn't the last thing in
 545                   ;; the doc string, and if there is anything on the same
 546                   ;; line after it, this code won't recognize the end of it.
 547                   (while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
 548                                             nil t)
 549                     (let ((col (- (match-end 1) (match-beginning 1))))
 550                       (while
 551                           (and (not (eobp))
 552                                ;; Stop at a pair of blank lines.
 553                                (not (looking-at "\n\\s-*\n")))
 554                         ;; Skip a single blank line.
 555                         (and (eolp) (forward-line))
 556                         (end-of-line)
 557                         (skip-chars-backward "^ \t\n")
 558                         (if (and (>= (current-column) col)
 559                                  (looking-at "\\(\\sw\\|\\s_\\)+$"))
 560                             (let ((sym (intern-soft (match-string 0))))
 561                               (if (fboundp sym)
 562                                   (help-xref-button 0 'help-function sym))))
 563                         (forward-line))))))
 564             (set-syntax-table stab))
 565           ;; Delete extraneous newlines at the end of the docstring
 566           (goto-char (point-max))
 567           (while (and (not (bobp)) (bolp))
 568             (delete-char -1))
 569           (insert "\n")
 570           (when (or help-xref-stack help-xref-forward-stack)
 571             (insert "\n"))
 572           ;; Make a back-reference in this buffer if appropriate.
 573           (when help-xref-stack
 574             (help-insert-xref-button help-back-label 'help-back
 575                                      (current-buffer)))
 576           ;; Make a forward-reference in this buffer if appropriate.
 577           (when help-xref-forward-stack
 578             (when help-xref-stack
 579               (insert "\t"))
 580             (help-insert-xref-button help-forward-label 'help-forward
 581                                      (current-buffer)))
 582           (when (or help-xref-stack help-xref-forward-stack)
 583             (insert "\n")))
 584         ;; View mode steals RET from us.
 585         (set (make-local-variable 'minor-mode-overriding-map-alist)
 586              (list (cons 'view-mode help-xref-override-view-map)))
 587         (set-buffer-modified-p old-modified)))))
 588
 589 ;;;###autoload
 590 (defun help-xref-button (match-number type &rest args)
 591   "Make a hyperlink for cross-reference text previously matched.
 592 MATCH-NUMBER is the subexpression of interest in the last matched
 593 regexp.  TYPE is the type of button to use.  Any remaining arguments are
 594 passed to the button's help-function when it is invoked.
 595 See `help-make-xrefs'."
 596   ;; Don't mung properties we've added specially in some instances.
 597   (unless (button-at (match-beginning match-number))
 598     (make-text-button (match-beginning match-number)
 599                       (match-end match-number)
 600                       'type type 'help-args args)))
 601
 602 ;;;###autoload
 603 (defun help-insert-xref-button (string type &rest args)
 604   "Insert STRING and make a hyperlink from cross-reference text on it.
 605 TYPE is the type of button to use.  Any remaining arguments are passed
 606 to the button's help-function when it is invoked.
 607 See `help-make-xrefs'."
 608   (unless (button-at (point))
 609     (insert-text-button string 'type type 'help-args args)))
 610
 611 ;;;###autoload
 612 (defun help-xref-on-pp (from to)
 613   "Add xrefs for symbols in `pp's output between FROM and TO."
 614   (if (> (- to from) 5000) nil
 615     (with-syntax-table emacs-lisp-mode-syntax-table
 616       (save-excursion
 617         (save-restriction
 618           (narrow-to-region from to)
 619           (goto-char (point-min))
 620           (condition-case nil
 621               (while (not (eobp))
 622                 (cond
 623                  ((looking-at "\"") (forward-sexp 1))
 624                  ((looking-at "#<") (search-forward ">" nil 'move))
 625                  ((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
 626                   (let* ((sym (intern-soft (match-string 1)))
 627                          (type (cond ((fboundp sym) 'help-function)
 628                                      ((or (memq sym '(t nil))
 629                                           (keywordp sym))
 630                                       nil)
 631                                      ((and sym
 632                                            (or (boundp sym)
 633                                                (get sym
 634                                                     'variable-documentation)))
 635                                       'help-variable))))
 636                     (when type (help-xref-button 1 type sym)))
 637                   (goto-char (match-end 1)))
 638                  (t (forward-char 1))))
 639             (error nil)))))))
 640
 641 \f
 642 ;; Additional functions for (re-)creating types of help buffers.
 643 (defun help-xref-interned (symbol)
 644   "Follow a hyperlink which appeared to be an arbitrary interned SYMBOL.
 645 Both variable, function and face documentation are extracted into a single
 646 help buffer."
 647   (with-current-buffer (help-buffer)
 648     ;; Push the previous item on the stack before clobbering the output buffer.
 649     (help-setup-xref nil nil)
 650     (let ((facedoc (when (facep symbol)
 651                      ;; Don't record the current entry in the stack.
 652                      (setq help-xref-stack-item nil)
 653                      (describe-face symbol)))
 654           (fdoc (when (fboundp symbol)
 655                   ;; Don't record the current entry in the stack.
 656                   (setq help-xref-stack-item nil)
 657                   (describe-function symbol)))
 658           (sdoc (when (or (boundp symbol)
 659                           (get symbol 'variable-documentation))
 660                   ;; Don't record the current entry in the stack.
 661                   (setq help-xref-stack-item nil)
 662                   (describe-variable symbol))))
 663       (cond
 664        (sdoc
 665         ;; We now have a help buffer on the variable.
 666         ;; Insert the function and face text before it.
 667         (when (or fdoc facedoc)
 668           (goto-char (point-min))
 669           (let ((inhibit-read-only t))
 670             (when fdoc
 671               (insert fdoc "\n\n")
 672               (when facedoc
 673                 (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 674                         " is also a " "face." "\n\n")))
 675             (when facedoc
 676               (insert facedoc "\n\n"))
 677             (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 678                     " is also a " "variable." "\n\n"))
 679           ;; Don't record the `describe-variable' item in the stack.
 680           (setq help-xref-stack-item nil)
 681           (help-setup-xref (list #'help-xref-interned symbol) nil)))
 682        (fdoc
 683         ;; We now have a help buffer on the function.
 684         ;; Insert face text before it.
 685         (when facedoc
 686           (goto-char (point-max))
 687           (let ((inhibit-read-only t))
 688             (insert "\n\n" (make-string 30 ?-) "\n\n" (symbol-name symbol)
 689                     " is also a " "face." "\n\n" facedoc))
 690           ;; Don't record the `describe-function' item in the stack.
 691           (setq help-xref-stack-item nil)
 692           (help-setup-xref (list #'help-xref-interned symbol) nil)))))))
 693
 694 \f
 695 ;; Navigation/hyperlinking with xrefs
 696
 697 (defun help-xref-go-back (buffer)
 698   "From BUFFER, go back to previous help buffer text using `help-xref-stack'."
 699   (let (item position method args)
 700     (with-current-buffer buffer
 701       (push (cons (point) help-xref-stack-item) help-xref-forward-stack)
 702       (when help-xref-stack
 703         (setq item (pop help-xref-stack)
 704               ;; Clear the current item so that it won't get pushed
 705               ;; by the function we're about to call.  TODO: We could also
 706               ;; push it onto a "forward" stack and add a `forw' button.
 707               help-xref-stack-item nil
 708               position (car item)
 709               method (cadr item)
 710               args (cddr item))))
 711     (apply method args)
 712     (with-current-buffer buffer
 713       (if (get-buffer-window buffer)
 714           (set-window-point (get-buffer-window buffer) position)
 715         (goto-char position)))))
 716
 717 (defun help-xref-go-forward (buffer)
 718   "From BUFFER, go forward to next help buffer."
 719   (let (item position method args)
 720     (with-current-buffer buffer
 721       (push (cons (point) help-xref-stack-item) help-xref-stack)
 722       (when help-xref-forward-stack
 723         (setq item (pop help-xref-forward-stack)
 724               ;; Clear the current item so that it won't get pushed
 725               ;; by the function we're about to call.  TODO: We could also
 726               ;; push it onto a "forward" stack and add a `forw' button.
 727               help-xref-stack-item nil
 728               position (car item)
 729               method (cadr item)
 730               args (cddr item))))
 731     (apply method args)
 732     (with-current-buffer buffer
 733       (if (get-buffer-window buffer)
 734           (set-window-point (get-buffer-window buffer) position)
 735         (goto-char position)))))
 736
 737 (defun help-go-back ()
 738   "Go back to previous topic in this help buffer."
 739   (interactive)
 740   (if help-xref-stack
 741       (help-xref-go-back (current-buffer))
 742     (error "No previous help buffer")))
 743
 744 (defun help-go-forward ()
 745   "Go back to next topic in this help buffer."
 746   (interactive)
 747   (if help-xref-forward-stack
 748       (help-xref-go-forward (current-buffer))
 749     (error "No next help buffer")))
 750
 751 (defun help-do-xref (pos function args)
 752   "Call the help cross-reference function FUNCTION with args ARGS.
 753 Things are set up properly so that the resulting help-buffer has
 754 a proper [back] button."
 755   ;; There is a reference at point.  Follow it.
 756   (let ((help-xref-following t))
 757     (apply function args)))
 758
 759 ;; The doc string is meant to explain what buttons do.
 760 (defun help-follow-mouse ()
 761   "Follow the cross-reference that you click on."
 762   (interactive)
 763   (error "No cross-reference here"))
 764
 765 ;; The doc string is meant to explain what buttons do.
 766 (defun help-follow ()
 767   "Follow cross-reference at point.
 768
 769 For the cross-reference format, see `help-make-xrefs'."
 770   (interactive)
 771   (error "No cross-reference here"))
 772
 773 (defun help-follow-symbol (&optional pos)
 774   "In help buffer, show docs for symbol at POS, defaulting to point.
 775 Show all docs for that symbol as either a variable, function or face."
 776   (interactive "d")
 777   (unless pos
 778     (setq pos (point)))
 779   ;; check if the symbol under point is a function, variable or face
 780   (let ((sym
 781          (intern
 782           (save-excursion
 783             (goto-char pos) (skip-syntax-backward "w_")
 784             (buffer-substring (point)
 785                               (progn (skip-syntax-forward "w_")
 786                                      (point)))))))
 787     (when (or (boundp sym)
 788               (get sym 'variable-documentation)
 789               (fboundp sym) (facep sym))
 790       (help-do-xref pos #'help-xref-interned (list sym)))))
 791
 792 (defun help-mode-revert-buffer (ignore-auto noconfirm)
 793   (when (or noconfirm (yes-or-no-p "Revert help buffer? "))
 794     (let ((pos (point))
 795           (item help-xref-stack-item)
 796           ;; Pretend there is no current item to add to the history.
 797           (help-xref-stack-item nil)
 798           ;; Use the current buffer.
 799           (help-xref-following t))
 800       (apply (car item) (cdr item))
 801       (goto-char pos))))
 802
 803 (defun help-insert-string (string)
 804   "Insert STRING to the help buffer and install xref info for it.
 805 This function can be used to restore the old contents of the help buffer
 806 when going back to the previous topic in the xref stack.  It is needed
 807 in case when it is impossible to recompute the old contents of the
 808 help buffer by other means."
 809   (setq help-xref-stack-item (list #'help-insert-string string))
 810   (with-output-to-temp-buffer (help-buffer)
 811     (insert string)))
 812
 813 (provide 'help-mode)
 814
 815 ;; arch-tag: 850954ae-3725-4cb4-8e91-0bf6d52d6b0b
 816 ;;; help-mode.el ends here