lisp/linum.el

   1 ;;; linum.el --- display line numbers in the left margin
   2
   3 ;; Copyright (C) 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Markus Triska <markus.triska@gmx.at>
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Display line numbers for the current buffer.
  29 ;;
  30 ;; Toggle display of line numbers with M-x linum-mode.  To enable
  31 ;; line numbering in all buffers, use M-x global-linum-mode.
  32
  33 ;;; Code:
  34
  35 (defconst linum-version "0.9wx")
  36
  37 (defvar linum-overlays nil "Overlays used in this buffer.")
  38 (defvar linum-available nil "Overlays available for reuse.")
  39 (defvar linum-before-numbering-hook nil
  40   "Functions run in each buffer before line numbering starts.")
  41
  42 (mapc #'make-variable-buffer-local '(linum-overlays linum-available))
  43
  44 (defgroup linum nil
  45   "Show line numbers in the left margin."
  46   :group 'convenience)
  47
  48 ;;;###autoload
  49 (defcustom linum-format 'dynamic
  50   "Format used to display line numbers.
  51 Either a format string like \"%7d\", `dynamic' to adapt the width
  52 as needed, or a function that is called with a line number as its
  53 argument and should evaluate to a string to be shown on that line.
  54 See also `linum-before-numbering-hook'."
  55   :group 'linum
  56   :type 'sexp)
  57
  58 (defface linum
  59   '((t :inherit shadow))
  60   "Face for displaying line numbers in the display margin."
  61   :group 'linum)
  62
  63 (defcustom linum-eager t
  64   "Whether line numbers should be updated after each command.
  65 The conservative setting `nil' might miss some buffer changes,
  66 and you have to scroll or press \\[recenter-top-bottom] to update the numbers."
  67   :group 'linum
  68   :type 'boolean)
  69
  70 (defcustom linum-delay t
  71   "Delay updates to give Emacs a chance for other changes."
  72   :group 'linum
  73   :type 'boolean)
  74
  75 ;;;###autoload
  76 (define-minor-mode linum-mode
  77   "Toggle display of line numbers in the left margin."
  78   :lighter ""                           ; for desktop.el
  79   (if linum-mode
  80       (progn
  81         (if linum-eager
  82             (add-hook 'post-command-hook (if linum-delay
  83                                              'linum-schedule
  84                                            'linum-update-current) nil t)
  85           (add-hook 'after-change-functions 'linum-after-change nil t))
  86         (add-hook 'window-scroll-functions 'linum-after-scroll nil t)
  87         ;; mistake in Emacs: window-size-change-functions cannot be local
  88         (add-hook 'window-size-change-functions 'linum-after-size)
  89         (add-hook 'change-major-mode-hook 'linum-delete-overlays nil t)
  90         (add-hook 'window-configuration-change-hook
  91                   'linum-after-config nil t)
  92         (linum-update-current))
  93     (remove-hook 'post-command-hook 'linum-update-current t)
  94     (remove-hook 'post-command-hook 'linum-schedule t)
  95     (remove-hook 'window-size-change-functions 'linum-after-size)
  96     (remove-hook 'window-scroll-functions 'linum-after-scroll t)
  97     (remove-hook 'after-change-functions 'linum-after-change t)
  98     (remove-hook 'window-configuration-change-hook 'linum-after-config t)
  99     (remove-hook 'change-major-mode-hook 'linum-delete-overlays t)
 100     (linum-delete-overlays)))
 101
 102 ;;;###autoload
 103 (define-globalized-minor-mode global-linum-mode linum-mode linum-on)
 104
 105 (defun linum-on ()
 106   (unless (minibufferp)
 107     (linum-mode 1)))
 108
 109 (defun linum-delete-overlays ()
 110   "Delete all overlays displaying line numbers for this buffer."
 111   (mapc #'delete-overlay linum-overlays)
 112   (setq linum-overlays nil)
 113   (dolist (w (get-buffer-window-list (current-buffer) nil t))
 114     (set-window-margins w 0)))
 115
 116 (defun linum-update-current ()
 117   "Update line numbers for the current buffer."
 118   (linum-update (current-buffer)))
 119
 120 (defun linum-update (buffer)
 121   "Update line numbers for all windows displaying BUFFER."
 122   (with-current-buffer buffer
 123     (when linum-mode
 124       (setq linum-available linum-overlays)
 125       (setq linum-overlays nil)
 126       (save-excursion
 127         (mapc #'linum-update-window
 128               (get-buffer-window-list buffer nil 'visible)))
 129       (mapc #'delete-overlay linum-available)
 130       (setq linum-available nil))))
 131
 132 (defun linum-update-window (win)
 133   "Update line numbers for the portion visible in window WIN."
 134   (goto-char (window-start win))
 135   (let ((line (line-number-at-pos))
 136         (limit (1+ (window-end win t)))
 137         (fmt (cond ((stringp linum-format) linum-format)
 138                    ((eq linum-format 'dynamic)
 139                     (let ((w (length (number-to-string
 140                                       (count-lines (point-min) (point-max))))))
 141                       (concat "%" (number-to-string w) "d")))))
 142         (width 0)
 143         visited
 144         ov)
 145     (run-hooks 'linum-before-numbering-hook)
 146     ;; Create an overlay (or reuse an existing one) for each
 147     ;; line visible in this window, if necessary.
 148     (while (and (not (eobp)) (< (point) limit))
 149       (setq visited nil)
 150       (dolist (o (overlays-in (point) (point)))
 151         (when (eq (overlay-get o 'linum-line) line)
 152           (unless (memq o linum-overlays)
 153             (push o linum-overlays))
 154           (setq linum-available (delete o linum-available))
 155           (setq visited t)))
 156       (let ((str (if fmt
 157                      (propertize (format fmt line) 'face 'linum)
 158                    (funcall linum-format line))))
 159         (setq width (max width (length str)))
 160         (unless visited
 161           (if (null linum-available)
 162               (setq ov (make-overlay (point) (point)))
 163             (setq ov (pop linum-available))
 164             (move-overlay ov (point) (point)))
 165           (push ov linum-overlays)
 166           (setq str (propertize " " 'display `((margin left-margin) ,str)))
 167           (overlay-put ov 'before-string str)
 168           (overlay-put ov 'linum-line line)))
 169       (forward-line)
 170       (setq line (1+ line)))
 171     (set-window-margins win width)))
 172
 173 (defun linum-after-change (beg end len)
 174   ;; update overlays on deletions, and after newlines are inserted
 175   (when (or (= beg end)
 176             (= end (point-max))
 177             (string-match-p "\n" (buffer-substring-no-properties beg end)))
 178     (linum-update-current)))
 179
 180 (defun linum-after-scroll (win start)
 181   (linum-update (window-buffer win)))
 182
 183 (defun linum-after-size (frame)
 184   (linum-after-config))
 185
 186 (defun linum-schedule ()
 187   ;; schedule an update; the delay gives Emacs a chance for display changes
 188   (run-with-idle-timer 0 nil #'linum-update-current))
 189
 190 (defun linum-after-config ()
 191   (walk-windows (lambda (w) (linum-update (window-buffer w))) nil 'visible))
 192
 193 (defun linum-unload-function ()
 194   "Unload the Linum library."
 195   (global-linum-mode -1)
 196   ;; continue standard unloading
 197   nil)
 198
 199 (provide 'linum)
 200
 201 ;; arch-tag: dea45631-ed3c-4867-8b49-1c41c80aec6a
 202 ;;; linum.el ends here