lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains those help commands which are complicated, and
  29 ;; which may not be used in every session.  For example
  30 ;; `describe-function' will probably be heavily used when doing elisp
  31 ;; programming, but not if just editing C files.  Simpler help commands
  32 ;; are in help.el
  33
  34 ;;; Code:
  35
  36 (require 'help-mode)
  37
  38
  39 ;;;###autoload
  40 (defun help-with-tutorial (&optional arg)
  41   "Select the Emacs learn-by-doing tutorial.
  42 If there is a tutorial version written in the language
  43 of the selected language environment, that version is used.
  44 If there's no tutorial in that language, `TUTORIAL' is selected.
  45 With ARG, you are asked to choose which language."
  46   (interactive "P")
  47   (let ((lang (if arg
  48                   (let ((minibuffer-setup-hook minibuffer-setup-hook))
  49                     (add-hook 'minibuffer-setup-hook
  50                               'minibuffer-completion-help)
  51                     (read-language-name 'tutorial "Language: " "English"))
  52                 (if (get-language-info current-language-environment 'tutorial)
  53                     current-language-environment
  54                   "English")))
  55         file filename)
  56     (setq filename (get-language-info lang 'tutorial))
  57     (setq file (expand-file-name (concat "~/" filename)))
  58     (delete-other-windows)
  59     (if (get-file-buffer file)
  60         (switch-to-buffer (get-file-buffer file))
  61       (switch-to-buffer (create-file-buffer file))
  62       (setq buffer-file-name file)
  63       (setq default-directory (expand-file-name "~/"))
  64       (setq buffer-auto-save-file-name nil)
  65       (insert-file-contents (expand-file-name filename data-directory))
  66       (hack-local-variables)
  67       (goto-char (point-min))
  68       (search-forward "\n<<")
  69       (beginning-of-line)
  70       ;; Convert the <<...>> line to the proper [...] line,
  71       ;; or just delete the <<...>> line if a [...] line follows.
  72       (cond ((save-excursion
  73                (forward-line 1)
  74                (looking-at "\\["))
  75              (delete-region (point) (progn (forward-line 1) (point))))
  76             ((looking-at "<<Blank lines inserted.*>>")
  77              (replace-match "[Middle of page left blank for didactic purposes.   Text continues below]"))
  78             (t
  79              (looking-at "<<")
  80              (replace-match "[")
  81              (search-forward ">>")
  82              (replace-match "]")))
  83       (beginning-of-line)
  84       (let ((n (- (window-height (selected-window))
  85                   (count-lines (point-min) (point))
  86                   6)))
  87         (if (< n 8)
  88             (progn
  89               ;; For a short gap, we don't need the [...] line,
  90               ;; so delete it.
  91               (delete-region (point) (progn (end-of-line) (point)))
  92               (newline n))
  93           ;; Some people get confused by the large gap.
  94           (newline (/ n 2))
  95
  96           ;; Skip the [...] line (don't delete it).
  97           (forward-line 1)
  98           (newline (- n (/ n 2)))))
  99       (goto-char (point-min))
 100       (setq buffer-undo-list nil)
 101       (set-buffer-modified-p nil))))
 102
 103 \f
 104 ;; Functions
 105
 106 ;;;###autoload
 107 (defun describe-function (function)
 108   "Display the full documentation of FUNCTION (a symbol)."
 109   (interactive
 110    (let ((fn (function-called-at-point))
 111          (enable-recursive-minibuffers t)
 112          val)
 113      (setq val (completing-read (if fn
 114                                     (format "Describe function (default %s): " fn)
 115                                   "Describe function: ")
 116                                 obarray 'fboundp t nil nil
 117                                 (and fn (symbol-name fn))))
 118      (list (if (equal val "")
 119                fn (intern val)))))
 120   (if (null function)
 121       (message "You didn't specify a function")
 122     (help-setup-xref (list #'describe-function function) (interactive-p))
 123     (save-excursion
 124       (with-output-to-temp-buffer (help-buffer)
 125         (prin1 function)
 126         ;; Use " is " instead of a colon so that
 127         ;; it is easier to get out the function name using forward-sexp.
 128         (princ " is ")
 129         (describe-function-1 function)
 130         (print-help-return-message)
 131         (with-current-buffer standard-output
 132           ;; Return the text we displayed.
 133           (buffer-string))))))
 134
 135 (defun help-split-fundoc (docstring def)
 136   "Split a function DOCSTRING into the actual doc and the usage info.
 137 Return (USAGE . DOC) or nil if there's no usage info.
 138 DEF is the function whose usage we're looking for in DOCSTRING."
 139   ;; Functions can get the calling sequence at the end of the doc string.
 140   ;; In cases where `function' has been fset to a subr we can't search for
 141   ;; function's name in the doc string so we use `fn' as the anonymous
 142   ;; function name instead.
 143   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
 144     (cons (format "(%s%s"
 145                   ;; Replace `fn' with the actual function name.
 146                   (if (consp def) "anonymous" def)
 147                   (match-string 1 docstring))
 148           (substring docstring 0 (match-beginning 0)))))
 149
 150 (defun help-add-fundoc-usage (docstring arglist)
 151   "Add the usage info to DOCSTRING.
 152 If DOCSTRING already has a usage info, then just return it unchanged.
 153 The usage info is built from ARGLIST.  DOCSTRING can be nil.
 154 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
 155   (unless (stringp docstring) (setq docstring "Not documented"))
 156   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
 157       docstring
 158     (concat docstring
 159             (if (string-match "\n?\n\\'" docstring)
 160                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
 161               "\n\n")
 162             (if (and (stringp arglist)
 163                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
 164                 (concat "(fn" (match-string 1 arglist) ")")
 165               (format "%S" (help-make-usage 'fn arglist))))))
 166
 167 (defun help-function-arglist (def)
 168   ;; Handle symbols aliased to other symbols.
 169   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 170   ;; If definition is a macro, find the function inside it.
 171   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 172   (cond
 173    ((byte-code-function-p def) (aref def 0))
 174    ((eq (car-safe def) 'lambda) (nth 1 def))
 175    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 176     "[Arg list not available until function definition is loaded.]")
 177    (t t)))
 178
 179 (defun help-make-usage (function arglist)
 180   (cons (if (symbolp function) function 'anonymous)
 181         (mapcar (lambda (arg)
 182                   (if (not (symbolp arg))
 183                       (if (and (consp arg) (symbolp (car arg)))
 184                           ;; CL style default values for optional args.
 185                           (cons (intern (upcase (symbol-name (car arg))))
 186                                 (cdr arg))
 187                         arg)
 188                     (let ((name (symbol-name arg)))
 189                       (if (string-match "\\`&" name) arg
 190                         (intern (upcase name))))))
 191                 arglist)))
 192
 193 ;; Could be this, if we make symbol-file do the work below.
 194 ;; (defun help-C-file-name (subr-or-var kind)
 195 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 196 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 197 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 198 ;;               (subr-name subr-or-var))
 199 ;;             (if (eq kind 'var) 'defvar 'defun)))
 200 ;;;###autoload
 201 (defun help-C-file-name (subr-or-var kind)
 202   "Return the name of the C file where SUBR-OR-VAR is defined.
 203 KIND should be `var' for a variable or `subr' for a subroutine."
 204   (let ((docbuf (get-buffer-create " *DOC*"))
 205         (name (if (eq 'var kind)
 206                   (concat "V" (symbol-name subr-or-var))
 207                 (concat "F" (subr-name subr-or-var)))))
 208     (with-current-buffer docbuf
 209       (goto-char (point-min))
 210       (if (eobp)
 211           (insert-file-contents-literally
 212            (expand-file-name internal-doc-file-name doc-directory)))
 213       (let ((file (catch 'loop
 214                     (while t
 215                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
 216                         (re-search-backward "\x1fS\\(.*\\)")
 217                         (let ((file (match-string 1)))
 218                           (if (member file build-files)
 219                               (throw 'loop file)
 220                             (goto-char pnt))))))))
 221         (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 222             (setq file (replace-match ".c" t t file)))
 223         (if (string-match "\\.c\\'" file)
 224             (concat "src/" file)
 225           file)))))
 226
 227 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
 228   "Face to highlight argument names in *Help* buffers."
 229   :group 'help)
 230
 231 (defun help-default-arg-highlight (arg)
 232   "Default function to highlight arguments in *Help* buffers.
 233 It returns ARG in face `help-argument-name'; ARG is also
 234 downcased if it displays differently than the default
 235 face (according to `face-differs-from-default-p')."
 236   (propertize (if (face-differs-from-default-p 'help-argument-name)
 237                   (downcase arg)
 238                 arg)
 239               'face 'help-argument-name))
 240
 241 (defun help-do-arg-highlight (doc args)
 242   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 243     (modify-syntax-entry ?\- "w")
 244     (dolist (arg args doc)
 245       (setq doc (replace-regexp-in-string
 246                  ;; This is heuristic, but covers all common cases
 247                  ;; except ARG1-ARG2
 248                  (concat "\\<"                   ; beginning of word
 249                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 250                          "\\("
 251                          (regexp-quote arg)
 252                          "\\)"
 253                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 254                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 255                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 256                          "\\>")                  ; end of word
 257                  (help-default-arg-highlight arg)
 258                  doc t t 1)))))
 259
 260 (defun help-highlight-arguments (usage doc &rest args)
 261   (when usage
 262     (with-temp-buffer
 263       (insert usage)
 264       (goto-char (point-min))
 265       (let ((case-fold-search nil)
 266             (next (not (or args (looking-at "\\["))))
 267             (opt nil))
 268         ;; Make a list of all arguments
 269         (skip-chars-forward "^ ")
 270         (while next
 271           (or opt (not (looking-at " &")) (setq opt t))
 272           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 273               (setq next nil)
 274             (setq args (cons (match-string 2) args))
 275             (when (and opt (string= (match-string 1) "("))
 276               ;; A pesky CL-style optional argument with default value,
 277               ;; so let's skip over it
 278               (search-backward "(")
 279               (goto-char (scan-sexps (point) 1)))))
 280         ;; Highlight aguments in the USAGE string
 281         (setq usage (help-do-arg-highlight (buffer-string) args))
 282         ;; Highlight arguments in the DOC string
 283         (setq doc (and doc (help-do-arg-highlight doc args))))))
 284   ;; Return value is like the one from help-split-fundoc, but highlighted
 285   (cons usage doc))
 286
 287 ;;;###autoload
 288 (defun describe-simplify-lib-file-name (file)
 289   "Simplify a library name FILE to a relative name, and make it a source file."
 290   (if file
 291       ;; Try converting the absolute file name to a library name.
 292       (let ((libname (file-name-nondirectory file)))
 293         ;; Now convert that back to a file name and see if we get
 294         ;; the original one.  If so, they are equivalent.
 295         (if (equal file (locate-file libname load-path '("")))
 296             (if (string-match "[.]elc\\'" libname)
 297                 (substring libname 0 -1)
 298               libname)
 299           file))))
 300
 301 ;;;###autoload
 302 (defun describe-function-1 (function)
 303   (let* ((def (if (symbolp function)
 304                   (symbol-function function)
 305                 function))
 306          file-name string
 307          (beg (if (commandp def) "an interactive " "a ")))
 308     (setq string
 309           (cond ((or (stringp def)
 310                      (vectorp def))
 311                  "a keyboard macro")
 312                 ((subrp def)
 313                  (if (eq 'unevalled (cdr (subr-arity def)))
 314                      (concat beg "special form")
 315                    (concat beg "built-in function")))
 316                 ((byte-code-function-p def)
 317                  (concat beg "compiled Lisp function"))
 318                 ((symbolp def)
 319                  (while (symbolp (symbol-function def))
 320                    (setq def (symbol-function def)))
 321                  (format "an alias for `%s'" def))
 322                 ((eq (car-safe def) 'lambda)
 323                  (concat beg "Lisp function"))
 324                 ((eq (car-safe def) 'macro)
 325                  "a Lisp macro")
 326                 ((eq (car-safe def) 'autoload)
 327                  (setq file-name (nth 1 def))
 328                  (format "%s autoloaded %s"
 329                          (if (commandp def) "an interactive" "an")
 330                          (if (eq (nth 4 def) 'keymap) "keymap"
 331                            (if (nth 4 def) "Lisp macro" "Lisp function"))
 332                          ))
 333                 ((keymapp def)
 334                  (let ((is-full nil)
 335                        (elts (cdr-safe def)))
 336                    (while elts
 337                      (if (char-table-p (car-safe elts))
 338                          (setq is-full t
 339                                elts nil))
 340                      (setq elts (cdr-safe elts)))
 341                    (if is-full
 342                        "a full keymap"
 343                      "a sparse keymap")))
 344                 (t "")))
 345     (princ string)
 346     (with-current-buffer standard-output
 347       (save-excursion
 348         (save-match-data
 349           (if (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 350               (help-xref-button 1 'help-function def)))))
 351     (or file-name
 352         (setq file-name (symbol-file function 'defun)))
 353     (setq file-name (describe-simplify-lib-file-name file-name))
 354     (when (equal file-name "loaddefs.el")
 355       ;; Find the real def site of the preloaded function.
 356       ;; This is necessary only for defaliases.
 357       (let ((location
 358              (condition-case nil
 359                  (find-function-search-for-symbol function nil "loaddefs.el")
 360                (error nil))))
 361         (when location
 362           (with-current-buffer (car location)
 363             (goto-char (cdr location))
 364             (when (re-search-backward
 365                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 366               (setq file-name (match-string 1)))))))
 367     (when (and (null file-name) (subrp def))
 368       ;; Find the C source file name.
 369       (setq file-name (if (get-buffer " *DOC*")
 370                           (help-C-file-name def 'subr)
 371                         'C-source)))
 372     (when file-name
 373       (princ " in `")
 374       ;; We used to add .el to the file name,
 375       ;; but that's completely wrong when the user used load-file.
 376       (princ (if (eq file-name 'C-source) "C source code" file-name))
 377       (princ "'")
 378       ;; Make a hyperlink to the library.
 379       (with-current-buffer standard-output
 380         (save-excursion
 381           (re-search-backward "`\\([^`']+\\)'" nil t)
 382           (help-xref-button 1 'help-function-def function file-name))))
 383     (princ ".")
 384     (terpri)
 385     (when (commandp function)
 386       (let* ((remapped (command-remapping function))
 387              (keys (where-is-internal
 388                     (or remapped function) overriding-local-map nil nil))
 389              non-modified-keys)
 390         ;; Which non-control non-meta keys run this command?
 391         (dolist (key keys)
 392           (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 393               (push key non-modified-keys)))
 394         (when remapped
 395           (princ "It is remapped to `")
 396           (princ (symbol-name remapped))
 397           (princ "'"))
 398
 399         (when keys
 400           (princ (if remapped " which is bound to " "It is bound to "))
 401           ;; FIXME: This list can be very long (f.ex. for self-insert-command).
 402           ;; If there are many, remove them from KEYS.
 403           (if (< (length non-modified-keys) 10)
 404               (princ (mapconcat 'key-description keys ", "))
 405             (dolist (key non-modified-keys)
 406               (setq keys (delq key keys)))
 407             (if keys
 408                 (progn
 409                   (princ (mapconcat 'key-description keys ", "))
 410                   (princ ", and many ordinary text characters"))
 411               (princ "many ordinary text characters"))))
 412         (when (or remapped keys non-modified-keys)
 413           (princ ".")
 414           (terpri))))
 415     (let* ((arglist (help-function-arglist def))
 416            (doc (documentation function))
 417            (usage (help-split-fundoc doc function)))
 418       (with-current-buffer standard-output
 419         ;; If definition is a keymap, skip arglist note.
 420         (unless (keymapp def)
 421           (let* ((use (cond
 422                         (usage (setq doc (cdr usage)) (car usage))
 423                         ((listp arglist)
 424                          (format "%S" (help-make-usage function arglist)))
 425                         ((stringp arglist) arglist)
 426                         ;; Maybe the arglist is in the docstring of the alias.
 427                         ((let ((fun function))
 428                            (while (and (symbolp fun)
 429                                        (setq fun (symbol-function fun))
 430                                        (not (setq usage (help-split-fundoc
 431                                                          (documentation fun)
 432                                                          function)))))
 433                            usage)
 434                          (car usage))
 435                         ((or (stringp def)
 436                              (vectorp def))
 437                          (format "\nMacro: %s" (format-kbd-macro def)))
 438                         (t "[Missing arglist.  Please make a bug report.]")))
 439                  (high (help-highlight-arguments use doc)))
 440             (let ((fill-begin (point)))
 441               (insert (car high) "\n")
 442               (fill-region fill-begin (point)))
 443             (setq doc (cdr high))))
 444         (let ((obsolete (and
 445                          ;; function might be a lambda construct.
 446                          (symbolp function)
 447                          (get function 'byte-obsolete-info))))
 448           (when obsolete
 449             (princ "\nThis function is obsolete")
 450             (when (nth 2 obsolete)
 451               (insert (format " since %s" (nth 2 obsolete))))
 452             (insert ";\n"
 453                     (if (stringp (car obsolete)) (car obsolete)
 454                       (format "use `%s' instead." (car obsolete)))
 455                     "\n"))
 456           (insert "\n"
 457                   (or doc "Not documented.")))))))
 458
 459 \f
 460 ;; Variables
 461
 462 ;;;###autoload
 463 (defun variable-at-point (&optional any-symbol)
 464   "Return the bound variable symbol found around point.
 465 Return 0 if there is no such symbol.
 466 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 467   (or (condition-case ()
 468           (with-syntax-table emacs-lisp-mode-syntax-table
 469             (save-excursion
 470               (or (not (zerop (skip-syntax-backward "_w")))
 471                   (eq (char-syntax (following-char)) ?w)
 472                   (eq (char-syntax (following-char)) ?_)
 473                   (forward-sexp -1))
 474               (skip-chars-forward "'")
 475               (let ((obj (read (current-buffer))))
 476                 (and (symbolp obj) (boundp obj) obj))))
 477         (error nil))
 478       (let* ((str (find-tag-default))
 479              (sym (if str (intern-soft str))))
 480         (if (and sym (or any-symbol (boundp sym)))
 481             sym
 482           (save-match-data
 483             (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 484               (setq sym (intern-soft (match-string 1 str)))
 485               (and (or any-symbol (boundp sym)) sym)))))
 486       0))
 487
 488 ;;;###autoload
 489 (defun describe-variable (variable &optional buffer)
 490   "Display the full documentation of VARIABLE (a symbol).
 491 Returns the documentation as a string, also.
 492 If VARIABLE has a buffer-local value in BUFFER (default to the current buffer),
 493 it is displayed along with the global value."
 494   (interactive
 495    (let ((v (variable-at-point))
 496          (enable-recursive-minibuffers t)
 497          val)
 498      (setq val (completing-read (if (symbolp v)
 499                                     (format
 500                                      "Describe variable (default %s): " v)
 501                                   "Describe variable: ")
 502                                 obarray
 503                                 '(lambda (vv)
 504                                    (or (boundp vv)
 505                                        (get vv 'variable-documentation)))
 506                                 t nil nil
 507                                 (if (symbolp v) (symbol-name v))))
 508      (list (if (equal val "")
 509                v (intern val)))))
 510   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 511   (if (not (symbolp variable))
 512       (message "You did not specify a variable")
 513     (save-excursion
 514       (let* ((valvoid (not (with-current-buffer buffer (boundp variable))))
 515              ;; Extract the value before setting up the output buffer,
 516              ;; in case `buffer' *is* the output buffer.
 517              (val (unless valvoid (buffer-local-value variable buffer)))
 518              val-start-pos)
 519         (help-setup-xref (list #'describe-variable variable buffer)
 520                          (interactive-p))
 521         (with-output-to-temp-buffer (help-buffer)
 522           (with-current-buffer buffer
 523             (prin1 variable)
 524             ;; Make a hyperlink to the library if appropriate.  (Don't
 525             ;; change the format of the buffer's initial line in case
 526             ;; anything expects the current format.)
 527             (let ((file-name (symbol-file variable 'defvar)))
 528               (setq file-name (describe-simplify-lib-file-name file-name))
 529               (when (equal file-name "loaddefs.el")
 530                 ;; Find the real def site of the preloaded variable.
 531                 (let ((location
 532                        (condition-case nil
 533                            (find-variable-noselect variable file-name)
 534                          (error nil))))
 535                   (when location
 536                     (with-current-buffer (car location)
 537                       (when (cdr location)
 538                         (goto-char (cdr location)))
 539                       (when (re-search-backward
 540                              "^;;; Generated autoloads from \\(.*\\)" nil t)
 541                         (setq file-name (match-string 1)))))))
 542               (when (and (null file-name)
 543                          (integerp (get variable 'variable-documentation)))
 544                 ;; It's a variable not defined in Elisp but in C.
 545                 (setq file-name
 546                       (if (get-buffer " *DOC*")
 547                           (help-C-file-name variable 'var)
 548                         'C-source)))
 549               (if file-name
 550                   (progn
 551                     (princ " is a variable defined in `")
 552                     (princ (if (eq file-name 'C-source) "C source code" file-name))
 553                     (princ "'.\n")
 554                     (with-current-buffer standard-output
 555                       (save-excursion
 556                         (re-search-backward "`\\([^`']+\\)'" nil t)
 557                         (help-xref-button 1 'help-variable-def
 558                                           variable file-name)))
 559                     (if valvoid
 560                         (princ "It is void as a variable.")
 561                       (princ "Its ")))
 562                 (if valvoid
 563                     (princ " is void as a variable.")
 564                   (princ "'s "))))
 565             (if valvoid
 566                 nil
 567               (with-current-buffer standard-output
 568                 (setq val-start-pos (point))
 569                 (princ "value is ")
 570                 (terpri)
 571                 (let ((from (point)))
 572                   (pp val)
 573                   ;; Hyperlinks in variable's value are quite frequently
 574                   ;; inappropriate e.g C-h v <RET> features <RET>
 575                   ;; (help-xref-on-pp from (point))
 576                   (if (< (point) (+ from 20))
 577                       (delete-region (1- from) from)))))
 578             (terpri)
 579
 580             (when (local-variable-p variable)
 581               (princ (format "%socal in buffer %s; "
 582                              (if (get variable 'permanent-local)
 583                                  "Permanently l" "L")
 584                              (buffer-name)))
 585               (if (not (default-boundp variable))
 586                   (princ "globally void")
 587                 (let ((val (default-value variable)))
 588                   (with-current-buffer standard-output
 589                     (princ "global value is ")
 590                     (terpri)
 591                     ;; Fixme: pp can take an age if you happen to
 592                     ;; ask for a very large expression.  We should
 593                     ;; probably print it raw once and check it's a
 594                     ;; sensible size before prettyprinting.  -- fx
 595                     (let ((from (point)))
 596                       (pp val)
 597                       ;; See previous comment for this function.
 598                       ;; (help-xref-on-pp from (point))
 599                       (if (< (point) (+ from 20))
 600                           (delete-region (1- from) from)))))))
 601             ;; Add a note for variables that have been make-var-buffer-local.
 602             (when (and (local-variable-if-set-p variable)
 603                        (or (not (local-variable-p variable))
 604                            (with-temp-buffer
 605                              (local-variable-if-set-p variable))))
 606               (princ "\nAutomatically becomes buffer-local when set in any fashion.\n"))
 607             (terpri)
 608
 609             ;; If the value is large, move it to the end.
 610             (with-current-buffer standard-output
 611               (when (> (count-lines (point-min) (point-max)) 10)
 612                 ;; Note that setting the syntax table like below
 613                 ;; makes forward-sexp move over a `'s' at the end
 614                 ;; of a symbol.
 615                 (set-syntax-table emacs-lisp-mode-syntax-table)
 616                 (goto-char val-start-pos)
 617                 (delete-region (point) (progn (end-of-line) (point)))
 618                 (save-excursion
 619                   (insert "\n\nValue:")
 620                   (set (make-local-variable 'help-button-cache)
 621                        (point-marker)))
 622                 (insert "value is shown ")
 623                 (insert-button "below"
 624                                'action help-button-cache
 625                                'follow-link t
 626                                'help-echo "mouse-2, RET: show value")
 627                 (insert ".\n\n")))
 628
 629             ;; Mention if it's an alias
 630             (let* ((alias (condition-case nil
 631                              (indirect-variable variable)
 632                            (error variable)))
 633                    (obsolete (get variable 'byte-obsolete-variable))
 634                    (safe-var (get variable 'safe-local-variable))
 635                    (doc (or (documentation-property variable 'variable-documentation)
 636                             (documentation-property alias 'variable-documentation))))
 637               (unless (eq alias variable)
 638                 (princ (format "\nThis variable is an alias for `%s'.\n" alias)))
 639               (when obsolete
 640                 (princ "\nThis variable is obsolete")
 641                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 642                 (princ ";") (terpri)
 643                 (princ (if (stringp (car obsolete)) (car obsolete)
 644                          (format "use `%s' instead." (car obsolete))))
 645                 (terpri))
 646               (when safe-var
 647                 (princ "This variable is safe as a file local variable ")
 648                 (princ "if its value\nsatisfies the predicate ")
 649                 (princ (if (byte-code-function-p safe-var)
 650                            "which is byte-compiled expression.\n"
 651                          (format "`%s'.\n" safe-var)))
 652                 (terpri))
 653               (princ "Documentation:\n")
 654               (princ (or doc "Not documented as a variable.")))
 655             ;; Make a link to customize if this variable can be customized.
 656             (if (custom-variable-p variable)
 657                 (let ((customize-label "customize"))
 658                   (terpri)
 659                   (terpri)
 660                   (princ (concat "You can " customize-label " this variable."))
 661                   (with-current-buffer standard-output
 662                     (save-excursion
 663                       (re-search-backward
 664                        (concat "\\(" customize-label "\\)") nil t)
 665                       (help-xref-button 1 'help-customize-variable variable)))))
 666             (print-help-return-message)
 667             (save-excursion
 668               (set-buffer standard-output)
 669               ;; Return the text we displayed.
 670               (buffer-string))))))))
 671
 672
 673 ;;;###autoload
 674 (defun describe-syntax (&optional buffer)
 675   "Describe the syntax specifications in the syntax table of BUFFER.
 676 The descriptions are inserted in a help buffer, which is then displayed.
 677 BUFFER defaults to the current buffer."
 678   (interactive)
 679   (setq buffer (or buffer (current-buffer)))
 680   (help-setup-xref (list #'describe-syntax buffer) (interactive-p))
 681   (with-output-to-temp-buffer (help-buffer)
 682     (let ((table (with-current-buffer buffer (syntax-table))))
 683       (with-current-buffer standard-output
 684         (describe-vector table 'internal-describe-syntax-value)
 685         (while (setq table (char-table-parent table))
 686           (insert "\nThe parent syntax table is:")
 687           (describe-vector table 'internal-describe-syntax-value))))))
 688
 689 (defun help-describe-category-set (value)
 690   (insert (cond
 691            ((null value) "default")
 692            ((char-table-p value) "deeper char-table ...")
 693            (t (condition-case err
 694                   (category-set-mnemonics value)
 695                 (error "invalid"))))))
 696
 697 ;;;###autoload
 698 (defun describe-categories (&optional buffer)
 699   "Describe the category specifications in the current category table.
 700 The descriptions are inserted in a buffer, which is then displayed.
 701 If BUFFER is non-nil, then describe BUFFER's category table instead.
 702 BUFFER should be a buffer or a buffer name."
 703   (interactive)
 704   (setq buffer (or buffer (current-buffer)))
 705   (help-setup-xref (list #'describe-categories buffer) (interactive-p))
 706   (with-output-to-temp-buffer (help-buffer)
 707     (let ((table (with-current-buffer buffer (category-table))))
 708       (with-current-buffer standard-output
 709         (describe-vector table 'help-describe-category-set)
 710         (let ((docs (char-table-extra-slot table 0)))
 711           (if (or (not (vectorp docs)) (/= (length docs) 95))
 712               (insert "Invalid first extra slot in this char table\n")
 713             (insert "Meanings of mnemonic characters are:\n")
 714             (dotimes (i 95)
 715               (let ((elt (aref docs i)))
 716                 (when elt
 717                   (insert (+ i ?\s) ": " elt "\n"))))
 718             (while (setq table (char-table-parent table))
 719               (insert "\nThe parent category table is:")
 720               (describe-vector table 'help-describe-category-set))))))))
 721
 722 (provide 'help-fns)
 723
 724 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 725 ;;; help-fns.el ends here