lisp/help-macro.el

   1 ;;; help-macro.el --- makes command line help such as help-for-help
   2
   3 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Lynn Slater <lrs@indetech.com>
   7 ;; Maintainer: FSF
   8 ;; Created: Mon Oct  1 11:42:39 1990
   9 ;; Adapted-By: ESR
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This file supplies the macro make-help-screen which constructs
  29 ;; single character dispatching with browsable help such as that provided
  30 ;; by help-for-help. This can be used to make many modes easier to use; for
  31 ;; example, the GNU Emacs Empire Tool uses this for every "nested" mode map
  32 ;; called from the main mode map.
  33
  34 ;;       The name of this package was changed from help-screen.el to
  35 ;; help-macro.el in order to fit in a 14-character limit.
  36
  37 ;;-> ***********************  Example of use *********************************
  38
  39 ;;->(make-help-screen help-for-empire-redistribute-map
  40 ;;->              "c:civ m:mil p:population f:food ?"
  41 ;;->              "You have discovered the GEET redistribution commands
  42 ;;->   From here, you can use the following options:
  43 ;;->
  44 ;;->c   Redistribute civs from overfull sectors into connected underfull ones
  45 ;;->      The functions typically named by empire-ideal-civ-fcn control
  46 ;;->          based in part on empire-sector-civ-threshold
  47 ;;->m   Redistribute military using levels given by empire-ideal-mil-fcn
  48 ;;->p   Redistribute excess population to highways for max pop growth
  49 ;;->      Excess is any sector so full babies will not be born.
  50 ;;->f   Even out food on highways to highway min and leave levels
  51 ;;->      This is good to pump max food to all warehouses/dist pts
  52 ;;->
  53 ;;->
  54 ;;->Use \\[help-for-empire-redistribute-map] for help on redistribution.
  55 ;;->Use \\[help-for-empire-extract-map] for help on data extraction.
  56 ;;->Please use \\[describe-key] to find out more about any of the other keys."
  57 ;;->              empire-shell-redistribute-map)
  58
  59 ;;->  (define-key c-mp "\C-h" 'help-for-empire-redistribute-map)
  60 ;;->  (define-key c-mp help-character 'help-for-empire-redistribute-map)
  61
  62 ;;; Change Log:
  63 ;;
  64 ;; 22-Jan-1991          Lynn Slater x2048
  65 ;;    Last Modified: Mon Oct  1 11:43:52 1990 #3 (Lynn Slater)
  66 ;;    documented better
  67
  68 ;;; Code:
  69
  70 (require 'backquote)
  71
  72 ;;;###autoload
  73 (defcustom three-step-help nil
  74   "*Non-nil means give more info about Help command in three steps.
  75 The three steps are simple prompt, prompt with all options,
  76 and window listing and describing the options.
  77 A value of nil means skip the middle step, so that
  78 \\[help-command] \\[help-command] gives the window that lists the options."
  79   :type 'boolean
  80   :group 'help)
  81
  82 (defmacro make-help-screen (fname help-line help-text helped-map)
  83   "Construct help-menu function name FNAME.
  84 When invoked, FNAME shows HELP-LINE and reads a command using HELPED-MAP.
  85 If the command is the help character, FNAME displays HELP-TEXT
  86 and continues trying to read a command using HELPED-MAP.
  87 If HELP-TEXT contains the sequence `%THIS-KEY%', that is replaced
  88 with the key sequence that invoked FNAME.
  89 When FNAME finally does get a command, it executes that command
  90 and then returns."
  91  (let ((doc-fn (intern (concat (symbol-name fname) "-doc"))))
  92   `(progn
  93     (defun ,doc-fn () ,help-text)
  94     (defun ,fname ()
  95            "Help command."
  96            (interactive)
  97            (let ((line-prompt
  98                   (substitute-command-keys ,help-line)))
  99              (if three-step-help
 100                  (message "%s" line-prompt))
 101              (let* ((help-screen (documentation (quote ,doc-fn)))
 102                     ;; We bind overriding-local-map for very small
 103                     ;; sections, *excluding* where we switch buffers
 104                     ;; and where we execute the chosen help command.
 105                     (local-map (make-sparse-keymap))
 106                     (minor-mode-map-alist nil)
 107                     (prev-frame (selected-frame))
 108                     config new-frame key char)
 109                (if (string-match "%THIS-KEY%" help-screen)
 110                    (setq help-screen
 111                          (replace-match (key-description (substring (this-command-keys) 0 -1))
 112                                         t t help-screen)))
 113                (unwind-protect
 114                    (progn
 115                      (setcdr local-map ,helped-map)
 116                      (define-key local-map [t] 'undefined)
 117                      ;; Make the scroll bar keep working normally.
 118                      (define-key local-map [vertical-scroll-bar]
 119                        (lookup-key global-map [vertical-scroll-bar]))
 120                      (if three-step-help
 121                          (progn
 122                            (setq key (let ((overriding-local-map local-map))
 123                                        (read-key-sequence nil)))
 124                            ;; Make the HELP key translate to C-h.
 125                            (if (lookup-key function-key-map key)
 126                                (setq key (lookup-key function-key-map key)))
 127                            (setq char (aref key 0)))
 128                        (setq char ??))
 129                      (if (or (eq char ??) (eq char help-char)
 130                              (memq char help-event-list))
 131                          (progn
 132                            (setq config (current-window-configuration))
 133                            (switch-to-buffer-other-window "*Help*")
 134                            (and (fboundp 'make-frame)
 135                                 (not (eq (window-frame (selected-window))
 136                                          prev-frame))
 137                                 (setq new-frame (window-frame (selected-window))
 138                                       config nil))
 139                            (setq buffer-read-only nil)
 140                            (let ((inhibit-read-only t))
 141                              (erase-buffer)
 142                              (insert help-screen))
 143                            (help-mode)
 144                            (goto-char (point-min))
 145                            (while (or (memq char (append help-event-list
 146                                                          (cons help-char '(?? ?\C-v ?\s ?\177 delete backspace vertical-scroll-bar ?\M-v))))
 147                                       (eq (car-safe char) 'switch-frame)
 148                                       (equal key "\M-v"))
 149                              (condition-case nil
 150                                  (progn
 151                                    (if (eq (car-safe char) 'switch-frame)
 152                                        (handle-switch-frame char))
 153                                    (if (memq char '(?\C-v ?\s))
 154                                        (scroll-up))
 155                                    (if (or (memq char '(?\177 ?\M-v
 156                                                         delete backspace))
 157                                            (equal key "\M-v"))
 158                                        (scroll-down)))
 159                                (error nil))
 160                              (let ((cursor-in-echo-area t)
 161                                    (overriding-local-map local-map))
 162                                (setq key (read-key-sequence
 163                                           (format "Type one of the options listed%s: "
 164                                                   (if (pos-visible-in-window-p
 165                                                        (point-max))
 166                                                       "" ", or SPACE or DEL to scroll")))
 167                                      char (aref key 0)))
 168
 169                              ;; If this is a scroll bar command, just run it.
 170                              (when (eq char 'vertical-scroll-bar)
 171                                (command-execute (lookup-key local-map key) nil key)))))
 172                      ;; We don't need the prompt any more.
 173                      (message "")
 174                      ;; Mouse clicks are not part of the help feature,
 175                      ;; so reexecute them in the standard environment.
 176                      (if (listp char)
 177                          (setq unread-command-events
 178                                (cons char unread-command-events)
 179                                config nil)
 180                        (let ((defn (lookup-key local-map key)))
 181                          (if defn
 182                              (progn
 183                                (if config
 184                                    (progn
 185                                      (set-window-configuration config)
 186                                      (setq config nil)))
 187                                (if new-frame
 188                                    (progn (iconify-frame new-frame)
 189                                           (setq new-frame nil)))
 190                                (call-interactively defn))
 191                            (ding)))))
 192                  (if new-frame (iconify-frame new-frame))
 193                  (if config
 194                      (set-window-configuration config))))))
 195      )))
 196
 197 (provide 'help-macro)
 198
 199 ;; arch-tag: 59fee949-1686-485a-8a05-83418073e257
 200 ;;; help-macro.el ends here