lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality
   2
   3 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   8 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   9 ;; Keywords: dired extensions files
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  30 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  31 ;; been removed or renamed in order to work properly with dired of GNU
  32 ;; Emacs.  All suggestions or comments are most welcomed.
  33
  34 ;;
  35 ;; Please, PLEASE, *PLEASE* see the info pages.
  36 ;;
  37
  38 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  39
  40 ;; INSTALLATION: In your ~/.emacs,
  41 ;;
  42 ;; (add-hook 'dired-load-hook
  43 ;;           (function (lambda ()
  44 ;;                       (load "dired-x")
  45 ;;                       ;; Set global variables here.  For example:
  46 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  47 ;;                       )))
  48 ;; (add-hook 'dired-mode-hook
  49 ;;           (function (lambda ()
  50 ;;                       ;; Set buffer-local variables here.  For example:
  51 ;;                       ;; (dired-omit-mode 1)
  52 ;;                       )))
  53 ;;
  54 ;; At load time dired-x.el will install itself, redefine some functions, and
  55 ;; bind some dired keys.  *Please* see the info pages for more details.
  56
  57 ;; *Please* see the info pages for more details.
  58
  59 ;; User defined variables:
  60 ;;
  61 ;;      dired-bind-vm
  62 ;;      dired-vm-read-only-folders
  63 ;;      dired-bind-jump
  64 ;;      dired-bind-info
  65 ;;      dired-bind-man
  66 ;;      dired-x-hands-off-my-keys
  67 ;;      dired-find-subdir
  68 ;;      dired-enable-local-variables
  69 ;;      dired-local-variables-file
  70 ;;      dired-guess-shell-gnutar
  71 ;;      dired-guess-shell-gzip-quiet
  72 ;;      dired-guess-shell-znew-switches
  73 ;;      dired-guess-shell-alist-user
  74 ;;      dired-clean-up-buffers-too
  75 ;;      dired-omit-mode
  76 ;;      dired-omit-files
  77 ;;      dired-omit-extensions
  78 ;;      dired-omit-size-limit
  79 ;;
  80 ;; To find out more about these variables, load this file, put your cursor at
  81 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  82 ;; the info pages for more details.
  83
  84 ;; When loaded this code redefines the following functions of GNU Emacs
  85 ;;
  86 ;;   Function                         Found in this file of GNU Emacs
  87 ;;   --------                         -------------------------------
  88 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  89 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  90 ;;   dired-initial-position           ../lisp/dired.el
  91 ;;
  92 ;;   dired-add-entry                  ../lisp/dired-aux.el
  93 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  94
  95 \f
  96 ;;; Code:
  97
  98 ;; LOAD.
  99
 100 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 101 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 102 ;; (instead of autoloading to dired as is suggested in the info-pages).
 103
 104 (require 'dired)
 105
 106 ;; We will redefine some functions and also need some macros so we need to
 107 ;; load dired stuff of GNU Emacs.
 108
 109 (require 'dired-aux)
 110
 111 (defvar vm-folder-directory)
 112 (eval-when-compile (require 'man))
 113
 114 ;;; User-defined variables.
 115
 116 (defgroup dired-x nil
 117   "Extended directory editing (dired-x)."
 118   :group 'dired)
 119
 120 (defgroup dired-keys nil
 121   "Dired keys customizations."
 122   :prefix "dired-"
 123   :group 'dired-x)
 124
 125 (defcustom dired-bind-vm nil
 126   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 127
 128 RMAIL files in the old Babyl format (used before before Emacs 23.1)
 129 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
 130 will run `rmail' on these files.  New RMAIL files use the standard
 131 mbox format, and so cannot be distinguished in this way."
 132   :type 'boolean
 133   :group 'dired-keys)
 134
 135 (defcustom dired-bind-jump t
 136   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 137   :type 'boolean
 138   :group 'dired-keys)
 139
 140 (defcustom dired-bind-man t
 141   "Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 142   :type 'boolean
 143   :group 'dired-keys)
 144
 145 (defcustom dired-bind-info t
 146   "Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 147   :type 'boolean
 148   :group 'dired-keys)
 149
 150 (defcustom dired-vm-read-only-folders nil
 151   "If non-nil, \\[dired-vm] will visit all folders read-only.
 152 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 153 files not writable by you are visited read-only.
 154
 155 Read-only folders only work in VM 5, not in VM 4."
 156   :type '(choice (const :tag "off" nil)
 157                  (const :tag "on" t)
 158                  (other :tag "non-writable only" if-file-read-only))
 159   :group 'dired-x)
 160
 161 (define-minor-mode dired-omit-mode
 162   "Toggle Dired-Omit mode.
 163 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 164 otherwise.  Enabling and disabling is buffer-local.
 165 If enabled, \"uninteresting\" files are not listed.
 166 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 167 plus those ending with extensions in `dired-omit-extensions'.
 168
 169 To enable omitting in every Dired buffer, you can put in your ~/.emacs
 170
 171   (add-hook 'dired-mode-hook (lambda () (dired-omit-mode 1)))
 172
 173 See Info node `(dired-x) Omitting Variables' for more information."
 174   :group 'dired-x
 175   (if dired-omit-mode
 176       ;; This will mention how many lines were omitted:
 177       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 178     (revert-buffer)))
 179
 180 ;; For backward compatibility
 181 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 182
 183 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 184   "Filenames matching this regexp will not be displayed.
 185 This only has effect when `dired-omit-mode' is t.  See interactive function
 186 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 187 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 188 files and lock files."
 189   :type 'regexp
 190   :group 'dired-x)
 191
 192 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 193   "If non-nil, Dired always finds a directory in a buffer of its own.
 194 If nil, Dired finds the directory as a subdirectory in some other buffer
 195 if it is present as one.
 196
 197 If there are several dired buffers for a directory, the most recently
 198 used is chosen.
 199
 200 Dired avoids switching to the current buffer, so that if you have
 201 a normal and a wildcard buffer for the same directory, \\[dired] will
 202 toggle between those two."
 203   :type 'boolean
 204   :group 'dired-x)
 205
 206 (defcustom dired-omit-size-limit 30000
 207   "Maximum size for the \"omitting\" feature.
 208 If nil, there is no maximum size."
 209   :type '(choice (const :tag "no maximum" nil) integer)
 210   :group 'dired-x)
 211
 212 (defcustom dired-enable-local-variables t
 213   "Control use of local-variables lists in Dired.
 214 The value can be t, nil or something else.
 215 A value of t means local-variables lists are obeyed;
 216 nil means they are ignored; anything else means query.
 217
 218 This temporarily overrides the value of `enable-local-variables' when
 219 listing a directory.  See also `dired-local-variables-file'."
 220   :type 'boolean
 221   :group 'dired-x)
 222
 223 (defcustom dired-guess-shell-gnutar (when (or (eq system-type 'gnu)
 224                                               (eq system-type 'gnu/linux))
 225                                       "tar")
 226   "If non-nil, name of GNU tar executable.
 227 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 228 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 229 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 230   :type '(choice (const :tag "Not GNU tar" nil)
 231                  (string :tag "Command name"))
 232   :group 'dired-x)
 233
 234 (defcustom dired-guess-shell-gzip-quiet t
 235   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 236   :type 'boolean
 237   :group 'dired-x)
 238
 239 (defcustom dired-guess-shell-znew-switches nil
 240   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 241   :type '(choice (const :tag "None" nil)
 242                  (string :tag "Switches"))
 243   :group 'dired-x)
 244
 245 (defcustom dired-clean-up-buffers-too t
 246   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 247   :type 'boolean
 248   :group 'dired-x)
 249
 250 ;;; KEY BINDINGS.
 251
 252 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 253 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 254 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 255 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 256 (define-key dired-mode-map "*." 'dired-mark-extension)
 257 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 258 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 259 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 260 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 261 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 262 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 263 (define-key dired-mode-map "V" 'dired-do-run-mail)
 264
 265 (if dired-bind-man
 266     (define-key dired-mode-map "N" 'dired-man))
 267
 268 (if dired-bind-info
 269     (define-key dired-mode-map "I" 'dired-info))
 270
 271 ;;; MENU BINDINGS
 272
 273 (let ((menu-bar (lookup-key dired-mode-map [menu-bar])))
 274   (let ((menu (lookup-key menu-bar [operate])))
 275     (define-key-after
 276       menu
 277       [find-files]
 278       '(menu-item
 279         "Find files"
 280         dired-do-find-marked-files
 281         :help "Find current or marked files")
 282       'delete)
 283     (define-key-after
 284       menu
 285       [relsymlink]
 286       '(menu-item
 287         "Relative symlink to..."
 288         dired-do-relsymlink
 289         :visible (fboundp 'make-symbolic-link)
 290         :help "Make relative symbolic links for current or marked files")
 291       'symlink))
 292   (let ((menu (lookup-key menu-bar [mark])))
 293     (define-key-after
 294       menu
 295       [flag-extension]
 296       '(menu-item
 297         "Flag extension..."
 298         dired-flag-extension
 299         :help "Flag files with a certain extension for deletion")
 300       'garbage-files)
 301     (define-key-after
 302       menu
 303       [mark-extension]
 304       '(menu-item
 305         "Mark extension..."
 306         dired-mark-extension
 307         :help "Mark files with a certain extension")
 308       'symlinks)
 309     (define-key-after
 310       menu
 311       [mark-omitted]
 312       '(menu-item
 313         "Mark omitted"
 314         dired-mark-omitted
 315         :help "Mark files matching `dired-omit-files' and `dired-omit-extensions'")
 316       'mark-extension))
 317   (let ((menu (lookup-key menu-bar [regexp])))
 318     (define-key-after
 319       menu
 320       [relsymlink-regexp]
 321       '(menu-item
 322         "Relative symlink..."
 323         dired-do-relsymlink-regexp
 324         :visible (fboundp 'make-symbolic-link)
 325         :help "Make relative symbolic links for files matching regexp")
 326       'symlink))
 327   (let ((menu (lookup-key menu-bar [immediate])))
 328     (define-key-after
 329       menu
 330       [omit-mode]
 331       '(menu-item
 332         "Omit mode" dired-omit-mode
 333         :button (:toggle . dired-omit-mode)
 334         :help "Enable or disable omitting \"uninteresting\" files")
 335       'dashes)))
 336
 337 ;;; GLOBAL BINDING.
 338 (if dired-bind-jump
 339     (progn
 340       (define-key global-map "\C-x\C-j" 'dired-jump)
 341       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 342
 343 \f
 344 ;; Install into appropriate hooks.
 345
 346 (add-hook 'dired-mode-hook 'dired-extra-startup)
 347 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 348
 349 (defun dired-extra-startup ()
 350   "Automatically put on `dired-mode-hook' to get extra Dired features:
 351 \\<dired-mode-map>
 352   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 353   \\[dired-info]\t-- run info on file
 354   \\[dired-man]\t-- run man on file
 355   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 356   \\[dired-omit-mode]\t-- toggle omitting of files
 357   \\[dired-mark-sexp]\t-- mark by Lisp expression
 358   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 359   \t   you can feed it to other commands using \\[yank]
 360
 361 For more features, see variables
 362
 363   `dired-bind-vm'
 364   `dired-bind-jump'
 365   `dired-bind-info'
 366   `dired-bind-man'
 367   `dired-vm-read-only-folders'
 368   `dired-omit-mode'
 369   `dired-omit-files'
 370   `dired-omit-extensions'
 371   `dired-omit-size-limit'
 372   `dired-find-subdir'
 373   `dired-enable-local-variables'
 374   `dired-local-variables-file'
 375   `dired-guess-shell-gnutar'
 376   `dired-guess-shell-gzip-quiet'
 377   `dired-guess-shell-znew-switches'
 378   `dired-guess-shell-alist-user'
 379   `dired-clean-up-buffers-too'
 380
 381 See also functions
 382
 383   `dired-flag-extension'
 384   `dired-virtual'
 385   `dired-jump'
 386   `dired-man'
 387   `dired-vm'
 388   `dired-rmail'
 389   `dired-info'
 390   `dired-do-find-marked-files'"
 391   (interactive)
 392
 393   ;; These must be done in each new dired buffer.
 394   (dired-hack-local-variables)
 395   (dired-omit-startup))
 396
 397 \f
 398 ;;; BUFFER CLEANING.
 399
 400 ;; REDEFINE.
 401 (defun dired-clean-up-after-deletion (fn)
 402   "Clean up after a deleted file or directory FN.
 403 Remove expanded subdir of deleted dir, if any."
 404   (save-excursion (and (cdr dired-subdir-alist)
 405                        (dired-goto-subdir fn)
 406                        (dired-kill-subdir)))
 407
 408   ;; Offer to kill buffer of deleted file FN.
 409   (if dired-clean-up-buffers-too
 410       (progn
 411         (let ((buf (get-file-buffer fn)))
 412           (and buf
 413                (funcall (function y-or-n-p)
 414                         (format "Kill buffer of %s, too? "
 415                                 (file-name-nondirectory fn)))
 416                (save-excursion ; you never know where kill-buffer leaves you
 417                  (kill-buffer buf))))
 418         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 419               (buf nil))
 420           (and buf-list
 421                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 422                                  (dired-plural-s (length buf-list))
 423                                  (file-name-nondirectory fn)))
 424                (while buf-list
 425                  (save-excursion (kill-buffer (car buf-list)))
 426                  (setq buf-list (cdr buf-list)))))))
 427   ;; Anything else?
 428   )
 429
 430 \f
 431 ;;; EXTENSION MARKING FUNCTIONS.
 432
 433 ;; Mark files with some extension.
 434 (defun dired-mark-extension (extension &optional marker-char)
 435   "Mark all files with a certain EXTENSION for use in later commands.
 436 A `.' is *not* automatically prepended to the string entered."
 437   ;; EXTENSION may also be a list of extensions instead of a single one.
 438   ;; Optional MARKER-CHAR is marker to use.
 439   (interactive "sMarking extension: \nP")
 440   (or (listp extension)
 441       (setq extension (list extension)))
 442   (dired-mark-files-regexp
 443    (concat ".";; don't match names with nothing but an extension
 444            "\\("
 445            (mapconcat 'regexp-quote extension "\\|")
 446            "\\)$")
 447    marker-char))
 448
 449 (defun dired-flag-extension (extension)
 450   "In dired, flag all files with a certain EXTENSION for deletion.
 451 A `.' is *not* automatically prepended to the string entered."
 452   (interactive "sFlagging extension: ")
 453   (dired-mark-extension extension dired-del-marker))
 454
 455 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 456
 457 (defvar dired-patch-unclean-extensions
 458   '(".rej" ".orig")
 459   "List of extensions of dispensable files created by the `patch' program.")
 460
 461 (defvar dired-tex-unclean-extensions
 462   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 463   "List of extensions of dispensable files created by TeX.")
 464
 465 (defvar dired-latex-unclean-extensions
 466   '(".idx" ".lof" ".lot" ".glo")
 467   "List of extensions of dispensable files created by LaTeX.")
 468
 469 (defvar dired-bibtex-unclean-extensions
 470   '(".blg" ".bbl")
 471   "List of extensions of dispensable files created by BibTeX.")
 472
 473 (defvar dired-texinfo-unclean-extensions
 474   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 475     ".tp" ".tps" ".vr" ".vrs")
 476   "List of extensions of dispensable files created by texinfo.")
 477
 478 (defun dired-clean-patch ()
 479   "Flag dispensable files created by patch for deletion.
 480 See variable `dired-patch-unclean-extensions'."
 481   (interactive)
 482   (dired-flag-extension dired-patch-unclean-extensions))
 483
 484 (defun dired-clean-tex ()
 485   "Flag dispensable files created by [La]TeX etc. for deletion.
 486 See variables `dired-tex-unclean-extensions',
 487 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 488 `dired-texinfo-unclean-extensions'."
 489   (interactive)
 490   (dired-flag-extension (append dired-texinfo-unclean-extensions
 491                                 dired-latex-unclean-extensions
 492                                 dired-bibtex-unclean-extensions
 493                                 dired-tex-unclean-extensions)))
 494
 495 (defun dired-very-clean-tex ()
 496   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 497 See variables `dired-texinfo-unclean-extensions',
 498 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 499 `dired-texinfo-unclean-extensions'."
 500   (interactive)
 501   (dired-flag-extension (append dired-texinfo-unclean-extensions
 502                                 dired-latex-unclean-extensions
 503                                 dired-bibtex-unclean-extensions
 504                                 dired-tex-unclean-extensions
 505                                 (list ".dvi"))))
 506 \f
 507 ;;; JUMP.
 508
 509 ;;;###autoload
 510 (defun dired-jump (&optional other-window file-name)
 511   "Jump to dired buffer corresponding to current buffer.
 512 If in a file, dired the current directory and move to file's line.
 513 If in Dired already, pop up a level and goto old directory's line.
 514 In case the proper dired file line cannot be found, refresh the dired
 515 buffer and try again.
 516 When OTHER-WINDOW is non-nil, jump to dired buffer in other window.
 517 Interactively with prefix argument, read FILE-NAME and
 518 move to its line in dired."
 519   (interactive
 520    (list nil (and current-prefix-arg
 521                   (read-file-name "Jump to dired file: "))))
 522   (let* ((file (or file-name buffer-file-name))
 523          (dir (if file (file-name-directory file) default-directory)))
 524     (if (and (eq major-mode 'dired-mode) (null file-name))
 525         (progn
 526           (setq dir (dired-current-directory))
 527           (dired-up-directory other-window)
 528           (or (dired-goto-file dir)
 529               ;; refresh and try again
 530               (progn
 531                 (dired-insert-subdir (file-name-directory dir))
 532                 (dired-goto-file dir))))
 533       (if other-window
 534           (dired-other-window dir)
 535         (dired dir))
 536       (if file
 537           (or (dired-goto-file file)
 538               ;; refresh and try again
 539               (progn
 540                 (dired-insert-subdir (file-name-directory file))
 541                 (dired-goto-file file))
 542               ;; Toggle omitting, if it is on, and try again.
 543               (if dired-omit-mode
 544                   (progn
 545                     (dired-omit-mode)
 546                     (dired-goto-file file))))))))
 547
 548 (defun dired-jump-other-window (&optional file-name)
 549   "Like \\[dired-jump] (`dired-jump') but in other window."
 550   (interactive
 551    (list (and current-prefix-arg
 552               (read-file-name "Jump to dired file: "))))
 553   (dired-jump t file-name))
 554 \f
 555 ;;; OMITTING.
 556
 557 ;; Enhanced omitting of lines from directory listings.
 558 ;; Marked files are never omitted.
 559
 560 ;; should probably get rid of this and always use 'no-dir.
 561 ;; sk 28-Aug-1991 09:37
 562 (defvar dired-omit-localp 'no-dir
 563   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 564 If it is `no-dir', omitting is much faster, but you can only match
 565 against the non-directory part of the file name.  Set it to nil if you
 566 need to match the entire file name.")
 567
 568 ;; \017=^O for Omit - other packages can chose other control characters.
 569 (defvar dired-omit-marker-char ?\017
 570   "Temporary marker used by Dired-Omit.
 571 Should never be used as marker by the user or other packages.")
 572
 573 (defun dired-omit-startup ()
 574   (or (assq 'dired-omit-mode minor-mode-alist)
 575       (setq minor-mode-alist
 576             (append '((dired-omit-mode
 577                        (:eval (if (eq major-mode 'dired-mode)
 578                                   " Omit" ""))))
 579                     minor-mode-alist))))
 580
 581 (defun dired-mark-omitted ()
 582   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 583   (interactive)
 584   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 585   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 586
 587 (defvar dired-omit-extensions
 588   (append completion-ignored-extensions
 589           dired-latex-unclean-extensions
 590           dired-bibtex-unclean-extensions
 591           dired-texinfo-unclean-extensions)
 592   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 593 Defaults to elements of `completion-ignored-extensions',
 594 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 595 `dired-texinfo-unclean-extensions'.
 596
 597 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 598 variables `dired-omit-mode' and `dired-omit-files'.")
 599
 600 (defun dired-omit-expunge (&optional regexp)
 601   "Erases all unmarked files matching REGEXP.
 602 Does nothing if global variable `dired-omit-mode' is nil, or if called
 603   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 604 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 605   filenames ending in `dired-omit-extensions'.
 606 If REGEXP is the empty string, this function is a no-op.
 607
 608 This functions works by temporarily binding `dired-marker-char' to
 609 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 610   (interactive "sOmit files (regexp): ")
 611   (if (and dired-omit-mode
 612            (or (called-interactively-p 'interactive)
 613                (not dired-omit-size-limit)
 614                (< (buffer-size) dired-omit-size-limit)
 615                (progn
 616                  (message "Not omitting: directory larger than %d characters."
 617                           dired-omit-size-limit)
 618                  (setq dired-omit-mode nil)
 619                  nil)))
 620       (let ((omit-re (or regexp (dired-omit-regexp)))
 621             (old-modified-p (buffer-modified-p))
 622             count)
 623         (or (string= omit-re "")
 624             (let ((dired-marker-char dired-omit-marker-char))
 625               (message "Omitting...")
 626               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 627                   (progn
 628                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 629                     (force-mode-line-update))
 630                 (message "(Nothing to omit)"))))
 631         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 632         ;; in mode-line of omitted buffers.
 633         (set-buffer-modified-p (and old-modified-p
 634                                     (save-excursion
 635                                       (goto-char (point-min))
 636                                       (re-search-forward dired-re-mark nil t))))
 637         count)))
 638
 639 (defun dired-omit-regexp ()
 640   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 641           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 642           (if dired-omit-extensions
 643               (concat ".";; a non-extension part should exist
 644                       "\\("
 645                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 646                       "\\)$")
 647             "")))
 648
 649 ;; Returns t if any work was done, nil otherwise.
 650 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 651   "Mark unmarked files matching REGEXP, displaying MSG.
 652 REGEXP is matched against the entire file name.
 653 Does not re-mark files which already have a mark.
 654 With prefix argument, unflag all those files.
 655 Optional fourth argument LOCALP is as in `dired-get-filename'."
 656   (interactive "P")
 657   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 658     (dired-mark-if
 659      (and
 660       ;; not already marked
 661       (looking-at " ")
 662       ;; uninteresting
 663       (let ((fn (dired-get-filename localp t)))
 664         (and fn (string-match regexp fn))))
 665      msg)))
 666
 667 ;; Compiler does not get fset.
 668 (declare-function dired-omit-old-add-entry "dired-x")
 669
 670 ;; REDEFINE.
 671 ;; Redefine dired-aux.el's version of `dired-add-entry'
 672 ;; Save old defun if not already done:
 673 (or (fboundp 'dired-omit-old-add-entry)
 674     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 675
 676 ;; REDEFINE.
 677 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 678   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 679   ;; files that are going to be omitted anyway.
 680   (if dired-omit-mode
 681       ;; perhaps return t without calling ls
 682       (let ((omit-re (dired-omit-regexp)))
 683         (if (or (string= omit-re "")
 684                 (not
 685                  (string-match omit-re
 686                                (cond
 687                                 ((eq 'no-dir dired-omit-localp)
 688                                  filename)
 689                                 ((eq t dired-omit-localp)
 690                                  (dired-make-relative filename))
 691                                 (t
 692                                  (dired-make-absolute
 693                                   filename
 694                                   (file-name-directory filename)))))))
 695             ;; if it didn't match, go ahead and add the entry
 696             (dired-omit-old-add-entry filename marker-char relative)
 697           ;; dired-add-entry returns t for success, perhaps we should
 698           ;; return file-exists-p
 699           t))
 700     ;; omitting is not turned on at all
 701     (dired-omit-old-add-entry filename marker-char relative)))
 702
 703 ;; Redefine it.
 704 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 705
 706 \f
 707 ;;; VIRTUAL DIRED MODE.
 708
 709 ;; For browsing `ls -lR' listings in a dired-like fashion.
 710
 711 (defalias 'virtual-dired 'dired-virtual)
 712 (defun dired-virtual (dirname &optional switches)
 713   "Put this buffer into Virtual Dired mode.
 714
 715 In Virtual Dired mode, all commands that do not actually consult the
 716 filesystem will work.
 717
 718 This is useful if you want to peruse and move around in an ls -lR
 719 output file, for example one you got from an ftp server.  With
 720 ange-ftp, you can even dired a directory containing an ls-lR file,
 721 visit that file and turn on virtual dired mode.  But don't try to save
 722 this file, as dired-virtual indents the listing and thus changes the
 723 buffer.
 724
 725 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 726 resume it in a later session.
 727
 728 Type \\<dired-mode-map>\\[revert-buffer] \
 729 in the Virtual Dired buffer and answer `y' to convert
 730 the virtual to a real dired buffer again.  You don't have to do this, though:
 731 you can relist single subdirs using \\[dired-do-redisplay]."
 732
 733   ;; DIRNAME is the top level directory of the buffer.  It will become
 734   ;; its `default-directory'.  If nil, the old value of
 735   ;; default-directory is used.
 736
 737   ;; Optional SWITCHES are the ls switches to use.
 738
 739   ;; Shell wildcards will be used if there already is a `wildcard'
 740   ;; line in the buffer (thus it is a saved Dired buffer), but there
 741   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 742   ;; hand if you want them.
 743
 744   (interactive
 745    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 746   (goto-char (point-min))
 747   (or (looking-at "  ")
 748       ;; if not already indented, do it now:
 749       (indent-region (point-min) (point-max) 2))
 750   (or dirname (setq dirname default-directory))
 751   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 752   (setq default-directory dirname)      ; contains no wildcards
 753   (let ((wildcard (save-excursion
 754                     (goto-char (point-min))
 755                     (forward-line 1)
 756                     (and (looking-at "^  wildcard ")
 757                          (buffer-substring (match-end 0)
 758                                            (progn (end-of-line) (point)))))))
 759   (if wildcard
 760         (setq dirname (expand-file-name wildcard default-directory))))
 761   ;; If raw ls listing (not a saved old dired buffer), give it a
 762   ;; decent subdir headerline:
 763   (goto-char (point-min))
 764   (or (looking-at dired-subdir-regexp)
 765       (insert "  "
 766               (directory-file-name (file-name-directory default-directory))
 767               ":\n"))
 768   (dired-mode dirname (or switches dired-listing-switches))
 769   (setq mode-name "Virtual Dired"
 770         revert-buffer-function 'dired-virtual-revert)
 771   (set (make-local-variable 'dired-subdir-alist) nil)
 772   (dired-build-subdir-alist)
 773   (goto-char (point-min))
 774   (dired-initial-position dirname))
 775
 776 (defun dired-virtual-guess-dir ()
 777   "Guess and return appropriate working directory of this buffer.
 778 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 779 based upon buffer contents.  If nothing could be guessed, returns
 780 nil."
 781
 782   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 783         (subexpr 2))
 784     (goto-char (point-min))
 785     (cond ((looking-at regexp)
 786            ;; If a saved dired buffer, look to which dir and
 787            ;; perhaps wildcard it belongs:
 788            (let ((dir (buffer-substring (match-beginning subexpr)
 789                                         (match-end subexpr))))
 790              (file-name-as-directory dir)))
 791           ;; Else no match for headerline found.  It's a raw ls listing.
 792           ;; In raw ls listings the directory does not have a headerline
 793           ;; try parent of first subdir, if any
 794           ((re-search-forward regexp nil t)
 795            (file-name-directory
 796             (directory-file-name
 797              (file-name-as-directory
 798               (buffer-substring (match-beginning subexpr)
 799                                 (match-end subexpr))))))
 800           (t                            ; if all else fails
 801            nil))))
 802
 803
 804 (defun dired-virtual-revert (&optional arg noconfirm)
 805   (if (not
 806        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 807       (error "Cannot revert a Virtual Dired buffer")
 808     (setq mode-name "Dired"
 809           revert-buffer-function 'dired-revert)
 810     (revert-buffer)))
 811
 812 ;; A zero-arg version of dired-virtual.
 813 (defun dired-virtual-mode ()
 814   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 815 Useful on `magic-mode-alist' with the regexp
 816
 817   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 818
 819 to put saved dired buffers automatically into Virtual Dired mode.
 820
 821 Also useful for `auto-mode-alist' like this:
 822
 823   (add-to-list 'auto-mode-alist
 824                '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))"
 825   (interactive)
 826   (dired-virtual (dired-virtual-guess-dir)))
 827
 828 \f
 829 ;;; SMART SHELL.
 830
 831 ;; An Emacs buffer can have but one working directory, stored in the
 832 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 833 ;; several subdirectories inserted, but still has but one working directory:
 834 ;; that of the top level Dired directory in that buffer.  For some commands
 835 ;; it is appropriate that they use the current Dired directory instead of
 836 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 837 ;; mechanism is provided for special handling of the working directory in
 838 ;; special major modes.
 839
 840 ;; It's easier to add to this alist than redefine function
 841 ;; default-directory while keeping the old information.
 842 (defconst default-directory-alist
 843   '((dired-mode . (if (fboundp 'dired-current-directory)
 844                       (dired-current-directory)
 845                     default-directory)))
 846   "Alist of major modes and their opinion on `default-directory'.
 847 This is given as a Lisp expression to evaluate.  A resulting value of
 848 nil is ignored in favor of `default-directory'.")
 849
 850 (defun dired-default-directory ()
 851   "Usage like variable `default-directory'.
 852 Knows about the special cases in variable `default-directory-alist'."
 853   (or (eval (cdr (assq major-mode default-directory-alist)))
 854       default-directory))
 855
 856 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 857   "Like function `shell-command', but in the current Virtual Dired directory."
 858   (interactive
 859    (list
 860     (read-shell-command "Shell command: " nil nil
 861                         (cond
 862                          (buffer-file-name (file-relative-name buffer-file-name))
 863                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 864     current-prefix-arg
 865     shell-command-default-error-buffer))
 866   (let ((default-directory (dired-default-directory)))
 867     (shell-command command output-buffer error-buffer)))
 868
 869 \f
 870 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 871
 872 ;; Brief Description:
 873 ;;;
 874 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 875 ;;;
 876 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 877 ;;;
 878 ;; * `dired-hack-local-variables' checks the value of
 879 ;;;   `dired-local-variables-file'
 880 ;;;
 881 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 882 ;;;   filename found in the directory of the Dired Buffer being created.
 883 ;;;
 884 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 885 ;;;   include it in the Dired Buffer at the bottom.
 886 ;;;
 887 ;; * Set `enable-local-variables' temporarily to the user variable
 888 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 889 ;;;   Dired Buffer.
 890
 891 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 892   "Filename, as string, containing local dired buffer variables to be hacked.
 893 If this file found in current directory, then it will be inserted into dired
 894 buffer and `hack-local-variables' will be run.  See Info node
 895 `(emacs)File Variables' for more information on local variables.
 896 See also `dired-enable-local-variables'.")
 897
 898 (defun dired-hack-local-variables ()
 899   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 900   (if (and dired-local-variables-file
 901            (stringp dired-local-variables-file)
 902            (file-exists-p dired-local-variables-file))
 903       (let ((opoint (point-max))
 904             buffer-read-only
 905             ;; In case user has `enable-local-variables' set to nil we
 906             ;; override it locally with dired's variable.
 907             (enable-local-variables dired-enable-local-variables))
 908         ;; Insert 'em.
 909         (save-excursion
 910           (goto-char opoint)
 911           (insert "\^L\n")
 912           (insert-file-contents dired-local-variables-file))
 913         ;; Hack 'em.
 914         (let ((buffer-file-name dired-local-variables-file))
 915           (hack-local-variables))
 916         ;; Make sure that the modeline shows the proper information.
 917         (dired-sort-set-modeline)
 918         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 919         (delete-region opoint (point-max)))))
 920
 921 (defun dired-omit-here-always ()
 922   "Create `dired-local-variables-file' for omitting and reverts directory.
 923 Sets `dired-omit-mode' to t in a local variables file that is readable by
 924 dired."
 925   (interactive)
 926   (if (file-exists-p dired-local-variables-file)
 927       (message "File `./%s' already exists." dired-local-variables-file)
 928
 929     ;; Create `dired-local-variables-file'.
 930     (with-current-buffer (get-buffer-create " *dot-dired*")
 931       (erase-buffer)
 932       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 933       (write-file dired-local-variables-file)
 934       (kill-buffer (current-buffer)))
 935
 936     ;; Run extra-hooks and revert directory.
 937     (dired-extra-startup)
 938     (dired-revert)))
 939
 940 \f
 941 ;;; GUESS SHELL COMMAND.
 942
 943 ;; Brief Description:
 944 ;;;
 945 ;; `dired-do-shell-command' is bound to `!' by dired.el.
 946 ;;;
 947 ;; * Redefine `dired-read-shell-command' so it calls
 948 ;;;   `dired-guess-shell-command'.
 949 ;;;
 950 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 951 ;;;    marked files.
 952 ;;;
 953 ;; * Parse `dired-guess-shell-alist-user' and
 954 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 955 ;;;   that matches the first file in the file list.
 956 ;;;
 957 ;; * If the REGEXP matches all the entries of the file list then evaluate
 958 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 959 ;;;   string.  COMMAND may be a list of commands.
 960 ;;;
 961 ;; * Return this command to `dired-guess-shell-command' which prompts user
 962 ;;;   with it.  The list of commands is put into the list of default values.
 963 ;;;   If a command is used successfully then it is stored permanently in
 964 ;;;   `dired-shell-command-history'.
 965
 966 ;; Guess what shell command to apply to a file.
 967 (defvar dired-shell-command-history nil
 968   "History list for commands that read dired-shell commands.")
 969
 970 ;; Default list of shell commands.
 971
 972 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 973 ;; install GNU zip's version of zcat.
 974
 975 (defvar dired-guess-shell-alist-default
 976   (list
 977    (list "\\.tar$"
 978          '(if dired-guess-shell-gnutar
 979               (concat dired-guess-shell-gnutar " xvf")
 980             "tar xvf")
 981          ;; Extract files into a separate subdirectory
 982          '(if dired-guess-shell-gnutar
 983               (concat "mkdir " (file-name-sans-extension file)
 984                       "; " dired-guess-shell-gnutar " -C "
 985                       (file-name-sans-extension file) " -xvf")
 986             (concat "mkdir " (file-name-sans-extension file)
 987                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 988          ;; List archive contents.
 989          '(if dired-guess-shell-gnutar
 990               (concat dired-guess-shell-gnutar " tvf")
 991             "tar tvf"))
 992
 993    ;; REGEXPS for compressed archives must come before the .Z rule to
 994    ;; be recognized:
 995    (list "\\.tar\\.Z$"
 996          ;; Untar it.
 997          '(if dired-guess-shell-gnutar
 998               (concat dired-guess-shell-gnutar " zxvf")
 999             (concat "zcat * | tar xvf -"))
1000          ;; Optional conversion to gzip format.
1001          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1002                   " " dired-guess-shell-znew-switches))
1003
1004    ;; gzip'ed archives
1005    (list "\\.t\\(ar\\.\\)?gz$"
1006          '(if dired-guess-shell-gnutar
1007               (concat dired-guess-shell-gnutar " zxvf")
1008             (concat "gunzip -qc * | tar xvf -"))
1009          ;; Extract files into a separate subdirectory
1010          '(if dired-guess-shell-gnutar
1011               (concat "mkdir " (file-name-sans-extension file)
1012                       "; " dired-guess-shell-gnutar " -C "
1013                       (file-name-sans-extension file) " -zxvf")
1014             (concat "mkdir " (file-name-sans-extension file)
1015                     "; gunzip -qc * | tar -C "
1016                     (file-name-sans-extension file) " -xvf -"))
1017          ;; Optional decompression.
1018          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
1019          ;; List archive contents.
1020          '(if dired-guess-shell-gnutar
1021               (concat dired-guess-shell-gnutar " ztvf")
1022             (concat "gunzip -qc * | tar tvf -")))
1023
1024    ;; bzip2'ed archives
1025    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
1026          "bunzip2 -c * | tar xvf -"
1027          ;; Extract files into a separate subdirectory
1028          '(concat "mkdir " (file-name-sans-extension file)
1029                   "; bunzip2 -c * | tar -C "
1030                   (file-name-sans-extension file) " -xvf -")
1031          ;; Optional decompression.
1032          "bunzip2")
1033
1034    ;; xz'ed archives
1035    (list "\\.t\\(ar\\.\\)?xz$"
1036          "unxz -c * | tar xvf -"
1037          ;; Extract files into a separate subdirectory
1038          '(concat "mkdir " (file-name-sans-extension file)
1039                   "; unxz -c * | tar -C "
1040                   (file-name-sans-extension file) " -xvf -")
1041          ;; Optional decompression.
1042          "unxz")
1043
1044    '("\\.shar\\.Z$" "zcat * | unshar")
1045    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
1046
1047    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
1048    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
1049          ;; Optional decompression.
1050          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1051    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
1052          ;; Optional conversion to gzip format.
1053          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1054                   " " dired-guess-shell-znew-switches))
1055
1056    '("\\.patch$" "cat * | patch")
1057    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
1058          ;; Optional decompression.
1059          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1060    (list "\\.patch\\.Z$" "zcat * | patch"
1061          ;; Optional conversion to gzip format.
1062          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1063                   " " dired-guess-shell-znew-switches))
1064
1065    ;; The following four extensions are useful with dired-man ("N" key)
1066    (list "\\.\\(?:[0-9]\\|man\\)$" '(progn (require 'man)
1067                                            (if (Man-support-local-filenames)
1068                                                "man -l"
1069                                              "cat * | tbl | nroff -man -h")))
1070    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z$" '(progn (require 'man)
1071                                                  (if (Man-support-local-filenames)
1072                                                      "man -l"
1073                                                    "gunzip -qc * | tbl | nroff -man -h"))
1074          ;; Optional decompression.
1075          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1076    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
1077                                  (if (Man-support-local-filenames)
1078                                      "man -l"
1079                                    "zcat * | tbl | nroff -man -h"))
1080          ;; Optional conversion to gzip format.
1081          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1082                   " " dired-guess-shell-znew-switches))
1083    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
1084
1085    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
1086    '("\\.au$" "play")                   ; play Sun audiofiles
1087    '("\\.mpe?g$\\|\\.avi$" "xine -p")
1088    '("\\.ogg$" "ogg123")
1089    '("\\.mp3$" "mpg123")
1090    '("\\.wav$" "play")
1091    '("\\.uu$" "uudecode")               ; for uudecoded files
1092    '("\\.hqx$" "mcvert")
1093    '("\\.sh$" "sh")                     ; execute shell scripts
1094    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
1095    '("\\.gp$" "gnuplot")
1096    '("\\.p[bgpn]m$" "xloadimage")
1097    '("\\.gif$" "xloadimage")            ; view gif pictures
1098    '("\\.tif$" "xloadimage")
1099    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
1100    '("\\.jpe?g$" "xloadimage")
1101    '("\\.fig$" "xfig")                  ; edit fig pictures
1102    '("\\.out$" "xgraph")                ; for plotting purposes.
1103    '("\\.tex$" "latex" "tex")
1104    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
1105    '("\\.pdf$" "xpdf")
1106    '("\\.doc$" "antiword" "strings")
1107    '("\\.rpm$" "rpm -qilp" "rpm -ivh")
1108    '("\\.dia$" "dia")
1109    '("\\.mgp$" "mgp")
1110
1111    ;; Some other popular archivers.
1112    (list "\\.zip$" "unzip" "unzip -l"
1113          ;; Extract files into a separate subdirectory
1114          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1115                   " -d " (file-name-sans-extension file)))
1116    '("\\.zoo$" "zoo x//")
1117    '("\\.lzh$" "lharc x")
1118    '("\\.arc$" "arc x")
1119    '("\\.shar$" "unshar")
1120
1121    ;; Compression.
1122    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1123    (list "\\.dz$" "dictunzip")
1124    (list "\\.bz2$" "bunzip2")
1125    (list "\\.xz$" "unxz")
1126    (list "\\.Z$" "uncompress"
1127          ;; Optional conversion to gzip format.
1128          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1129                   " " dired-guess-shell-znew-switches))
1130
1131    '("\\.sign?$" "gpg --verify"))
1132
1133   "Default alist used for shell command guessing.
1134 See `dired-guess-shell-alist-user'.")
1135
1136 (defcustom dired-guess-shell-alist-user nil
1137   "User-defined alist of rules for suggested commands.
1138 These rules take precedence over the predefined rules in the variable
1139 `dired-guess-shell-alist-default' (to which they are prepended).
1140
1141 Each element of this list looks like
1142
1143     \(REGEXP COMMAND...\)
1144
1145 where each COMMAND can either be a string or a Lisp expression that evaluates
1146 to a string.  If several COMMANDs are given, the first one will be the default
1147 and the rest will be added temporarily to the history and can be retrieved
1148 with \\[previous-history-element] (M-p) .
1149
1150 The variable `dired-guess-shell-case-fold-search' controls whether
1151 REGEXP is matched case-sensitively.
1152
1153 You can set this variable in your ~/.emacs.  For example, to add rules for
1154 `.foo' and `.bar' files, write
1155
1156  \(setq dired-guess-shell-alist-user
1157        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1158               ;; possibly more rules ...
1159               (list \"\\\\.bar\\\\'\";; rule with condition test
1160                     '(if condition
1161                           \"BAR-COMMAND-1\"
1162                         \"BAR-COMMAND-2\")))\)"
1163   :group 'dired-x
1164   :type '(alist :key-type regexp :value-type (repeat sexp)))
1165
1166 (defcustom dired-guess-shell-case-fold-search t
1167   "If non-nil, `dired-guess-shell-alist-default' and
1168 `dired-guess-shell-alist-user' are matched case-insensitively."
1169   :group 'dired-x
1170   :type 'boolean)
1171
1172 (defun dired-guess-default (files)
1173   "Guess a shell commands for FILES.  Return command or list of commands.
1174 See `dired-guess-shell-alist-user'."
1175
1176   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1177          ;; Prepend the user's alist to the default alist.
1178          (alist (append dired-guess-shell-alist-user
1179                         dired-guess-shell-alist-default))
1180          (file (car files))
1181          (flist (cdr files))
1182          elt regexp cmds)
1183
1184     ;; Find the first match in the alist for first file in FILES.
1185     (while alist
1186       (setq elt (car alist)
1187             regexp (car elt)
1188             alist (cdr alist))
1189       (if (string-match regexp file)
1190           (setq cmds (cdr elt)
1191                 alist nil)))
1192
1193     ;; If more than one file, see if all of FILES match regular expression.
1194     (while (and flist
1195                 (string-match regexp (car flist)))
1196       (setq flist (cdr flist)))
1197
1198     ;; If flist is still non-nil, then do not guess since this means that not
1199     ;; all the files in FILES were matched by the regexp.
1200     (setq cmds (and (not flist) cmds))
1201
1202     ;; Return commands or nil if flist is still non-nil.
1203     ;; Evaluate the commands in order that any logical testing will be done.
1204     (cond ((not (cdr cmds))
1205            (eval (car cmds))) ; single command
1206           (t
1207            (mapcar (function eval) cmds)))))
1208
1209 (defun dired-guess-shell-command (prompt files)
1210   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1211   (let ((default (dired-guess-default files))
1212         default-list val)
1213     (if (null default)
1214         ;; Nothing to guess
1215         (read-shell-command prompt nil 'dired-shell-command-history)
1216       (if (listp default)
1217           ;; More than one guess
1218           (setq default-list default
1219                 default (car default)
1220                 prompt (concat
1221                         prompt
1222                         (format "{%d guesses} " (length default-list))))
1223         ;; Just one guess
1224         (setq default-list (list default)))
1225       ;; Put the first guess in the prompt but not in the initial value.
1226       (setq prompt (concat prompt (format "[%s] " default)))
1227       ;; All guesses can be retrieved with M-n
1228       (setq val (read-shell-command prompt nil
1229                                     'dired-shell-command-history
1230                                     default-list))
1231       ;; If we got a return, then return default.
1232       (if (equal val "") default val))))
1233
1234 ;; REDEFINE.
1235 ;; Redefine dired-aux.el's version:
1236 (defun dired-read-shell-command (prompt arg files)
1237   "Read a dired shell command prompting with PROMPT (using `read-shell-command').
1238 ARG is the prefix arg and may be used to indicate in the prompt which
1239 FILES are affected.
1240 This is an extra function so that you can redefine it."
1241   (minibuffer-with-setup-hook
1242       (lambda ()
1243         (set (make-local-variable 'minibuffer-default-add-function)
1244              'minibuffer-default-add-dired-shell-commands))
1245     (dired-mark-pop-up
1246      nil 'shell files
1247      'dired-guess-shell-command
1248      (format prompt (dired-mark-prompt arg files)) ; PROMPT
1249      files)))                                      ; FILES
1250
1251 \f
1252 ;;; RELATIVE SYMBOLIC LINKS.
1253
1254 (declare-function make-symbolic-link "fileio.c")
1255
1256 (defvar dired-keep-marker-relsymlink ?S
1257   "See variable `dired-keep-marker-move'.")
1258
1259 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1260   "Make a symbolic link (pointing to FILE1) in FILE2.
1261 The link is relative (if possible), for example
1262
1263     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1264
1265 results in
1266
1267     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1268   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1269   (let (name1 name2 len1 len2 (index 0) sub)
1270     (setq file1 (expand-file-name file1)
1271           file2 (expand-file-name file2)
1272           len1 (length file1)
1273           len2 (length file2))
1274     ;; Find common initial file name components:
1275     (let (next)
1276       (while (and (setq next (string-match "/" file1 index))
1277                   (setq next (1+ next))
1278                   (< next (min len1 len2))
1279                   ;; For the comparison, both substrings must end in
1280                   ;; `/', so NEXT is *one plus* the result of the
1281                   ;; string-match.
1282                   ;; E.g., consider the case of linking "/tmp/a/abc"
1283                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1284                   ;; of "/tmp/" as common initial component
1285                   (string-equal (substring file1 0 next)
1286                                 (substring file2 0 next)))
1287         (setq index next))
1288       (setq name2 file2
1289             sub (substring file1 0 index)
1290             name1 (substring file1 index)))
1291     (if (string-equal sub "/")
1292         ;; No common initial file name found
1293         (setq name1 file1)
1294       ;; Else they have a common parent directory
1295       (let ((tem (substring file2 index))
1296             (start 0)
1297             (count 0))
1298         ;; Count number of slashes we must compensate for ...
1299         (while (setq start (string-match "/" tem start))
1300           (setq count (1+ count)
1301                 start (1+ start)))
1302         ;; ... and prepend a "../" for each slash found:
1303         (while (> count 0)
1304           (setq count (1- count)
1305                 name1 (concat "../" name1)))))
1306     (make-symbolic-link
1307      (directory-file-name name1)        ; must not link to foo/
1308                                         ; (trailing slash!)
1309      name2 ok-if-already-exists)))
1310
1311 ;;;###autoload
1312 (defun dired-do-relsymlink (&optional arg)
1313    "Relative symlink all marked (or next ARG) files into a directory.
1314 Otherwise make a relative symbolic link to the current file.
1315 This creates relative symbolic links like
1316
1317     foo -> ../bar/foo
1318
1319 not absolute ones like
1320
1321     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1322
1323 For absolute symlinks, use \\[dired-do-symlink]."
1324   (interactive "P")
1325   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1326                            "RelSymLink" arg dired-keep-marker-relsymlink))
1327
1328 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1329   "RelSymlink all marked files containing REGEXP to NEWNAME.
1330 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1331 for more info."
1332   (interactive (dired-mark-read-regexp "RelSymLink"))
1333   (dired-do-create-files-regexp
1334    (function dired-make-relative-symlink)
1335    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1336
1337 \f
1338 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1339
1340 ;; Brief Description:
1341 ;;;
1342 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1343 ;;;
1344 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1345 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1346 ;;;
1347 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1348 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1349 ;;;
1350 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1351 ;;;   list each time.
1352 ;;;
1353 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1354 ;;;   element of FILE-LIST.
1355 ;;;
1356 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1357 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1358 ;;;   cognizant of the window-configuration.
1359 ;;;
1360 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1361 ;;;   of FILE-LIST giving each a window of height `size'.
1362
1363 (defun dired-do-find-marked-files (&optional noselect)
1364   "Find all marked files displaying all of them simultaneously.
1365 With optional NOSELECT just find files but do not select them.
1366
1367 The current window is split across all files marked, as evenly as possible.
1368 Remaining lines go to bottom-most window.  The number of files that can be
1369 displayed this way is restricted by the height of the current window and
1370 `window-min-height'.
1371
1372 To keep dired buffer displayed, type \\[split-window-vertically] first.
1373 To display just marked files, type \\[delete-other-windows] first."
1374
1375   (interactive "P")
1376   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1377
1378 (defun dired-simultaneous-find-file (file-list noselect)
1379
1380   "Visit all files in FILE-LIST and display them simultaneously.
1381 The current window is split across all files in FILE-LIST, as evenly as
1382 possible.  Remaining lines go to the bottom-most window.  The number of
1383 files that can be displayed this way is restricted by the height of the
1384 current window and the variable `window-min-height'.  With non-nil
1385 NOSELECT the files are merely found but not selected."
1386
1387   ;; We don't make this function interactive because it is usually too clumsy
1388   ;; to specify FILE-LIST interactively unless via dired.
1389
1390   (let (size)
1391
1392     (if noselect
1393         ;; Do not select the buffer.
1394         (find-file-noselect (car file-list))
1395
1396       ;; We will have to select the buffer.  Calculate and check window size.
1397       (setq size (/ (window-height) (length file-list)))
1398       (or (<= window-min-height size)
1399           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1400       (find-file (car file-list)))
1401
1402     ;; Decrement.
1403     (setq file-list (cdr file-list))
1404
1405     (while file-list
1406
1407       (if noselect
1408           ;; Do not select the buffer.
1409           (find-file-noselect (car file-list))
1410
1411         ;; Vertically split off a window of desired size.  Upper window will
1412         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1413         (select-window (split-window nil size))
1414         (find-file (car file-list)))
1415
1416       ;; Decrement.
1417       (setq file-list (cdr file-list)))))
1418
1419 \f
1420 ;;; MISCELLANEOUS COMMANDS.
1421
1422 ;; Run man on files.
1423
1424 (defun dired-man ()
1425   "Run man on this file.  Display old buffer if buffer name matches filename.
1426 Uses `man.el' of \\[manual-entry] fame."
1427   (interactive)
1428   (require 'man)
1429   (let* ((file (dired-get-filename))
1430          (manual-program (replace-regexp-in-string "\\*" "%s"
1431                           (dired-guess-shell-command
1432                            "Man command: " (list file)))))
1433     (Man-getpage-in-background file)))
1434
1435 ;; Run Info on files.
1436
1437 (defun dired-info ()
1438   "Run info on this file."
1439   (interactive)
1440   (info (dired-get-filename)))
1441
1442 ;; Run mail on mail folders.
1443
1444 ;; Avoid compiler warning.
1445 (eval-when-compile
1446   (when (not (fboundp 'vm-visit-folder))
1447     (defun vm-visit-folder (file &optional arg)
1448       nil)))
1449
1450 (defun dired-vm (&optional read-only)
1451   "Run VM on this file.
1452 With prefix arg, visit folder read-only (this requires at least VM 5).
1453 See also variable `dired-vm-read-only-folders'."
1454   (interactive "P")
1455   (let ((dir (dired-current-directory))
1456         (fil (dired-get-filename)))
1457     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1458     (cond (read-only (vm-visit-folder fil t))
1459           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1460           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1461           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1462     ;; so that pressing `v' inside VM does prompt within current directory:
1463     (set (make-local-variable 'vm-folder-directory) dir)))
1464
1465 (defun dired-rmail ()
1466   "Run RMAIL on this file."
1467   (interactive)
1468   (rmail (dired-get-filename)))
1469
1470 (defun dired-do-run-mail ()
1471   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1472   (interactive)
1473   (if dired-bind-vm
1474       ;; Read mail folder using vm.
1475       (dired-vm)
1476     ;; Read mail folder using rmail.
1477     (dired-rmail)))
1478
1479 \f
1480 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1481
1482 (declare-function dired-old-find-buffer-nocreate "dired-x")
1483
1484 (or (fboundp 'dired-old-find-buffer-nocreate)
1485     (fset 'dired-old-find-buffer-nocreate
1486           (symbol-function 'dired-find-buffer-nocreate)))
1487
1488 ;; REDEFINE.
1489 ;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1490 (defun dired-find-buffer-nocreate (dirname &optional mode)
1491   (if (and dired-find-subdir
1492            ;; don't try to find a wildcard as a subdirectory
1493            (string-equal dirname (file-name-directory dirname)))
1494       (let* ((cur-buf (current-buffer))
1495              (buffers (nreverse
1496                        (dired-buffers-for-dir (expand-file-name dirname))))
1497              (cur-buf-matches (and (memq cur-buf buffers)
1498                                    ;; wildcards must match, too:
1499                                    (equal dired-directory dirname))))
1500         ;; We don't want to switch to the same buffer---
1501         (setq buffers (delq cur-buf buffers));;need setq with delq
1502         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1503             ;; ---unless it's the only possibility:
1504             (and cur-buf-matches cur-buf)))
1505     (dired-old-find-buffer-nocreate dirname mode)))
1506
1507 ;; This should be a builtin
1508 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1509   "Return t if BUFFER1 is more recently used than BUFFER2."
1510   (if (equal buffer1 buffer2)
1511       nil
1512     (let ((more-recent nil)
1513           (list (buffer-list)))
1514       (while (and list
1515                   (not (setq more-recent (equal buffer1 (car list))))
1516                   (not (equal buffer2 (car list))))
1517         (setq list (cdr list)))
1518       more-recent)))
1519
1520 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1521 ;; (defun dired-buffers-for-dir-exact (dir)
1522 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1523 ;; ;; at top level, or as subdirectory.
1524 ;; ;; Top level matches must match the wildcard part too, if any.
1525 ;; ;; The list is in reverse order of buffer creation, most recent last.
1526 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1527 ;; ;; dired-buffers.
1528 ;;   (let ((alist dired-buffers) result elt)
1529 ;;     (while alist
1530 ;;       (setq elt (car alist)
1531 ;;             alist (cdr alist))
1532 ;;       (let ((buf (cdr elt)))
1533 ;;         (if (buffer-name buf)
1534 ;;             ;; Top level must match exactly against dired-directory in
1535 ;;             ;; case one of them is a wildcard.
1536 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1537 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1538 ;;                 (setq result (cons buf result)))
1539 ;;           ;; else buffer is killed - clean up:
1540 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1541 ;;     result))
1542
1543 ;; REDEFINE.
1544 ;; Redefines dired.el's version of `dired-initial-position'
1545 (defun dired-initial-position (dirname)
1546   "Where point should go in a new listing of DIRNAME.
1547 Point assumed at beginning of new subdir line.
1548 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1549   (end-of-line)
1550   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1551   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1552
1553 \f
1554 ;; Does anyone use this? - lrd 6/29/93.
1555 ;; Apparently people do use it. - lrd 12/22/97.
1556 (defun dired-mark-sexp (predicate &optional unflag-p)
1557   "Mark files for which PREDICATE returns non-nil.
1558 With a prefix arg, unflag those files instead.
1559
1560 PREDICATE is a lisp expression that can refer to the following symbols:
1561
1562     inode  [integer] the inode of the file (only for ls -i output)
1563     s      [integer] the size of the file for ls -s output
1564                      (usually in blocks or, with -k, in KByte)
1565     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1566     nlink  [integer] number of links to file
1567     uid    [string]  owner
1568     gid    [string]  group  (If the gid is not displayed by ls,
1569                      this will still be set (to the same as uid))
1570     size   [integer] file size in bytes
1571     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1572     name   [string]  the name of the file
1573     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1574
1575 For example, use
1576
1577         (equal 0 size)
1578
1579 to mark all zero length files."
1580   ;; Using sym="" instead of nil avoids the trap of
1581   ;; (string-match "foo" sym) into which a user would soon fall.
1582   ;; Give `equal' instead of `=' in the example, as this works on
1583   ;; integers and strings.
1584   (interactive "xMark if (lisp expr): \nP")
1585   (message "%s" predicate)
1586   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1587         inode s mode nlink uid gid size time name sym)
1588     (dired-mark-if
1589      (save-excursion
1590        (and
1591         ;; Sets vars
1592         ;;                inode s mode nlink uid gid size time name sym
1593
1594         ;; according to current file line.  Returns t for success, nil if
1595         ;; there is no file line.  Upon success, all variables are set, either
1596         ;; to nil or the appropriate value, so they need not be initialized.
1597         ;; Moves point within the current line.
1598         (if (dired-move-to-filename)
1599             (let (pos
1600                   (mode-len 10) ; length of mode string
1601                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1602                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1603               (beginning-of-line)
1604               (forward-char 2)
1605               (if (looking-at dired-re-inode-size)
1606                   (progn
1607                     (goto-char (match-end 0))
1608                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1609                                                                     (match-end 1)))
1610                           s (string-to-number (buffer-substring (match-beginning 2)
1611                                                                 (match-end 2)))))
1612                 (setq inode nil
1613                       s nil))
1614               (setq mode (buffer-substring (point) (+ mode-len (point))))
1615               (forward-char mode-len)
1616               (setq nlink (read (current-buffer)))
1617               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1618               (setq uid (buffer-substring (+ (point) 1)
1619                                           (progn (forward-word 1) (point))))
1620               (re-search-forward directory-listing-before-filename-regexp)
1621               (goto-char (match-beginning 1))
1622               (forward-char -1)
1623               (setq size (string-to-number (buffer-substring (save-excursion
1624                                                                (backward-word 1)
1625                                                                (setq pos (point)))
1626                                                              (point))))
1627               (goto-char pos)
1628               (backward-word 1)
1629               ;; if no gid is displayed, gid will be set to uid
1630               ;; but user will then not reference it anyway in PREDICATE.
1631               (setq gid (buffer-substring (save-excursion
1632                                             (forward-word 1) (point))
1633                                           (point))
1634                     time (buffer-substring (match-beginning 1)
1635                                            (1- (dired-move-to-filename)))
1636                     name (buffer-substring (point)
1637                                            (or
1638                                             (dired-move-to-end-of-filename t)
1639                                             (point)))
1640                     sym  (progn
1641                            (if (looking-at " -> ")
1642                                (buffer-substring
1643                                 (progn (forward-char 4) (point))
1644                                 (progn (end-of-line) (point)))
1645                              "")))
1646               t)
1647           nil)
1648                       (eval predicate)))
1649      (format "'%s file" predicate))))
1650
1651 \f
1652 ;;; FIND FILE AT POINT.
1653
1654 (defvar dired-x-hands-off-my-keys t
1655   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1656 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1657 If you change this variable after `dired-x.el' is loaded then do
1658 \\[dired-x-bind-find-file].")
1659
1660 ;; Bind `dired-x-find-file{-other-window}' over wherever
1661 ;; `find-file{-other-window}' is bound?
1662 (defun dired-x-bind-find-file ()
1663   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1664 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1665 Binding direction based on `dired-x-hands-off-my-keys'.
1666 This function is part of `after-init-hook'."
1667   (interactive)
1668   (if (called-interactively-p 'interactive)
1669       (setq dired-x-hands-off-my-keys
1670             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1671   (cond ((not dired-x-hands-off-my-keys)
1672          (substitute-key-definition 'find-file
1673                                     'dired-x-find-file
1674                                     (current-global-map))
1675          (substitute-key-definition 'find-file-other-window
1676                                     'dired-x-find-file-other-window
1677                                     (current-global-map)))
1678         (t
1679          (substitute-key-definition 'dired-x-find-file
1680                                     'find-file
1681                                     (current-global-map))
1682          (substitute-key-definition 'dired-x-find-file-other-window
1683                                     'find-file-other-window
1684                                     (current-global-map))))
1685   ;; Clear mini-buffer.
1686   (message nil))
1687
1688 ;; Now call it so binding is correct and put on `after-init-hook' in case
1689 ;; user changes binding.
1690 (dired-x-bind-find-file)
1691 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1692
1693 (defun dired-x-find-file (filename)
1694   "Edit file FILENAME.
1695 May create a new window, or reuse an existing one.
1696 See the function `display-buffer'.
1697
1698 Identical to `find-file' except when called interactively, with a prefix arg
1699 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1700 Useful for editing file mentioned in buffer you are viewing,
1701 or to test if that file exists.  Use minibuffer after snatching filename."
1702   (interactive (list (read-filename-at-point "Find file: ")))
1703   (find-file (expand-file-name filename)))
1704
1705 (defun dired-x-find-file-other-window (filename)
1706   "Edit file FILENAME, in another window.
1707 May create a new window, or reuse an existing one.
1708 See the function `display-buffer'.
1709
1710 Identical to `find-file-other-window' except when called interactively, with
1711 a prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1712 Useful for editing file mentioned in buffer you are viewing,
1713 or to test if that file exists.  Use minibuffer after snatching filename."
1714   (interactive (list (read-filename-at-point "Find file: ")))
1715   (find-file-other-window (expand-file-name filename)))
1716
1717 ;;; Internal functions.
1718
1719 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1720 (defun dired-filename-at-point ()
1721   "Get the filename closest to point, but do not change position.
1722 Has a preference for looking backward when not directly on a symbol.
1723 Not perfect - point must be in middle of or end of filename."
1724
1725   (let ((filename-chars "-.[:alnum:]_/:$+@")
1726         start end filename prefix)
1727
1728     (save-excursion
1729       ;; First see if just past a filename.
1730       (if (not (eobp))
1731           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1732               (progn
1733                 (skip-chars-backward " \n\t\r({[]})")
1734                 (if (not (bobp))
1735                     (backward-char 1)))))
1736
1737       (if (string-match (concat "[" filename-chars "]")
1738                         (char-to-string (following-char)))
1739           (progn
1740             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1741                 (forward-char)
1742               (goto-char (point-min)))
1743             (setq start (point))
1744             (setq prefix
1745                   (and (string-match
1746                         "^\\w+@"
1747                         (buffer-substring start (line-beginning-position)))
1748                        "/"))
1749             (goto-char start)
1750             (if (string-match "[/~]" (char-to-string (preceding-char)))
1751                 (setq start (1- start)))
1752             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1753
1754         (error "No file found around point!"))
1755
1756       ;; Return string.
1757       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1758
1759 (defun read-filename-at-point (prompt)
1760   "Return filename prompting with PROMPT with completion.
1761 If `current-prefix-arg' is non-nil, uses name at point as guess."
1762   (if current-prefix-arg
1763       (let ((guess (dired-filename-at-point)))
1764         (read-file-name prompt
1765                         (file-name-directory guess)
1766                         guess
1767                         nil (file-name-nondirectory guess)))
1768     (read-file-name prompt default-directory)))
1769 \f
1770 ;;; BUG REPORTS
1771
1772 ;; Fixme: get rid of this later.
1773
1774 ;; This section is provided for reports.  It uses Barry A. Warsaw's
1775 ;; reporter.el which is bundled with GNU Emacs v19.
1776
1777 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1778   "Address(es) accepting submission of reports on dired-x.el.")
1779
1780 (defconst dired-x-variable-list
1781   (list
1782    'dired-bind-vm
1783    'dired-vm-read-only-folders
1784    'dired-bind-jump
1785    'dired-bind-info
1786    'dired-bind-man
1787    'dired-find-subdir
1788    'dired-enable-local-variables
1789    'dired-local-variables-file
1790    'dired-guess-shell-gnutar
1791    'dired-guess-shell-gzip-quiet
1792    'dired-guess-shell-znew-switches
1793    'dired-guess-shell-alist-user
1794    'dired-clean-up-buffers-too
1795    'dired-omit-mode
1796    'dired-omit-files
1797    'dired-omit-extensions
1798    )
1799   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1800
1801 (defun dired-x-submit-report ()
1802   "Submit via `reporter.el' a bug report on program.
1803 Send report on `dired-x-file' version `dired-x-version', to
1804 `dired-x-maintainer' at address `dired-x-help-address' listing
1805 variables `dired-x-variable-list' in the message."
1806   (interactive)
1807
1808   (reporter-submit-bug-report
1809    dired-x-help-address                 ; address
1810    "dired-x"                            ; pkgname
1811    dired-x-variable-list                ; varlist
1812    nil nil                              ; pre-/post-hooks
1813    ""))
1814
1815 \f
1816 ;; As Barry Warsaw would say: "This might be useful..."
1817 (provide 'dired-x)
1818
1819 ;; Local Variables:
1820 ;; byte-compile-dynamic: t
1821 ;; generated-autoload-file: "dired.el"
1822 ;; End:
1823
1824 ;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1825 ;;; dired-x.el ends here