lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 2 Dec 2001
   8 ;; Keywords: buffer, convenience
   9 ;; Package: ibuffer
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicity (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'ibuf-macs)
  38   (require 'cl))
  39
  40 ;;; Utility functions
  41 (defun ibuffer-delete-alist (key alist)
  42   "Delete all entries in ALIST that have a key equal to KEY."
  43   (let (entry)
  44     (while (setq entry (assoc key alist))
  45       (setq alist (delete entry alist)))
  46     alist))
  47
  48 ;; borrowed from Gnus
  49 (defun ibuffer-remove-duplicates (list)
  50   "Return a copy of LIST with duplicate elements removed."
  51   (let ((new nil)
  52         (tail list))
  53     (while tail
  54       (or (member (car tail) new)
  55           (setq new (cons (car tail) new)))
  56       (setq tail (cdr tail)))
  57     (nreverse new)))
  58
  59 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  60   (let ((hip-crowd nil)
  61         (lamers nil))
  62     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  63       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  64           (push ibuffer-split-list-elt hip-crowd)
  65         (push ibuffer-split-list-elt lamers)))
  66     ;; Too bad Emacs Lisp doesn't have multiple values.
  67     (list (nreverse hip-crowd) (nreverse lamers))))
  68
  69 (defcustom ibuffer-never-show-predicates nil
  70   "A list of predicates (a regexp or function) for buffers not to display.
  71 If a regexp, then it will be matched against the buffer's name.
  72 If a function, it will be called with the buffer as an argument, and
  73 should return non-nil if this buffer should not be shown."
  74   :type '(repeat (choice regexp function))
  75   :require 'ibuf-ext
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-buffers-changed nil)
  95
  96 (defcustom ibuffer-saved-filters '(("gnus"
  97                                     ((or (mode . message-mode)
  98                                          (mode . mail-mode)
  99                                          (mode . gnus-group-mode)
 100                                          (mode . gnus-summary-mode)
 101                                          (mode . gnus-article-mode))))
 102                                    ("programming"
 103                                     ((or (mode . emacs-lisp-mode)
 104                                          (mode . cperl-mode)
 105                                          (mode . c-mode)
 106                                          (mode . java-mode)
 107                                          (mode . idl-mode)
 108                                          (mode . lisp-mode)))))
 109
 110   "An alist of filter qualifiers to switch between.
 111
 112 This variable should look like ((\"STRING\" QUALIFIERS)
 113                                 (\"STRING\" QUALIFIERS) ...), where
 114 QUALIFIERS is a list of the same form as
 115 `ibuffer-filtering-qualifiers'.
 116 See also the variables `ibuffer-filtering-qualifiers',
 117 `ibuffer-filtering-alist', and the functions
 118 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 119   :type '(repeat sexp)
 120   :group 'ibuffer)
 121
 122 (defvar ibuffer-filtering-qualifiers nil
 123   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 124 See also `ibuffer-filtering-alist'.")
 125
 126 ;; This is now frobbed by `define-ibuffer-filter'.
 127 (defvar ibuffer-filtering-alist nil
 128   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 129
 130 You most likely do not want to modify this variable directly; see
 131 `define-ibuffer-filter'.
 132
 133 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 134 displaying information to the user.  FUNCTION is given a buffer and
 135 the value of the qualifier, and returns non-nil if and only if the
 136 buffer should be displayed.")
 137
 138 (defcustom ibuffer-filter-format-alist nil
 139   "An alist which has special formats used when a filter is active.
 140 The contents of this variable should look like:
 141  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 142
 143 For example, suppose that when you add a filter for buffers whose
 144 major mode is `emacs-lisp-mode', you only want to see the mark and the
 145 name of the buffer.  You could accomplish that by adding:
 146  (mode ((mark \" \" name)))
 147 to this variable."
 148   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 149                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 150   :group 'ibuffer)
 151
 152 (defvar ibuffer-cached-filter-formats nil)
 153 (defvar ibuffer-compiled-filter-formats nil)
 154
 155 (defvar ibuffer-filter-groups nil
 156   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 157 The SYMBOL should be one from `ibuffer-filtering-alist'.
 158 The QUALIFIER should be the same as QUALIFIER in
 159 `ibuffer-filtering-qualifiers'.")
 160
 161 (defcustom ibuffer-show-empty-filter-groups t
 162   "If non-nil, then show the names of filter groups which are empty."
 163   :type 'boolean
 164   :group 'ibuffer)
 165
 166 (defcustom ibuffer-saved-filter-groups nil
 167   "An alist of filtering groups to switch between.
 168
 169 This variable should look like ((\"STRING\" QUALIFIERS)
 170                                 (\"STRING\" QUALIFIERS) ...), where
 171 QUALIFIERS is a list of the same form as
 172 `ibuffer-filtering-qualifiers'.
 173
 174 See also the variables `ibuffer-filter-groups',
 175 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 176 functions `ibuffer-switch-to-saved-filter-groups',
 177 `ibuffer-save-filter-groups'."
 178   :type '(repeat sexp)
 179   :group 'ibuffer)
 180
 181 (defvar ibuffer-hidden-filter-groups nil
 182   "A list of filtering groups which are currently hidden.")
 183
 184 (defvar ibuffer-filter-group-kill-ring nil)
 185
 186 (defcustom ibuffer-old-time 72
 187   "The number of hours before a buffer is considered \"old\"."
 188   :type '(choice (const :tag "72 hours (3 days)" 72)
 189                  (const :tag "48 hours (2 days)" 48)
 190                  (const :tag "24 hours (1 day)" 24)
 191                  (integer :tag "hours"))
 192   :group 'ibuffer)
 193
 194 (defcustom ibuffer-save-with-custom t
 195   "If non-nil, then use Custom to save interactively changed variables.
 196 Currently, this only applies to `ibuffer-saved-filters' and
 197 `ibuffer-saved-filter-groups'."
 198   :type 'boolean
 199   :group 'ibuffer)
 200
 201 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 202   (or
 203    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 204    (and (not
 205          (or
 206           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 207           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 208         (or all
 209             (not
 210              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 211         (or ibuffer-view-ibuffer
 212             (and ibuffer-buf
 213                  (not (eq ibuffer-buf buf))))
 214         (or
 215          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 216          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 217
 218 ;;;###autoload
 219 (define-minor-mode ibuffer-auto-mode
 220   "Toggle use of Ibuffer's auto-update facility.
 221 With numeric ARG, enable auto-update if and only if ARG is positive."
 222   nil nil nil
 223   (unless (derived-mode-p 'ibuffer-mode)
 224     (error "This buffer is not in Ibuffer mode"))
 225   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 226   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 227
 228 (defun ibuffer-auto-update-changed ()
 229   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 230     (dolist (buf (buffer-list))
 231       (ignore-errors
 232         (with-current-buffer buf
 233           (when (and ibuffer-auto-mode
 234                      (derived-mode-p 'ibuffer-mode))
 235             (ibuffer-update nil t)))))))
 236
 237 ;;;###autoload
 238 (defun ibuffer-mouse-filter-by-mode (event)
 239   "Enable or disable filtering by the major mode chosen via mouse."
 240   (interactive "e")
 241   (ibuffer-interactive-filter-by-mode event))
 242
 243 ;;;###autoload
 244 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 245   "Enable or disable filtering by the major mode at point."
 246   (interactive "d")
 247   (if (eventp event-or-point)
 248       (posn-set-point (event-end event-or-point))
 249     (goto-char event-or-point))
 250   (let ((buf (ibuffer-current-buffer)))
 251     (if (assq 'mode ibuffer-filtering-qualifiers)
 252         (setq ibuffer-filtering-qualifiers
 253               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 254       (ibuffer-push-filter (cons 'mode (buffer-local-value 'major-mode buf)))))
 255   (ibuffer-update nil t))
 256
 257 ;;;###autoload
 258 (defun ibuffer-mouse-toggle-filter-group (event)
 259   "Toggle the display status of the filter group chosen with the mouse."
 260   (interactive "e")
 261   (ibuffer-toggle-filter-group-1 (save-excursion
 262                                    (mouse-set-point event)
 263                                    (point))))
 264
 265 ;;;###autoload
 266 (defun ibuffer-toggle-filter-group ()
 267   "Toggle the display status of the filter group on this line."
 268   (interactive)
 269   (ibuffer-toggle-filter-group-1 (point)))
 270
 271 (defun ibuffer-toggle-filter-group-1 (posn)
 272   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 273     (unless (stringp name)
 274       (error "No filtering group name present"))
 275     (if (member name ibuffer-hidden-filter-groups)
 276         (setq ibuffer-hidden-filter-groups
 277               (delete name ibuffer-hidden-filter-groups))
 278       (push name ibuffer-hidden-filter-groups))
 279     (ibuffer-update nil t)))
 280
 281 ;;;###autoload
 282 (defun ibuffer-forward-filter-group (&optional count)
 283   "Move point forwards by COUNT filtering groups."
 284   (interactive "P")
 285   (unless count
 286     (setq count 1))
 287   (when (> count 0)
 288     (when (get-text-property (point) 'ibuffer-filter-group-name)
 289       (goto-char (next-single-property-change
 290                   (point) 'ibuffer-filter-group-name
 291                   nil (point-max))))
 292     (goto-char (next-single-property-change
 293                 (point) 'ibuffer-filter-group-name
 294                 nil (point-max)))
 295     (ibuffer-forward-filter-group (1- count)))
 296   (ibuffer-forward-line 0))
 297
 298 ;;;###autoload
 299 (defun ibuffer-backward-filter-group (&optional count)
 300   "Move point backwards by COUNT filtering groups."
 301   (interactive "P")
 302   (unless count
 303     (setq count 1))
 304   (when (> count 0)
 305     (when (get-text-property (point) 'ibuffer-filter-group-name)
 306       (goto-char (previous-single-property-change
 307                   (point) 'ibuffer-filter-group-name
 308                   nil (point-min))))
 309     (goto-char (previous-single-property-change
 310                 (point) 'ibuffer-filter-group-name
 311                 nil (point-min)))
 312     (ibuffer-backward-filter-group (1- count)))
 313   (when (= (point) (point-min))
 314     (goto-char (point-max))
 315     (ibuffer-backward-filter-group 1))
 316   (ibuffer-forward-line 0))
 317
 318 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 319 (define-ibuffer-op shell-command-pipe (command)
 320   "Pipe the contents of each marked buffer to shell command COMMAND."
 321   (:interactive "sPipe to shell command: "
 322    :opstring "Shell command executed on"
 323    :modifier-p nil)
 324   (shell-command-on-region
 325    (point-min) (point-max) command
 326    (get-buffer-create "* ibuffer-shell-output*")))
 327
 328 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 329 (define-ibuffer-op shell-command-pipe-replace (command)
 330   "Replace the contents of marked buffers with output of pipe to COMMAND."
 331   (:interactive "sPipe to shell command (replace): "
 332    :opstring "Buffer contents replaced in"
 333    :active-opstring "replace buffer contents in"
 334    :dangerous t
 335    :modifier-p t)
 336   (with-current-buffer buf
 337     (shell-command-on-region (point-min) (point-max)
 338                              command nil t)))
 339
 340 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 341 (define-ibuffer-op shell-command-file (command)
 342   "Run shell command COMMAND separately on files of marked buffers."
 343   (:interactive "sShell command on buffer's file: "
 344    :opstring "Shell command executed on"
 345    :modifier-p nil)
 346   (shell-command (concat command " "
 347                          (shell-quote-argument
 348                           (if buffer-file-name
 349                               buffer-file-name
 350                             (make-temp-file
 351                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 352
 353 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 354 (define-ibuffer-op eval (form)
 355   "Evaluate FORM in each of the buffers.
 356 Does not display the buffer during evaluation. See
 357 `ibuffer-do-view-and-eval' for that."
 358   (:interactive
 359    (list
 360     (read-from-minibuffer
 361      "Eval in buffers (form): "
 362      nil read-expression-map t 'read-expression-history))
 363    :opstring "evaluated in"
 364    :modifier-p :maybe)
 365   (eval form))
 366
 367 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 368 (define-ibuffer-op view-and-eval (form)
 369   "Evaluate FORM while displaying each of the marked buffers.
 370 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 371   (:interactive
 372    (list
 373     (read-from-minibuffer
 374      "Eval viewing in buffers (form): "
 375      nil read-expression-map t 'read-expression-history))
 376    :opstring "evaluated in"
 377    :complex t
 378    :modifier-p :maybe)
 379   (let ((ibuffer-buf (current-buffer)))
 380     (unwind-protect
 381         (progn
 382           (switch-to-buffer buf)
 383           (eval form))
 384       (switch-to-buffer ibuffer-buf))))
 385
 386 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 387 (define-ibuffer-op rename-uniquely ()
 388   "Rename marked buffers as with `rename-uniquely'."
 389   (:opstring "renamed"
 390    :modifier-p t)
 391   (rename-uniquely))
 392
 393 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 394 (define-ibuffer-op revert ()
 395   "Revert marked buffers as with `revert-buffer'."
 396   (:dangerous t
 397    :opstring "reverted"
 398    :active-opstring "revert"
 399    :modifier-p :maybe)
 400   (revert-buffer t t))
 401
 402 ;;;###autoload (autoload 'ibuffer-do-isearch "ibuf-ext")
 403 (define-ibuffer-op ibuffer-do-isearch ()
 404   "Perform a `isearch-forward' in marked buffers."
 405   (:interactive ()
 406    :opstring "searched in"
 407    :complex t
 408    :modifier-p :maybe)
 409   (multi-isearch-buffers (ibuffer-get-marked-buffers)))
 410
 411 ;;;###autoload (autoload 'ibuffer-do-isearch-regexp "ibuf-ext")
 412 (define-ibuffer-op ibuffer-do-isearch-regexp ()
 413   "Perform a `isearch-forward-regexp' in marked buffers."
 414   (:interactive ()
 415    :opstring "searched regexp in"
 416    :complex t
 417    :modifier-p :maybe)
 418   (multi-isearch-buffers-regexp (ibuffer-get-marked-buffers)))
 419
 420 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 421 (define-ibuffer-op replace-regexp (from-str to-str)
 422   "Perform a `replace-regexp' in marked buffers."
 423   (:interactive
 424    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 425           (to-str (read-from-minibuffer (concat "Replace " from-str
 426                                                 " with: "))))
 427      (list from-str to-str))
 428    :opstring "replaced in"
 429    :complex t
 430    :modifier-p :maybe)
 431   (save-window-excursion
 432     (switch-to-buffer buf)
 433     (save-excursion
 434       (goto-char (point-min))
 435       (let ((case-fold-search ibuffer-case-fold-search))
 436         (while (re-search-forward from-str nil t)
 437           (replace-match to-str))))
 438     t))
 439
 440 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 441 (define-ibuffer-op query-replace (&rest args)
 442   "Perform a `query-replace' in marked buffers."
 443   (:interactive
 444    (query-replace-read-args "Query replace" t t)
 445    :opstring "replaced in"
 446    :complex t
 447    :modifier-p :maybe)
 448   (save-window-excursion
 449     (switch-to-buffer buf)
 450     (save-excursion
 451       (let ((case-fold-search ibuffer-case-fold-search))
 452         (goto-char (point-min))
 453         (apply #'query-replace args)))
 454     t))
 455
 456 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 457 (define-ibuffer-op query-replace-regexp (&rest args)
 458   "Perform a `query-replace-regexp' in marked buffers."
 459   (:interactive
 460    (query-replace-read-args "Query replace regexp" t t)
 461    :opstring "replaced in"
 462    :complex t
 463    :modifier-p :maybe)
 464   (save-window-excursion
 465     (switch-to-buffer buf)
 466     (save-excursion
 467       (let ((case-fold-search ibuffer-case-fold-search))
 468         (goto-char (point-min))
 469         (apply #'query-replace-regexp args)))
 470     t))
 471
 472 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 473 (define-ibuffer-op print ()
 474   "Print marked buffers as with `print-buffer'."
 475   (:opstring "printed"
 476    :modifier-p nil)
 477   (print-buffer))
 478
 479 ;;;###autoload
 480 (defun ibuffer-included-in-filters-p (buf filters)
 481   (not
 482    (memq nil ;; a filter will return nil if it failed
 483          (mapcar
 484           ;; filter should be like (TYPE . QUALIFIER), or
 485           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 486           #'(lambda (qual)
 487               (ibuffer-included-in-filter-p buf qual))
 488           filters))))
 489
 490 (defun ibuffer-included-in-filter-p (buf filter)
 491   (if (eq (car filter) 'not)
 492       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 493     (ibuffer-included-in-filter-p-1 buf filter)))
 494
 495 (defun ibuffer-included-in-filter-p-1 (buf filter)
 496   (not
 497    (not
 498     (case (car filter)
 499       (or
 500        (memq t (mapcar #'(lambda (x)
 501                            (ibuffer-included-in-filter-p buf x))
 502                        (cdr filter))))
 503       (saved
 504        (let ((data
 505               (assoc (cdr filter)
 506                      ibuffer-saved-filters)))
 507          (unless data
 508            (ibuffer-filter-disable t)
 509            (error "Unknown saved filter %s" (cdr filter)))
 510          (ibuffer-included-in-filters-p buf (cadr data))))
 511       (t
 512        (let ((filterdat (assq (car filter)
 513                               ibuffer-filtering-alist)))
 514          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 515          ;; just a sanity check
 516         (unless filterdat
 517           (ibuffer-filter-disable t)
 518           (error "Undefined filter %s" (car filter)))
 519         (not
 520          (not
 521           (funcall (caddr filterdat)
 522                    buf
 523                    (cdr filter))))))))))
 524
 525 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 526   (let ((filter-group-alist (if nodefault
 527                                 ibuffer-filter-groups
 528                               (append ibuffer-filter-groups
 529                                       (list (cons "Default" nil))))))
 530 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 531 ;;       (setq filter-group-alist (ibuffer-delete-alist
 532 ;;                                 hidden filter-group-alist)))
 533     (let ((vec (make-vector (length filter-group-alist) nil))
 534           (i 0))
 535       (dolist (filtergroup filter-group-alist)
 536         (let ((filterset (cdr filtergroup)))
 537           (multiple-value-bind (hip-crowd lamers)
 538               (values-list
 539                (ibuffer-split-list (lambda (bufmark)
 540                                      (ibuffer-included-in-filters-p (car bufmark)
 541                                                                     filterset))
 542                                    bmarklist))
 543             (aset vec i hip-crowd)
 544             (incf i)
 545             (setq bmarklist lamers))))
 546       (let (ret)
 547         (dotimes (j i ret)
 548           (let ((bufs (aref vec j)))
 549             (unless (and noempty (null bufs))
 550               (push (cons (car (nth j filter-group-alist))
 551                           bufs)
 552                     ret))))))))
 553
 554 ;;;###autoload
 555 (defun ibuffer-filters-to-filter-group (name)
 556   "Make the current filters into a filtering group."
 557   (interactive "sName for filtering group: ")
 558   (when (null ibuffer-filtering-qualifiers)
 559     (error "No filters in effect"))
 560   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 561   (ibuffer-filter-disable))
 562
 563 ;;;###autoload
 564 (defun ibuffer-set-filter-groups-by-mode ()
 565   "Set the current filter groups to filter by mode."
 566   (interactive)
 567   (setq ibuffer-filter-groups
 568         (mapcar (lambda (mode)
 569                   (cons (format "%s" mode) `((mode . ,mode))))
 570                 (let ((modes
 571                        (ibuffer-remove-duplicates
 572                         (mapcar (lambda (buf)
 573                                   (buffer-local-value 'major-mode buf))
 574                                 (buffer-list)))))
 575                   (if ibuffer-view-ibuffer
 576                       modes
 577                     (delq 'ibuffer-mode modes)))))
 578   (ibuffer-update nil t))
 579
 580 ;;;###autoload
 581 (defun ibuffer-pop-filter-group ()
 582   "Remove the first filter group."
 583   (interactive)
 584   (when (null ibuffer-filter-groups)
 585     (error "No filter groups active"))
 586   (setq ibuffer-hidden-filter-groups
 587         (delete (pop ibuffer-filter-groups)
 588                 ibuffer-hidden-filter-groups))
 589   (ibuffer-update nil t))
 590
 591 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 592   (when (and (not noerror) (null ibuffer-filter-groups))
 593     (error "No filter groups active"))
 594   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 595   ;; groups, possibly excluding empty groups or Default.
 596   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 597   ;; Default if necessary.
 598   (completing-read msg (nconc
 599                         (ibuffer-generate-filter-groups
 600                          (ibuffer-current-state-list)
 601                          (not ibuffer-show-empty-filter-groups)
 602                          nodefault)
 603                         (if nodefault
 604                             (remove "Default" ibuffer-hidden-filter-groups)
 605                           ibuffer-hidden-filter-groups))
 606                    nil t))
 607
 608 ;;;###autoload
 609 (defun ibuffer-decompose-filter-group (group)
 610   "Decompose the filter group GROUP into active filters."
 611   (interactive
 612    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 613   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 614     (setq ibuffer-filter-groups (ibuffer-delete-alist
 615                                  group ibuffer-filter-groups)
 616           ibuffer-filtering-qualifiers data))
 617   (ibuffer-update nil t))
 618
 619 ;;;###autoload
 620 (defun ibuffer-clear-filter-groups ()
 621   "Remove all filter groups."
 622   (interactive)
 623   (setq ibuffer-filter-groups nil
 624         ibuffer-hidden-filter-groups nil)
 625   (ibuffer-update nil t))
 626
 627 (defun ibuffer-current-filter-groups-with-position ()
 628   (save-excursion
 629     (goto-char (point-min))
 630     (let ((pos nil)
 631           (result nil))
 632       (while (and (not (eobp))
 633                   (setq pos (next-single-property-change
 634                              (point) 'ibuffer-filter-group-name)))
 635         (goto-char pos)
 636         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 637                     pos)
 638               result)
 639         (goto-char (next-single-property-change
 640                     pos 'ibuffer-filter-group-name)))
 641       (nreverse result))))
 642
 643 ;;;###autoload
 644 (defun ibuffer-jump-to-filter-group (name)
 645   "Move point to the filter group whose name is NAME."
 646   (interactive
 647    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 648   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 649       (goto-char (cdr it))
 650     (error "No filter group with name %s" name)))
 651
 652 ;;;###autoload
 653 (defun ibuffer-kill-filter-group (name)
 654   "Kill the filter group named NAME.
 655 The group will be added to `ibuffer-filter-group-kill-ring'."
 656   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 657   (when (equal name "Default")
 658     (error "Can't kill default filter group"))
 659   (ibuffer-aif (assoc name ibuffer-filter-groups)
 660       (progn
 661         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 662         (setq ibuffer-filter-groups (ibuffer-delete-alist
 663                                      name ibuffer-filter-groups))
 664         (setq ibuffer-hidden-filter-groups
 665               (delete name ibuffer-hidden-filter-groups)))
 666     (error "No filter group with name \"%s\"" name))
 667   (ibuffer-update nil t))
 668
 669 ;;;###autoload
 670 (defun ibuffer-kill-line (&optional arg interactive-p)
 671   "Kill the filter group at point.
 672 See also `ibuffer-kill-filter-group'."
 673   (interactive "P\np")
 674   (ibuffer-aif (save-excursion
 675                  (ibuffer-forward-line 0)
 676                  (get-text-property (point) 'ibuffer-filter-group-name))
 677       (progn
 678         (ibuffer-kill-filter-group it))
 679       (funcall (if interactive-p #'call-interactively #'funcall)
 680                #'kill-line arg)))
 681
 682 (defun ibuffer-insert-filter-group-before (newgroup group)
 683   (let* ((found nil)
 684          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 685                     (res 0))
 686                 (while groups
 687                   (if (equal (car groups) group)
 688                       (setq found t
 689                             groups nil)
 690                     (incf res)
 691                     (setq groups (cdr groups))))
 692                 res)))
 693     (cond ((not found)
 694            (setq ibuffer-filter-groups
 695                  (nconc ibuffer-filter-groups (list newgroup))))
 696           ((zerop pos)
 697            (push newgroup ibuffer-filter-groups))
 698           (t
 699            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 700              (setf (cdr cell) (cons (car cell) (cdr cell)))
 701              (setf (car cell) newgroup))))))
 702
 703 ;;;###autoload
 704 (defun ibuffer-yank ()
 705   "Yank the last killed filter group before group at point."
 706   (interactive)
 707   (ibuffer-yank-filter-group
 708    (or (get-text-property (point) 'ibuffer-filter-group-name)
 709        (get-text-property (point) 'ibuffer-filter-group)
 710        (error "No filter group at point"))))
 711
 712 ;;;###autoload
 713 (defun ibuffer-yank-filter-group (name)
 714   "Yank the last killed filter group before group named NAME."
 715   (interactive (list (ibuffer-read-filter-group-name
 716                         "Yank filter group before group: ")))
 717   (unless ibuffer-filter-group-kill-ring
 718     (error "The Ibuffer filter group kill-ring is empty"))
 719   (save-excursion
 720     (ibuffer-forward-line 0)
 721     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 722                                         name))
 723   (ibuffer-update nil t))
 724
 725 ;;;###autoload
 726 (defun ibuffer-save-filter-groups (name groups)
 727   "Save all active filter groups GROUPS as NAME.
 728 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 729 prompt for NAME, and use the current filters."
 730   (interactive
 731    (if (null ibuffer-filter-groups)
 732        (error "No filter groups active")
 733      (list
 734       (read-from-minibuffer "Save current filter groups as: ")
 735       ibuffer-filter-groups)))
 736   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 737       (setcdr it groups)
 738     (push (cons name groups) ibuffer-saved-filter-groups))
 739   (ibuffer-maybe-save-stuff))
 740
 741 ;;;###autoload
 742 (defun ibuffer-delete-saved-filter-groups (name)
 743   "Delete saved filter groups with NAME.
 744 They are removed from `ibuffer-saved-filter-groups'."
 745   (interactive
 746    (list
 747     (if (null ibuffer-saved-filter-groups)
 748         (error "No saved filter groups")
 749       (completing-read "Delete saved filter group: "
 750                        ibuffer-saved-filter-groups nil t))))
 751   (setq ibuffer-saved-filter-groups
 752         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 753   (ibuffer-maybe-save-stuff)
 754   (ibuffer-update nil t))
 755
 756 ;;;###autoload
 757 (defun ibuffer-switch-to-saved-filter-groups (name)
 758   "Set this buffer's filter groups to saved version with NAME.
 759 The value from `ibuffer-saved-filter-groups' is used."
 760   (interactive
 761    (list
 762     (if (null ibuffer-saved-filter-groups)
 763         (error "No saved filters")
 764       (completing-read "Switch to saved filter group: "
 765                        ibuffer-saved-filter-groups nil t))))
 766   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 767         ibuffer-hidden-filter-groups nil)
 768   (ibuffer-update nil t))
 769
 770 ;;;###autoload
 771 (defun ibuffer-filter-disable (&optional delete-filter-groups)
 772   "Disable all filters currently in effect in this buffer.
 773 With optional arg DELETE-FILTER-GROUPS non-nil, delete all filter
 774 group definitions by setting `ibuffer-filter-groups' to nil."
 775   (interactive)
 776   (setq ibuffer-filtering-qualifiers nil)
 777   (if delete-filter-groups
 778       (setq ibuffer-filter-groups nil))
 779   (let ((buf (ibuffer-current-buffer)))
 780     (ibuffer-update nil t)
 781     (when buf
 782       (ibuffer-jump-to-buffer (buffer-name buf)))))
 783
 784 ;;;###autoload
 785 (defun ibuffer-pop-filter ()
 786   "Remove the top filter in this buffer."
 787   (interactive)
 788   (when (null ibuffer-filtering-qualifiers)
 789     (error "No filters in effect"))
 790   (pop ibuffer-filtering-qualifiers)
 791   (let ((buf (ibuffer-current-buffer)))
 792     (ibuffer-update nil t)
 793     (when buf
 794       (ibuffer-jump-to-buffer (buffer-name buf)))))
 795
 796 (defun ibuffer-push-filter (qualifier)
 797   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 798   (push qualifier ibuffer-filtering-qualifiers))
 799
 800 ;;;###autoload
 801 (defun ibuffer-decompose-filter ()
 802   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 803
 804 This means that the topmost filter on the filtering stack, which must
 805 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 806 turned into two separate filters [name: foo] and [mode: bar-mode]."
 807   (interactive)
 808   (when (null ibuffer-filtering-qualifiers)
 809     (error "No filters in effect"))
 810   (let ((lim (pop ibuffer-filtering-qualifiers)))
 811     (case (car lim)
 812       (or
 813        (setq ibuffer-filtering-qualifiers (append
 814                                           (cdr lim)
 815                                           ibuffer-filtering-qualifiers)))
 816       (saved
 817        (let ((data
 818               (assoc (cdr lim)
 819                      ibuffer-saved-filters)))
 820          (unless data
 821            (ibuffer-filter-disable)
 822            (error "Unknown saved filter %s" (cdr lim)))
 823          (setq ibuffer-filtering-qualifiers (append
 824                                             (cadr data)
 825                                             ibuffer-filtering-qualifiers))))
 826       (not
 827        (push (cdr lim)
 828              ibuffer-filtering-qualifiers))
 829       (t
 830        (error "Filter type %s is not compound" (car lim)))))
 831   (ibuffer-update nil t))
 832
 833 ;;;###autoload
 834 (defun ibuffer-exchange-filters ()
 835   "Exchange the top two filters on the stack in this buffer."
 836   (interactive)
 837   (when (< (length ibuffer-filtering-qualifiers)
 838            2)
 839     (error "Need two filters to exchange"))
 840   (let ((first (pop ibuffer-filtering-qualifiers))
 841         (second (pop ibuffer-filtering-qualifiers)))
 842     (push first ibuffer-filtering-qualifiers)
 843     (push second ibuffer-filtering-qualifiers))
 844   (ibuffer-update nil t))
 845
 846 ;;;###autoload
 847 (defun ibuffer-negate-filter ()
 848   "Negate the sense of the top filter in the current buffer."
 849   (interactive)
 850   (when (null ibuffer-filtering-qualifiers)
 851     (error "No filters in effect"))
 852   (let ((lim (pop ibuffer-filtering-qualifiers)))
 853     (push (if (eq (car lim) 'not)
 854               (cdr lim)
 855             (cons 'not lim))
 856           ibuffer-filtering-qualifiers))
 857   (ibuffer-update nil t))
 858
 859 ;;;###autoload
 860 (defun ibuffer-or-filter (&optional reverse)
 861   "Replace the top two filters in this buffer with their logical OR.
 862 If optional argument REVERSE is non-nil, instead break the top OR
 863 filter into parts."
 864   (interactive "P")
 865   (if reverse
 866       (progn
 867         (when (or (null ibuffer-filtering-qualifiers)
 868                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 869           (error "Top filter is not an OR"))
 870         (let ((lim (pop ibuffer-filtering-qualifiers)))
 871           (setq ibuffer-filtering-qualifiers
 872                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 873     (when (< (length ibuffer-filtering-qualifiers) 2)
 874       (error "Need two filters to OR"))
 875     ;; If the second filter is an OR, just add to it.
 876     (let ((first (pop ibuffer-filtering-qualifiers))
 877           (second (pop ibuffer-filtering-qualifiers)))
 878       (if (eq 'or (car second))
 879           (push (nconc (list 'or first) (cdr second))
 880                 ibuffer-filtering-qualifiers)
 881         (push (list 'or first second)
 882               ibuffer-filtering-qualifiers))))
 883   (ibuffer-update nil t))
 884
 885 (defun ibuffer-maybe-save-stuff ()
 886   (when ibuffer-save-with-custom
 887     (if (fboundp 'customize-save-variable)
 888         (progn
 889           (customize-save-variable 'ibuffer-saved-filters
 890                                    ibuffer-saved-filters)
 891           (customize-save-variable 'ibuffer-saved-filter-groups
 892                                    ibuffer-saved-filter-groups))
 893       (message "Not saved permanently: Customize not available"))))
 894
 895 ;;;###autoload
 896 (defun ibuffer-save-filters (name filters)
 897   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 898 Interactively, prompt for NAME, and use the current filters."
 899   (interactive
 900    (if (null ibuffer-filtering-qualifiers)
 901        (error "No filters currently in effect")
 902      (list
 903       (read-from-minibuffer "Save current filters as: ")
 904       ibuffer-filtering-qualifiers)))
 905   (ibuffer-aif (assoc name ibuffer-saved-filters)
 906       (setcdr it filters)
 907     (push (list name filters) ibuffer-saved-filters))
 908   (ibuffer-maybe-save-stuff))
 909
 910 ;;;###autoload
 911 (defun ibuffer-delete-saved-filters (name)
 912   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 913   (interactive
 914    (list
 915     (if (null ibuffer-saved-filters)
 916         (error "No saved filters")
 917       (completing-read "Delete saved filters: "
 918                        ibuffer-saved-filters nil t))))
 919   (setq ibuffer-saved-filters
 920         (ibuffer-delete-alist name ibuffer-saved-filters))
 921   (ibuffer-maybe-save-stuff)
 922   (ibuffer-update nil t))
 923
 924 ;;;###autoload
 925 (defun ibuffer-add-saved-filters (name)
 926   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 927   (interactive
 928    (list
 929     (if (null ibuffer-saved-filters)
 930         (error "No saved filters")
 931       (completing-read "Add saved filters: "
 932                        ibuffer-saved-filters nil t))))
 933   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 934   (ibuffer-update nil t))
 935
 936 ;;;###autoload
 937 (defun ibuffer-switch-to-saved-filters (name)
 938   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 939   (interactive
 940    (list
 941     (if (null ibuffer-saved-filters)
 942         (error "No saved filters")
 943       (completing-read "Switch to saved filters: "
 944                        ibuffer-saved-filters nil t))))
 945   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 946   (ibuffer-update nil t))
 947
 948 (defun ibuffer-format-filter-group-data (filter)
 949   (if (equal filter "Default")
 950       ""
 951     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 952                                  (cdr (assq filter ibuffer-filter-groups))
 953                                  " "))))
 954
 955 (defun ibuffer-format-qualifier (qualifier)
 956   (if (eq (car-safe qualifier) 'not)
 957       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 958     (ibuffer-format-qualifier-1 qualifier)))
 959
 960 (defun ibuffer-format-qualifier-1 (qualifier)
 961   (case (car qualifier)
 962     (saved
 963      (concat " [filter: " (cdr qualifier) "]"))
 964     (or
 965      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 966                                (cdr qualifier) "") "]"))
 967     (t
 968      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 969        (unless qualifier
 970          (error "Ibuffer: bad qualifier %s" qualifier))
 971        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 972
 973
 974 (defun ibuffer-list-buffer-modes ()
 975   "Create an alist of buffer modes currently in use.
 976 The list returned will be of the form (\"MODE-NAME\" . MODE-SYMBOL)."
 977   (let ((bufs (buffer-list))
 978         (modes)
 979         (this-mode))
 980     (while bufs
 981       (setq this-mode (buffer-local-value 'major-mode (car bufs))
 982             bufs (cdr bufs))
 983       (add-to-list
 984        'modes
 985        `(,(symbol-name this-mode) .
 986          ,this-mode)))
 987     modes))
 988
 989
 990 ;;; Extra operation definitions
 991
 992 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 993 (define-ibuffer-filter mode
 994   "Toggle current view to buffers with major mode QUALIFIER."
 995   (:description "major mode"
 996    :reader
 997    (intern
 998     (completing-read "Filter by major mode: " obarray
 999                      #'(lambda (e)
1000                          (string-match "-mode$"
1001                                        (symbol-name e)))
1002                      t
1003                      (let ((buf (ibuffer-current-buffer)))
1004                        (if (and buf (buffer-live-p buf))
1005                            (symbol-name (buffer-local-value 'major-mode buf))
1006                          "")))))
1007   (eq qualifier (buffer-local-value 'major-mode buf)))
1008
1009 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1010 (define-ibuffer-filter used-mode
1011   "Toggle current view to buffers with major mode QUALIFIER.
1012 Called interactively, this function allows selection of modes
1013 currently used by buffers."
1014   (:description "major mode in use"
1015                 :reader
1016                 (intern
1017                  (completing-read "Filter by major mode: "
1018                                   (ibuffer-list-buffer-modes)
1019                                   nil
1020                                   t
1021                                   (let ((buf (ibuffer-current-buffer)))
1022                                     (if (and buf (buffer-live-p buf))
1023                                         (symbol-name (buffer-local-value
1024                                                       'major-mode buf))
1025                                       "")))))
1026   (eq qualifier (buffer-local-value 'major-mode buf)))
1027
1028 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1029 (define-ibuffer-filter name
1030   "Toggle current view to buffers with name matching QUALIFIER."
1031   (:description "buffer name"
1032    :reader (read-from-minibuffer "Filter by name (regexp): "))
1033   (string-match qualifier (buffer-name buf)))
1034
1035 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1036 (define-ibuffer-filter filename
1037   "Toggle current view to buffers with filename matching QUALIFIER."
1038   (:description "filename"
1039    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1040   (ibuffer-awhen (buffer-local-value 'buffer-file-name buf)
1041     (string-match qualifier it)))
1042
1043 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1044 (define-ibuffer-filter size-gt
1045   "Toggle current view to buffers with size greater than QUALIFIER."
1046   (:description "size greater than"
1047    :reader
1048    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1049   (> (with-current-buffer buf (buffer-size))
1050      qualifier))
1051
1052 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1053 (define-ibuffer-filter size-lt
1054    "Toggle current view to buffers with size less than QUALIFIER."
1055   (:description "size less than"
1056    :reader
1057    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1058   (< (with-current-buffer buf (buffer-size))
1059      qualifier))
1060
1061 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1062 (define-ibuffer-filter content
1063    "Toggle current view to buffers whose contents match QUALIFIER."
1064   (:description "content"
1065    :reader (read-from-minibuffer "Filter by content (regexp): "))
1066   (with-current-buffer buf
1067     (save-excursion
1068       (goto-char (point-min))
1069       (re-search-forward qualifier nil t))))
1070
1071 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1072 (define-ibuffer-filter predicate
1073    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1074   (:description "predicate"
1075    :reader (read-minibuffer "Filter by predicate (form): "))
1076   (with-current-buffer buf
1077     (eval qualifier)))
1078
1079 ;;; Sorting
1080
1081 ;;;###autoload
1082 (defun ibuffer-toggle-sorting-mode ()
1083   "Toggle the current sorting mode.
1084 Default sorting modes are:
1085  Recency - the last time the buffer was viewed
1086  Name - the name of the buffer
1087  Major Mode - the name of the major mode of the buffer
1088  Size - the size of the buffer"
1089   (interactive)
1090   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1091     (add-to-list 'modes 'recency)
1092     (setq modes (sort modes 'string-lessp))
1093     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1094                     (car modes))))
1095       (setq ibuffer-sorting-mode next)
1096       (message "Sorting by %s" next)))
1097   (ibuffer-redisplay t))
1098
1099 ;;;###autoload
1100 (defun ibuffer-invert-sorting ()
1101   "Toggle whether or not sorting is in reverse order."
1102   (interactive)
1103   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1104   (message "Sorting order %s"
1105            (if ibuffer-sorting-reversep
1106                "reversed"
1107              "normal"))
1108   (ibuffer-redisplay t))
1109
1110 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1111 (define-ibuffer-sorter major-mode
1112   "Sort the buffers by major modes.
1113 Ordering is lexicographic."
1114   (:description "major mode")
1115   (string-lessp (downcase
1116                  (symbol-name (buffer-local-value 'major-mode (car a))))
1117                 (downcase
1118                  (symbol-name (buffer-local-value 'major-mode (car b))))))
1119
1120 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1121 (define-ibuffer-sorter mode-name
1122   "Sort the buffers by their mode name.
1123 Ordering is lexicographic."
1124   (:description "major mode name")
1125   (string-lessp (downcase
1126                  (with-current-buffer
1127                      (car a)
1128                    (format-mode-line mode-name)))
1129                 (downcase
1130                  (with-current-buffer
1131                      (car b)
1132                    (format-mode-line mode-name)))))
1133
1134 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1135 (define-ibuffer-sorter alphabetic
1136   "Sort the buffers by their names.
1137 Ordering is lexicographic."
1138   (:description "buffer name")
1139   (string-lessp
1140    (buffer-name (car a))
1141    (buffer-name (car b))))
1142
1143 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1144 (define-ibuffer-sorter size
1145  "Sort the buffers by their size."
1146   (:description "size")
1147   (< (with-current-buffer (car a)
1148        (buffer-size))
1149      (with-current-buffer (car b)
1150        (buffer-size))))
1151
1152 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1153 (define-ibuffer-sorter filename/process
1154  "Sort the buffers by their file name/process name."
1155   (:description "file name")
1156   (string-lessp
1157    ;; FIXME: For now just compare the file name and the process name
1158    ;; (if it exists).  Is there a better way to do this?
1159    (or (buffer-file-name (car a))
1160        (let ((pr-a (get-buffer-process (car a))))
1161          (and (processp pr-a) (process-name pr-a))))
1162    (or (buffer-file-name (car b))
1163        (let ((pr-b (get-buffer-process (car b))))
1164          (and (processp pr-b) (process-name pr-b))))))
1165
1166 ;;; Functions to emulate bs.el
1167
1168 ;;;###autoload
1169 (defun ibuffer-bs-show ()
1170   "Emulate `bs-show' from the bs.el package."
1171   (interactive)
1172   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1173   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1174
1175 (defun ibuffer-bs-toggle-all ()
1176   "Emulate `bs-toggle-show-all' from the bs.el package."
1177   (interactive)
1178   (if ibuffer-filtering-qualifiers
1179       (ibuffer-pop-filter)
1180     (progn (ibuffer-push-filter '(filename . ".*"))
1181            (ibuffer-update nil t))))
1182
1183 ;;; Handy functions
1184
1185 ;;;###autoload
1186 (defun ibuffer-add-to-tmp-hide (regexp)
1187   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1188 This means that buffers whose name matches REGEXP will not be shown
1189 for this Ibuffer session."
1190   (interactive
1191    (list
1192     (read-from-minibuffer "Never show buffers matching: "
1193                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1194   (push regexp ibuffer-tmp-hide-regexps))
1195
1196 ;;;###autoload
1197 (defun ibuffer-add-to-tmp-show (regexp)
1198   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1199 This means that buffers whose name matches REGEXP will always be shown
1200 for this Ibuffer session."
1201   (interactive
1202    (list
1203     (read-from-minibuffer "Always show buffers matching: "
1204                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1205   (push regexp ibuffer-tmp-show-regexps))
1206
1207 ;;;###autoload
1208 (defun ibuffer-forward-next-marked (&optional count mark direction)
1209   "Move forward by COUNT marked buffers (default 1).
1210
1211 If MARK is non-nil, it should be a character denoting the type of mark
1212 to move by.  The default is `ibuffer-marked-char'.
1213
1214 If DIRECTION is non-nil, it should be an integer; negative integers
1215 mean move backwards, non-negative integers mean move forwards."
1216   (interactive "P")
1217   (unless count
1218     (setq count 1))
1219   (unless mark
1220     (setq mark ibuffer-marked-char))
1221   (unless direction
1222     (setq direction 1))
1223   ;; Skip the title
1224   (ibuffer-forward-line 0)
1225   (let ((opos (point)))
1226     (ibuffer-forward-line direction)
1227     (while (not (or (= (point) opos)
1228                     (eq (ibuffer-current-mark) mark)))
1229       (ibuffer-forward-line direction))
1230     (when (and (= (point) opos)
1231                (not (eq (ibuffer-current-mark) mark)))
1232       (error "No buffers with mark %c" mark))))
1233
1234 ;;;###autoload
1235 (defun ibuffer-backwards-next-marked (&optional count mark)
1236    "Move backwards by COUNT marked buffers (default 1).
1237
1238 If MARK is non-nil, it should be a character denoting the type of mark
1239 to move by.  The default is `ibuffer-marked-char'."
1240    (interactive "P")
1241    (ibuffer-forward-next-marked count mark -1))
1242
1243 ;;;###autoload
1244 (defun ibuffer-do-kill-lines ()
1245   "Hide all of the currently marked lines."
1246   (interactive)
1247   (if (= (ibuffer-count-marked-lines) 0)
1248       (message "No buffers marked; use 'm' to mark a buffer")
1249     (let ((count
1250            (ibuffer-map-marked-lines
1251             #'(lambda (_buf _mark)
1252                 'kill))))
1253       (message "Killed %s lines" count))))
1254
1255 ;;;###autoload
1256 (defun ibuffer-jump-to-buffer (name)
1257   "Move point to the buffer whose name is NAME.
1258
1259 If called interactively, prompt for a buffer name and go to the
1260 corresponding line in the Ibuffer buffer.  If said buffer is in a
1261 hidden group filter, open it.
1262
1263 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1264 visible buffers in the completion list.  Calling the command with
1265 a prefix argument reverses the meaning of that variable."
1266   (interactive (list
1267                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1268                   (when current-prefix-arg
1269                     (setq only-visible (not only-visible)))
1270                   (if only-visible
1271                       (let ((table (mapcar #'(lambda (x)
1272                                                (buffer-name (car x)))
1273                                            (ibuffer-current-state-list))))
1274                         (when (null table)
1275                           (error "No buffers!"))
1276                         (completing-read "Jump to buffer: "
1277                                          table nil t))
1278                     (read-buffer "Jump to buffer: " nil t)))))
1279   (when (not (string= "" name))
1280     (let (buf-point)
1281       ;; Blindly search for our buffer: it is very likely that it is
1282       ;; not in a hidden filter group.
1283       (ibuffer-map-lines #'(lambda (buf _marks)
1284                              (when (string= (buffer-name buf) name)
1285                                (setq buf-point (point))
1286                                nil))
1287                          t nil)
1288       (when (and
1289              (null buf-point)
1290              (not (null ibuffer-hidden-filter-groups)))
1291         ;; We did not find our buffer.  It must be in a hidden filter
1292         ;; group, so go through all hidden filter groups to find it.
1293         (catch 'found
1294           (dolist (group ibuffer-hidden-filter-groups)
1295             (ibuffer-jump-to-filter-group group)
1296             (ibuffer-toggle-filter-group)
1297             (ibuffer-map-lines #'(lambda (buf _marks)
1298                                    (when (string= (buffer-name buf) name)
1299                                      (setq buf-point (point))
1300                                      nil))
1301                                t group)
1302             (if buf-point
1303                 (throw 'found nil)
1304               (ibuffer-toggle-filter-group)))))
1305       (if (null buf-point)
1306           ;; Still not found even though we expanded all hidden filter
1307           ;; groups: that must be because it's hidden by predicate:
1308           ;; we won't bother trying to display it.
1309           (error "No buffer with name %s" name)
1310         (goto-char buf-point)))))
1311
1312 (declare-function diff-sentinel "diff"
1313                   (code &optional old-temp-file new-temp-file))
1314
1315 (defun ibuffer-diff-buffer-with-file-1 (buffer)
1316   (let ((bufferfile (buffer-local-value 'buffer-file-name buffer))
1317         (tempfile (make-temp-file "buffer-content-")))
1318     (when bufferfile
1319       (unwind-protect
1320           (progn
1321             (with-current-buffer buffer
1322               (write-region nil nil tempfile nil 'nomessage))
1323             (let* ((old (expand-file-name bufferfile))
1324                    (new (expand-file-name tempfile))
1325                    (oldtmp (file-local-copy old))
1326                    (newtmp (file-local-copy new))
1327                    (switches diff-switches)
1328                    (command
1329                     (mapconcat
1330                      'identity
1331                      `(,diff-command
1332                        ;; Use explicitly specified switches
1333                        ,@(if (listp switches) switches (list switches))
1334                        ,@(if (or old new)
1335                              (list "-L" (shell-quote-argument old)
1336                                    "-L" (shell-quote-argument
1337                                          (format "Buffer %s" (buffer-name buffer)))))
1338                        ,(shell-quote-argument (or oldtmp old))
1339                        ,(shell-quote-argument (or newtmp new)))
1340                      " ")))
1341               (let ((inhibit-read-only t))
1342                 (insert command "\n")
1343                 (diff-sentinel
1344                  (call-process shell-file-name nil
1345                                (current-buffer) nil
1346                                shell-command-switch command)))
1347               (insert "\n"))))
1348       (sit-for 0)
1349       (when (file-exists-p tempfile)
1350         (delete-file tempfile)))))
1351
1352 ;;;###autoload
1353 (defun ibuffer-diff-with-file ()
1354   "View the differences between marked buffers and their associated files.
1355 If no buffers are marked, use buffer at point.
1356 This requires the external program \"diff\" to be in your `exec-path'."
1357   (interactive)
1358   (require 'diff)
1359   (let ((marked-bufs (ibuffer-get-marked-buffers)))
1360     (when (null marked-bufs)
1361       (setq marked-bufs (list (ibuffer-current-buffer t))))
1362     (with-current-buffer (get-buffer-create "*Ibuffer Diff*")
1363       (setq buffer-read-only nil)
1364       (buffer-disable-undo (current-buffer))
1365       (erase-buffer)
1366       (buffer-enable-undo (current-buffer))
1367       (diff-mode)
1368       (dolist (buf marked-bufs)
1369         (unless (buffer-live-p buf)
1370           (error "Buffer %s has been killed" buf))
1371         (ibuffer-diff-buffer-with-file-1 buf))
1372       (setq buffer-read-only t)))
1373   (switch-to-buffer "*Ibuffer Diff*"))
1374
1375 ;;;###autoload
1376 (defun ibuffer-copy-filename-as-kill (&optional arg)
1377   "Copy filenames of marked buffers into the kill ring.
1378
1379 The names are separated by a space.
1380 If a buffer has no filename, it is ignored.
1381
1382 With no prefix arg, use the filename sans its directory of each marked file.
1383 With a zero prefix arg, use the complete filename of each marked file.
1384 With \\[universal-argument], use the filename of each marked file relative
1385 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1386
1387 You can then feed the file name(s) to other commands with \\[yank]."
1388   (interactive "p")
1389   (if (zerop (ibuffer-count-marked-lines))
1390       (message "No buffers marked; use 'm' to mark a buffer")
1391     (let ((ibuffer-copy-filename-as-kill-result "")
1392           (type (cond ((zerop arg)
1393                        'full)
1394                       ((= arg 4)
1395                        'relative)
1396                       (t
1397                        'name))))
1398       (ibuffer-map-marked-lines
1399        #'(lambda (buf _mark)
1400            (setq ibuffer-copy-filename-as-kill-result
1401                  (concat ibuffer-copy-filename-as-kill-result
1402                          (let ((name (buffer-file-name buf)))
1403                            (if name
1404                                (case type
1405                                  (full
1406                                   name)
1407                                  (relative
1408                                   (file-relative-name
1409                                    name (or ibuffer-default-directory
1410                                             default-directory)))
1411                                  (t
1412                                   (file-name-nondirectory name)))
1413                              ""))
1414                          " "))))
1415       (kill-new ibuffer-copy-filename-as-kill-result))))
1416
1417 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1418   (let ((count
1419          (ibuffer-map-lines
1420           #'(lambda (buf _mark)
1421               (when (funcall func buf)
1422                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1423                                         ibuffer-marked-char))
1424                 t))
1425           nil
1426           group)))
1427     (ibuffer-redisplay t)
1428     (unless (eq ibuffer-mark-on-buffer-mark ?\s)
1429       (message "Marked %s buffers" count))))
1430
1431 ;;;###autoload
1432 (defun ibuffer-mark-by-name-regexp (regexp)
1433   "Mark all buffers whose name matches REGEXP."
1434   (interactive "sMark by name (regexp): ")
1435   (ibuffer-mark-on-buffer
1436    #'(lambda (buf)
1437        (string-match regexp (buffer-name buf)))))
1438
1439 ;;;###autoload
1440 (defun ibuffer-mark-by-mode-regexp (regexp)
1441   "Mark all buffers whose major mode matches REGEXP."
1442   (interactive "sMark by major mode (regexp): ")
1443   (ibuffer-mark-on-buffer
1444    #'(lambda (buf)
1445        (with-current-buffer buf
1446          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1447
1448 ;;;###autoload
1449 (defun ibuffer-mark-by-file-name-regexp (regexp)
1450   "Mark all buffers whose file name matches REGEXP."
1451   (interactive "sMark by file name (regexp): ")
1452   (ibuffer-mark-on-buffer
1453    #'(lambda (buf)
1454        (let ((name (or (buffer-file-name buf)
1455                        (with-current-buffer buf
1456                          (and
1457                           (boundp 'dired-directory)
1458                           (stringp dired-directory)
1459                           dired-directory)))))
1460          (when name
1461            (string-match regexp name))))))
1462
1463 ;;;###autoload
1464 (defun ibuffer-mark-by-mode (mode)
1465   "Mark all buffers whose major mode equals MODE."
1466   (interactive
1467    (list (intern (completing-read "Mark by major mode: " obarray
1468                                   #'(lambda (e)
1469                                       ;; kind of a hack...
1470                                       (and (fboundp e)
1471                                            (string-match "-mode$"
1472                                                          (symbol-name e))))
1473                                   t
1474                                   (let ((buf (ibuffer-current-buffer)))
1475                                     (if (and buf (buffer-live-p buf))
1476                                         (with-current-buffer buf
1477                                           (cons (symbol-name major-mode)
1478                                                 0))
1479                                       ""))))))
1480   (ibuffer-mark-on-buffer
1481    #'(lambda (buf)
1482        (eq (buffer-local-value 'major-mode buf) mode))))
1483
1484 ;;;###autoload
1485 (defun ibuffer-mark-modified-buffers ()
1486   "Mark all modified buffers."
1487   (interactive)
1488   (ibuffer-mark-on-buffer
1489    #'(lambda (buf) (buffer-modified-p buf))))
1490
1491 ;;;###autoload
1492 (defun ibuffer-mark-unsaved-buffers ()
1493   "Mark all modified buffers that have an associated file."
1494   (interactive)
1495   (ibuffer-mark-on-buffer
1496    #'(lambda (buf) (and (buffer-local-value 'buffer-file-name buf)
1497                         (buffer-modified-p buf)))))
1498
1499 ;;;###autoload
1500 (defun ibuffer-mark-dissociated-buffers ()
1501   "Mark all buffers whose associated file does not exist."
1502   (interactive)
1503   (ibuffer-mark-on-buffer
1504    #'(lambda (buf)
1505        (with-current-buffer buf
1506          (or
1507           (and buffer-file-name
1508                (not (file-exists-p buffer-file-name)))
1509           (and (eq major-mode 'dired-mode)
1510                (boundp 'dired-directory)
1511                (stringp dired-directory)
1512                (not (file-exists-p (file-name-directory dired-directory)))))))))
1513
1514 ;;;###autoload
1515 (defun ibuffer-mark-help-buffers ()
1516   "Mark buffers like *Help*, *Apropos*, *Info*."
1517   (interactive)
1518   (ibuffer-mark-on-buffer
1519    #'(lambda (buf)
1520        (with-current-buffer buf
1521          (memq major-mode ibuffer-help-buffer-modes)))))
1522
1523 ;;;###autoload
1524 (defun ibuffer-mark-compressed-file-buffers ()
1525   "Mark buffers whose associated file is compressed."
1526   (interactive)
1527   (ibuffer-mark-on-buffer
1528    #'(lambda (buf)
1529        (with-current-buffer buf
1530          (and buffer-file-name
1531               (string-match ibuffer-compressed-file-name-regexp
1532                            buffer-file-name))))))
1533
1534 ;;;###autoload
1535 (defun ibuffer-mark-old-buffers ()
1536   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1537   (interactive)
1538   (ibuffer-mark-on-buffer
1539    #'(lambda (buf)
1540        (with-current-buffer buf
1541          ;; hacked from midnight.el
1542          (when buffer-display-time
1543            (let* ((tm (current-time))
1544                   (now (+ (* (float (ash 1 16)) (car tm))
1545                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1546                   (then (+ (* (float (ash 1 16))
1547                               (car buffer-display-time))
1548                            (float (cadr buffer-display-time))
1549                            (* 0.0000001 (caddr buffer-display-time)))))
1550              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1551
1552 ;;;###autoload
1553 (defun ibuffer-mark-special-buffers ()
1554   "Mark all buffers whose name begins and ends with '*'."
1555   (interactive)
1556   (ibuffer-mark-on-buffer
1557    #'(lambda (buf) (string-match "^\\*.+\\*$"
1558                                  (buffer-name buf)))))
1559
1560 ;;;###autoload
1561 (defun ibuffer-mark-read-only-buffers ()
1562   "Mark all read-only buffers."
1563   (interactive)
1564   (ibuffer-mark-on-buffer
1565    #'(lambda (buf) (buffer-local-value 'buffer-read-only buf))))
1566
1567 ;;;###autoload
1568 (defun ibuffer-mark-dired-buffers ()
1569   "Mark all `dired' buffers."
1570   (interactive)
1571   (ibuffer-mark-on-buffer
1572    #'(lambda (buf) (eq (buffer-local-value 'major-mode buf) 'dired-mode))))
1573
1574 ;;;###autoload
1575 (defun ibuffer-do-occur (regexp &optional nlines)
1576   "View lines which match REGEXP in all marked buffers.
1577 Optional argument NLINES says how many lines of context to display: it
1578 defaults to one."
1579   (interactive (occur-read-primary-args))
1580   (if (or (not (integerp nlines))
1581           (< nlines 0))
1582       (setq nlines 0))
1583   (when (zerop (ibuffer-count-marked-lines))
1584     (ibuffer-set-mark ibuffer-marked-char))
1585   (let ((ibuffer-do-occur-bufs nil))
1586     ;; Accumulate a list of marked buffers
1587     (ibuffer-map-marked-lines
1588      #'(lambda (buf _mark)
1589          (push buf ibuffer-do-occur-bufs)))
1590     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1591
1592 (provide 'ibuf-ext)
1593
1594 ;; Local Variables:
1595 ;; generated-autoload-file: "ibuffer.el"
1596 ;; End:
1597
1598 ;;; ibuf-ext.el ends here