lisp/org/org-timer.el

   1 ;;; org-timer.el --- The relative timer code for Org-mode
   2
   3 ;; Copyright (C) 2008-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the relative timer code for Org-mode
  28
  29 ;;; Code:
  30
  31 (require 'org)
  32
  33 (declare-function org-notify "org-clock" (notification &optional play-sound))
  34 (declare-function org-agenda-error "org-agenda" ())
  35
  36 (defvar org-timer-start-time nil
  37   "t=0 for the running timer.")
  38
  39 (defvar org-timer-pause-time nil
  40   "Time when the timer was paused.")
  41
  42 (defconst org-timer-re "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
  43   "Regular expression used to match timer stamps.")
  44
  45 (defcustom org-timer-format "%s "
  46   "The format to insert the time of the timer.
  47 This format must contain one instance of \"%s\" which will be replaced by
  48 the value of the relative timer."
  49   :group 'org-time
  50   :type 'string)
  51
  52 (defcustom org-timer-default-timer 0
  53   "The default timer when a timer is set.
  54 When 0, the user is prompted for a value."
  55   :group 'org-time
  56   :version "24.1"
  57   :type 'number)
  58
  59 (defcustom org-timer-display 'mode-line
  60   "When a timer is running, org-mode can display it in the mode
  61 line and/or frame title.
  62 Allowed values are:
  63
  64 both         displays in both mode line and frame title
  65 mode-line    displays only in mode line (default)
  66 frame-title  displays only in frame title
  67 nil          current timer is not displayed"
  68   :group 'org-time
  69   :type '(choice
  70           (const :tag "Mode line" mode-line)
  71           (const :tag "Frame title" frame-title)
  72           (const :tag "Both" both)
  73           (const :tag "None" nil)))
  74
  75 (defvar org-timer-start-hook nil
  76   "Hook run after relative timer is started.")
  77
  78 (defvar org-timer-stop-hook nil
  79   "Hook run before relative timer is stopped.")
  80
  81 (defvar org-timer-pause-hook nil
  82   "Hook run before relative timer is paused.")
  83
  84 (defvar org-timer-continue-hook nil
  85   "Hook run after relative timer is continued.")
  86
  87 (defvar org-timer-set-hook nil
  88   "Hook run after countdown timer is set.")
  89
  90 (defvar org-timer-done-hook nil
  91   "Hook run after countdown timer reaches zero.")
  92
  93 (defvar org-timer-cancel-hook nil
  94   "Hook run before countdown timer is canceled.")
  95
  96 ;;;###autoload
  97 (defun org-timer-start (&optional offset)
  98   "Set the starting time for the relative timer to now.
  99 When called with prefix argument OFFSET, prompt the user for an offset time,
 100 with the default taken from a timer stamp at point, if any.
 101 If OFFSET is a string or an integer, it is directly taken to be the offset
 102 without user interaction.
 103 When called with a double prefix arg, all timer strings in the active
 104 region will be shifted by a specific amount.  You will be prompted for
 105 the amount, with the default to make the first timer string in
 106 the region 0:00:00."
 107   (interactive "P")
 108   (if (equal offset '(16))
 109       (call-interactively 'org-timer-change-times-in-region)
 110     (let (delta def s)
 111       (if (not offset)
 112           (setq org-timer-start-time (current-time))
 113         (cond
 114          ((integerp offset) (setq delta offset))
 115          ((stringp offset) (setq delta (org-timer-hms-to-secs offset)))
 116          (t
 117           (setq def (if (org-in-regexp org-timer-re)
 118                         (match-string 0)
 119                       "0:00:00")
 120                 s (read-string
 121                    (format "Restart timer with offset [%s]: " def)))
 122           (unless (string-match "\\S-" s) (setq s def))
 123           (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete s)))))
 124         (setq org-timer-start-time
 125               (seconds-to-time
 126                (- (float-time) delta))))
 127       (org-timer-set-mode-line 'on)
 128       (message "Timer start time set to %s, current value is %s"
 129                (format-time-string "%T" org-timer-start-time)
 130                (org-timer-secs-to-hms (or delta 0)))
 131       (run-hooks 'org-timer-start-hook))))
 132
 133 (defun org-timer-pause-or-continue (&optional stop)
 134   "Pause or continue the relative timer.
 135 With prefix arg STOP, stop it entirely."
 136   (interactive "P")
 137   (cond
 138    (stop (org-timer-stop))
 139    ((not org-timer-start-time) (error "No timer is running"))
 140    (org-timer-pause-time
 141     ;; timer is paused, continue
 142     (setq org-timer-start-time
 143           (seconds-to-time
 144            (-
 145             (float-time)
 146             (- (float-time org-timer-pause-time)
 147                (float-time org-timer-start-time))))
 148           org-timer-pause-time nil)
 149     (org-timer-set-mode-line 'on)
 150     (run-hooks 'org-timer-continue-hook)
 151     (message "Timer continues at %s" (org-timer-value-string)))
 152    (t
 153     ;; pause timer
 154     (run-hooks 'org-timer-pause-hook)
 155     (setq org-timer-pause-time (current-time))
 156     (org-timer-set-mode-line 'pause)
 157     (message "Timer paused at %s" (org-timer-value-string)))))
 158
 159 (defvar org-timer-current-timer nil)
 160 (defun org-timer-stop ()
 161   "Stop the relative timer."
 162   (interactive)
 163   (run-hooks 'org-timer-stop-hook)
 164   (setq org-timer-start-time nil
 165         org-timer-pause-time nil
 166         org-timer-current-timer nil)
 167   (org-timer-set-mode-line 'off)
 168   (message "Timer stopped"))
 169
 170 ;;;###autoload
 171 (defun org-timer (&optional restart no-insert-p)
 172   "Insert a H:MM:SS string from the timer into the buffer.
 173 The first time this command is used, the timer is started.  When used with
 174 a \\[universal-argument] prefix, force restarting the timer.
 175 When used with a double prefix argument \\[universal-argument], change all the timer string
 176 in the region by a fixed amount.  This can be used to recalibrate a timer
 177 that was not started at the correct moment.
 178
 179 If NO-INSERT-P is non-nil, return the string instead of inserting
 180 it in the buffer."
 181   (interactive "P")
 182   (when (or (equal restart '(4)) (not org-timer-start-time))
 183     (org-timer-start))
 184   (if no-insert-p
 185       (org-timer-value-string)
 186     (insert (org-timer-value-string))))
 187
 188 (defun org-timer-value-string ()
 189   "Set the timer string."
 190   (format org-timer-format
 191           (org-timer-secs-to-hms
 192            (abs (floor (org-timer-seconds))))))
 193
 194 (defvar org-timer-timer-is-countdown nil)
 195 (defun org-timer-seconds ()
 196   (if org-timer-timer-is-countdown
 197       (- (float-time org-timer-start-time)
 198          (float-time))
 199     (- (float-time org-timer-pause-time)
 200        (float-time org-timer-start-time))))
 201
 202 ;;;###autoload
 203 (defun org-timer-change-times-in-region (beg end delta)
 204   "Change all h:mm:ss time in region by a DELTA."
 205   (interactive
 206    "r\nsEnter time difference like \"-1:08:26\".  Default is first time to zero: ")
 207   (let ((re "[-+]?[0-9]+:[0-9]\\{2\\}:[0-9]\\{2\\}") p)
 208     (unless (string-match "\\S-" delta)
 209       (save-excursion
 210         (goto-char beg)
 211         (when (re-search-forward re end t)
 212           (setq delta (match-string 0))
 213           (if (equal (string-to-char delta) ?-)
 214               (setq delta (substring delta 1))
 215             (setq delta (concat "-" delta))))))
 216     (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete delta)))
 217     (when (= delta 0) (error "No change"))
 218     (save-excursion
 219       (goto-char end)
 220       (while (re-search-backward re beg t)
 221         (setq p (point))
 222         (replace-match
 223          (save-match-data
 224            (org-timer-secs-to-hms (+ (org-timer-hms-to-secs (match-string 0)) delta)))
 225          t t)
 226         (goto-char p)))))
 227
 228 ;;;###autoload
 229 (defun org-timer-item (&optional arg)
 230   "Insert a description-type item with the current timer value."
 231   (interactive "P")
 232   (let ((itemp (org-in-item-p)) (pos (point)))
 233     (cond
 234      ;; In a timer list, insert with `org-list-insert-item',
 235      ;; then fix the list.
 236      ((and itemp (goto-char itemp) (org-at-item-timer-p))
 237       (let* ((struct (org-list-struct))
 238              (prevs (org-list-prevs-alist struct))
 239              (s (concat (org-timer (when arg '(4)) t) ":: ")))
 240         (setq struct (org-list-insert-item pos struct prevs nil s))
 241         (org-list-write-struct struct (org-list-parents-alist struct))
 242         (looking-at org-list-full-item-re)
 243         (goto-char (match-end 0))))
 244      ;; In a list of another type, don't break anything: throw an error.
 245      (itemp (goto-char pos) (error "This is not a timer list"))
 246      ;; Else, start a new list.
 247      (t
 248       (beginning-of-line)
 249       (org-indent-line)
 250       (insert  "- ")
 251       (org-timer (when arg '(4)))
 252       (insert ":: ")))))
 253
 254 (defun org-timer-fix-incomplete (hms)
 255   "If hms is a H:MM:SS string with missing hour or hour and minute, fix it."
 256   (if (string-match "\\(?:\\([0-9]+:\\)?\\([0-9]+:\\)\\)?\\([0-9]+\\)" hms)
 257       (replace-match
 258        (format "%d:%02d:%02d"
 259                (if (match-end 1) (string-to-number (match-string 1 hms)) 0)
 260                (if (match-end 2) (string-to-number (match-string 2 hms)) 0)
 261                (string-to-number (match-string 3 hms)))
 262        t t hms)
 263     (error "Cannot parse HMS string \"%s\"" hms)))
 264
 265 (defun org-timer-hms-to-secs (hms)
 266   "Convert h:mm:ss string to an integer time.
 267 If the string starts with a minus sign, the integer will be negative."
 268   (if (not (string-match
 269             "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
 270             hms))
 271       0
 272     (let* ((h (string-to-number (match-string 1 hms)))
 273            (m (string-to-number (match-string 2 hms)))
 274            (s (string-to-number (match-string 3 hms)))
 275            (sign (equal (substring (match-string 1 hms) 0 1) "-")))
 276       (setq h (abs h))
 277       (* (if sign -1 1) (+ s (* 60 (+ m (* 60 h))))))))
 278
 279 (defun org-timer-secs-to-hms (s)
 280   "Convert integer S into h:mm:ss.
 281 If the integer is negative, the string will start with \"-\"."
 282   (let (sign m h)
 283     (setq sign (if (< s 0) "-" "")
 284           s (abs s)
 285           m (/ s 60) s (- s (* 60 m))
 286           h (/ m 60) m (- m (* 60 h)))
 287     (format "%s%d:%02d:%02d" sign h m s)))
 288
 289 (defvar org-timer-mode-line-timer nil)
 290 (defvar org-timer-mode-line-string nil)
 291
 292 (defun org-timer-set-mode-line (value)
 293   "Set the mode-line display of the relative timer.
 294 VALUE can be `on', `off', or `pause'."
 295   (when (or (eq org-timer-display 'mode-line)
 296             (eq org-timer-display 'both))
 297     (or global-mode-string (setq global-mode-string '("")))
 298     (or (memq 'org-timer-mode-line-string global-mode-string)
 299         (setq global-mode-string
 300               (append global-mode-string '(org-timer-mode-line-string)))))
 301   (when (or (eq org-timer-display 'frame-title)
 302             (eq org-timer-display 'both))
 303     (or (memq 'org-timer-mode-line-string frame-title-format)
 304         (setq frame-title-format
 305               (append frame-title-format '(org-timer-mode-line-string)))))
 306   (cond
 307    ((equal value 'off)
 308     (when org-timer-mode-line-timer
 309       (cancel-timer org-timer-mode-line-timer)
 310       (setq org-timer-mode-line-timer nil))
 311     (when (or (eq org-timer-display 'mode-line)
 312               (eq org-timer-display 'both))
 313       (setq global-mode-string
 314             (delq 'org-timer-mode-line-string global-mode-string)))
 315     (when (or (eq org-timer-display 'frame-title)
 316               (eq org-timer-display 'both))
 317       (setq frame-title-format
 318             (delq 'org-timer-mode-line-string frame-title-format)))
 319     (force-mode-line-update))
 320    ((equal value 'pause)
 321     (when org-timer-mode-line-timer
 322       (cancel-timer org-timer-mode-line-timer)
 323       (setq org-timer-mode-line-timer nil)))
 324    ((equal value 'on)
 325     (when (or (eq org-timer-display 'mode-line)
 326               (eq org-timer-display 'both))
 327       (or global-mode-string (setq global-mode-string '("")))
 328       (or (memq 'org-timer-mode-line-string global-mode-string)
 329           (setq global-mode-string
 330                 (append global-mode-string '(org-timer-mode-line-string)))))
 331     (when (or (eq org-timer-display 'frame-title)
 332               (eq org-timer-display 'both))
 333       (or (memq 'org-timer-mode-line-string frame-title-format)
 334           (setq frame-title-format
 335                 (append frame-title-format '(org-timer-mode-line-string)))))
 336     (org-timer-update-mode-line)
 337     (when org-timer-mode-line-timer
 338       (cancel-timer org-timer-mode-line-timer)
 339       (setq org-timer-mode-line-timer nil))
 340     (when org-timer-display
 341       (setq org-timer-mode-line-timer
 342             (run-with-timer 1 1 'org-timer-update-mode-line))))))
 343
 344 (defun org-timer-update-mode-line ()
 345   "Update the timer time in the mode line."
 346   (if org-timer-pause-time
 347       nil
 348     (setq org-timer-mode-line-string
 349           (concat " <" (substring (org-timer-value-string) 0 -1) ">"))
 350     (force-mode-line-update)))
 351
 352 (defun org-timer-cancel-timer ()
 353   "Cancel the current timer."
 354   (interactive)
 355   (when (eval org-timer-current-timer)
 356     (run-hooks 'org-timer-cancel-hook)
 357     (cancel-timer org-timer-current-timer)
 358     (setq org-timer-current-timer nil)
 359     (setq org-timer-timer-is-countdown nil)
 360     (org-timer-set-mode-line 'off))
 361   (message "Last timer canceled"))
 362
 363 (defun org-timer-show-remaining-time ()
 364   "Display the remaining time before the timer ends."
 365   (interactive)
 366   (require 'time)
 367   (if (not org-timer-current-timer)
 368       (message "No timer set")
 369     (let* ((rtime (decode-time
 370                    (time-subtract (timer--time org-timer-current-timer)
 371                                   (current-time))))
 372            (rsecs (nth 0 rtime))
 373            (rmins (nth 1 rtime)))
 374       (message "%d minute(s) %d seconds left before next time out"
 375                rmins rsecs))))
 376
 377 (defvar org-clock-sound)
 378
 379 ;;;###autoload
 380 (defun org-timer-set-timer (&optional opt)
 381   "Prompt for a duration and set a timer.
 382
 383 If `org-timer-default-timer' is not zero, suggest this value as
 384 the default duration for the timer.  If a timer is already set,
 385 prompt the user if she wants to replace it.
 386
 387 Called with a numeric prefix argument, use this numeric value as
 388 the duration of the timer.
 389
 390 Called with a `C-u' prefix arguments, use `org-timer-default-timer'
 391 without prompting the user for a duration.
 392
 393 With two `C-u' prefix arguments, use `org-timer-default-timer'
 394 without prompting the user for a duration and automatically
 395 replace any running timer."
 396   (interactive "P")
 397   (let ((minutes (or (and (numberp opt) (number-to-string opt))
 398                      (and (listp opt) (not (null opt))
 399                           (number-to-string org-timer-default-timer))
 400                      (read-from-minibuffer
 401                       "How many minutes left? "
 402                       (if (not (eq org-timer-default-timer 0))
 403                           (number-to-string org-timer-default-timer))))))
 404     (if (not (string-match "[0-9]+" minutes))
 405         (org-timer-show-remaining-time)
 406       (let* ((mins (string-to-number (match-string 0 minutes)))
 407              (secs (* mins 60))
 408              (hl (cond
 409                   ((string-match "Org Agenda" (buffer-name))
 410                    (let* ((marker (or (get-text-property (point) 'org-marker)
 411                                       (org-agenda-error)))
 412                           (hdmarker (or (get-text-property (point) 'org-hd-marker)
 413                                         marker))
 414                           (pos (marker-position marker)))
 415                      (with-current-buffer (marker-buffer marker)
 416                        (widen)
 417                        (goto-char pos)
 418                        (org-show-entry)
 419                        (or (ignore-errors (org-get-heading))
 420                            (concat "File:" (file-name-nondirectory (buffer-file-name)))))))
 421                   ((derived-mode-p 'org-mode)
 422                    (or (ignore-errors (org-get-heading))
 423                        (concat "File:" (file-name-nondirectory (buffer-file-name)))))
 424                   (t (error "Not in an Org buffer"))))
 425              timer-set)
 426         (if (or (and org-timer-current-timer
 427                      (or (equal opt '(16))
 428                          (y-or-n-p "Replace current timer? ")))
 429                 (not org-timer-current-timer))
 430             (progn
 431               (require 'org-clock)
 432               (when org-timer-current-timer
 433                 (cancel-timer org-timer-current-timer))
 434               (setq org-timer-current-timer
 435                     (run-with-timer
 436                      secs nil `(lambda ()
 437                                  (setq org-timer-current-timer nil)
 438                                  (org-notify ,(format "%s: time out" hl) ,org-clock-sound)
 439                                  (setq org-timer-timer-is-countdown nil)
 440                                  (org-timer-set-mode-line 'off)
 441                                  (run-hooks 'org-timer-done-hook))))
 442               (run-hooks 'org-timer-set-hook)
 443               (setq org-timer-timer-is-countdown t
 444                     org-timer-start-time
 445                     (time-add (current-time) (seconds-to-time (* mins 60))))
 446               (org-timer-set-mode-line 'on))
 447           (message "No timer set"))))))
 448
 449 (provide 'org-timer)
 450
 451 ;; Local variables:
 452 ;; generated-autoload-file: "org-loaddefs.el"
 453 ;; End:
 454
 455 ;;; org-timer.el ends here