lisp/emacs-lisp/find-func.el

   1 ;;; find-func.el --- find the definition of the Emacs Lisp function near point
   2
   3 ;; Copyright (C) 1997, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Jens Petersen <petersen@kurims.kyoto-u.ac.jp>
   6 ;; Maintainer: petersen@kurims.kyoto-u.ac.jp
   7 ;; Keywords: emacs-lisp, functions, variables
   8 ;; Created: 97/07/25
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; The funniest thing about this is that I can't imagine why a package
  30 ;; so obviously useful as this hasn't been written before!!
  31 ;; ;;; find-func
  32 ;; (find-function-setup-keys)
  33 ;;
  34 ;; or just:
  35 ;;
  36 ;; (load "find-func")
  37 ;;
  38 ;; if you don't like the given keybindings and away you go!  It does
  39 ;; pretty much what you would expect, putting the cursor at the
  40 ;; definition of the function or variable at point.
  41 ;;
  42 ;; The code started out from `describe-function', `describe-key'
  43 ;; ("help.el") and `fff-find-loaded-emacs-lisp-function' (Noah Friedman's
  44 ;; "fff.el").
  45
  46 ;;; Code:
  47
  48 (require 'loadhist)
  49
  50 ;;; User variables:
  51
  52 (defgroup find-function nil
  53   "Finds the definition of the Emacs Lisp symbol near point."
  54 ;;   :prefix "find-function"
  55   :group 'lisp)
  56
  57 (defcustom find-function-regexp
  58   ;; Match things like (defun foo ...), (defmacro foo ...),
  59   ;; (define-skeleton foo ...), (define-generic-mode 'foo ...),
  60   ;;  (define-derived-mode foo ...), (define-minor-mode foo)
  61   "^\\s-*(\\(def\\(ine-skeleton\\|ine-generic-mode\\|ine-derived-mode\\|\
  62 \[^cgv\W]\\w+\\*?\\)\\|define-minor-mode\
  63 \\|easy-mmode-define-global-mode\\)\\(\\s-\\|\n\\)+'?\
  64 %s\\(\\s-\\|$\\|\(\\|\)\\)"
  65   "The regexp used by `find-function' to search for a function definition.
  66 Note it must contain a `%s' at the place where `format'
  67 should insert the function name.  The default value avoids `defconst',
  68 `defgroup', `defvar'.
  69
  70 Please send improvements and fixes to the maintainer."
  71   :type 'regexp
  72   :group 'find-function
  73   :version "21.1")
  74
  75 (defcustom find-variable-regexp
  76   "^\\s-*(def[^umag]\\(\\w\\|\\s_\\)+\\*?\\s-+%s\\(\\s-\\|$\\)"
  77   "The regexp used by `find-variable' to search for a variable definition.
  78 It should match right up to the variable name.  The default value
  79 avoids `defun', `defmacro', `defalias', `defadvice', `defgroup'.
  80
  81 Please send improvements and fixes to the maintainer."
  82   :type 'regexp
  83   :group 'find-function
  84   :version "21.1")
  85
  86 (defcustom find-function-source-path nil
  87   "The default list of directories where `find-function' searches.
  88
  89 If this variable is nil then `find-function' searches `load-path' by
  90 default."
  91   :type '(repeat directory)
  92   :group 'find-function)
  93
  94 (defcustom find-function-recenter-line 1
  95   "The window line-number from which to start displaying a symbol definition.
  96 A value of nil implies center the beginning of the definition.
  97 See the function `center-to-window-line' for more information, and
  98 `find-function' and `find-variable'."
  99   :group 'find-function
 100   :version "20.3")
 101
 102 (defcustom find-function-after-hook nil
 103   "Hook run after finding symbol definition.
 104
 105 See the functions `find-function' and `find-variable'."
 106   :group 'find-function
 107   :version "20.3")
 108
 109 ;;; Functions:
 110
 111 (defun find-function-search-for-symbol (symbol variable-p library)
 112   "Search for SYMBOL.
 113 If VARIABLE-P is nil, `find-function-regexp' is used, otherwise
 114 `find-variable-regexp' is used.   The search is done in library LIBRARY."
 115   (if (null library)
 116       (error "Don't know where `%s' is defined" symbol))
 117   (save-match-data
 118     (if (string-match "\\.el\\(c\\)\\'" library)
 119         (setq library (substring library 0 (match-beginning 1))))
 120     (let* ((path find-function-source-path)
 121            (compression (or (rassq 'jka-compr-handler file-name-handler-alist)
 122                             (member 'crypt-find-file-hook find-file-hooks)))
 123            (filename (progn
 124                        ;; use `file-name-sans-extension' here? (if it gets fixed)
 125                        (if (string-match "\\(\\.el\\)\\'" library)
 126                            (setq library (substring library 0
 127                                                     (match-beginning 1))))
 128                        (or (locate-library (concat library ".el") t path)
 129                            (locate-library library t path)
 130                            (if compression
 131                                (or (locate-library (concat library ".el.gz")
 132                                                    t path)
 133                                    (locate-library (concat library ".gz")
 134                                                    t path)))))))
 135       (if (not filename)
 136           (error "The library `%s' is not in the path" library))
 137       (with-current-buffer (find-file-noselect filename)
 138         (let ((regexp (format (if variable-p
 139                                   find-variable-regexp
 140                                 find-function-regexp)
 141                               (regexp-quote (symbol-name symbol))))
 142               (syn-table (syntax-table)))
 143           (unwind-protect
 144               (progn
 145                 (set-syntax-table emacs-lisp-mode-syntax-table)
 146                 (goto-char (point-min))
 147                 (if (or (re-search-forward regexp nil t)
 148                         (re-search-forward
 149                          (concat "^([^ ]+ +"
 150                                  (regexp-quote (symbol-name symbol))
 151                                  "\\>")
 152                          nil t))
 153                     (progn
 154                       (beginning-of-line)
 155                       (cons (current-buffer) (point)))
 156                   (error "Cannot find definition of `%s' in library `%s'"
 157                          symbol library)))
 158             (set-syntax-table syn-table)))))))
 159
 160 ;;;###autoload
 161 (defun find-function-noselect (function)
 162   "Return a pair (BUFFER . POINT) pointing to the definition of FUNCTION.
 163
 164 Finds the Emacs Lisp library containing the definition of FUNCTION
 165 in a buffer and the point of the definition.  The buffer is
 166 not selected.
 167
 168 If the file where FUNCTION is defined is not known, then it is
 169 searched for in `find-function-source-path' if non nil, otherwise
 170 in `load-path'."
 171   (if (not function)
 172       (error "You didn't specify a function"))
 173   (and (subrp (symbol-function function))
 174        (error "%s is a primitive function" function))
 175   (let ((def (symbol-function function))
 176         aliases)
 177     (while (symbolp def)
 178       (or (eq def function)
 179           (if aliases
 180               (setq aliases (concat aliases
 181                                     (format ", which is an alias for `%s'"
 182                                             (symbol-name def))))
 183             (setq aliases (format "`%s' an alias for `%s'"
 184                                   function (symbol-name def)))))
 185       (setq function (symbol-function function)
 186             def (symbol-function function)))
 187     (if aliases
 188         (message aliases))
 189     (let ((library
 190            (cond ((eq (car-safe def) 'autoload)
 191                   (nth 1 def))
 192                  ((symbol-file function)))))
 193       (find-function-search-for-symbol function nil library))))
 194
 195 (defalias 'function-at-point 'function-called-at-point)
 196
 197 (defun find-function-read (&optional variable-p)
 198   "Read and return an interned symbol, defaulting to the one near point.
 199
 200 If the optional VARIABLE-P is nil, then a function is gotten
 201 defaulting to the value of the function `function-at-point', otherwise
 202 a variable is asked for, with the default coming from
 203 `variable-at-point'."
 204   (let ((symb (funcall (if variable-p
 205                            'variable-at-point
 206                          'function-at-point)))
 207         (enable-recursive-minibuffers t)
 208         val)
 209     (if (equal symb 0)
 210         (setq symb nil))
 211     (setq val (if variable-p
 212                   (completing-read
 213                    (concat "Find variable"
 214                            (if symb
 215                                (format " (default %s)" symb))
 216                            ": ")
 217                    obarray 'boundp t nil)
 218                 (completing-read
 219                  (concat "Find function"
 220                          (if symb
 221                              (format " (default %s)" symb))
 222                          ": ")
 223                  obarray 'fboundp t nil)))
 224     (list (if (equal val "")
 225               symb
 226             (intern val)))))
 227
 228 (defun find-function-do-it (symbol variable-p switch-fn)
 229   "Find Emacs Lisp SYMBOL in a buffer and display it.
 230 If VARIABLE-P is nil, a function definition is searched for, otherwise
 231 a variable definition is searched for.  The start of a definition is
 232 centered according to the variable `find-function-recenter-line'.
 233 See also `find-function-after-hook'  It is displayed with function SWITCH-FN.
 234
 235 Point is saved in the buffer if it is one of the current buffers."
 236   (let* ((orig-point (point))
 237         (orig-buf (window-buffer))
 238         (orig-buffers (buffer-list))
 239         (buffer-point (save-excursion
 240                         (funcall (if variable-p
 241                                       'find-variable-noselect
 242                                     'find-function-noselect)
 243                                   symbol)))
 244         (new-buf (car buffer-point))
 245         (new-point (cdr buffer-point)))
 246     (when buffer-point
 247       (when (memq new-buf orig-buffers)
 248         (push-mark orig-point))
 249       (funcall switch-fn new-buf)
 250       (goto-char new-point)
 251       (recenter find-function-recenter-line)
 252       (run-hooks 'find-function-after-hook))))
 253
 254 ;;;###autoload
 255 (defun find-function (function)
 256   "Find the definition of the FUNCTION near point.
 257
 258 Finds the Emacs Lisp library containing the definition of the function
 259 near point (selected by `function-at-point') in a buffer and
 260 places point before the definition.  Point is saved in the buffer if
 261 it is one of the current buffers.
 262
 263 The library where FUNCTION is defined is searched for in
 264 `find-function-source-path', if non nil, otherwise in `load-path'.
 265 See also `find-function-recenter-line' and `find-function-after-hook'."
 266   (interactive (find-function-read))
 267   (find-function-do-it function nil 'switch-to-buffer))
 268
 269 ;;;###autoload
 270 (defun find-function-other-window (function)
 271   "Find, in another window, the definition of FUNCTION near point.
 272
 273 See `find-function' for more details."
 274   (interactive (find-function-read))
 275   (find-function-do-it function nil 'switch-to-buffer-other-window))
 276
 277 ;;;###autoload
 278 (defun find-function-other-frame (function)
 279   "Find, in ananother frame, the definition of FUNCTION near point.
 280
 281 See `find-function' for more details."
 282   (interactive (find-function-read))
 283   (find-function-do-it function nil 'switch-to-buffer-other-frame))
 284
 285 ;;;###autoload
 286 (defun find-variable-noselect (variable &optional file)
 287   "Return a pair `(BUFFER . POINT)' pointing to the definition of SYMBOL.
 288
 289 Finds the Emacs Lisp library containing the definition of SYMBOL
 290 in a buffer and the point of the definition.  The buffer is
 291 not selected.
 292
 293 The library where VARIABLE is defined is searched for in FILE or
 294 `find-function-source-path', if non nil, otherwise in `load-path'."
 295   (if (not variable)
 296       (error "You didn't specify a variable"))
 297   (let ((library (or file (symbol-file variable))))
 298     (find-function-search-for-symbol variable 'variable library)))
 299
 300 ;;;###autoload
 301 (defun find-variable (variable)
 302   "Find the definition of the VARIABLE near point.
 303
 304 Finds the Emacs Lisp library containing the definition of the variable
 305 near point (selected by `variable-at-point') in a buffer and
 306 places point before the definition.  Point is saved in the buffer if
 307 it is one of the current buffers.
 308
 309 The library where VARIABLE is defined is searched for in
 310 `find-function-source-path', if non nil, otherwise in `load-path'.
 311 See also `find-function-recenter-line' and `find-function-after-hook'."
 312   (interactive (find-function-read 'variable))
 313   (find-function-do-it variable t 'switch-to-buffer))
 314
 315 ;;;###autoload
 316 (defun find-variable-other-window (variable)
 317   "Find, in another window, the definition of VARIABLE near point.
 318
 319 See `find-variable' for more details."
 320   (interactive (find-function-read 'variable))
 321   (find-function-do-it variable t 'switch-to-buffer-other-window))
 322
 323 ;;;###autoload
 324 (defun find-variable-other-frame (variable)
 325   "Find, in annother frame, the definition of VARIABLE near point.
 326
 327 See `find-variable' for more details."
 328   (interactive (find-function-read 'variable))
 329   (find-function-do-it variable t 'switch-to-buffer-other-frame))
 330
 331 ;;;###autoload
 332 (defun find-function-on-key (key)
 333   "Find the function that KEY invokes.  KEY is a string.
 334 Point is saved if FUNCTION is in the current buffer."
 335   (interactive "kFind function on key: ")
 336   (save-excursion
 337     (let* ((event (and (eventp key) (aref key 0))) ; Null event OK below.
 338            (start (event-start event))
 339            (modifiers (event-modifiers event))
 340            (window (and (or (memq 'click modifiers) (memq 'down modifiers)
 341                             (memq 'drag modifiers))
 342                         (posn-window start))))
 343       ;; For a mouse button event, go to the button it applies to
 344       ;; to get the right key bindings.  And go to the right place
 345       ;; in case the keymap depends on where you clicked.
 346       (when (windowp window)
 347         (set-buffer (window-buffer window))
 348         (goto-char (posn-point start)))
 349       (let ((defn (key-binding key))
 350             (key-desc (key-description key)))
 351         (if (or (null defn) (integerp defn))
 352             (message "%s is unbound" key-desc)
 353           (if (consp defn)
 354               (message "%s runs %s" key-desc (prin1-to-string defn))
 355             (find-function-other-window defn)))))))
 356
 357 ;;;###autoload
 358 (defun find-function-at-point ()
 359   "Find directly the function at point in the other window."
 360   (interactive)
 361   (let ((symb (function-at-point)))
 362     (when symb
 363       (find-function-other-window symb))))
 364
 365 ;;;###autoload
 366 (defun find-variable-at-point ()
 367   "Find directly the function at point in the other window."
 368   (interactive)
 369   (let ((symb (variable-at-point)))
 370     (when (and symb (not (equal symb 0)))
 371       (find-variable-other-window symb))))
 372
 373 ;;;###autoload
 374 (defun find-function-setup-keys ()
 375   "Define some key bindings for the find-function family of functions."
 376   (define-key ctl-x-map "F" 'find-function)
 377   (define-key ctl-x-4-map "F" 'find-function-other-window)
 378   (define-key ctl-x-5-map "F" 'find-function-other-frame)
 379   (define-key ctl-x-map "K" 'find-function-on-key)
 380   (define-key ctl-x-map "V" 'find-variable)
 381   (define-key ctl-x-4-map "V" 'find-variable-other-window)
 382   (define-key ctl-x-5-map "V" 'find-variable-other-frame))
 383
 384 (provide 'find-func)
 385
 386 ;;; find-func.el ends here