lisp/view.el

   1 ;;; view.el --- peruse file or buffer without editing.
   2
   3 ;; Copyright (C) 1985, 1989, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: K. Shane Hartman
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This package provides the `view' minor mode documented in the Emacs
  27 ;; user's manual.
  28
  29 ;;; Code:
  30
  31 ;;;###autoload
  32 (defvar view-highlight-face 'highlight
  33    "*The overlay face used for highlighting the match found by View mode search.")
  34
  35 (defvar view-mode nil "Non-nil if View mode is enabled.")
  36 (make-variable-buffer-local 'view-mode)
  37
  38 (defvar view-mode-auto-exit nil
  39   "Non-nil means scrolling past the end of buffer exits View mode.")
  40 (make-variable-buffer-local 'view-mode-auto-exit)
  41
  42 (defvar view-old-buffer-read-only nil)
  43 (make-variable-buffer-local 'view-old-buffer-read-only)
  44 (defvar view-old-Helper-return-blurb)
  45 (make-variable-buffer-local 'view-old-Helper-return-blurb)
  46
  47 (defvar view-scroll-size nil)
  48 (make-variable-buffer-local 'view-scroll-size)
  49
  50 (defvar view-last-regexp nil)
  51 (make-variable-buffer-local 'view-last-regexp)
  52
  53 (defvar view-exit-action nil)
  54 (make-variable-buffer-local 'view-exit-action)
  55 (defvar view-return-here nil)
  56 (make-variable-buffer-local 'view-return-here)
  57 (defvar view-exit-position nil)
  58 (make-variable-buffer-local 'view-exit-position)
  59
  60 (defvar view-overlay nil
  61   "Overlay used to display where a search operation found its match.
  62 This is local in each buffer, once it is used.")
  63 (make-variable-buffer-local 'view-overlay)
  64
  65 (or (assq 'view-mode minor-mode-alist)
  66     (setq minor-mode-alist
  67           (cons '(view-mode " View") minor-mode-alist)))
  68
  69 (defvar view-mode-map nil)
  70 (if view-mode-map
  71     nil
  72   (setq view-mode-map (make-keymap))
  73   (suppress-keymap view-mode-map)
  74   (define-key view-mode-map "q" 'view-exit)
  75   (define-key view-mode-map "<" 'beginning-of-buffer)
  76   (define-key view-mode-map ">" 'end-of-buffer)
  77   (define-key view-mode-map "\ev" 'View-scroll-lines-backward)
  78   (define-key view-mode-map "\C-v" 'View-scroll-lines-forward)
  79   (define-key view-mode-map " " 'View-scroll-lines-forward)
  80   (define-key view-mode-map "\C-?" 'View-scroll-lines-backward)
  81   (define-key view-mode-map "\n" 'View-scroll-one-more-line)
  82   (define-key view-mode-map "\r" 'View-scroll-one-more-line)
  83   (define-key view-mode-map "z" 'View-scroll-lines-forward-set-scroll-size)
  84   (define-key view-mode-map "g" 'View-goto-line)
  85   (define-key view-mode-map "=" 'what-line)
  86   (define-key view-mode-map "." 'set-mark-command)
  87   (define-key view-mode-map "'" 'View-back-to-mark)
  88   (define-key view-mode-map "@" 'View-back-to-mark)
  89   (define-key view-mode-map "x" 'exchange-point-and-mark)
  90   (define-key view-mode-map "h" 'describe-mode)
  91   (define-key view-mode-map "?" 'describe-mode)
  92   (define-key view-mode-map "s" 'isearch-forward)
  93   (define-key view-mode-map "r" 'isearch-backward)
  94   (define-key view-mode-map "/" 'View-search-regexp-forward)
  95   (define-key view-mode-map "\\" 'View-search-regexp-backward)
  96   ;; This conflicts with the standard binding of isearch-regexp-forward
  97   (define-key view-mode-map "\e\C-s" 'View-search-regexp-forward)
  98   (define-key view-mode-map "\e\C-r" 'View-search-regexp-backward)
  99   (define-key view-mode-map "n" 'View-search-last-regexp-forward)
 100   (define-key view-mode-map "p" 'View-search-last-regexp-backward)
 101   )
 102
 103 (or (assq 'view-mode minor-mode-map-alist)
 104     (setq minor-mode-map-alist
 105           (cons (cons 'view-mode view-mode-map) minor-mode-map-alist)))
 106
 107
 108 ;;;###autoload
 109 (defun view-file (file-name)
 110   "View FILE in View mode, returning to previous buffer when done.
 111 The usual Emacs commands are not available; instead,
 112 a special set of commands (mostly letters and punctuation)
 113 are defined for moving around in the buffer.
 114 Space scrolls forward, Delete scrolls backward.
 115 For list of all View commands, type ? or h while viewing.
 116
 117 This command runs the normal hook `view-mode-hook'."
 118   (interactive "fView file: ")
 119   (let ((old-buf (current-buffer))
 120         (had-a-buf (get-file-buffer file-name))
 121         (buf-to-view (find-file-noselect file-name)))
 122     ;; This used to pass t as second argument,
 123     ;; but then the buffer did not show up in the Buffers menu.
 124     (switch-to-buffer buf-to-view had-a-buf)
 125     (view-mode-enter old-buf
 126                      (and (not had-a-buf) (not (buffer-modified-p buf-to-view))
 127                           'kill-buffer))))
 128
 129 ;;;###autoload
 130 (defun view-file-other-window (file-name)
 131   "View FILE in View mode in other window.
 132 Return to previous buffer when done.
 133 The usual Emacs commands are not available; instead,
 134 a special set of commands (mostly letters and punctuation)
 135 are defined for moving around in the buffer.
 136 Space scrolls forward, Delete scrolls backward.
 137 For list of all View commands, type ? or h while viewing.
 138
 139 This command runs the normal hook `view-mode-hook'."
 140   (interactive "fView file: ")
 141   (let ((old-arrangement (current-window-configuration))
 142         (had-a-buf (get-file-buffer file-name))
 143         (buf-to-view (find-file-noselect file-name)))
 144     (switch-to-buffer-other-window buf-to-view)
 145     (view-mode-enter old-arrangement
 146                      (and (not had-a-buf) (not (buffer-modified-p buf-to-view))
 147                           'kill-buffer))))
 148
 149 ;;;###autoload
 150 (defun view-buffer (buffer-name)
 151   "View BUFFER in View mode, returning to previous buffer when done.
 152 The usual Emacs commands are not available; instead,
 153 a special set of commands (mostly letters and punctuation)
 154 are defined for moving around in the buffer.
 155 Space scrolls forward, Delete scrolls backward.
 156 For list of all View commands, type ? or h while viewing.
 157
 158 This command runs the normal hook `view-mode-hook'."
 159   (interactive "bView buffer: ")
 160   (let ((old-buf (current-buffer)))
 161     (switch-to-buffer buffer-name t)
 162     (view-mode-enter old-buf nil)))
 163
 164 ;;;###autoload
 165 (defun view-buffer-other-window (buffer-name not-return)
 166   "View BUFFER in View mode in another window.
 167 Return to previous buffer when done, unless NOT-RETURN is non-nil.
 168
 169 The usual Emacs commands are not available in View mode; instead,
 170 a special set of commands (mostly letters and punctuation)
 171 are defined for moving around in the buffer.
 172 Space scrolls forward, Delete scrolls backward.
 173 For list of all View commands, type ? or h while viewing.
 174
 175 This command runs the normal hook `view-mode-hook'."
 176   (interactive "bView buffer:\nP")
 177   (let ((return-to (and not-return (current-window-configuration))))
 178     (switch-to-buffer-other-window buffer-name)
 179     (view-mode-enter return-to)))
 180
 181 ;;;###autoload
 182 (defun view-mode (&optional arg)
 183   "Toggle View mode.
 184 If you use this function to turn on View mode,
 185 \"exiting\" View mode does nothing except turn View mode off.
 186 The other way to turn View mode on is by calling
 187 `view-mode-enter'.
 188
 189 Letters do not insert themselves.  Instead these commands are provided.
 190 Most commands take prefix arguments.  Commands dealing with lines
 191 default to \"scroll size\" lines (initially size of window).
 192 Search commands default to a repeat count of one.
 193
 194 M-< or <        move to beginning of buffer.
 195 M-> or >        move to end of buffer.
 196 C-v or Space    scroll forward lines.
 197 M-v or DEL      scroll backward lines.
 198 CR or LF        scroll forward one line (backward with prefix argument).
 199 z               like Space except set number of lines for further
 200                    scrolling commands to scroll by.
 201 C-u and Digits  provide prefix arguments.  `-' denotes negative argument.
 202 =               prints the current line number.
 203 g               goes to line given by prefix argument.
 204 / or M-C-s      searches forward for regular expression
 205 \\ or M-C-r     searches backward for regular expression.
 206 n               searches forward for last regular expression.
 207 p               searches backward for last regular expression.
 208 C-@ or .        set the mark.
 209 x               exchanges point and mark.
 210 C-s or s        do forward incremental search.
 211 C-r or r        do reverse incremental search.
 212 @ or '          return to mark and pops mark ring.
 213                   Mark ring is pushed at start of every
 214                   successful search and when jump to line to occurs.
 215                   The mark is set on jump to buffer start or end.
 216 ? or h          provide help message (list of commands).
 217 \\[help-command]                provides help (list of commands or description of a command).
 218 C-n             moves down lines vertically.
 219 C-p             moves upward lines vertically.
 220 C-l             recenters the screen.
 221 q               exit view-mode and return to previous buffer."
 222   (interactive "P")
 223   (setq view-mode
 224         (if (null arg)
 225             (not view-mode)
 226           (> (prefix-numeric-value arg) 0)))
 227   (force-mode-line-update))
 228
 229 (defun view-mode-enter (&optional prev-buffer action)
 230   "Enter View mode, a Minor mode for viewing text but not editing it.
 231 See the function `view-mode' for more details.
 232
 233 This function runs the normal hook `view-mode-hook'.
 234
 235 \\{view-mode-map}"
 236 ;  Not interactive because dangerous things happen
 237 ;  if you call it without passing a buffer as argument
 238 ;  and they are not easy to fix.
 239 ;  (interactive)
 240   (setq view-old-buffer-read-only buffer-read-only)
 241   (setq view-old-Helper-return-blurb
 242         (and (boundp 'Helper-return-blurb) Helper-return-blurb))
 243
 244   ;; Enable view-exit to make use of the data we just saved
 245   ;; and to perform the exit action.
 246   (setq view-mode-auto-exit t)
 247
 248   (setq buffer-read-only t)
 249   (setq view-mode t)
 250   (setq Helper-return-blurb
 251         (format "continue viewing %s"
 252                 (if (buffer-file-name)
 253                     (file-name-nondirectory (buffer-file-name))
 254                     (buffer-name))))
 255
 256   (setq view-exit-action action)
 257   (setq view-return-here prev-buffer)
 258   (setq view-exit-position (point-marker))
 259
 260   (beginning-of-line)
 261   (setq goal-column nil)
 262
 263   (run-hooks 'view-mode-hook)
 264   (message
 265      (substitute-command-keys
 266       "Type \\[help-command] for help, \\[describe-mode] for commands, \\[view-exit] to quit.")))
 267 \f
 268 (defun view-exit ()
 269   "Exit from view-mode.
 270 If you viewed an existing buffer, that buffer returns to its previous mode.
 271 If you viewed a file that was not present in Emacs, its buffer is killed."
 272   (interactive)
 273   (setq view-mode nil)
 274   (and view-overlay (delete-overlay view-overlay))
 275   (force-mode-line-update)
 276   (cond (view-mode-auto-exit
 277          (setq buffer-read-only view-old-buffer-read-only)
 278          (setq view-mode-auto-exit nil)
 279
 280          (goto-char view-exit-position)
 281          (set-marker view-exit-position nil)
 282
 283          ;; Now do something to the buffer that we were viewing
 284          ;; (such as kill it).
 285          (let ((viewed-buffer (current-buffer))
 286                (action view-exit-action))
 287            (cond
 288             ((bufferp view-return-here)
 289              (switch-to-buffer view-return-here))
 290             ((window-configuration-p view-return-here)
 291              (set-window-configuration view-return-here)))
 292            (if action (funcall action viewed-buffer))))))
 293
 294 (defun view-window-size () (1- (window-height)))
 295
 296 (defun view-scroll-size ()
 297   (min (view-window-size) (or view-scroll-size (view-window-size))))
 298
 299 (defvar view-mode-hook nil
 300   "Normal hook run when starting to view a buffer or file.")
 301
 302 ;(defun view-last-command (&optional who what)
 303 ;  (setq view-last-command-entry this-command)
 304 ;  (setq view-last-command who)
 305 ;  (setq view-last-command-argument what))
 306
 307 ;(defun View-repeat-last-command ()
 308 ;  "Repeat last command issued in View mode."
 309 ;  (interactive)
 310 ;  (if (and view-last-command
 311 ;          (eq view-last-command-entry last-command))
 312 ;      (funcall view-last-command view-last-command-argument))
 313 ;  (setq this-command view-last-command-entry))
 314
 315 (defun View-goto-line (line)
 316   "Move to line LINE in View mode.
 317 Display is centered at LINE.  Sets mark at starting position and pushes
 318 mark ring."
 319   (interactive "p")
 320   (push-mark)
 321   (goto-line line)
 322   (recenter (/ (view-window-size) 2)))
 323
 324 (defun View-scroll-lines-forward (&optional lines)
 325   "Scroll forward in View mode, or exit if end of text is visible.
 326 No arg means whole window full, or number of lines set by \\[View-scroll-lines-forward-set-scroll-size].
 327 Arg is number of lines to scroll."
 328   (interactive "P")
 329   (setq lines
 330         (if lines (prefix-numeric-value lines)
 331           (view-scroll-size)))
 332   (if (and (pos-visible-in-window-p (point-max))
 333            ;; Allow scrolling backward at the end of the buffer.
 334            (> lines 0)
 335            view-mode-auto-exit)
 336       (view-exit)
 337     ;; (view-last-command 'View-scroll-lines-forward lines)
 338     (if (>= lines (view-window-size))
 339         (scroll-up nil)
 340       (if (>= (- lines) (view-window-size))
 341           (scroll-down nil)
 342         (scroll-up lines)))
 343     (cond ((pos-visible-in-window-p (point-max))
 344            (goto-char (point-max))
 345            (message (substitute-command-keys
 346                      "End.  Type \\[view-exit] to quit viewing."))))
 347     (move-to-window-line -1)
 348     (beginning-of-line)))
 349
 350 (defun View-scroll-lines-forward-set-scroll-size (&optional lines)
 351   "Scroll forward LINES lines in View mode, setting the \"scroll size\".
 352 This is the number of lines which \\[View-scroll-lines-forward] and \\[View-scroll-lines-backward] scroll by default.
 353 The absolute value of LINES is used, so this command can be used to scroll
 354 backwards (but \"scroll size\" is always positive).  If LINES is greater than
 355 window height or omitted, then window height is assumed.  If LINES is less
 356 than window height then scrolling context is provided from previous screen."
 357   (interactive "P")
 358   (if (not lines)
 359       (setq view-scroll-size (view-window-size))
 360     (setq lines (prefix-numeric-value lines))
 361     (setq view-scroll-size
 362           (min (if (> lines 0) lines (- lines)) (view-window-size))))
 363   (View-scroll-lines-forward lines))
 364
 365 (defun View-scroll-one-more-line (&optional arg)
 366   "Scroll one more line up in View mode.
 367 With ARG scroll one line down."
 368   (interactive "P")
 369   (View-scroll-lines-forward (if (not arg) 1 -1)))
 370
 371 (defun View-scroll-lines-backward (&optional lines)
 372   "Scroll backward in View mode.
 373 No arg means whole window full, or number of lines set by \\[View-scroll-lines-forward-set-scroll-size].
 374 Arg is number of lines to scroll."
 375   (interactive "P")
 376   (View-scroll-lines-forward (if lines
 377                                  (- (prefix-numeric-value lines))
 378                                (- (view-scroll-size)))))
 379
 380 (defun View-search-regexp-forward (n regexp)
 381   "Search forward for Nth occurrence of REGEXP.
 382 Displays line found at center of window.  REGEXP is remembered for
 383 searching with \\[View-search-last-regexp-forward] and \\[View-search-last-regexp-backward].  Sets mark at starting position and pushes mark ring.
 384
 385 The variable `view-highlight-face' controls the face that is used
 386 for highlighting the match that is found."
 387   (interactive "p\nsSearch forward (regexp): ")
 388 ;;;(view-last-command 'View-search-last-regexp-forward n)
 389   (view-search n (if (equal regexp "") view-last-regexp regexp)))
 390
 391 (defun View-search-regexp-backward (n regexp)
 392   "Search backward from window start for Nth instance of REGEXP.
 393 Displays line found at center of window.  REGEXP is remembered for
 394 searching with \\[View-search-last-regexp-forward] and \\[View-search-last-regexp-backward].  Sets mark at starting position and pushes mark ring.
 395
 396 The variable `view-highlight-face' controls the face that is used
 397 for highlighting the match that is found."
 398   (interactive "p\nsSearch backward (regexp): ")
 399   (View-search-regexp-forward (- n)
 400                               (if (equal regexp "") view-last-regexp regexp)))
 401
 402 (defun View-search-last-regexp-forward (n)
 403   "Search forward from window end for Nth instance of last regexp.
 404 Displays line found at center of window.  Sets mark at starting position
 405 and pushes mark ring.
 406
 407 The variable `view-highlight-face' controls the face that is used
 408 for highlighting the match that is found."
 409   (interactive "p")
 410   (View-search-regexp-forward n view-last-regexp))
 411
 412 (defun View-search-last-regexp-backward (n)
 413   "Search backward from window start for Nth instance of last regexp.
 414 Displays line found at center of window.  Sets mark at starting position and
 415 pushes mark ring.
 416
 417 The variable `view-highlight-face' controls the face that is used
 418 for highlighting the match that is found."
 419   (interactive "p")
 420   (View-search-regexp-backward n view-last-regexp))
 421
 422 (defun View-back-to-mark (&optional ignore)
 423   "Return to last mark set in View mode, else beginning of file.
 424 Displays line at center of window.  Pops mark ring so successive
 425 invocations return to earlier marks."
 426   (interactive)
 427   (goto-char (or (mark t) (point-min)))
 428   (pop-mark)
 429   (recenter (/ (view-window-size) 2)))
 430
 431 (defun view-search (times regexp)
 432   (setq view-last-regexp regexp)
 433   (let (where)
 434     (save-excursion
 435       (move-to-window-line (if (< times 0) 0 -1))
 436       (if (re-search-forward regexp nil t times)
 437           (setq where (point))))
 438     (if where
 439         (progn
 440           (push-mark)
 441           (goto-char where)
 442           (if view-overlay
 443               (move-overlay view-overlay (match-beginning 0) (match-end 0))
 444             (setq view-overlay
 445                   (make-overlay (match-beginning 0) (match-end 0))))
 446           (overlay-put view-overlay 'face view-highlight-face)
 447           (beginning-of-line)
 448           (recenter (/ (view-window-size) 2)))
 449       (message "Can't find occurrence %d of %s" times regexp)
 450       (sit-for 4))))
 451
 452 \f
 453 (provide 'view)
 454
 455 ;;; view.el ends here