lisp/gnus/pop3.el

   1 ;;; pop3.el --- Post Office Protocol (RFC 1460) interface
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Richard L. Pieri <ratinox@peorth.gweep.net>
   7 ;; Maintainer: FSF
   8 ;; Keywords: mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Most of the standard Post Office Protocol version 3 (RFC 1460) commands
  28 ;; are implemented.  The LIST command has not been implemented due to lack
  29 ;; of actual usefulness.
  30 ;; The optional POP3 command TOP has not been implemented.
  31
  32 ;; This program was inspired by Kyle E. Jones's vm-pop program.
  33
  34 ;;; Code:
  35
  36 (require 'mail-utils)
  37 (defvar parse-time-months)
  38
  39 (defgroup pop3 nil
  40   "Post Office Protocol."
  41   :group 'mail
  42   :group 'mail-source)
  43
  44 (defcustom pop3-maildrop (or (user-login-name)
  45                              (getenv "LOGNAME")
  46                              (getenv "USER"))
  47   "*POP3 maildrop."
  48   :version "22.1" ;; Oort Gnus
  49   :type 'string
  50   :group 'pop3)
  51
  52 (defcustom pop3-mailhost (or (getenv "MAILHOST") ;; nil -> mismatch
  53                              "pop3")
  54   "*POP3 mailhost."
  55   :version "22.1" ;; Oort Gnus
  56   :type 'string
  57   :group 'pop3)
  58
  59 (defcustom pop3-port 110
  60   "*POP3 port."
  61   :version "22.1" ;; Oort Gnus
  62   :type 'number
  63   :group 'pop3)
  64
  65 (defcustom pop3-password-required t
  66   "*Non-nil if a password is required when connecting to POP server."
  67   :version "22.1" ;; Oort Gnus
  68   :type 'boolean
  69   :group 'pop3)
  70
  71 ;; Should this be customizable?
  72 (defvar pop3-password nil
  73   "*Password to use when connecting to POP server.")
  74
  75 (defcustom pop3-authentication-scheme 'pass
  76   "*POP3 authentication scheme.
  77 Defaults to `pass', for the standard USER/PASS authentication.  The other
  78 valid value is 'apop'."
  79   :type '(choice (const :tag "Normal user/password" pass)
  80                  (const :tag "APOP" apop))
  81   :version "22.1" ;; Oort Gnus
  82   :group 'pop3)
  83
  84 (defcustom pop3-leave-mail-on-server nil
  85   "*Non-nil if the mail is to be left on the POP server after fetching.
  86
  87 If `pop3-leave-mail-on-server' is non-nil the mail is to be left
  88 on the POP server after fetching.  Note that POP servers maintain
  89 no state information between sessions, so what the client
  90 believes is there and what is actually there may not match up.
  91 If they do not, then you may get duplicate mails or the whole
  92 thing can fall apart and leave you with a corrupt mailbox."
  93   ;; We can't use the UILD support from XEmacs mail-lib or cvs.m17n.org:
  94   ;; http://thread.gmane.org/v9lld8fml4.fsf@marauder.physik.uni-ulm.de
  95   ;; http://thread.gmane.org/b9yy8hzy9ej.fsf@jpl.org
  96   ;; Any volunteer to re-implement this?
  97   :version "22.1" ;; Oort Gnus
  98   :type 'boolean
  99   :group 'pop3)
 100
 101 (defvar pop3-timestamp nil
 102   "Timestamp returned when initially connected to the POP server.
 103 Used for APOP authentication.")
 104
 105 (defvar pop3-read-point nil)
 106 (defvar pop3-debug nil)
 107
 108 ;; Borrowed from nnheader-accept-process-output in nnheader.el.  See the
 109 ;; comments there for explanations about the values.
 110
 111 (eval-and-compile
 112   (if (and (fboundp 'nnheader-accept-process-output)
 113            (boundp 'nnheader-read-timeout))
 114       (defalias 'pop3-accept-process-output 'nnheader-accept-process-output)
 115     ;; Borrowed from `nnheader.el':
 116     (defvar pop3-read-timeout
 117       (if (string-match "windows-nt\\|os/2\\|emx\\|cygwin"
 118                         (symbol-name system-type))
 119           1.0
 120         0.01)
 121       "How long pop3 should wait between checking for the end of output.
 122 Shorter values mean quicker response, but are more CPU intensive.")
 123     (defun pop3-accept-process-output (process)
 124       (accept-process-output
 125        process
 126        (truncate pop3-read-timeout)
 127        (truncate (* (- pop3-read-timeout
 128                        (truncate pop3-read-timeout))
 129                     1000))))))
 130
 131 (defun pop3-movemail (&optional crashbox)
 132   "Transfer contents of a maildrop to the specified CRASHBOX."
 133   (or crashbox (setq crashbox (expand-file-name "~/.crashbox")))
 134   (let* ((process (pop3-open-server pop3-mailhost pop3-port))
 135          (crashbuf (get-buffer-create " *pop3-retr*"))
 136          (n 1)
 137          message-count
 138          (pop3-password pop3-password))
 139     ;; for debugging only
 140     (if pop3-debug (switch-to-buffer (process-buffer process)))
 141     ;; query for password
 142     (if (and pop3-password-required (not pop3-password))
 143         (setq pop3-password
 144               (read-passwd (format "Password for %s: " pop3-maildrop))))
 145     (cond ((equal 'apop pop3-authentication-scheme)
 146            (pop3-apop process pop3-maildrop))
 147           ((equal 'pass pop3-authentication-scheme)
 148            (pop3-user process pop3-maildrop)
 149            (pop3-pass process))
 150           (t (error "Invalid POP3 authentication scheme")))
 151     (setq message-count (car (pop3-stat process)))
 152     (unwind-protect
 153         (while (<= n message-count)
 154           (message "Retrieving message %d of %d from %s..."
 155                    n message-count pop3-mailhost)
 156           (pop3-retr process n crashbuf)
 157           (save-excursion
 158             (set-buffer crashbuf)
 159             (let ((coding-system-for-write 'binary))
 160               (write-region (point-min) (point-max) crashbox t 'nomesg))
 161             (set-buffer (process-buffer process))
 162             (while (> (buffer-size) 5000)
 163               (goto-char (point-min))
 164               (forward-line 50)
 165               (delete-region (point-min) (point))))
 166           (unless pop3-leave-mail-on-server
 167             (pop3-dele process n))
 168           (setq n (+ 1 n))
 169           (pop3-accept-process-output process))
 170       (when (and pop3-leave-mail-on-server
 171                  (> n 1))
 172         (message "pop3.el doesn't support UIDL.  Setting `pop3-leave-mail-on-server'
 173 to %s might not give the result you'd expect." pop3-leave-mail-on-server)
 174         (sit-for 1))
 175       (pop3-quit process))
 176     (kill-buffer crashbuf))
 177   t)
 178
 179 (defun pop3-get-message-count ()
 180   "Return the number of messages in the maildrop."
 181   (let* ((process (pop3-open-server pop3-mailhost pop3-port))
 182          message-count
 183          (pop3-password pop3-password))
 184     ;; for debugging only
 185     (if pop3-debug (switch-to-buffer (process-buffer process)))
 186     ;; query for password
 187     (if (and pop3-password-required (not pop3-password))
 188         (setq pop3-password
 189               (read-passwd (format "Password for %s: " pop3-maildrop))))
 190     (cond ((equal 'apop pop3-authentication-scheme)
 191            (pop3-apop process pop3-maildrop))
 192           ((equal 'pass pop3-authentication-scheme)
 193            (pop3-user process pop3-maildrop)
 194            (pop3-pass process))
 195           (t (error "Invalid POP3 authentication scheme")))
 196     (setq message-count (car (pop3-stat process)))
 197     (pop3-quit process)
 198     message-count))
 199
 200 (autoload 'open-tls-stream "tls")
 201 (autoload 'starttls-open-stream "starttls")
 202 (autoload 'starttls-negotiate "starttls") ; avoid warning
 203
 204 (defcustom pop3-stream-type nil
 205   "*Transport security type for POP3 connexions.
 206 This may be either nil (plain connexion), `ssl' (use an
 207 SSL/TSL-secured stream) or `starttls' (use the starttls mechanism
 208 to turn on TLS security after opening the stream).  However, if
 209 this is nil, `ssl' is assumed for connexions to port
 210 995 (pop3s)."
 211   :version "23.1" ;; No Gnus
 212   :group 'pop3
 213   :type '(choice (const :tag "Plain" nil)
 214                  (const :tag "SSL/TLS" ssl)
 215                  (const starttls)))
 216
 217 (defun pop3-open-server (mailhost port)
 218   "Open TCP connection to MAILHOST on PORT.
 219 Returns the process associated with the connection."
 220   (let ((coding-system-for-read 'binary)
 221         (coding-system-for-write 'binary)
 222         process)
 223     (save-excursion
 224       (set-buffer (get-buffer-create (concat " trace of POP session to "
 225                                              mailhost)))
 226       (erase-buffer)
 227       (setq pop3-read-point (point-min))
 228       (setq process
 229             (cond
 230              ((or (eq pop3-stream-type 'ssl)
 231                   (and (not pop3-stream-type) (member port '(995 "pop3s"))))
 232               ;; gnutls-cli, openssl don't accept service names
 233               (if (or (equal port "pop3s")
 234                       (null port))
 235                   (setq port 995))
 236               (let ((process (open-tls-stream "POP" (current-buffer)
 237                                               mailhost port)))
 238                 (when process
 239                   ;; There's a load of info printed that needs deleting.
 240                   (let ((again 't))
 241                     ;; repeat until
 242                     ;; - either we received the +OK line
 243                     ;; - or accept-process-output timed out without getting
 244                     ;;   anything
 245                     (while (and again
 246                                 (setq again (memq (process-status process)
 247                                                   '(open run))))
 248                       (setq again (pop3-accept-process-output process))
 249                       (goto-char (point-max))
 250                       (forward-line -1)
 251                       (cond ((looking-at "\\+OK")
 252                              (setq again nil)
 253                              (delete-region (point-min) (point)))
 254                             ((not again)
 255                              (pop3-quit process)
 256                              (error "POP SSL connexion failed")))))
 257                   process)))
 258              ((eq pop3-stream-type 'starttls)
 259               ;; gnutls-cli, openssl don't accept service names
 260               (if (equal port "pop3")
 261                   (setq port 110))
 262               (let ((process (starttls-open-stream "POP" (current-buffer)
 263                                                    mailhost (or port 110))))
 264                 (pop3-send-command process "STLS")
 265                 (let ((response (pop3-read-response process t)))
 266                   (if (and response (string-match "+OK" response))
 267                       (starttls-negotiate process)
 268                     (pop3-quit process)
 269                     (error "POP server doesn't support starttls")))
 270                 process))
 271              (t
 272               (open-network-stream "POP" (current-buffer) mailhost port))))
 273       (let ((response (pop3-read-response process t)))
 274         (setq pop3-timestamp
 275               (substring response (or (string-match "<" response) 0)
 276                          (+ 1 (or (string-match ">" response) -1)))))
 277       process)))
 278
 279 ;; Support functions
 280
 281 (defun pop3-process-filter (process output)
 282   (save-excursion
 283     (set-buffer (process-buffer process))
 284     (goto-char (point-max))
 285     (insert output)))
 286
 287 (defun pop3-send-command (process command)
 288   (set-buffer (process-buffer process))
 289   (goto-char (point-max))
 290   ;; (if (= (aref command 0) ?P)
 291   ;;     (insert "PASS <omitted>\r\n")
 292   ;;   (insert command "\r\n"))
 293   (setq pop3-read-point (point))
 294   (goto-char (point-max))
 295   (process-send-string process (concat command "\r\n")))
 296
 297 (defun pop3-read-response (process &optional return)
 298   "Read the response from the server.
 299 Return the response string if optional second argument is non-nil."
 300   (let ((case-fold-search nil)
 301         match-end)
 302     (save-excursion
 303       (set-buffer (process-buffer process))
 304       (goto-char pop3-read-point)
 305       (while (and (memq (process-status process) '(open run))
 306                   (not (search-forward "\r\n" nil t)))
 307         (pop3-accept-process-output process)
 308         (goto-char pop3-read-point))
 309       (setq match-end (point))
 310       (goto-char pop3-read-point)
 311       (if (looking-at "-ERR")
 312           (error "%s" (buffer-substring (point) (- match-end 2)))
 313         (if (not (looking-at "+OK"))
 314             (progn (setq pop3-read-point match-end) nil)
 315           (setq pop3-read-point match-end)
 316           (if return
 317               (buffer-substring (point) match-end)
 318             t)
 319           )))))
 320
 321 (defun pop3-clean-region (start end)
 322   (setq end (set-marker (make-marker) end))
 323   (save-excursion
 324     (goto-char start)
 325     (while (and (< (point) end) (search-forward "\r\n" end t))
 326       (replace-match "\n" t t))
 327     (goto-char start)
 328     (while (and (< (point) end) (re-search-forward "^\\." end t))
 329       (replace-match "" t t)
 330       (forward-char)))
 331   (set-marker end nil))
 332
 333 ;; Copied from message-make-date.
 334 (defun pop3-make-date (&optional now)
 335   "Make a valid date header.
 336 If NOW, use that time instead."
 337   (require 'parse-time)
 338   (let* ((now (or now (current-time)))
 339          (zone (nth 8 (decode-time now)))
 340          (sign "+"))
 341     (when (< zone 0)
 342       (setq sign "-")
 343       (setq zone (- zone)))
 344     (concat
 345      (format-time-string "%d" now)
 346      ;; The month name of the %b spec is locale-specific.  Pfff.
 347      (format " %s "
 348              (capitalize (car (rassoc (nth 4 (decode-time now))
 349                                       parse-time-months))))
 350      (format-time-string "%Y %H:%M:%S " now)
 351      ;; We do all of this because XEmacs doesn't have the %z spec.
 352      (format "%s%02d%02d" sign (/ zone 3600) (/ (% zone 3600) 60)))))
 353
 354 (defun pop3-munge-message-separator (start end)
 355   "Check to see if a message separator exists.  If not, generate one."
 356   (save-excursion
 357     (save-restriction
 358       (narrow-to-region start end)
 359       (goto-char (point-min))
 360       (if (not (or (looking-at "From .?") ; Unix mail
 361                    (looking-at "\001\001\001\001\n") ; MMDF
 362                    (looking-at "BABYL OPTIONS:") ; Babyl
 363                    ))
 364           (let* ((from (mail-strip-quoted-names (mail-fetch-field "From")))
 365                  (tdate (mail-fetch-field "Date"))
 366                  (date (split-string (or (and tdate
 367                                               (not (string= "" tdate))
 368                                               tdate)
 369                                          (pop3-make-date))
 370                                      " "))
 371                  (From_))
 372             ;; sample date formats I have seen
 373             ;; Date: Tue, 9 Jul 1996 09:04:21 -0400 (EDT)
 374             ;; Date: 08 Jul 1996 23:22:24 -0400
 375             ;; should be
 376             ;; Tue Jul 9 09:04:21 1996
 377
 378             ;; Fixme: This should use timezone on the date field contents.
 379             (setq date
 380                   (cond ((not date)
 381                          "Tue Jan 1 00:00:0 1900")
 382                         ((string-match "[A-Z]" (nth 0 date))
 383                          (format "%s %s %s %s %s"
 384                                  (nth 0 date) (nth 2 date) (nth 1 date)
 385                                  (nth 4 date) (nth 3 date)))
 386                         (t
 387                          ;; this really needs to be better but I don't feel
 388                          ;; like writing a date to day converter.
 389                          (format "Sun %s %s %s %s"
 390                                  (nth 1 date) (nth 0 date)
 391                                  (nth 3 date) (nth 2 date)))
 392                         ))
 393             (setq From_ (format "\nFrom %s  %s\n" from date))
 394             (while (string-match "," From_)
 395               (setq From_ (concat (substring From_ 0 (match-beginning 0))
 396                                   (substring From_ (match-end 0)))))
 397             (goto-char (point-min))
 398             (insert From_)
 399             (if (search-forward "\n\n" nil t)
 400                 nil
 401               (goto-char (point-max))
 402               (insert "\n"))
 403             (narrow-to-region (point) (point-max))
 404             (let ((size (- (point-max) (point-min))))
 405               (goto-char (point-min))
 406               (widen)
 407               (forward-line -1)
 408               (insert (format "Content-Length: %s\n" size)))
 409             )))))
 410
 411 ;; The Command Set
 412
 413 ;; AUTHORIZATION STATE
 414
 415 (defun pop3-user (process user)
 416   "Send USER information to POP3 server."
 417   (pop3-send-command process (format "USER %s" user))
 418   (let ((response (pop3-read-response process t)))
 419     (if (not (and response (string-match "+OK" response)))
 420         (error "USER %s not valid" user))))
 421
 422 (defun pop3-pass (process)
 423   "Send authentication information to the server."
 424   (pop3-send-command process (format "PASS %s" pop3-password))
 425   (let ((response (pop3-read-response process t)))
 426     (if (not (and response (string-match "+OK" response)))
 427         (pop3-quit process))))
 428
 429 (defun pop3-apop (process user)
 430   "Send alternate authentication information to the server."
 431   (let ((pass pop3-password))
 432     (if (and pop3-password-required (not pass))
 433         (setq pass
 434               (read-passwd (format "Password for %s: " pop3-maildrop))))
 435     (if pass
 436         (let ((hash (md5 (concat pop3-timestamp pass) nil nil 'binary)))
 437           (pop3-send-command process (format "APOP %s %s" user hash))
 438           (let ((response (pop3-read-response process t)))
 439             (if (not (and response (string-match "+OK" response)))
 440                 (pop3-quit process)))))
 441     ))
 442
 443 ;; TRANSACTION STATE
 444
 445 (defun pop3-stat (process)
 446   "Return the number of messages in the maildrop and the maildrop's size."
 447   (pop3-send-command process "STAT")
 448   (let ((response (pop3-read-response process t)))
 449     (list (string-to-number (nth 1 (split-string response " ")))
 450           (string-to-number (nth 2 (split-string response " "))))
 451     ))
 452
 453 (defun pop3-list (process &optional msg)
 454   "Scan listing of available messages.
 455 This function currently does nothing.")
 456
 457 (defun pop3-retr (process msg crashbuf)
 458   "Retrieve message-id MSG to buffer CRASHBUF."
 459   (pop3-send-command process (format "RETR %s" msg))
 460   (pop3-read-response process)
 461   (let ((start pop3-read-point) end)
 462     (save-excursion
 463       (set-buffer (process-buffer process))
 464       (while (not (re-search-forward "^\\.\r\n" nil t))
 465         (pop3-accept-process-output process)
 466         (goto-char start))
 467       (setq pop3-read-point (point-marker))
 468       ;; this code does not seem to work for some POP servers...
 469       ;; and I cannot figure out why not.
 470       ;;      (goto-char (match-beginning 0))
 471       ;;      (backward-char 2)
 472       ;;      (if (not (looking-at "\r\n"))
 473       ;;          (insert "\r\n"))
 474       ;;      (re-search-forward "\\.\r\n")
 475       (goto-char (match-beginning 0))
 476       (setq end (point-marker))
 477       (pop3-clean-region start end)
 478       (pop3-munge-message-separator start end)
 479       (save-excursion
 480         (set-buffer crashbuf)
 481         (erase-buffer))
 482       (copy-to-buffer crashbuf start end)
 483       (delete-region start end)
 484       )))
 485
 486 (defun pop3-dele (process msg)
 487   "Mark message-id MSG as deleted."
 488   (pop3-send-command process (format "DELE %s" msg))
 489   (pop3-read-response process))
 490
 491 (defun pop3-noop (process msg)
 492   "No-operation."
 493   (pop3-send-command process "NOOP")
 494   (pop3-read-response process))
 495
 496 (defun pop3-last (process)
 497   "Return highest accessed message-id number for the session."
 498   (pop3-send-command process "LAST")
 499   (let ((response (pop3-read-response process t)))
 500     (string-to-number (nth 1 (split-string response " ")))
 501     ))
 502
 503 (defun pop3-rset (process)
 504   "Remove all delete marks from current maildrop."
 505   (pop3-send-command process "RSET")
 506   (pop3-read-response process))
 507
 508 ;; UPDATE
 509
 510 (defun pop3-quit (process)
 511   "Close connection to POP3 server.
 512 Tell server to remove all messages marked as deleted, unlock the maildrop,
 513 and close the connection."
 514   (pop3-send-command process "QUIT")
 515   (pop3-read-response process t)
 516   (if process
 517       (save-excursion
 518         (set-buffer (process-buffer process))
 519         (goto-char (point-max))
 520         (delete-process process))))
 521 \f
 522 ;; Summary of POP3 (Post Office Protocol version 3) commands and responses
 523
 524 ;;; AUTHORIZATION STATE
 525
 526 ;; Initial TCP connection
 527 ;; Arguments: none
 528 ;; Restrictions: none
 529 ;; Possible responses:
 530 ;;  +OK [POP3 server ready]
 531
 532 ;; USER name
 533 ;; Arguments: a server specific user-id (required)
 534 ;; Restrictions: authorization state [after unsuccessful USER or PASS
 535 ;; Possible responses:
 536 ;;  +OK [valid user-id]
 537 ;;  -ERR [invalid user-id]
 538
 539 ;; PASS string
 540 ;; Arguments: a server/user-id specific password (required)
 541 ;; Restrictions: authorization state, after successful USER
 542 ;; Possible responses:
 543 ;;  +OK [maildrop locked and ready]
 544 ;;  -ERR [invalid password]
 545 ;;  -ERR [unable to lock maildrop]
 546
 547 ;; STLS      (RFC 2595)
 548 ;; Arguments: none
 549 ;; Restrictions: Only permitted in AUTHORIZATION state.
 550 ;; Possible responses:
 551 ;;  +OK
 552 ;;  -ERR
 553
 554 ;;; TRANSACTION STATE
 555
 556 ;; STAT
 557 ;; Arguments: none
 558 ;; Restrictions: transaction state
 559 ;; Possible responses:
 560 ;;  +OK nn mm [# of messages, size of maildrop]
 561
 562 ;; LIST [msg]
 563 ;; Arguments: a message-id (optional)
 564 ;; Restrictions: transaction state; msg must not be deleted
 565 ;; Possible responses:
 566 ;;  +OK [scan listing follows]
 567 ;;  -ERR [no such message]
 568
 569 ;; RETR msg
 570 ;; Arguments: a message-id (required)
 571 ;; Restrictions: transaction state; msg must not be deleted
 572 ;; Possible responses:
 573 ;;  +OK [message contents follow]
 574 ;;  -ERR [no such message]
 575
 576 ;; DELE msg
 577 ;; Arguments: a message-id (required)
 578 ;; Restrictions: transaction state; msg must not be deleted
 579 ;; Possible responses:
 580 ;;  +OK [message deleted]
 581 ;;  -ERR [no such message]
 582
 583 ;; NOOP
 584 ;; Arguments: none
 585 ;; Restrictions: transaction state
 586 ;; Possible responses:
 587 ;;  +OK
 588
 589 ;; LAST
 590 ;; Arguments: none
 591 ;; Restrictions: transaction state
 592 ;; Possible responses:
 593 ;;  +OK nn [highest numbered message accessed]
 594
 595 ;; RSET
 596 ;; Arguments: none
 597 ;; Restrictions: transaction state
 598 ;; Possible responses:
 599 ;;  +OK [all delete marks removed]
 600
 601 ;;; UPDATE STATE
 602
 603 ;; QUIT
 604 ;; Arguments: none
 605 ;; Restrictions: none
 606 ;; Possible responses:
 607 ;;  +OK [TCP connection closed]
 608
 609 (provide 'pop3)
 610
 611 ;; arch-tag: 2facc142-1d74-498e-82af-4659b64cac12
 612 ;;; pop3.el ends here