lisp/image-mode.el

   1 ;;; image-mode.el --- support for visiting image files
   2 ;;
   3 ;; Copyright (C) 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Richard Stallman <rms@gnu.org>
   6 ;; Keywords: multimedia
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Defines a major mode for visiting image files
  26 ;; that allows conversion between viewing the text of the file
  27 ;; and viewing the file as an image.  Viewing the image
  28 ;; works by putting a `display' text-property on the
  29 ;; image data, with the image-data still present underneath; if the
  30 ;; resulting buffer file is saved to another name it will correctly save
  31 ;; the image data to the new file.
  32
  33 ;;; Code:
  34
  35 (require 'image)
  36 (eval-when-compile (require 'cl))
  37
  38 ;;;###autoload (push '("\\.jpe?g\\'"    . image-mode) auto-mode-alist)
  39 ;;;###autoload (push '("\\.png\\'"      . image-mode) auto-mode-alist)
  40 ;;;###autoload (push '("\\.gif\\'"      . image-mode) auto-mode-alist)
  41 ;;;###autoload (push '("\\.tiff?\\'"    . image-mode) auto-mode-alist)
  42 ;;;###autoload (push '("\\.p[bpgn]m\\'" . image-mode) auto-mode-alist)
  43
  44 ;;;###autoload (push '("\\.x[bp]m\\'"   . c-mode)     auto-mode-alist)
  45 ;;;###autoload (push '("\\.x[bp]m\\'"   . image-mode-maybe) auto-mode-alist)
  46
  47 ;;;###autoload (push '("\\.svgz?\\'"    . xml-mode)   auto-mode-alist)
  48 ;;;###autoload (push '("\\.svgz?\\'"    . image-mode-maybe) auto-mode-alist)
  49
  50 ;;; Image mode window-info management.
  51
  52 (defvar image-mode-winprops-alist t)
  53 (make-variable-buffer-local 'image-mode-winprops-alist)
  54
  55 (defvar image-mode-new-window-functions nil
  56   "Special hook run when image data is requested in a new window.
  57 It is called with one argument, the initial WINPROPS.")
  58
  59 (defun image-mode-winprops (&optional window cleanup)
  60   "Return winprops of WINDOW.
  61 A winprops object has the shape (WINDOW . ALIST)."
  62   (cond ((null window)
  63          (setq window (selected-window)))
  64         ((not (windowp window))
  65          (error "Not a window: %s" window)))
  66   (when cleanup
  67     (setq image-mode-winprops-alist
  68           (delq nil (mapcar (lambda (winprop)
  69                               (if (window-live-p (car-safe winprop))
  70                                   winprop))
  71                             image-mode-winprops-alist))))
  72   (let ((winprops (assq window image-mode-winprops-alist)))
  73     ;; For new windows, set defaults from the latest.
  74     (unless winprops
  75       (setq winprops (cons window
  76                            (copy-alist (cdar image-mode-winprops-alist))))
  77       (run-hook-with-args 'image-mode-new-window-functions winprops))
  78     ;; Move window to front.
  79     (setq image-mode-winprops-alist
  80           (cons winprops (delq winprops image-mode-winprops-alist)))
  81     winprops))
  82
  83 (defun image-mode-window-get (prop &optional winprops)
  84   (unless (consp winprops) (setq winprops (image-mode-winprops winprops)))
  85   (cdr (assq prop (cdr winprops))))
  86
  87 (defsetf image-mode-window-get (prop &optional winprops) (val)
  88   `(image-mode-window-put ,prop ,val ,winprops))
  89
  90 (defun image-mode-window-put (prop val &optional winprops)
  91   (unless (consp winprops) (setq winprops (image-mode-winprops winprops)))
  92   (setcdr winprops (cons (cons prop val)
  93                          (delq (assq prop (cdr winprops)) (cdr winprops)))))
  94
  95 (defun image-set-window-vscroll (vscroll)
  96   (setf (image-mode-window-get 'vscroll) vscroll)
  97   (set-window-vscroll (selected-window) vscroll))
  98
  99 (defun image-set-window-hscroll (ncol)
 100   (setf (image-mode-window-get 'hscroll) ncol)
 101   (set-window-hscroll (selected-window) ncol))
 102
 103 (defun image-mode-reapply-winprops ()
 104   ;; When set-window-buffer, set hscroll and vscroll to what they were
 105   ;; last time the image was displayed in this window.
 106   (when (and (image-get-display-property)
 107              (listp image-mode-winprops-alist))
 108     (let* ((winprops (image-mode-winprops nil t))
 109            (hscroll (image-mode-window-get 'hscroll winprops))
 110            (vscroll (image-mode-window-get 'vscroll winprops)))
 111       (if hscroll (set-window-hscroll (selected-window) hscroll))
 112       (if vscroll (set-window-vscroll (selected-window) vscroll)))))
 113
 114 (defun image-mode-setup-winprops ()
 115   ;; Record current scroll settings.
 116   (unless (listp image-mode-winprops-alist)
 117     (setq image-mode-winprops-alist nil))
 118   (add-hook 'window-configuration-change-hook
 119             'image-mode-reapply-winprops nil t))
 120
 121 ;;; Image scrolling functions
 122
 123 (defun image-get-display-property ()
 124   (get-char-property (point-min) 'display
 125                      ;; There might be different images for different displays.
 126                      (if (eq (window-buffer) (current-buffer))
 127                          (selected-window))))
 128
 129 (declare-function image-size "image.c" (spec &optional pixels frame))
 130
 131 (defun image-forward-hscroll (&optional n)
 132   "Scroll image in current window to the left by N character widths.
 133 Stop if the right edge of the image is reached."
 134   (interactive "p")
 135   (cond ((= n 0) nil)
 136         ((< n 0)
 137          (image-set-window-hscroll (max 0 (+ (window-hscroll) n))))
 138         (t
 139          (let* ((image (image-get-display-property))
 140                 (edges (window-inside-edges))
 141                 (win-width (- (nth 2 edges) (nth 0 edges)))
 142                 (img-width (ceiling (car (image-size image)))))
 143            (image-set-window-hscroll (min (max 0 (- img-width win-width))
 144                                           (+ n (window-hscroll))))))))
 145
 146 (defun image-backward-hscroll (&optional n)
 147   "Scroll image in current window to the right by N character widths.
 148 Stop if the left edge of the image is reached."
 149   (interactive "p")
 150   (image-forward-hscroll (- n)))
 151
 152 (defun image-next-line (&optional n)
 153   "Scroll image in current window upward by N lines.
 154 Stop if the bottom edge of the image is reached."
 155   (interactive "p")
 156   (cond ((= n 0) nil)
 157         ((< n 0)
 158          (image-set-window-vscroll (max 0 (+ (window-vscroll) n))))
 159         (t
 160          (let* ((image (image-get-display-property))
 161                 (edges (window-inside-edges))
 162                 (win-height (- (nth 3 edges) (nth 1 edges)))
 163                 (img-height (ceiling (cdr (image-size image)))))
 164            (image-set-window-vscroll (min (max 0 (- img-height win-height))
 165                                           (+ n (window-vscroll))))))))
 166
 167 (defun image-previous-line (&optional n)
 168   "Scroll image in current window downward by N lines.
 169 Stop if the top edge of the image is reached."
 170   (interactive "p")
 171   (image-next-line (- n)))
 172
 173 (defun image-scroll-up (&optional n)
 174   "Scroll image in current window upward by N lines.
 175 Stop if the bottom edge of the image is reached.
 176 If ARG is omitted or nil, scroll upward by a near full screen.
 177 A near full screen is `next-screen-context-lines' less than a full screen.
 178 Negative ARG means scroll downward.
 179 If ARG is the atom `-', scroll downward by nearly full screen.
 180 When calling from a program, supply as argument a number, nil, or `-'."
 181   (interactive "P")
 182   (cond ((null n)
 183          (let* ((edges (window-inside-edges))
 184                 (win-height (- (nth 3 edges) (nth 1 edges))))
 185            (image-next-line
 186             (max 0 (- win-height next-screen-context-lines)))))
 187         ((eq n '-)
 188          (let* ((edges (window-inside-edges))
 189                 (win-height (- (nth 3 edges) (nth 1 edges))))
 190            (image-next-line
 191             (min 0 (- next-screen-context-lines win-height)))))
 192         (t (image-next-line (prefix-numeric-value n)))))
 193
 194 (defun image-scroll-down (&optional n)
 195   "Scroll image in current window downward by N lines.
 196 Stop if the top edge of the image is reached.
 197 If ARG is omitted or nil, scroll downward by a near full screen.
 198 A near full screen is `next-screen-context-lines' less than a full screen.
 199 Negative ARG means scroll upward.
 200 If ARG is the atom `-', scroll upward by nearly full screen.
 201 When calling from a program, supply as argument a number, nil, or `-'."
 202   (interactive "P")
 203   (cond ((null n)
 204          (let* ((edges (window-inside-edges))
 205                 (win-height (- (nth 3 edges) (nth 1 edges))))
 206            (image-next-line
 207             (min 0 (- next-screen-context-lines win-height)))))
 208         ((eq n '-)
 209          (let* ((edges (window-inside-edges))
 210                 (win-height (- (nth 3 edges) (nth 1 edges))))
 211            (image-next-line
 212             (max 0 (- win-height next-screen-context-lines)))))
 213         (t (image-next-line (- (prefix-numeric-value n))))))
 214
 215 (defun image-bol (arg)
 216   "Scroll horizontally to the left edge of the image in the current window.
 217 With argument ARG not nil or 1, move forward ARG - 1 lines first,
 218 stopping if the top or bottom edge of the image is reached."
 219   (interactive "p")
 220   (and arg
 221        (/= (setq arg (prefix-numeric-value arg)) 1)
 222        (image-next-line (- arg 1)))
 223   (image-set-window-hscroll 0))
 224
 225 (defun image-eol (arg)
 226   "Scroll horizontally to the right edge of the image in the current window.
 227 With argument ARG not nil or 1, move forward ARG - 1 lines first,
 228 stopping if the top or bottom edge of the image is reached."
 229   (interactive "p")
 230   (and arg
 231        (/= (setq arg (prefix-numeric-value arg)) 1)
 232        (image-next-line (- arg 1)))
 233   (let* ((image (image-get-display-property))
 234          (edges (window-inside-edges))
 235          (win-width (- (nth 2 edges) (nth 0 edges)))
 236          (img-width (ceiling (car (image-size image)))))
 237     (image-set-window-hscroll (max 0 (- img-width win-width)))))
 238
 239 (defun image-bob ()
 240   "Scroll to the top-left corner of the image in the current window."
 241   (interactive)
 242   (image-set-window-hscroll 0)
 243   (image-set-window-vscroll 0))
 244
 245 (defun image-eob ()
 246   "Scroll to the bottom-right corner of the image in the current window."
 247   (interactive)
 248   (let* ((image (image-get-display-property))
 249          (edges (window-inside-edges))
 250          (win-width (- (nth 2 edges) (nth 0 edges)))
 251          (img-width (ceiling (car (image-size image))))
 252          (win-height (- (nth 3 edges) (nth 1 edges)))
 253          (img-height (ceiling (cdr (image-size image)))))
 254     (image-set-window-hscroll (max 0 (- img-width win-width)))
 255     (image-set-window-vscroll (max 0 (- img-height win-height)))))
 256
 257 ;; Adjust frame and image size.
 258
 259 (defun image-mode-fit-frame ()
 260   "Fit the frame to the current image.
 261 This function assumes the current frame has only one window."
 262   ;; FIXME: This does not take into account decorations like mode-line,
 263   ;; minibuffer, header-line, ...
 264   (interactive)
 265   (let* ((saved (frame-parameter nil 'image-mode-saved-size))
 266          (display (image-get-display-property))
 267          (size (image-size display)))
 268     (if (and saved
 269              (eq (caar saved) (frame-width))
 270              (eq (cdar saved) (frame-height)))
 271         (progn ;; Toggle back to previous non-fitted size.
 272           (set-frame-parameter nil 'image-mode-saved-size nil)
 273           (setq size (cdr saved)))
 274       ;; Round up size, and save current size so we can toggle back to it.
 275       (setcar size (ceiling (car size)))
 276       (setcdr size (ceiling (cdr size)))
 277       (set-frame-parameter nil 'image-mode-saved-size
 278                            (cons size (cons (frame-width) (frame-height)))))
 279     (set-frame-width  (selected-frame) (car size))
 280     (set-frame-height (selected-frame) (cdr size))))
 281
 282 ;;; Image Mode setup
 283
 284 (defvar image-type nil
 285   "Current image type.
 286 This variable is used to display the current image type in the mode line.")
 287 (make-variable-buffer-local 'image-type)
 288
 289 (defvar image-mode-map
 290   (let ((map (make-sparse-keymap)))
 291     (suppress-keymap map)
 292     (define-key map "q"         'quit-window)
 293     (define-key map "\C-c\C-c" 'image-toggle-display)
 294     (define-key map (kbd "SPC")       'image-scroll-up)
 295     (define-key map (kbd "DEL")       'image-scroll-down)
 296     (define-key map [remap forward-char] 'image-forward-hscroll)
 297     (define-key map [remap backward-char] 'image-backward-hscroll)
 298     (define-key map [remap previous-line] 'image-previous-line)
 299     (define-key map [remap next-line] 'image-next-line)
 300     (define-key map [remap scroll-up] 'image-scroll-up)
 301     (define-key map [remap scroll-down] 'image-scroll-down)
 302     (define-key map [remap move-beginning-of-line] 'image-bol)
 303     (define-key map [remap move-end-of-line] 'image-eol)
 304     (define-key map [remap beginning-of-buffer] 'image-bob)
 305     (define-key map [remap end-of-buffer] 'image-eob)
 306     map)
 307   "Major mode keymap for viewing images in Image mode.")
 308
 309 (defvar image-mode-text-map
 310   (let ((map (make-sparse-keymap)))
 311     (define-key map "\C-c\C-c" 'image-toggle-display)
 312     map)
 313   "Major mode keymap for viewing images as text in Image mode.")
 314
 315 (defvar bookmark-make-record-function)
 316
 317 ;;;###autoload
 318 (defun image-mode ()
 319   "Major mode for image files.
 320 You can use \\<image-mode-map>\\[image-toggle-display]
 321 to toggle between display as an image and display as text."
 322   (interactive)
 323   (kill-all-local-variables)
 324   (setq major-mode 'image-mode)
 325   ;; Use our own bookmarking function for images.
 326   (set (make-local-variable 'bookmark-make-record-function)
 327        'image-bookmark-make-record)
 328
 329   ;; Keep track of [vh]scroll when switching buffers
 330   (image-mode-setup-winprops)
 331
 332   (add-hook 'change-major-mode-hook 'image-toggle-display-text nil t)
 333   (if (display-images-p)
 334       (if (not (image-get-display-property))
 335           (image-toggle-display)
 336         ;; Set next vars when image is already displayed but local
 337         ;; variables were cleared by kill-all-local-variables
 338         (use-local-map image-mode-map)
 339         (setq cursor-type nil truncate-lines t
 340               image-type (plist-get (cdr (image-get-display-property)) :type)))
 341     (setq image-type "text")
 342     (use-local-map image-mode-text-map))
 343   (setq mode-name (format "Image[%s]" image-type))
 344   (run-mode-hooks 'image-mode-hook)
 345   (if (display-images-p)
 346       (message "%s" (concat
 347                      (substitute-command-keys
 348                       "Type \\[image-toggle-display] to view as ")
 349                      (if (image-get-display-property)
 350                          "text" "an image") "."))))
 351
 352 ;;;###autoload
 353 (define-minor-mode image-minor-mode
 354   "Toggle Image minor mode.
 355 With arg, turn Image minor mode on if arg is positive, off otherwise.
 356 See the command `image-mode' for more information on this mode."
 357   nil (:eval (format " Image[%s]" image-type)) image-mode-text-map
 358   :group 'image
 359   :version "22.1"
 360   (if (not image-minor-mode)
 361       (image-toggle-display-text)
 362     (image-mode-setup-winprops)
 363     (add-hook 'change-major-mode-hook (lambda () (image-minor-mode -1)) nil t)
 364     (if (display-images-p)
 365         (if (not (image-get-display-property))
 366             (image-toggle-display)
 367           (setq cursor-type nil truncate-lines t
 368                 image-type (plist-get (cdr (image-get-display-property)) :type)))
 369       (setq image-type "text")
 370       (use-local-map image-mode-text-map))
 371     (if (display-images-p)
 372         (message "%s" (concat
 373                        (substitute-command-keys
 374                         "Type \\[image-toggle-display] to view the image as ")
 375                        (if (image-get-display-property)
 376                            "text" "an image") ".")))))
 377
 378 ;;;###autoload
 379 (defun image-mode-maybe ()
 380   "Set major or minor mode for image files.
 381 Set Image major mode only when there are no other major modes
 382 associated with a filename in `auto-mode-alist'.  When an image
 383 filename matches another major mode in `auto-mode-alist' then
 384 set that major mode and Image minor mode.
 385
 386 See commands `image-mode' and `image-minor-mode' for more
 387 information on these modes."
 388   (interactive)
 389   (let* ((mode-alist
 390           (delq nil (mapcar
 391                      (lambda (elt)
 392                        (unless (memq (or (car-safe (cdr elt)) (cdr elt))
 393                                      '(image-mode image-mode-maybe))
 394                          elt))
 395                      auto-mode-alist))))
 396     (if (assoc-default buffer-file-name mode-alist 'string-match)
 397         (let ((auto-mode-alist mode-alist)
 398               (magic-mode-alist nil))
 399           (set-auto-mode)
 400           (image-minor-mode t))
 401       (image-mode))))
 402
 403 (defun image-toggle-display-text ()
 404   "Showing the text of the image file."
 405   (if (image-get-display-property)
 406       (image-toggle-display)))
 407
 408 (defvar archive-superior-buffer)
 409 (defvar tar-superior-buffer)
 410 (declare-function image-refresh "image.c" (spec &optional frame))
 411
 412 (defun image-toggle-display ()
 413   "Start or stop displaying an image file as the actual image.
 414 This command toggles between showing the text of the image file
 415 and showing the image as an image."
 416   (interactive)
 417   (if (image-get-display-property)
 418       (let ((inhibit-read-only t)
 419             (buffer-undo-list t)
 420             (modified (buffer-modified-p)))
 421         (remove-list-of-text-properties (point-min) (point-max)
 422                                         '(display intangible read-nonsticky
 423                                                   read-only front-sticky))
 424         (set-buffer-modified-p modified)
 425         (kill-local-variable 'cursor-type)
 426         (kill-local-variable 'truncate-lines)
 427         (kill-local-variable 'auto-hscroll-mode)
 428         (use-local-map image-mode-text-map)
 429         (setq image-type "text")
 430         (if (eq major-mode 'image-mode)
 431             (setq mode-name "Image[text]"))
 432         (if (called-interactively-p 'any)
 433             (message "Repeat this command to go back to displaying the image")))
 434     ;; Turn the image data into a real image, but only if the whole file
 435     ;; was inserted
 436     (let* ((filename (buffer-file-name))
 437            (data-p (not (and filename
 438                              (file-readable-p filename)
 439                              (not (file-remote-p filename))
 440                              (not (buffer-modified-p))
 441                              (not (and (boundp 'archive-superior-buffer)
 442                                        archive-superior-buffer))
 443                              (not (and (boundp 'tar-superior-buffer)
 444                                        tar-superior-buffer)))))
 445            (file-or-data (if data-p
 446                              (string-make-unibyte
 447                               (buffer-substring-no-properties (point-min) (point-max)))
 448                            filename))
 449            (type (image-type file-or-data nil data-p))
 450            (image (create-image file-or-data type data-p))
 451            (props
 452             `(display ,image
 453                       intangible ,image
 454                       rear-nonsticky (display intangible)
 455                       read-only t front-sticky (read-only)))
 456            (inhibit-read-only t)
 457            (buffer-undo-list t)
 458            (modified (buffer-modified-p)))
 459       (image-refresh image)
 460       (let ((buffer-file-truename nil)) ; avoid changing dir mtime by lock_file
 461         (add-text-properties (point-min) (point-max) props)
 462         (restore-buffer-modified-p modified))
 463       ;; Inhibit the cursor when the buffer contains only an image,
 464       ;; because cursors look very strange on top of images.
 465       (setq cursor-type nil)
 466       ;; This just makes the arrow displayed in the right fringe
 467       ;; area look correct when the image is wider than the window.
 468       (setq truncate-lines t)
 469       ;; Allow navigation of large images
 470       (set (make-local-variable 'auto-hscroll-mode) nil)
 471       (use-local-map image-mode-map)
 472       (setq image-type type)
 473       (if (eq major-mode 'image-mode)
 474           (setq mode-name (format "Image[%s]" type)))
 475       (if (called-interactively-p 'any)
 476           (message "Repeat this command to go back to displaying the file as text")))))
 477 \f
 478 ;;; Support for bookmark.el
 479 (declare-function bookmark-make-record-default "bookmark"
 480                   (&optional point-only))
 481 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
 482 (declare-function bookmark-default-handler "bookmark" (bmk))
 483
 484 (defun image-bookmark-make-record ()
 485   (nconc (bookmark-make-record-default)
 486          `((image-type . ,image-type)
 487            (handler    . image-bookmark-jump))))
 488
 489 ;;;###autoload
 490 (defun image-bookmark-jump (bmk)
 491   ;; This implements the `handler' function interface for record type
 492   ;; returned by `bookmark-make-record-function', which see.
 493   (prog1 (bookmark-default-handler bmk)
 494     (when (not (string= image-type (bookmark-prop-get bmk 'image-type)))
 495       (image-toggle-display))))
 496 \f
 497 (provide 'image-mode)
 498
 499 ;; arch-tag: b5b2b7e6-26a7-4b79-96e3-1546b5c4c6cb
 500 ;;; image-mode.el ends here