lisp/vc-cvs.el

   1 ;;; vc-cvs.el --- non-resident support for CVS version-control
   2
   3 ;; Copyright (C) 1995, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author:      FSF (see vc.el for full credits)
   7 ;; Maintainer:  Andre Spiegel <spiegel@gnu.org>
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl) (require 'vc))
  29
  30 ;; Clear up the cache to force vc-call to check again and discover
  31 ;; new functions when we reload this file.
  32 (put 'CVS 'vc-functions nil)
  33
  34 ;;; Properties of the backend.
  35
  36 (defun vc-cvs-revision-granularity () 'file)
  37
  38 (defun vc-cvs-checkout-model (files)
  39   "CVS-specific version of `vc-checkout-model'."
  40   (if (getenv "CVSREAD")
  41       'announce
  42     (let* ((file (if (consp files) (car files) files))
  43            (attrib (file-attributes file)))
  44       (or (vc-file-getprop file 'vc-checkout-model)
  45           (vc-file-setprop
  46            file 'vc-checkout-model
  47            (if (and attrib ;; don't check further if FILE doesn't exist
  48                     ;; If the file is not writable (despite CVSREAD being
  49                     ;; undefined), this is probably because the file is being
  50                     ;; "watched" by other developers.
  51                     ;; (If vc-mistrust-permissions was t, we actually shouldn't
  52                     ;; trust this, but there is no other way to learn this from
  53                     ;; CVS at the moment (version 1.9).)
  54                     (string-match "r-..-..-." (nth 8 attrib)))
  55                'announce
  56              'implicit))))))
  57
  58 ;;;
  59 ;;; Customization options
  60 ;;;
  61
  62 (defcustom vc-cvs-global-switches nil
  63   "Global switches to pass to any CVS command."
  64   :type '(choice (const :tag "None" nil)
  65                  (string :tag "Argument String")
  66                  (repeat :tag "Argument List"
  67                          :value ("")
  68                          string))
  69   :version "22.1"
  70   :group 'vc)
  71
  72 (defcustom vc-cvs-register-switches nil
  73   "Switches for registering a file into CVS.
  74 A string or list of strings passed to the checkin program by
  75 \\[vc-register].  If nil, use the value of `vc-register-switches'.
  76 If t, use no switches."
  77   :type '(choice (const :tag "Unspecified" nil)
  78                  (const :tag "None" t)
  79                  (string :tag "Argument String")
  80                  (repeat :tag "Argument List" :value ("") string))
  81   :version "21.1"
  82   :group 'vc)
  83
  84 (defcustom vc-cvs-diff-switches nil
  85   "String or list of strings specifying switches for CVS diff under VC.
  86 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  87   :type '(choice (const :tag "Unspecified" nil)
  88                  (const :tag "None" t)
  89                  (string :tag "Argument String")
  90                  (repeat :tag "Argument List" :value ("") string))
  91   :version "21.1"
  92   :group 'vc)
  93
  94 (defcustom vc-cvs-header (or (cdr (assoc 'CVS vc-header-alist)) '("\$Id\$"))
  95   "Header keywords to be inserted by `vc-insert-headers'."
  96   :version "21.1"
  97   :type '(repeat string)
  98   :group 'vc)
  99
 100 (defcustom vc-cvs-use-edit t
 101   "Non-nil means to use `cvs edit' to \"check out\" a file.
 102 This is only meaningful if you don't use the implicit checkout model
 103 \(i.e. if you have $CVSREAD set)."
 104   :type 'boolean
 105   :version "21.1"
 106   :group 'vc)
 107
 108 (defcustom vc-cvs-stay-local 'only-file
 109   "Non-nil means use local operations when possible for remote repositories.
 110 This avoids slow queries over the network and instead uses heuristics
 111 and past information to determine the current status of a file.
 112
 113 If value is the symbol `only-file' `vc-dir' will connect to the
 114 server, but heuristics will be used to determine the status for
 115 all other VC operations.
 116
 117 The value can also be a regular expression or list of regular
 118 expressions to match against the host name of a repository; then VC
 119 only stays local for hosts that match it.  Alternatively, the value
 120 can be a list of regular expressions where the first element is the
 121 symbol `except'; then VC always stays local except for hosts matched
 122 by these regular expressions."
 123   :type '(choice (const :tag "Always stay local" t)
 124                  (const :tag "Only for file operations" only-file)
 125                  (const :tag "Don't stay local" nil)
 126                  (list :format "\nExamine hostname and %v"
 127                        :tag "Examine hostname ..."
 128                        (set :format "%v" :inline t
 129                             (const :format "%t" :tag "don't" except))
 130                        (regexp :format " stay local,\n%t: %v"
 131                                :tag "if it matches")
 132                        (repeat :format "%v%i\n" :inline t (regexp :tag "or"))))
 133   :version "23.1"
 134   :group 'vc)
 135
 136 (defcustom vc-cvs-sticky-date-format-string "%c"
 137   "Format string for mode-line display of sticky date.
 138 Format is according to `format-time-string'.  Only used if
 139 `vc-cvs-sticky-tag-display' is t."
 140   :type '(string)
 141   :version "22.1"
 142   :group 'vc)
 143
 144 (defcustom vc-cvs-sticky-tag-display t
 145   "Specify the mode-line display of sticky tags.
 146 Value t means default display, nil means no display at all.  If the
 147 value is a function or macro, it is called with the sticky tag and
 148 its' type as parameters, in that order.  TYPE can have three different
 149 values: `symbolic-name' (TAG is a string), `revision-number' (TAG is a
 150 string) and `date' (TAG is a date as returned by `encode-time').  The
 151 return value of the function or macro will be displayed as a string.
 152
 153 Here's an example that will display the formatted date for sticky
 154 dates and the word \"Sticky\" for sticky tag names and revisions.
 155
 156   (lambda (tag type)
 157     (cond ((eq type 'date) (format-time-string
 158                               vc-cvs-sticky-date-format-string tag))
 159           ((eq type 'revision-number) \"Sticky\")
 160           ((eq type 'symbolic-name) \"Sticky\")))
 161
 162 Here's an example that will abbreviate to the first character only,
 163 any text before the first occurrence of `-' for sticky symbolic tags.
 164 If the sticky tag is a revision number, the word \"Sticky\" is
 165 displayed.  Date and time is displayed for sticky dates.
 166
 167    (lambda (tag type)
 168      (cond ((eq type 'date) (format-time-string \"%Y%m%d %H:%M\" tag))
 169            ((eq type 'revision-number) \"Sticky\")
 170            ((eq type 'symbolic-name)
 171             (condition-case nil
 172                 (progn
 173                   (string-match \"\\\\([^-]*\\\\)\\\\(.*\\\\)\" tag)
 174                   (concat (substring (match-string 1 tag) 0 1) \":\"
 175                           (substring (match-string 2 tag) 1 nil)))
 176               (error tag)))))       ; Fall-back to given tag name.
 177
 178 See also variable `vc-cvs-sticky-date-format-string'."
 179   :type '(choice boolean function)
 180   :version "22.1"
 181   :group 'vc)
 182
 183 ;;;
 184 ;;; Internal variables
 185 ;;;
 186
 187
 188 ;;;
 189 ;;; State-querying functions
 190 ;;;
 191
 192 ;;;###autoload (defun vc-cvs-registered (f)
 193 ;;;###autoload   (when (file-readable-p (expand-file-name
 194 ;;;###autoload                    "CVS/Entries" (file-name-directory f)))
 195 ;;;###autoload       (load "vc-cvs")
 196 ;;;###autoload       (vc-cvs-registered f)))
 197
 198 (defun vc-cvs-registered (file)
 199   "Check if FILE is CVS registered."
 200   (let ((dirname (or (file-name-directory file) ""))
 201         (basename (file-name-nondirectory file))
 202         ;; make sure that the file name is searched case-sensitively
 203         (case-fold-search nil))
 204     (if (file-readable-p (expand-file-name "CVS/Entries" dirname))
 205         (or (string= basename "")
 206             (with-temp-buffer
 207               (vc-cvs-get-entries dirname)
 208               (goto-char (point-min))
 209               (cond ((re-search-forward
 210                       (concat "^/" (regexp-quote basename) "/[^/]") nil t)
 211                      (beginning-of-line)
 212                      (vc-cvs-parse-entry file)
 213                      t)
 214                     (t nil))))
 215       nil)))
 216
 217 (defun vc-cvs-state (file)
 218   "CVS-specific version of `vc-state'."
 219   (if (vc-stay-local-p file 'CVS)
 220       (let ((state (vc-file-getprop file 'vc-state)))
 221         ;; If we should stay local, use the heuristic but only if
 222         ;; we don't have a more precise state already available.
 223         (if (memq state '(up-to-date edited nil))
 224             (vc-cvs-state-heuristic file)
 225           state))
 226     (with-temp-buffer
 227       (cd (file-name-directory file))
 228       (let (process-file-side-effects)
 229         (vc-cvs-command t 0 file "status"))
 230       (vc-cvs-parse-status t))))
 231
 232 (defun vc-cvs-state-heuristic (file)
 233   "CVS-specific state heuristic."
 234   ;; If the file has not changed since checkout, consider it `up-to-date'.
 235   ;; Otherwise consider it `edited'.
 236   (let ((checkout-time (vc-file-getprop file 'vc-checkout-time))
 237         (lastmod (nth 5 (file-attributes file))))
 238     (cond
 239      ((equal checkout-time lastmod) 'up-to-date)
 240      ((string= (vc-working-revision file) "0") 'added)
 241      ((null checkout-time) 'unregistered)
 242      (t 'edited))))
 243
 244 (defun vc-cvs-working-revision (file)
 245   "CVS-specific version of `vc-working-revision'."
 246   ;; There is no need to consult RCS headers under CVS, because we
 247   ;; get the workfile version for free when we recognize that a file
 248   ;; is registered in CVS.
 249   (vc-cvs-registered file)
 250   (vc-file-getprop file 'vc-working-revision))
 251
 252 (defun vc-cvs-mode-line-string (file)
 253   "Return string for placement into the modeline for FILE.
 254 Compared to the default implementation, this function does two things:
 255 Handle the special case of a CVS file that is added but not yet
 256 committed and support display of sticky tags."
 257   (let* ((sticky-tag (vc-file-getprop file 'vc-cvs-sticky-tag))
 258          help-echo
 259          (string
 260           (let ((def-ml (vc-default-mode-line-string 'CVS file)))
 261             (setq help-echo
 262                   (get-text-property 0 'help-echo def-ml))
 263             def-ml)))
 264     (propertize
 265      (if (zerop (length sticky-tag))
 266          string
 267        (setq help-echo (format "%s on the '%s' branch"
 268                                help-echo sticky-tag))
 269        (concat string "[" sticky-tag "]"))
 270      'help-echo help-echo)))
 271
 272
 273 ;;;
 274 ;;; State-changing functions
 275 ;;;
 276
 277 (defun vc-cvs-register (files &optional rev comment)
 278   "Register FILES into the CVS version-control system.
 279 COMMENT can be used to provide an initial description of FILES.
 280 Passes either `vc-cvs-register-switches' or `vc-register-switches'
 281 to the CVS command."
 282   ;; Register the directories if needed.
 283   (let (dirs)
 284     (dolist (file files)
 285       (and (not (vc-cvs-responsible-p file))
 286            (vc-cvs-could-register file)
 287            (push (directory-file-name (file-name-directory file)) dirs)))
 288     (if dirs (vc-cvs-register dirs)))
 289   (apply 'vc-cvs-command nil 0 files
 290          "add"
 291          (and comment (string-match "[^\t\n ]" comment)
 292               (concat "-m" comment))
 293          (vc-switches 'CVS 'register)))
 294
 295 (defun vc-cvs-responsible-p (file)
 296   "Return non-nil if CVS thinks it is responsible for FILE."
 297   (file-directory-p (expand-file-name "CVS"
 298                                       (if (file-directory-p file)
 299                                           file
 300                                         (file-name-directory file)))))
 301
 302 (defun vc-cvs-could-register (file)
 303   "Return non-nil if FILE could be registered in CVS.
 304 This is only possible if CVS is managing FILE's directory or one of
 305 its parents."
 306   (let ((dir file))
 307     (while (and (stringp dir)
 308                 (not (equal dir (setq dir (file-name-directory dir))))
 309                 dir)
 310       (setq dir (if (file-exists-p
 311                      (expand-file-name "CVS/Entries" dir))
 312                     t
 313                   (directory-file-name dir))))
 314     (eq dir t)))
 315
 316 (defun vc-cvs-checkin (files rev comment)
 317   "CVS-specific version of `vc-backend-checkin'."
 318   (unless (or (not rev) (vc-cvs-valid-revision-number-p rev))
 319     (if (not (vc-cvs-valid-symbolic-tag-name-p rev))
 320         (error "%s is not a valid symbolic tag name" rev)
 321       ;; If the input revison is a valid symbolic tag name, we create it
 322       ;; as a branch, commit and switch to it.
 323       (apply 'vc-cvs-command nil 0 files "tag" "-b" (list rev))
 324       (apply 'vc-cvs-command nil 0 files "update" "-r" (list rev))
 325       (mapc (lambda (file) (vc-file-setprop file 'vc-cvs-sticky-tag rev))
 326             files)))
 327   (let ((status (apply 'vc-cvs-command nil 1 files
 328                        "ci" (if rev (concat "-r" rev))
 329                        (concat "-m" comment)
 330                        (vc-switches 'CVS 'checkin))))
 331     (set-buffer "*vc*")
 332     (goto-char (point-min))
 333     (when (not (zerop status))
 334       ;; Check checkin problem.
 335       (cond
 336        ((re-search-forward "Up-to-date check failed" nil t)
 337         (mapc (lambda (file) (vc-file-setprop file 'vc-state 'needs-merge))
 338               files)
 339         (error "%s" (substitute-command-keys
 340                 (concat "Up-to-date check failed: "
 341                         "type \\[vc-next-action] to merge in changes"))))
 342        (t
 343         (pop-to-buffer (current-buffer))
 344         (goto-char (point-min))
 345         (shrink-window-if-larger-than-buffer)
 346         (error "Check-in failed"))))
 347     ;; Single-file commit?  Then update the revision by parsing the buffer.
 348     ;; Otherwise we can't necessarily tell what goes with what; clear
 349     ;; its properties so they have to be refetched.
 350     (if (= (length files) 1)
 351         (vc-file-setprop
 352          (car files) 'vc-working-revision
 353          (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 354       (mapc 'vc-file-clearprops files))
 355     ;; Anyway, forget the checkout model of the file, because we might have
 356     ;; guessed wrong when we found the file.  After commit, we can
 357     ;; tell it from the permissions of the file (see
 358     ;; vc-cvs-checkout-model).
 359     (mapc (lambda (file) (vc-file-setprop file 'vc-checkout-model nil))
 360           files)
 361
 362     ;; if this was an explicit check-in (does not include creation of
 363     ;; a branch), remove the sticky tag.
 364     (if (and rev (not (vc-cvs-valid-symbolic-tag-name-p rev)))
 365         (vc-cvs-command nil 0 files "update" "-A"))))
 366
 367 (defun vc-cvs-find-revision (file rev buffer)
 368   (apply 'vc-cvs-command
 369          buffer 0 file
 370          "-Q"                           ; suppress diagnostic output
 371          "update"
 372          (and rev (not (string= rev ""))
 373               (concat "-r" rev))
 374          "-p"
 375          (vc-switches 'CVS 'checkout)))
 376
 377 (defun vc-cvs-checkout (file &optional editable rev)
 378   "Checkout a revision of FILE into the working area.
 379 EDITABLE non-nil means that the file should be writable.
 380 REV is the revision to check out."
 381   (message "Checking out %s..." file)
 382   ;; Change buffers to get local value of vc-checkout-switches.
 383   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 384     (if (and (file-exists-p file) (not rev))
 385         ;; If no revision was specified, just make the file writable
 386         ;; if necessary (using `cvs-edit' if requested).
 387         (and editable (not (eq (vc-cvs-checkout-model (list file)) 'implicit))
 388              (if vc-cvs-use-edit
 389                  (vc-cvs-command nil 0 file "edit")
 390                (set-file-modes file (logior (file-modes file) 128))
 391                (if (equal file buffer-file-name) (toggle-read-only -1))))
 392       ;; Check out a particular revision (or recreate the file).
 393       (vc-file-setprop file 'vc-working-revision nil)
 394       (apply 'vc-cvs-command nil 0 file
 395              (and editable "-w")
 396              "update"
 397              (when rev
 398                (unless (eq rev t)
 399                  ;; default for verbose checkout: clear the
 400                  ;; sticky tag so that the actual update will
 401                  ;; get the head of the trunk
 402                  (if (string= rev "")
 403                      "-A"
 404                    (concat "-r" rev))))
 405              (vc-switches 'CVS 'checkout)))
 406     (vc-mode-line file 'CVS))
 407   (message "Checking out %s...done" file))
 408
 409 (defun vc-cvs-delete-file (file)
 410   (vc-cvs-command nil 0 file "remove" "-f"))
 411
 412 (defun vc-cvs-revert (file &optional contents-done)
 413   "Revert FILE to the working revision on which it was based."
 414   (vc-default-revert 'CVS file contents-done)
 415   (unless (eq (vc-cvs-checkout-model (list file)) 'implicit)
 416     (if vc-cvs-use-edit
 417         (vc-cvs-command nil 0 file "unedit")
 418       ;; Make the file read-only by switching off all w-bits
 419       (set-file-modes file (logand (file-modes file) 3950)))))
 420
 421 (defun vc-cvs-merge (file first-revision &optional second-revision)
 422   "Merge changes into current working copy of FILE.
 423 The changes are between FIRST-REVISION and SECOND-REVISION."
 424   (vc-cvs-command nil 0 file
 425                  "update" "-kk"
 426                  (concat "-j" first-revision)
 427                  (concat "-j" second-revision))
 428   (vc-file-setprop file 'vc-state 'edited)
 429   (with-current-buffer (get-buffer "*vc*")
 430     (goto-char (point-min))
 431     (if (re-search-forward "conflicts during merge" nil t)
 432         (progn
 433           (vc-file-setprop file 'vc-state 'conflict)
 434           ;; signal error
 435           1)
 436       (vc-file-setprop file 'vc-state 'edited)
 437       ;; signal success
 438       0)))
 439
 440 (defun vc-cvs-merge-news (file)
 441   "Merge in any new changes made to FILE."
 442   (message "Merging changes into %s..." file)
 443   ;; (vc-file-setprop file 'vc-working-revision nil)
 444   (vc-file-setprop file 'vc-checkout-time 0)
 445   (vc-cvs-command nil nil file "update")
 446   ;; Analyze the merge result reported by CVS, and set
 447   ;; file properties accordingly.
 448   (with-current-buffer (get-buffer "*vc*")
 449     (goto-char (point-min))
 450     ;; get new working revision
 451     (if (re-search-forward
 452          "^Merging differences between [0-9.]* and \\([0-9.]*\\) into" nil t)
 453         (vc-file-setprop file 'vc-working-revision (match-string 1))
 454       (vc-file-setprop file 'vc-working-revision nil))
 455     ;; get file status
 456     (prog1
 457         (if (eq (buffer-size) 0)
 458             0 ;; there were no news; indicate success
 459           (if (re-search-forward
 460                (concat "^\\([CMUP] \\)?"
 461                        (regexp-quote
 462                         (substring file (length (expand-file-name
 463                                                  "." default-directory))))
 464                        "\\( already contains the differences between \\)?")
 465                nil t)
 466               (cond
 467                ;; Merge successful, we are in sync with repository now
 468                ((or (match-string 2)
 469                     (string= (match-string 1) "U ")
 470                     (string= (match-string 1) "P "))
 471                 (vc-file-setprop file 'vc-state 'up-to-date)
 472                 (vc-file-setprop file 'vc-checkout-time
 473                                  (nth 5 (file-attributes file)))
 474                 0);; indicate success to the caller
 475                ;; Merge successful, but our own changes are still in the file
 476                ((string= (match-string 1) "M ")
 477                 (vc-file-setprop file 'vc-state 'edited)
 478                 0);; indicate success to the caller
 479                ;; Conflicts detected!
 480                (t
 481                 (vc-file-setprop file 'vc-state 'conflict)
 482                 1);; signal the error to the caller
 483                )
 484             (pop-to-buffer "*vc*")
 485             (error "Couldn't analyze cvs update result")))
 486       (message "Merging changes into %s...done" file))))
 487
 488 (defun vc-cvs-modify-change-comment (files rev comment)
 489   "Modify the change comments for FILES on a specified REV.
 490 Will fail unless you have administrative privileges on the repo."
 491   (vc-cvs-command nil 0 files "admin" (concat "-m" rev ":" comment)))
 492
 493 ;;;
 494 ;;; History functions
 495 ;;;
 496
 497 (declare-function vc-rcs-print-log-cleanup "vc-rcs" ())
 498
 499 (defun vc-cvs-print-log (files &optional buffer)
 500   "Get change logs associated with FILES."
 501   (require 'vc-rcs)
 502   ;; It's just the catenation of the individual logs.
 503   (vc-cvs-command
 504    buffer
 505    (if (vc-stay-local-p files 'CVS) 'async 0)
 506    files "log")
 507   (with-current-buffer buffer
 508     (vc-exec-after (vc-rcs-print-log-cleanup))))
 509
 510 (defun vc-cvs-comment-history (file)
 511   "Get comment history of a file."
 512   (vc-call-backend 'RCS 'comment-history file))
 513
 514 (defun vc-cvs-diff (files &optional oldvers newvers buffer)
 515   "Get a difference report using CVS between two revisions of FILE."
 516   (let* (process-file-side-effects
 517          (async (and (not vc-disable-async-diff)
 518                      (vc-stay-local-p files 'CVS)))
 519          (invoke-cvs-diff-list nil)
 520          status)
 521     ;; Look through the file list and see if any files have backups
 522     ;; that can be used to do a plain "diff" instead of "cvs diff".
 523     (dolist (file files)
 524       (let ((ov oldvers)
 525             (nv newvers))
 526         (when (or (not ov) (string-equal ov ""))
 527           (setq ov (vc-working-revision file)))
 528         (when (string-equal nv "")
 529           (setq nv nil))
 530         (let ((file-oldvers (vc-version-backup-file file ov))
 531               (file-newvers (if (not nv)
 532                                 file
 533                               (vc-version-backup-file file nv)))
 534               (coding-system-for-read (vc-coding-system-for-diff file)))
 535           (if (and file-oldvers file-newvers)
 536               (progn
 537                 ;; This used to append diff-switches and vc-diff-switches,
 538                 ;; which was consistent with the vc-diff-switches doc at that
 539                 ;; time, but not with the actual behavior of any other VC diff.
 540                 (apply 'vc-do-command (or buffer "*vc-diff*") 1 "diff" nil
 541                        ;; Not a CVS diff, does not use vc-cvs-diff-switches.
 542                        (append (vc-switches nil 'diff)
 543                                (list (file-relative-name file-oldvers)
 544                                      (file-relative-name file-newvers))))
 545                 (setq status 0))
 546             (push file invoke-cvs-diff-list)))))
 547     (when invoke-cvs-diff-list
 548       (setq status (apply 'vc-cvs-command (or buffer "*vc-diff*")
 549                           (if async 'async 1)
 550                           invoke-cvs-diff-list "diff"
 551                           (and oldvers (concat "-r" oldvers))
 552                           (and newvers (concat "-r" newvers))
 553                           (vc-switches 'CVS 'diff))))
 554     (if async 1 status))) ; async diff, pessimistic assumption
 555
 556 (defconst vc-cvs-annotate-first-line-re "^[0-9]")
 557
 558 (defun vc-cvs-annotate-process-filter (process string)
 559   (setq string (concat (process-get process 'output) string))
 560   (if (not (string-match vc-cvs-annotate-first-line-re string))
 561       ;; Still waiting for the first real line.
 562       (process-put process 'output string)
 563     (let ((vc-filter (process-get process 'vc-filter)))
 564       (set-process-filter process vc-filter)
 565       (funcall vc-filter process (substring string (match-beginning 0))))))
 566
 567 (defun vc-cvs-annotate-command (file buffer &optional revision)
 568   "Execute \"cvs annotate\" on FILE, inserting the contents in BUFFER.
 569 Optional arg REVISION is a revision to annotate from."
 570   (vc-cvs-command buffer
 571                   (if (vc-stay-local-p file 'CVS)
 572                       'async 0)
 573                   file "annotate"
 574                   (if revision (concat "-r" revision)))
 575   ;; Strip the leading few lines.
 576   (let ((proc (get-buffer-process buffer)))
 577     (if proc
 578         ;; If running asynchronously, use a process filter.
 579         (progn
 580           (process-put proc 'vc-filter (process-filter proc))
 581           (set-process-filter proc 'vc-cvs-annotate-process-filter))
 582       (with-current-buffer buffer
 583         (goto-char (point-min))
 584         (re-search-forward vc-cvs-annotate-first-line-re)
 585         (delete-region (point-min) (1- (point)))))))
 586
 587 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 588
 589 (defun vc-cvs-annotate-current-time ()
 590   "Return the current time, based at midnight of the current day, and
 591 encoded as fractional days."
 592   (vc-annotate-convert-time
 593    (apply 'encode-time 0 0 0 (nthcdr 3 (decode-time (current-time))))))
 594
 595 (defun vc-cvs-annotate-time ()
 596   "Return the time of the next annotation (as fraction of days)
 597 systime, or nil if there is none."
 598   (let* ((bol (point))
 599          (cache (get-text-property bol 'vc-cvs-annotate-time))
 600          (inhibit-read-only t)
 601          (inhibit-modification-hooks t))
 602     (cond
 603      (cache)
 604      ((looking-at
 605        "^\\S-+\\s-+\\S-+\\s-+\\([0-9]+\\)-\\(\\sw+\\)-\\([0-9]+\\)): ")
 606       (let ((day (string-to-number (match-string 1)))
 607             (month (cdr (assq (intern (match-string 2))
 608                               '((Jan .  1) (Feb .  2) (Mar .  3)
 609                                 (Apr .  4) (May .  5) (Jun .  6)
 610                                 (Jul .  7) (Aug .  8) (Sep .  9)
 611                                 (Oct . 10) (Nov . 11) (Dec . 12)))))
 612             (year (let ((tmp (string-to-number (match-string 3))))
 613                     ;; Years 0..68 are 2000..2068.
 614                     ;; Years 69..99 are 1969..1999.
 615                     (+ (cond ((> 69 tmp) 2000)
 616                              ((> 100 tmp) 1900)
 617                              (t 0))
 618                        tmp))))
 619         (put-text-property
 620          bol (1+ bol) 'vc-cvs-annotate-time
 621          (setq cache (cons
 622                       ;; Position at end makes for nicer overlay result.
 623                       ;; Don't put actual buffer pos here, but only relative
 624                       ;; distance, so we don't ever move backward in the
 625                       ;; goto-char below, even if the text is moved.
 626                       (- (match-end 0) (match-beginning 0))
 627                       (vc-annotate-convert-time
 628                        (encode-time 0 0 0 day month year))))))))
 629     (when cache
 630       (goto-char (+ bol (car cache)))   ; Fontify from here to eol.
 631       (cdr cache))))                    ; days (float)
 632
 633 (defun vc-cvs-annotate-extract-revision-at-line ()
 634   (save-excursion
 635     (beginning-of-line)
 636     (if (re-search-forward "^\\([0-9]+\\.[0-9]+\\(\\.[0-9]+\\)*\\) +("
 637                            (line-end-position) t)
 638         (match-string-no-properties 1)
 639       nil)))
 640
 641 (defun vc-cvs-previous-revision (file rev)
 642   (vc-call-backend 'RCS 'previous-revision file rev))
 643
 644 (defun vc-cvs-next-revision (file rev)
 645   (vc-call-backend 'RCS 'next-revision file rev))
 646
 647 ;; FIXME: This should probably be replaced by code using cvs2cl.
 648 (defun vc-cvs-update-changelog (files)
 649   (vc-call-backend 'RCS 'update-changelog files))
 650
 651 ;;;
 652 ;;; Tag system
 653 ;;;
 654
 655 (defun vc-cvs-create-tag (dir name branchp)
 656   "Assign to DIR's current revision a given NAME.
 657 If BRANCHP is non-nil, the name is created as a branch (and the current
 658 workspace is immediately moved to that new branch)."
 659   (vc-cvs-command nil 0 dir "tag" "-c" (if branchp "-b") name)
 660   (when branchp (vc-cvs-command nil 0 dir "update" "-r" name)))
 661
 662 (defun vc-cvs-retrieve-tag (dir name update)
 663   "Retrieve a tag at and below DIR.
 664 NAME is the name of the tag; if it is empty, do a `cvs update'.
 665 If UPDATE is non-nil, then update (resynch) any affected buffers."
 666   (with-current-buffer (get-buffer-create "*vc*")
 667     (let ((default-directory dir)
 668           (sticky-tag))
 669       (erase-buffer)
 670       (if (or (not name) (string= name ""))
 671           (vc-cvs-command t 0 nil "update")
 672         (vc-cvs-command t 0 nil "update" "-r" name)
 673         (setq sticky-tag name))
 674       (when update
 675         (goto-char (point-min))
 676         (while (not (eobp))
 677           (if (looking-at "\\([CMUP]\\) \\(.*\\)")
 678               (let* ((file (expand-file-name (match-string 2) dir))
 679                      (state (match-string 1))
 680                      (buffer (find-buffer-visiting file)))
 681                 (when buffer
 682                   (cond
 683                    ((or (string= state "U")
 684                         (string= state "P"))
 685                     (vc-file-setprop file 'vc-state 'up-to-date)
 686                     (vc-file-setprop file 'vc-working-revision nil)
 687                     (vc-file-setprop file 'vc-checkout-time
 688                                      (nth 5 (file-attributes file))))
 689                    ((or (string= state "M")
 690                         (string= state "C"))
 691                     (vc-file-setprop file 'vc-state 'edited)
 692                     (vc-file-setprop file 'vc-working-revision nil)
 693                     (vc-file-setprop file 'vc-checkout-time 0)))
 694                   (vc-file-setprop file 'vc-cvs-sticky-tag sticky-tag)
 695                   (vc-resynch-buffer file t t))))
 696           (forward-line 1))))))
 697
 698
 699 ;;;
 700 ;;; Miscellaneous
 701 ;;;
 702
 703 (defun vc-cvs-make-version-backups-p (file)
 704   "Return non-nil if version backups should be made for FILE."
 705   (vc-stay-local-p file 'CVS))
 706
 707 (defun vc-cvs-check-headers ()
 708   "Check if the current file has any headers in it."
 709   (save-excursion
 710     (goto-char (point-min))
 711     (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 712 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 713
 714
 715 ;;;
 716 ;;; Internal functions
 717 ;;;
 718
 719 (defun vc-cvs-command (buffer okstatus files &rest flags)
 720   "A wrapper around `vc-do-command' for use in vc-cvs.el.
 721 The difference to vc-do-command is that this function always invokes `cvs',
 722 and that it passes `vc-cvs-global-switches' to it before FLAGS."
 723   (apply 'vc-do-command (or buffer "*vc*") okstatus "cvs" files
 724          (if (stringp vc-cvs-global-switches)
 725              (cons vc-cvs-global-switches flags)
 726            (append vc-cvs-global-switches
 727                    flags))))
 728
 729 (defun vc-cvs-stay-local-p (file)  ;Back-compatibility.
 730   (vc-stay-local-p file 'CVS))
 731
 732 (defun vc-cvs-repository-hostname (dirname)
 733   "Hostname of the CVS server associated to workarea DIRNAME."
 734   (let ((rootname (expand-file-name "CVS/Root" dirname)))
 735     (when (file-readable-p rootname)
 736       (with-temp-buffer
 737         (let ((coding-system-for-read
 738                (or file-name-coding-system
 739                    default-file-name-coding-system)))
 740           (vc-insert-file rootname))
 741         (goto-char (point-min))
 742         (nth 2 (vc-cvs-parse-root
 743                 (buffer-substring (point)
 744                                   (line-end-position))))))))
 745
 746 (defun vc-cvs-parse-uhp (path)
 747   "parse user@host/path into (user@host /path)"
 748   (if (string-match "\\([^/]+\\)\\(/.*\\)" path)
 749       (list (match-string 1 path) (match-string 2 path))
 750       (list nil path)))
 751
 752 (defun vc-cvs-parse-root (root)
 753   "Split CVS ROOT specification string into a list of fields.
 754 A CVS root specification of the form
 755   [:METHOD:][[USER@]HOSTNAME]:?/path/to/repository
 756 is converted to a normalized record with the following structure:
 757   \(METHOD USER HOSTNAME CVS-ROOT).
 758 The default METHOD for a CVS root of the form
 759   /path/to/repository
 760 is `local'.
 761 The default METHOD for a CVS root of the form
 762   [USER@]HOSTNAME:/path/to/repository
 763 is `ext'.
 764 For an empty string, nil is returned (invalid CVS root)."
 765   ;; Split CVS root into colon separated fields (0-4).
 766   ;; The `x:' makes sure, that leading colons are not lost;
 767   ;; `HOST:/PATH' is then different from `:METHOD:/PATH'.
 768   (let* ((root-list (cdr (split-string (concat "x:" root) ":")))
 769          (len (length root-list))
 770          ;; All syntactic varieties will get a proper METHOD.
 771          (root-list
 772           (cond
 773            ((= len 0)
 774             ;; Invalid CVS root
 775             nil)
 776            ((= len 1)
 777             (let ((uhp (vc-cvs-parse-uhp (car root-list))))
 778               (cons (if (car uhp) "ext" "local") uhp)))
 779            ((= len 2)
 780             ;; [USER@]HOST:PATH => method `ext'
 781             (and (not (equal (car root-list) ""))
 782                  (cons "ext" root-list)))
 783            ((= len 3)
 784             ;; :METHOD:PATH or :METHOD:USER@HOSTNAME/PATH
 785             (cons (cadr root-list)
 786                   (vc-cvs-parse-uhp (caddr root-list))))
 787            (t
 788             ;; :METHOD:[USER@]HOST:PATH
 789             (cdr root-list)))))
 790     (if root-list
 791         (let ((method (car root-list))
 792               (uhost (or (cadr root-list) ""))
 793               (root (nth 2 root-list))
 794               user host)
 795           ;; Split USER@HOST
 796           (if (string-match "\\(.*\\)@\\(.*\\)" uhost)
 797               (setq user (match-string 1 uhost)
 798                     host (match-string 2 uhost))
 799             (setq host uhost))
 800           ;; Remove empty HOST
 801           (and (equal host "")
 802                (setq host))
 803           ;; Fix windows style CVS root `:local:C:\\project\\cvs\\some\\dir'
 804           (and host
 805                (equal method "local")
 806                (setq root (concat host ":" root) host))
 807           ;; Normalize CVS root record
 808           (list method user host root)))))
 809
 810 ;; XXX: This does not work correctly for subdirectories.  "cvs status"
 811 ;; information is context sensitive, it contains lines like:
 812 ;; cvs status: Examining DIRNAME
 813 ;; and the file entries after that don't show the full path.
 814 ;; Because of this VC directory listings only show changed files
 815 ;; at the top level for CVS.
 816 (defun vc-cvs-parse-status (&optional full)
 817   "Parse output of \"cvs status\" command in the current buffer.
 818 Set file properties accordingly.  Unless FULL is t, parse only
 819 essential information. Note that this can never set the 'ignored
 820 state."
 821   (let (file status missing)
 822     (goto-char (point-min))
 823     (while (looking-at "? \\(.*\\)")
 824       (setq file (expand-file-name (match-string 1)))
 825       (vc-file-setprop file 'vc-state 'unregistered)
 826       (forward-line 1))
 827     (when (re-search-forward "^File: " nil t)
 828       (when (setq missing (looking-at "no file "))
 829         (goto-char (match-end 0)))
 830       (cond
 831        ((re-search-forward "\\=\\([^ \t]+\\)" nil t)
 832         (setq file (expand-file-name (match-string 1)))
 833         (setq status(if (re-search-forward "\\=[ \t]+Status: \\(.*\\)" nil t)
 834                         (match-string 1) "Unknown"))
 835         (when (and full
 836                    (re-search-forward
 837                     "\\(RCS Version\\|RCS Revision\\|Repository revision\\):\
 838 \[\t ]+\\([0-9.]+\\)"
 839                     nil t))
 840             (vc-file-setprop file 'vc-latest-revision (match-string 2)))
 841         (vc-file-setprop
 842          file 'vc-state
 843          (cond
 844           ((string-match "Up-to-date" status)
 845            (vc-file-setprop file 'vc-checkout-time
 846                             (nth 5 (file-attributes file)))
 847            'up-to-date)
 848           ((string-match "Locally Modified" status)             'edited)
 849           ((string-match "Needs Merge" status)                  'needs-merge)
 850           ((string-match "Needs \\(Checkout\\|Patch\\)" status)
 851            (if missing 'missing 'needs-update))
 852           ((string-match "Locally Added" status)                'added)
 853           ((string-match "Locally Removed" status)              'removed)
 854           ((string-match "File had conflicts " status)          'conflict)
 855           ((string-match "Unknown" status)                      'unregistered)
 856           (t 'edited))))))))
 857
 858 (defun vc-cvs-after-dir-status (update-function)
 859   ;; Heavily inspired by vc-cvs-parse-status. AKA a quick hack.
 860   ;; This needs a lot of testing.
 861   (let ((status nil)
 862         (status-str nil)
 863         (file nil)
 864         (result nil)
 865         (missing nil)
 866         (ignore-next nil)
 867         (subdir default-directory))
 868     (goto-char (point-min))
 869     (while
 870         ;; Look for either a file entry, an unregistered file, or a
 871         ;; directory change.
 872         (re-search-forward
 873          "\\(^=+\n\\([^=c?\n].*\n\\|\n\\)+\\)\\|\\(\\(^?? .*\n\\)+\\)\\|\\(^cvs status: \\(Examining\\|nothing\\) .*\n\\)"
 874          nil t)
 875       ;; FIXME: get rid of narrowing here.
 876       (narrow-to-region (match-beginning 0) (match-end 0))
 877       (goto-char (point-min))
 878       ;; The subdir
 879       (when (looking-at "cvs status: Examining \\(.+\\)")
 880         (setq subdir (expand-file-name (match-string 1))))
 881       ;; Unregistered files
 882       (while (looking-at "? \\(.*\\)")
 883         (setq file (file-relative-name
 884                     (expand-file-name (match-string 1) subdir)))
 885         (push (list file 'unregistered) result)
 886         (forward-line 1))
 887       (when (looking-at "cvs status: nothing known about")
 888         ;; We asked about a non existent file.  The output looks like this:
 889
 890         ;; cvs status: nothing known about `lisp/v.diff'
 891         ;; ===================================================================
 892         ;; File: no file v.diff            Status: Unknown
 893         ;;
 894         ;;    Working revision:    No entry for v.diff
 895         ;;    Repository revision: No revision control file
 896         ;;
 897
 898         ;; Due to narrowing in this iteration we only see the "cvs
 899         ;; status:" line, so just set a flag so that we can ignore the
 900         ;; file in the next iteration.
 901         (setq ignore-next t))
 902       ;; A file entry.
 903       (when (re-search-forward "^File: \\(no file \\)?\\(.*[^ \t]\\)[ \t]+Status: \\(.*\\)" nil t)
 904         (setq missing (match-string 1))
 905         (setq file (file-relative-name
 906                     (expand-file-name (match-string 2) subdir)))
 907         (setq status-str (match-string 3))
 908         (setq status
 909               (cond
 910                ((string-match "Up-to-date" status-str) 'up-to-date)
 911                ((string-match "Locally Modified" status-str) 'edited)
 912                ((string-match "Needs Merge" status-str) 'needs-merge)
 913                ((string-match "Needs \\(Checkout\\|Patch\\)" status-str)
 914                 (if missing 'missing 'needs-update))
 915                ((string-match "Locally Added" status-str) 'added)
 916                ((string-match "Locally Removed" status-str) 'removed)
 917                ((string-match "File had conflicts " status-str) 'conflict)
 918                ((string-match "Unknown" status-str) 'unregistered)
 919                (t 'edited)))
 920         (if ignore-next
 921             (setq ignore-next nil)
 922           (unless (eq status 'up-to-date)
 923             (push (list file status) result))))
 924       (goto-char (point-max))
 925       (widen))
 926     (funcall update-function result))
 927   ;; Alternative implementation: use the "update" command instead of
 928   ;; the "status" command.
 929   ;; (let ((result nil)
 930   ;;    (translation '((?? . unregistered)
 931   ;;                   (?A . added)
 932   ;;                   (?C . conflict)
 933   ;;                   (?M . edited)
 934   ;;                   (?P . needs-merge)
 935   ;;                   (?R . removed)
 936   ;;                   (?U . needs-update))))
 937   ;;   (goto-char (point-min))
 938   ;;   (while (not (eobp))
 939   ;;     (if (looking-at "^[ACMPRU?] \\(.*\\)$")
 940   ;;      (push (list (match-string 1)
 941   ;;                  (cdr (assoc (char-after) translation)))
 942   ;;            result)
 943   ;;    (cond
 944   ;;     ((looking-at "cvs update: warning: \\(.*\\) was lost")
 945   ;;      ;; Format is:
 946   ;;      ;; cvs update: warning: FILENAME was lost
 947   ;;      ;; U FILENAME
 948   ;;      (push (list (match-string 1) 'missing) result)
 949   ;;      ;; Skip the "U" line
 950   ;;      (forward-line 1))
 951   ;;     ((looking-at "cvs update: New directory `\\(.*\\)' -- ignored")
 952   ;;      (push (list (match-string 1) 'unregistered) result))))
 953   ;;     (forward-line 1))
 954   ;;   (funcall update-function result)))
 955   )
 956
 957 ;; Based on vc-cvs-dir-state-heuristic from Emacs 22.
 958 (defun vc-cvs-dir-status-heuristic (dir update-function &optional basedir)
 959   "Find the CVS state of all files in DIR, using only local information."
 960   (let (file basename status result dirlist)
 961     (with-temp-buffer
 962       (vc-cvs-get-entries dir)
 963       (goto-char (point-min))
 964       (while (not (eobp))
 965         (if (looking-at "D/\\([^/]*\\)////")
 966             (push (expand-file-name (match-string 1) dir) dirlist)
 967           ;; CVS-removed files are not taken under VC control.
 968           (when (looking-at "/\\([^/]*\\)/[^/-]")
 969             (setq basename (match-string 1)
 970                   file (expand-file-name basename dir)
 971                   status (or (vc-file-getprop file 'vc-state)
 972                              (vc-cvs-parse-entry file t)))
 973             (unless (eq status 'up-to-date)
 974               (push (list (if basedir
 975                               (file-relative-name file basedir)
 976                             basename)
 977                           status) result))))
 978         (forward-line 1)))
 979     (dolist (subdir dirlist)
 980       (setq result (append result
 981                            (vc-cvs-dir-status-heuristic subdir nil
 982                                                         (or basedir dir)))))
 983     (if basedir result
 984       (funcall update-function result))))
 985
 986 (defun vc-cvs-dir-status (dir update-function)
 987   "Create a list of conses (file . state) for DIR."
 988   ;; FIXME check all files in DIR instead?
 989   (let ((local (vc-stay-local-p dir 'CVS)))
 990     (if (and local (not (eq local 'only-file)))
 991         (vc-cvs-dir-status-heuristic dir update-function)
 992       (vc-cvs-command (current-buffer) 'async dir "-f" "status")
 993       ;; Alternative implementation: use the "update" command instead of
 994       ;; the "status" command.
 995       ;; (vc-cvs-command (current-buffer) 'async
 996       ;;                  (file-relative-name dir)
 997       ;;                  "-f" "-n" "update" "-d" "-P")
 998       (vc-exec-after
 999        `(vc-cvs-after-dir-status (quote ,update-function))))))
1000
1001 (defun vc-cvs-dir-status-files (dir files default-state update-function)
1002   "Create a list of conses (file . state) for DIR."
1003   (apply 'vc-cvs-command (current-buffer) 'async dir "-f" "status" files)
1004   (vc-exec-after
1005    `(vc-cvs-after-dir-status (quote ,update-function))))
1006
1007 (defun vc-cvs-file-to-string (file)
1008   "Read the content of FILE and return it as a string."
1009   (condition-case nil
1010       (with-temp-buffer
1011         (insert-file-contents file)
1012         (goto-char (point-min))
1013         (buffer-substring (point) (point-max)))
1014     (file-error nil)))
1015
1016 (defun vc-cvs-dir-extra-headers (dir)
1017   "Extract and represent per-directory properties of a CVS working copy."
1018   (let ((repo
1019          (condition-case nil
1020              (with-temp-buffer
1021                (insert-file-contents "CVS/Root")
1022                (goto-char (point-min))
1023                (and (looking-at ":ext:") (delete-char 5))
1024                (concat (buffer-substring (point) (1- (point-max))) "\n"))
1025            (file-error nil)))
1026         (module
1027          (condition-case nil
1028              (with-temp-buffer
1029                (insert-file-contents "CVS/Repository")
1030                (goto-char (point-min))
1031                (skip-chars-forward "^\n")
1032                (concat (buffer-substring (point-min) (point)) "\n"))
1033            (file-error nil))))
1034     (concat
1035      (cond (repo
1036             (concat (propertize "Repository : " 'face 'font-lock-type-face)
1037                     (propertize repo 'face 'font-lock-variable-name-face)))
1038            (t ""))
1039      (cond (module
1040             (concat (propertize "Module     : " 'face 'font-lock-type-face)
1041                     (propertize module 'face 'font-lock-variable-name-face)))
1042            (t ""))
1043      (if (file-readable-p "CVS/Tag")
1044          (let ((tag (vc-cvs-file-to-string "CVS/Tag")))
1045            (cond
1046             ((string-match "\\`T" tag)
1047              (concat (propertize "Tag        : " 'face 'font-lock-type-face)
1048                      (propertize (substring tag 1)
1049                                  'face 'font-lock-variable-name-face)))
1050             ((string-match "\\`D" tag)
1051              (concat (propertize "Date       : " 'face 'font-lock-type-face)
1052                      (propertize (substring tag 1)
1053                                  'face 'font-lock-variable-name-face)))
1054             (t ""))))
1055
1056      ;; In CVS, branch is a per-file property, not a per-directory property.
1057      ;; We can't really do this here without making dangerous assumptions.
1058      ;;(propertize "Branch:     " 'face 'font-lock-type-face)
1059      ;;(propertize "ADD CODE TO PRINT THE BRANCH NAME\n"
1060      ;;  'face 'font-lock-warning-face)
1061      )))
1062
1063 (defun vc-cvs-get-entries (dir)
1064   "Insert the CVS/Entries file from below DIR into the current buffer.
1065 This function ensures that the correct coding system is used for that,
1066 which may not be the one that is used for the files' contents.
1067 CVS/Entries should only be accessed through this function."
1068   (let ((coding-system-for-read (or file-name-coding-system
1069                                     default-file-name-coding-system)))
1070     (vc-insert-file (expand-file-name "CVS/Entries" dir))))
1071
1072 (defun vc-cvs-valid-symbolic-tag-name-p (tag)
1073   "Return non-nil if TAG is a valid symbolic tag name."
1074   ;; According to the CVS manual, a valid symbolic tag must start with
1075   ;; an uppercase or lowercase letter and can contain uppercase and
1076   ;; lowercase letters, digits, `-', and `_'.
1077   (and (string-match "^[a-zA-Z]" tag)
1078        (not (string-match "[^a-z0-9A-Z-_]" tag))))
1079
1080 (defun vc-cvs-valid-revision-number-p (tag)
1081   "Return non-nil if TAG is a valid revision number."
1082   (and (string-match "^[0-9]" tag)
1083        (not (string-match "[^0-9.]" tag))))
1084
1085 (defun vc-cvs-parse-sticky-tag (match-type match-tag)
1086   "Parse and return the sticky tag as a string.
1087 `match-data' is protected."
1088   (let ((data (match-data))
1089         (tag)
1090         (type (cond ((string= match-type "D") 'date)
1091                     ((string= match-type "T")
1092                      (if (vc-cvs-valid-symbolic-tag-name-p match-tag)
1093                          'symbolic-name
1094                        'revision-number))
1095                     (t nil))))
1096     (unwind-protect
1097         (progn
1098           (cond
1099            ;; Sticky Date tag.  Convert to a proper date value (`encode-time')
1100            ((eq type 'date)
1101             (string-match
1102              "\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)"
1103              match-tag)
1104             (let* ((year-tmp (string-to-number (match-string 1 match-tag)))
1105                    (month    (string-to-number (match-string 2 match-tag)))
1106                    (day      (string-to-number (match-string 3 match-tag)))
1107                    (hour     (string-to-number (match-string 4 match-tag)))
1108                    (min      (string-to-number (match-string 5 match-tag)))
1109                    (sec      (string-to-number (match-string 6 match-tag)))
1110                    ;; Years 0..68 are 2000..2068.
1111                    ;; Years 69..99 are 1969..1999.
1112                    (year (+ (cond ((> 69 year-tmp) 2000)
1113                                   ((> 100 year-tmp) 1900)
1114                                   (t 0))
1115                             year-tmp)))
1116               (setq tag (encode-time sec min hour day month year))))
1117            ;; Sticky Tag name or revision number
1118            ((eq type 'symbolic-name) (setq tag match-tag))
1119            ((eq type 'revision-number) (setq tag match-tag))
1120            ;; Default is no sticky tag at all
1121            (t nil))
1122           (cond ((eq vc-cvs-sticky-tag-display nil) nil)
1123                 ((eq vc-cvs-sticky-tag-display t)
1124                  (cond ((eq type 'date) (format-time-string
1125                                          vc-cvs-sticky-date-format-string
1126                                          tag))
1127                        ((eq type 'symbolic-name) tag)
1128                        ((eq type 'revision-number) tag)
1129                        (t nil)))
1130                 ((functionp vc-cvs-sticky-tag-display)
1131                  (funcall vc-cvs-sticky-tag-display tag type))
1132                 (t nil)))
1133
1134       (set-match-data data))))
1135
1136 (defun vc-cvs-parse-entry (file &optional set-state)
1137   "Parse a line from CVS/Entries.
1138 Compare modification time to that of the FILE, set file properties
1139 accordingly.  However, `vc-state' is set only if optional arg SET-STATE
1140 is non-nil."
1141   (cond
1142    ;; entry for a "locally added" file (not yet committed)
1143    ((looking-at "/[^/]+/0/")
1144     (vc-file-setprop file 'vc-checkout-time 0)
1145     (vc-file-setprop file 'vc-working-revision "0")
1146     (if set-state (vc-file-setprop file 'vc-state 'added)))
1147    ;; normal entry
1148    ((looking-at
1149      (concat "/[^/]+"
1150              ;; revision
1151              "/\\([^/]*\\)"
1152              ;; timestamp and optional conflict field
1153              "/\\([^/]*\\)/"
1154              ;; options
1155              "\\([^/]*\\)/"
1156              ;; sticky tag
1157              "\\(.\\|\\)" ;Sticky tag type (date or tag name, could be empty)
1158              "\\(.*\\)"))               ;Sticky tag
1159     (vc-file-setprop file 'vc-working-revision (match-string 1))
1160     (vc-file-setprop file 'vc-cvs-sticky-tag
1161                      (vc-cvs-parse-sticky-tag (match-string 4)
1162                                               (match-string 5)))
1163     ;; Compare checkout time and modification time.
1164     ;; This is intentionally different from the algorithm that CVS uses
1165     ;; (which is based on textual comparison), because there can be problems
1166     ;; generating a time string that looks exactly like the one from CVS.
1167     (let ((mtime (nth 5 (file-attributes file))))
1168       (require 'parse-time)
1169       (let ((parsed-time
1170              (parse-time-string (concat (match-string 2) " +0000"))))
1171         (cond ((and (not (string-match "\\+" (match-string 2)))
1172                     (car parsed-time)
1173                     (equal mtime (apply 'encode-time parsed-time)))
1174                (vc-file-setprop file 'vc-checkout-time mtime)
1175                (if set-state (vc-file-setprop file 'vc-state 'up-to-date)))
1176               (t
1177                (vc-file-setprop file 'vc-checkout-time 0)
1178                (if set-state (vc-file-setprop file 'vc-state 'edited)))))))))
1179
1180 ;; Completion of revision names.
1181 ;; Just so I don't feel like I'm duplicating code from pcl-cvs, I'll use
1182 ;; `cvs log' so I can list all the revision numbers rather than only
1183 ;; tag names.
1184
1185 (defun vc-cvs-revision-table (file)
1186   (let (process-file-side-effects
1187         (default-directory (file-name-directory file))
1188         (res nil))
1189     (with-temp-buffer
1190       (vc-cvs-command t nil file "log")
1191       (goto-char (point-min))
1192       (when (re-search-forward "^symbolic names:\n" nil t)
1193         (while (looking-at "^   \\(.*\\): \\(.*\\)")
1194           (push (cons (match-string 1) (match-string 2)) res)
1195           (forward-line 1)))
1196       (while (re-search-forward "^revision \\([0-9.]+\\)" nil t)
1197         (push (match-string 1) res))
1198       res)))
1199
1200 (defun vc-cvs-revision-completion-table (files)
1201   (lexical-let ((files files)
1202                 table)
1203     (setq table (lazy-completion-table
1204                  table (lambda () (vc-cvs-revision-table (car files)))))
1205     table))
1206
1207
1208 (provide 'vc-cvs)
1209
1210 ;; arch-tag: 60e1402a-aa53-4607-927a-cf74f144b432
1211 ;;; vc-cvs.el ends here