lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1996, 1997, 2000, 2001, 2002,
   4 ;;   2003, 2004  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package supplies the string and regular-expression replace functions
  28 ;; documented in the Emacs user's manual.
  29
  30 ;;; Code:
  31
  32 (defcustom case-replace t
  33   "*Non-nil means `query-replace' should preserve case in replacements."
  34   :type 'boolean
  35   :group 'matching)
  36
  37 (defvar query-replace-history nil)
  38
  39 (defvar query-replace-interactive nil
  40   "Non-nil means `query-replace' uses the last search string.
  41 That becomes the \"string to replace\".")
  42
  43 (defcustom query-replace-from-history-variable 'query-replace-history
  44   "History list to use for the FROM argument of `query-replace' commands.
  45 The value of this variable should be a symbol; that symbol
  46 is used as a variable to hold a history list for the strings
  47 or patterns to be replaced."
  48   :group 'matching
  49   :type 'symbol
  50   :version "20.3")
  51
  52 (defcustom query-replace-to-history-variable 'query-replace-history
  53   "History list to use for the TO argument of `query-replace' commands.
  54 The value of this variable should be a symbol; that symbol
  55 is used as a variable to hold a history list for replacement
  56 strings or patterns."
  57   :group 'matching
  58   :type 'symbol
  59   :version "20.3")
  60
  61 (defcustom query-replace-skip-read-only nil
  62   "*Non-nil means `query-replace' and friends ignore read-only matches."
  63   :type 'boolean
  64   :group 'matching
  65   :version "21.4")
  66
  67 (defun query-replace-descr (string)
  68   (mapconcat 'isearch-text-char-description string ""))
  69
  70 (defun query-replace-read-from (string regexp-flag)
  71   "Query and return the `from' argument of a query-replace operation.
  72 The return value can also be a pair (FROM . TO) indicating that the user
  73 wants to replace FROM with TO."
  74   (if query-replace-interactive
  75       (car (if regexp-flag regexp-search-ring search-ring))
  76     (let* ((lastfrom (car (symbol-value query-replace-from-history-variable)))
  77            (lastto (car (symbol-value query-replace-to-history-variable)))
  78            (from
  79             ;; The save-excursion here is in case the user marks and copies
  80             ;; a region in order to specify the minibuffer input.
  81             ;; That should not clobber the region for the query-replace itself.
  82             (save-excursion
  83               (when (equal lastfrom lastto)
  84                 ;; Typically, this is because the two histlists are shared.
  85                 (setq lastfrom (cadr (symbol-value
  86                                       query-replace-from-history-variable))))
  87               (read-from-minibuffer
  88                (if (and lastto lastfrom)
  89                    (format "%s (default %s -> %s): " string
  90                            (query-replace-descr lastfrom)
  91                            (query-replace-descr lastto))
  92                  (format "%s: " string))
  93                nil nil nil
  94                query-replace-from-history-variable
  95                nil t))))
  96       (if (and (zerop (length from)) lastto lastfrom)
  97           (cons lastfrom
  98                 (query-replace-compile-replacement lastto regexp-flag))
  99         ;; Warn if user types \n or \t, but don't reject the input.
 100         (and regexp-flag
 101              (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\[nt]\\)" from)
 102              (let ((match (match-string 3 from)))
 103                (cond
 104                 ((string= match "\\n")
 105                  (message "Note: `\\n' here doesn't match a newline; to do that, type C-q C-j instead"))
 106                 ((string= match "\\t")
 107                  (message "Note: `\\t' here doesn't match a tab; to do that, just type TAB")))
 108                (sit-for 2)))
 109         from))))
 110
 111 (defun query-replace-compile-replacement (to regexp-flag)
 112   "Maybe convert a regexp replacement TO to Lisp.
 113 Returns a list suitable for `perform-replace' if necessary,
 114 the original string if not."
 115   (if (and regexp-flag
 116            (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to))
 117       (let (pos list char)
 118         (while
 119             (progn
 120               (setq pos (match-end 0))
 121               (push (substring to 0 (- pos 2)) list)
 122               (setq char (aref to (1- pos))
 123                     to (substring to pos))
 124               (cond ((eq char ?\#)
 125                      (push '(number-to-string replace-count) list))
 126                     ((eq char ?\,)
 127                      (setq pos (read-from-string to))
 128                      (push `(replace-quote ,(car pos)) list)
 129                      (let ((end
 130                             ;; Swallow a space after a symbol
 131                             ;; if there is a space.
 132                             (if (and (or (symbolp (car pos))
 133                                          ;; Swallow a space after 'foo
 134                                          ;; but not after (quote foo).
 135                                          (and (eq (car-safe (car pos)) 'quote)
 136                                               (not (= ?\( (aref to 0)))))
 137                                      (eq (string-match " " to (cdr pos))
 138                                          (cdr pos)))
 139                                 (1+ (cdr pos))
 140                               (cdr pos))))
 141                        (setq to (substring to end)))))
 142               (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to)))
 143         (setq to (nreverse (delete "" (cons to list))))
 144         (replace-match-string-symbols to)
 145         (cons 'replace-eval-replacement
 146               (if (cdr to)
 147                   (cons 'concat to)
 148                 (car to))))
 149     to))
 150
 151
 152 (defun query-replace-read-to (from string regexp-flag)
 153   "Query and return the `to' argument of a query-replace operation."
 154   (query-replace-compile-replacement
 155    (save-excursion
 156      (read-from-minibuffer
 157       (format "%s %s with: " string (query-replace-descr from))
 158       nil nil nil
 159       query-replace-to-history-variable from t))
 160    regexp-flag))
 161
 162 (defun query-replace-read-args (string regexp-flag &optional noerror)
 163   (unless noerror
 164     (barf-if-buffer-read-only))
 165   (let* ((from (query-replace-read-from string regexp-flag))
 166          (to (if (consp from) (prog1 (cdr from) (setq from (car from)))
 167                (query-replace-read-to from string regexp-flag))))
 168     (list from to current-prefix-arg)))
 169
 170 (defun query-replace (from-string to-string &optional delimited start end)
 171   "Replace some occurrences of FROM-STRING with TO-STRING.
 172 As each match is found, the user must type a character saying
 173 what to do with it.  For directions, type \\[help-command] at that time.
 174
 175 In Transient Mark mode, if the mark is active, operate on the contents
 176 of the region.  Otherwise, operate from point to the end of the buffer.
 177
 178 If `query-replace-interactive' is non-nil, the last incremental search
 179 string is used as FROM-STRING--you don't have to specify it with the
 180 minibuffer.
 181
 182 Matching is independent of case if `case-fold-search' is non-nil and
 183 FROM-STRING has no uppercase letters.  Replacement transfers the case
 184 pattern of the old text to the new text, if `case-replace' and
 185 `case-fold-search' are non-nil and FROM-STRING has no uppercase
 186 letters.  \(Transferring the case pattern means that if the old text
 187 matched is all caps, or capitalized, then its replacement is upcased
 188 or capitalized.)
 189
 190 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 191 only matches surrounded by word boundaries.
 192 Fourth and fifth arg START and END specify the region to operate on.
 193
 194 To customize possible responses, change the \"bindings\" in `query-replace-map'."
 195   (interactive (let ((common
 196                       (query-replace-read-args "Query replace" nil)))
 197                  (list (nth 0 common) (nth 1 common) (nth 2 common)
 198                        ;; These are done separately here
 199                        ;; so that command-history will record these expressions
 200                        ;; rather than the values they had this time.
 201                        (if (and transient-mark-mode mark-active)
 202                            (region-beginning))
 203                        (if (and transient-mark-mode mark-active)
 204                            (region-end)))))
 205   (perform-replace from-string to-string t nil delimited nil nil start end))
 206
 207 (define-key esc-map "%" 'query-replace)
 208
 209 (defun query-replace-regexp (regexp to-string &optional delimited start end)
 210   "Replace some things after point matching REGEXP with TO-STRING.
 211 As each match is found, the user must type a character saying
 212 what to do with it.  For directions, type \\[help-command] at that time.
 213
 214 In Transient Mark mode, if the mark is active, operate on the contents
 215 of the region.  Otherwise, operate from point to the end of the buffer.
 216
 217 If `query-replace-interactive' is non-nil, the last incremental search
 218 regexp is used as REGEXP--you don't have to specify it with the
 219 minibuffer.
 220
 221 Matching is independent of case if `case-fold-search' is non-nil and
 222 REGEXP has no uppercase letters.  Replacement transfers the case
 223 pattern of the old text to the new text, if `case-replace' and
 224 `case-fold-search' are non-nil and REGEXP has no uppercase letters.
 225 \(Transferring the case pattern means that if the old text matched is
 226 all caps, or capitalized, then its replacement is upcased or
 227 capitalized.)
 228
 229 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 230 only matches surrounded by word boundaries.
 231 Fourth and fifth arg START and END specify the region to operate on.
 232
 233 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 234 and `\\=\\N' (where N is a digit) stands for
 235 whatever what matched the Nth `\\(...\\)' in REGEXP.
 236 `\\?' lets you edit the replacement text in the minibuffer
 237 at the given position for each replacement.
 238
 239 In interactive calls, the replacement text can contain `\\,'
 240 followed by a Lisp expression.  Each
 241 replacement evaluates that expression to compute the replacement
 242 string.  Inside of that expression, `\\&' is a string denoting the
 243 whole match as a string, `\\N' for a partial match, `\\#&' and `\\#N'
 244 for the whole or a partial match converted to a number with
 245 `string-to-number', and `\\#' itself for the number of replacements
 246 done so far (starting with zero).
 247
 248 If the replacement expression is a symbol, write a space after it
 249 to terminate it.  One space there, if any, will be discarded.
 250
 251 When using those Lisp features interactively in the replacement
 252 text, TO-STRING is actually made a list instead of a string.
 253 Use \\[repeat-complex-command] after this command for details."
 254   (interactive
 255    (let ((common
 256           (query-replace-read-args "Query replace regexp" t)))
 257      (list (nth 0 common) (nth 1 common) (nth 2 common)
 258            ;; These are done separately here
 259            ;; so that command-history will record these expressions
 260            ;; rather than the values they had this time.
 261            (if (and transient-mark-mode mark-active)
 262                (region-beginning))
 263            (if (and transient-mark-mode mark-active)
 264                (region-end)))))
 265   (perform-replace regexp to-string t t delimited nil nil start end))
 266
 267 (define-key esc-map [?\C-%] 'query-replace-regexp)
 268
 269 (defun query-replace-regexp-eval (regexp to-expr &optional delimited start end)
 270   "Replace some things after point matching REGEXP with the result of TO-EXPR.
 271 As each match is found, the user must type a character saying
 272 what to do with it.  For directions, type \\[help-command] at that time.
 273
 274 TO-EXPR is a Lisp expression evaluated to compute each replacement.  It may
 275 reference `replace-count' to get the number of replacements already made.
 276 If the result of TO-EXPR is not a string, it is converted to one using
 277 `prin1-to-string' with the NOESCAPE argument (which see).
 278
 279 For convenience, when entering TO-EXPR interactively, you can use `\\&' or
 280 `\\0' to stand for whatever matched the whole of REGEXP, and `\\N' (where
 281 N is a digit) to stand for whatever matched the Nth `\\(...\\)' in REGEXP.
 282 Use `\\#&' or `\\#N' if you want a number instead of a string.
 283 In interactive use, `\\#' in itself stands for `replace-count'.
 284
 285 In Transient Mark mode, if the mark is active, operate on the contents
 286 of the region.  Otherwise, operate from point to the end of the buffer.
 287
 288 If `query-replace-interactive' is non-nil, the last incremental search
 289 regexp is used as REGEXP--you don't have to specify it with the
 290 minibuffer.
 291
 292 Preserves case in each replacement if `case-replace' and `case-fold-search'
 293 are non-nil and REGEXP has no uppercase letters.
 294
 295 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 296 only matches that are surrounded by word boundaries.
 297 Fourth and fifth arg START and END specify the region to operate on."
 298   (interactive
 299    (progn
 300    (barf-if-buffer-read-only)
 301    (let* ((from
 302            ;; Let-bind the history var to disable the "foo -> bar" default.
 303            ;; Maybe we shouldn't disable this default, but for now I'll
 304            ;; leave it off.  --Stef
 305            (let ((query-replace-to-history-variable nil))
 306              (query-replace-read-from "Query replace regexp" t)))
 307           (to (list (read-from-minibuffer
 308                      (format "Query replace regexp %s with eval: "
 309                              (query-replace-descr from))
 310                      nil nil t query-replace-to-history-variable from t))))
 311      ;; We make TO a list because replace-match-string-symbols requires one,
 312      ;; and the user might enter a single token.
 313      (replace-match-string-symbols to)
 314      (list from (car to) current-prefix-arg
 315            (if (and transient-mark-mode mark-active)
 316                (region-beginning))
 317            (if (and transient-mark-mode mark-active)
 318                (region-end))))))
 319   (perform-replace regexp (cons 'replace-eval-replacement to-expr)
 320                    t 'literal delimited nil nil start end))
 321
 322 (defun map-query-replace-regexp (regexp to-strings &optional n start end)
 323   "Replace some matches for REGEXP with various strings, in rotation.
 324 The second argument TO-STRINGS contains the replacement strings,
 325 separated by spaces.  Third arg DELIMITED (prefix arg if interactive),
 326 if non-nil, means replace only matches surrounded by word boundaries.
 327 This command works like `query-replace-regexp' except that each
 328 successive replacement uses the next successive replacement string,
 329 wrapping around from the last such string to the first.
 330
 331 In Transient Mark mode, if the mark is active, operate on the contents
 332 of the region.  Otherwise, operate from point to the end of the buffer.
 333
 334 Non-interactively, TO-STRINGS may be a list of replacement strings.
 335
 336 If `query-replace-interactive' is non-nil, the last incremental search
 337 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 338
 339 A prefix argument N says to use each replacement string N times
 340 before rotating to the next.
 341 Fourth and fifth arg START and END specify the region to operate on."
 342   (interactive
 343    (let* ((from (if query-replace-interactive
 344                     (car regexp-search-ring)
 345                   (read-from-minibuffer "Map query replace (regexp): "
 346                                         nil nil nil
 347                                         'query-replace-history nil t)))
 348           (to (read-from-minibuffer
 349                (format "Query replace %s with (space-separated strings): "
 350                        (query-replace-descr from))
 351                nil nil nil
 352                'query-replace-history from t)))
 353      (list from to
 354            (and current-prefix-arg
 355                 (prefix-numeric-value current-prefix-arg))
 356            (if (and transient-mark-mode mark-active)
 357                (region-beginning))
 358            (if (and transient-mark-mode mark-active)
 359                (region-end)))))
 360   (let (replacements)
 361     (if (listp to-strings)
 362         (setq replacements to-strings)
 363       (while (/= (length to-strings) 0)
 364         (if (string-match " " to-strings)
 365             (setq replacements
 366                   (append replacements
 367                           (list (substring to-strings 0
 368                                            (string-match " " to-strings))))
 369                   to-strings (substring to-strings
 370                                        (1+ (string-match " " to-strings))))
 371           (setq replacements (append replacements (list to-strings))
 372                 to-strings ""))))
 373     (perform-replace regexp replacements t t nil n nil start end)))
 374
 375 (defun replace-string (from-string to-string &optional delimited start end)
 376   "Replace occurrences of FROM-STRING with TO-STRING.
 377 Preserve case in each match if `case-replace' and `case-fold-search'
 378 are non-nil and FROM-STRING has no uppercase letters.
 379 \(Preserving case means that if the string matched is all caps, or capitalized,
 380 then its replacement is upcased or capitalized.)
 381
 382 In Transient Mark mode, if the mark is active, operate on the contents
 383 of the region.  Otherwise, operate from point to the end of the buffer.
 384
 385 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 386 only matches surrounded by word boundaries.
 387 Fourth and fifth arg START and END specify the region to operate on.
 388
 389 If `query-replace-interactive' is non-nil, the last incremental search
 390 string is used as FROM-STRING--you don't have to specify it with the
 391 minibuffer.
 392
 393 This function is usually the wrong thing to use in a Lisp program.
 394 What you probably want is a loop like this:
 395   (while (search-forward FROM-STRING nil t)
 396     (replace-match TO-STRING nil t))
 397 which will run faster and will not set the mark or print anything.
 398 \(You may need a more complex loop if FROM-STRING can match the null string
 399 and TO-STRING is also null.)"
 400   (interactive
 401    (let ((common
 402           (query-replace-read-args "Replace string" nil)))
 403      (list (nth 0 common) (nth 1 common) (nth 2 common)
 404            (if (and transient-mark-mode mark-active)
 405                (region-beginning))
 406            (if (and transient-mark-mode mark-active)
 407                (region-end)))))
 408   (perform-replace from-string to-string nil nil delimited nil nil start end))
 409
 410 (defun replace-regexp (regexp to-string &optional delimited start end)
 411   "Replace things after point matching REGEXP with TO-STRING.
 412 Preserve case in each match if `case-replace' and `case-fold-search'
 413 are non-nil and REGEXP has no uppercase letters.
 414
 415 In Transient Mark mode, if the mark is active, operate on the contents
 416 of the region.  Otherwise, operate from point to the end of the buffer.
 417
 418 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 419 only matches surrounded by word boundaries.
 420 Fourth and fifth arg START and END specify the region to operate on.
 421
 422 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 423 and `\\=\\N' (where N is a digit) stands for
 424 whatever what matched the Nth `\\(...\\)' in REGEXP.
 425 `\\?' lets you edit the replacement text in the minibuffer
 426 at the given position for each replacement.
 427
 428 In interactive calls, the replacement text may contain `\\,'
 429 followed by a Lisp expression used as part of the replacement
 430 text.  Inside of that expression, `\\&' is a string denoting the
 431 whole match, `\\N' a partial matches, `\\#&' and `\\#N' the
 432 respective numeric values from `string-to-number', and `\\#'
 433 itself for `replace-count', the number of replacements occured so
 434 far.
 435
 436 If your Lisp expression is an identifier and the next letter in
 437 the replacement string would be interpreted as part of it, you
 438 can wrap it with an expression like `\\,(or \\#)'.  Incidentally,
 439 for this particular case you may also enter `\\#' in the
 440 replacement text directly.
 441
 442 When using those Lisp features interactively in the replacement
 443 text, TO-STRING is actually made a list instead of a string.
 444 Use \\[repeat-complex-command] after this command for details.
 445
 446 If `query-replace-interactive' is non-nil, the last incremental search
 447 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 448
 449 This function is usually the wrong thing to use in a Lisp program.
 450 What you probably want is a loop like this:
 451   (while (re-search-forward REGEXP nil t)
 452     (replace-match TO-STRING nil nil))
 453 which will run faster and will not set the mark or print anything."
 454   (interactive
 455    (let ((common
 456           (query-replace-read-args "Replace regexp" t)))
 457      (list (nth 0 common) (nth 1 common) (nth 2 common)
 458            (if (and transient-mark-mode mark-active)
 459                (region-beginning))
 460            (if (and transient-mark-mode mark-active)
 461                (region-end)))))
 462   (perform-replace regexp to-string nil t delimited nil nil start end))
 463
 464 \f
 465 (defvar regexp-history nil
 466   "History list for some commands that read regular expressions.")
 467
 468
 469 (defalias 'delete-non-matching-lines 'keep-lines)
 470 (defalias 'delete-matching-lines 'flush-lines)
 471 (defalias 'count-matches 'how-many)
 472
 473
 474 (defun keep-lines-read-args (prompt)
 475   "Read arguments for `keep-lines' and friends.
 476 Prompt for a regexp with PROMPT.
 477 Value is a list, (REGEXP)."
 478   (list (read-from-minibuffer prompt nil nil nil
 479                               'regexp-history nil t)))
 480
 481 (defun keep-lines (regexp &optional rstart rend)
 482   "Delete all lines except those containing matches for REGEXP.
 483 A match split across lines preserves all the lines it lies in.
 484 Applies to all lines after point.
 485
 486 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 487 the matching is case-sensitive.
 488
 489 Second and third arg RSTART and REND specify the region to operate on.
 490
 491 Interactively, in Transient Mark mode when the mark is active, operate
 492 on the contents of the region.  Otherwise, operate from point to the
 493 end of the buffer."
 494
 495   (interactive
 496    (progn
 497      (barf-if-buffer-read-only)
 498      (keep-lines-read-args "Keep lines (containing match for regexp): ")))
 499   (if rstart
 500       (progn
 501         (goto-char (min rstart rend))
 502         (setq rend (copy-marker (max rstart rend))))
 503     (if (and transient-mark-mode mark-active)
 504         (setq rstart (region-beginning)
 505               rend (copy-marker (region-end)))
 506       (setq rstart (point)
 507             rend (point-max-marker)))
 508     (goto-char rstart))
 509   (save-excursion
 510     (or (bolp) (forward-line 1))
 511     (let ((start (point))
 512           (case-fold-search  (and case-fold-search
 513                                   (isearch-no-upper-case-p regexp t))))
 514       (while (< (point) rend)
 515         ;; Start is first char not preserved by previous match.
 516         (if (not (re-search-forward regexp rend 'move))
 517             (delete-region start rend)
 518           (let ((end (save-excursion (goto-char (match-beginning 0))
 519                                      (beginning-of-line)
 520                                      (point))))
 521             ;; Now end is first char preserved by the new match.
 522             (if (< start end)
 523                 (delete-region start end))))
 524
 525         (setq start (save-excursion (forward-line 1) (point)))
 526         ;; If the match was empty, avoid matching again at same place.
 527         (and (< (point) rend)
 528              (= (match-beginning 0) (match-end 0))
 529              (forward-char 1))))))
 530
 531
 532 (defun flush-lines (regexp &optional rstart rend)
 533   "Delete lines containing matches for REGEXP.
 534 If a match is split across lines, all the lines it lies in are deleted.
 535 Applies to lines after point.
 536
 537 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 538 the matching is case-sensitive.
 539
 540 Second and third arg RSTART and REND specify the region to operate on.
 541
 542 Interactively, in Transient Mark mode when the mark is active, operate
 543 on the contents of the region.  Otherwise, operate from point to the
 544 end of the buffer."
 545
 546   (interactive
 547    (progn
 548      (barf-if-buffer-read-only)
 549      (keep-lines-read-args "Flush lines (containing match for regexp): ")))
 550   (if rstart
 551       (progn
 552         (goto-char (min rstart rend))
 553         (setq rend (copy-marker (max rstart rend))))
 554     (if (and transient-mark-mode mark-active)
 555         (setq rstart (region-beginning)
 556               rend (copy-marker (region-end)))
 557       (setq rstart (point)
 558             rend (point-max-marker)))
 559     (goto-char rstart))
 560   (let ((case-fold-search (and case-fold-search
 561                                (isearch-no-upper-case-p regexp t))))
 562     (save-excursion
 563       (while (and (< (point) rend)
 564                   (re-search-forward regexp rend t))
 565         (delete-region (save-excursion (goto-char (match-beginning 0))
 566                                        (beginning-of-line)
 567                                        (point))
 568                        (progn (forward-line 1) (point)))))))
 569
 570
 571 (defun how-many (regexp &optional rstart rend)
 572   "Print number of matches for REGEXP following point.
 573
 574 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 575 the matching is case-sensitive.
 576
 577 Second and third arg RSTART and REND specify the region to operate on.
 578
 579 Interactively, in Transient Mark mode when the mark is active, operate
 580 on the contents of the region.  Otherwise, operate from point to the
 581 end of the buffer."
 582
 583   (interactive
 584    (keep-lines-read-args "How many matches for (regexp): "))
 585   (save-excursion
 586     (if rstart
 587         (goto-char (min rstart rend))
 588       (if (and transient-mark-mode mark-active)
 589           (setq rstart (region-beginning)
 590                 rend (copy-marker (region-end)))
 591         (setq rstart (point)
 592               rend (point-max-marker)))
 593       (goto-char rstart))
 594     (let ((count 0)
 595           opoint
 596           (case-fold-search (and case-fold-search
 597                                  (isearch-no-upper-case-p regexp t))))
 598       (while (and (< (point) rend)
 599                   (progn (setq opoint (point))
 600                          (re-search-forward regexp rend t)))
 601         (if (= opoint (point))
 602             (forward-char 1)
 603           (setq count (1+ count))))
 604       (message "%d occurrences" count))))
 605
 606 \f
 607 (defvar occur-mode-map
 608   (let ((map (make-sparse-keymap)))
 609     (define-key map [mouse-2] 'occur-mode-mouse-goto)
 610     (define-key map "\C-c\C-c" 'occur-mode-goto-occurrence)
 611     (define-key map "\C-m" 'occur-mode-goto-occurrence)
 612     (define-key map "o" 'occur-mode-goto-occurrence-other-window)
 613     (define-key map "\C-o" 'occur-mode-display-occurrence)
 614     (define-key map "\M-n" 'occur-next)
 615     (define-key map "\M-p" 'occur-prev)
 616     (define-key map "r" 'occur-rename-buffer)
 617     (define-key map "c" 'clone-buffer)
 618     (define-key map "g" 'revert-buffer)
 619     (define-key map "q" 'quit-window)
 620     (define-key map "z" 'kill-this-buffer)
 621     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
 622     map)
 623   "Keymap for `occur-mode'.")
 624
 625 (defvar occur-revert-arguments nil
 626   "Arguments to pass to `occur-1' to revert an Occur mode buffer.
 627 See `occur-revert-function'.")
 628
 629 (defcustom occur-mode-hook '(turn-on-font-lock)
 630   "Hook run when entering Occur mode."
 631   :type 'hook
 632   :group 'matching)
 633
 634 (defcustom occur-hook nil
 635   "Hook run when `occur' is called."
 636   :type 'hook
 637   :group 'matching)
 638
 639 (put 'occur-mode 'mode-class 'special)
 640 (defun occur-mode ()
 641   "Major mode for output from \\[occur].
 642 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 643 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 644 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 645
 646 \\{occur-mode-map}"
 647   (interactive)
 648   (kill-all-local-variables)
 649   (use-local-map occur-mode-map)
 650   (setq major-mode 'occur-mode)
 651   (setq mode-name "Occur")
 652   (set (make-local-variable 'revert-buffer-function) 'occur-revert-function)
 653   (make-local-variable 'occur-revert-arguments)
 654   (add-hook 'change-major-mode-hook 'font-lock-defontify nil t)
 655   (setq next-error-function 'occur-next-error)
 656   (run-hooks 'occur-mode-hook))
 657
 658 (defun occur-revert-function (ignore1 ignore2)
 659   "Handle `revert-buffer' for Occur mode buffers."
 660   (apply 'occur-1 (append occur-revert-arguments (list (buffer-name)))))
 661
 662 (defun occur-mode-mouse-goto (event)
 663   "In Occur mode, go to the occurrence whose line you click on."
 664   (interactive "e")
 665   (let (pos)
 666     (save-excursion
 667       (set-buffer (window-buffer (posn-window (event-end event))))
 668       (save-excursion
 669         (goto-char (posn-point (event-end event)))
 670         (setq pos (occur-mode-find-occurrence))))
 671     (pop-to-buffer (marker-buffer pos))
 672     (goto-char pos)))
 673
 674 (defun occur-mode-find-occurrence ()
 675   (let ((pos (get-text-property (point) 'occur-target)))
 676     (unless pos
 677       (error "No occurrence on this line"))
 678     (unless (buffer-live-p (marker-buffer pos))
 679       (error "Buffer for this occurrence was killed"))
 680     pos))
 681
 682 (defun occur-mode-goto-occurrence ()
 683   "Go to the occurrence the current line describes."
 684   (interactive)
 685   (let ((pos (occur-mode-find-occurrence)))
 686     (pop-to-buffer (marker-buffer pos))
 687     (goto-char pos)))
 688
 689 (defun occur-mode-goto-occurrence-other-window ()
 690   "Go to the occurrence the current line describes, in another window."
 691   (interactive)
 692   (let ((pos (occur-mode-find-occurrence)))
 693     (switch-to-buffer-other-window (marker-buffer pos))
 694     (goto-char pos)))
 695
 696 (defun occur-mode-display-occurrence ()
 697   "Display in another window the occurrence the current line describes."
 698   (interactive)
 699   (let ((pos (occur-mode-find-occurrence))
 700         window
 701         ;; Bind these to ensure `display-buffer' puts it in another window.
 702         same-window-buffer-names
 703         same-window-regexps)
 704     (setq window (display-buffer (marker-buffer pos)))
 705     ;; This is the way to set point in the proper window.
 706     (save-selected-window
 707       (select-window window)
 708       (goto-char pos))))
 709
 710 (defun occur-find-match (n search message)
 711   (if (not n) (setq n 1))
 712   (let ((r))
 713     (while (> n 0)
 714       (setq r (funcall search (point) 'occur-match))
 715       (and r
 716            (get-text-property r 'occur-match)
 717            (setq r (funcall search r 'occur-match)))
 718       (if r
 719           (goto-char r)
 720         (error message))
 721       (setq n (1- n)))))
 722
 723 (defun occur-next (&optional n)
 724   "Move to the Nth (default 1) next match in an Occur mode buffer."
 725   (interactive "p")
 726   (occur-find-match n #'next-single-property-change "No more matches"))
 727
 728 (defun occur-prev (&optional n)
 729   "Move to the Nth (default 1) previous match in an Occur mode buffer."
 730   (interactive "p")
 731   (occur-find-match n #'previous-single-property-change "No earlier matches"))
 732
 733 (defun occur-next-error (&optional argp reset)
 734   "Move to the Nth (default 1) next match in an Occur mode buffer.
 735 Compatibility function for \\[next-error] invocations."
 736   (interactive "p")
 737   (when reset
 738     (occur-find-match 0 #'next-single-property-change "No first match"))
 739   (occur-find-match
 740    (prefix-numeric-value argp)
 741    (if (> 0 (prefix-numeric-value argp))
 742        #'previous-single-property-change
 743      #'next-single-property-change)
 744    "No more matches")
 745   ;; In case the *Occur* buffer is visible in a nonselected window.
 746   (set-window-point (get-buffer-window (current-buffer)) (point))
 747   (occur-mode-goto-occurrence))
 748
 749 \f
 750 (defcustom list-matching-lines-default-context-lines 0
 751   "*Default number of context lines included around `list-matching-lines' matches.
 752 A negative number means to include that many lines before the match.
 753 A positive number means to include that many lines both before and after."
 754   :type 'integer
 755   :group 'matching)
 756
 757 (defalias 'list-matching-lines 'occur)
 758
 759 (defcustom list-matching-lines-face 'bold
 760   "*Face used by \\[list-matching-lines] to show the text that matches.
 761 If the value is nil, don't highlight the matching portions specially."
 762   :type 'face
 763   :group 'matching)
 764
 765 (defcustom list-matching-lines-buffer-name-face 'underline
 766   "*Face used by \\[list-matching-lines] to show the names of buffers.
 767 If the value is nil, don't highlight the buffer names specially."
 768   :type 'face
 769   :group 'matching)
 770
 771 (defun occur-accumulate-lines (count &optional no-props)
 772   (save-excursion
 773     (let ((forwardp (> count 0))
 774           (result nil))
 775       (while (not (or (zerop count)
 776                       (if forwardp
 777                           (eobp)
 778                         (bobp))))
 779         (setq count (+ count (if forwardp -1 1)))
 780         (push
 781          (funcall (if no-props
 782                       #'buffer-substring-no-properties
 783                     #'buffer-substring)
 784           (line-beginning-position)
 785           (line-end-position))
 786          result)
 787         (forward-line (if forwardp 1 -1)))
 788       (nreverse result))))
 789
 790 (defun occur-read-primary-args ()
 791   (list (let* ((default (car regexp-history))
 792                (input
 793                 (read-from-minibuffer
 794                  (if default
 795                      (format "List lines matching regexp (default `%s'): "
 796                              (query-replace-descr default))
 797                    "List lines matching regexp: ")
 798                  nil
 799                  nil
 800                  nil
 801                  'regexp-history
 802                  default)))
 803           (if (equal input "")
 804               default
 805             input))
 806         (when current-prefix-arg
 807           (prefix-numeric-value current-prefix-arg))))
 808
 809 (defun occur-rename-buffer (&optional unique-p)
 810   "Rename the current *Occur* buffer to *Occur: original-buffer-name*.
 811 Here `original-buffer-name' is the buffer name were occur was originally run.
 812 When given the prefix argument, the renaming will not clobber the existing
 813 buffer(s) of that name, but use `generate-new-buffer-name' instead.
 814 You can add this to `occur-hook' if you always want a separate *Occur*
 815 buffer for each buffer where you invoke `occur'."
 816   (interactive "P")
 817   (with-current-buffer
 818       (if (eq major-mode 'occur-mode) (current-buffer) (get-buffer "*Occur*"))
 819     (rename-buffer (concat "*Occur: "
 820                            (mapconcat #'buffer-name
 821                                       (car (cddr occur-revert-arguments)) "/")
 822                            "*")
 823                    unique-p)))
 824
 825 (defun occur (regexp &optional nlines)
 826   "Show all lines in the current buffer containing a match for REGEXP.
 827
 828 If a match spreads across multiple lines, all those lines are shown.
 829
 830 Each line is displayed with NLINES lines before and after, or -NLINES
 831 before if NLINES is negative.
 832 NLINES defaults to `list-matching-lines-default-context-lines'.
 833 Interactively it is the prefix arg.
 834
 835 The lines are shown in a buffer named `*Occur*'.
 836 It serves as a menu to find any of the occurrences in this buffer.
 837 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 838
 839 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 840 the matching is case-sensitive."
 841   (interactive (occur-read-primary-args))
 842   (occur-1 regexp nlines (list (current-buffer))))
 843
 844 (defun multi-occur (bufs regexp &optional nlines)
 845   "Show all lines in buffers BUFS containing a match for REGEXP.
 846 This function acts on multiple buffers; otherwise, it is exactly like
 847 `occur'."
 848   (interactive
 849    (cons
 850     (let* ((bufs (list (read-buffer "First buffer to search: "
 851                                     (current-buffer) t)))
 852            (buf nil)
 853            (ido-ignore-item-temp-list bufs))
 854       (while (not (string-equal
 855                    (setq buf (read-buffer
 856                               (if (eq read-buffer-function 'ido-read-buffer)
 857                                   "Next buffer to search (C-j to end): "
 858                                 "Next buffer to search (RET to end): ")
 859                               nil t))
 860                    ""))
 861         (add-to-list 'bufs buf)
 862         (setq ido-ignore-item-temp-list bufs))
 863       (nreverse (mapcar #'get-buffer bufs)))
 864     (occur-read-primary-args)))
 865   (occur-1 regexp nlines bufs))
 866
 867 (defun multi-occur-by-filename-regexp (bufregexp regexp &optional nlines)
 868   "Show all lines matching REGEXP in buffers named by BUFREGEXP.
 869 See also `multi-occur'."
 870   (interactive
 871    (cons
 872     (let* ((default (car regexp-history))
 873            (input
 874             (read-from-minibuffer
 875              "List lines in buffers whose filename matches regexp: "
 876              nil
 877              nil
 878              nil
 879              'regexp-history)))
 880       (if (equal input "")
 881           default
 882         input))
 883     (occur-read-primary-args)))
 884   (when bufregexp
 885     (occur-1 regexp nlines
 886              (delq nil
 887                    (mapcar (lambda (buf)
 888                              (when (and (buffer-file-name buf)
 889                                         (string-match bufregexp
 890                                                       (buffer-file-name buf)))
 891                                buf))
 892                            (buffer-list))))))
 893
 894 (defun occur-1 (regexp nlines bufs &optional buf-name)
 895   (unless buf-name
 896     (setq buf-name "*Occur*"))
 897   (let ((occur-buf (get-buffer-create buf-name))
 898         (made-temp-buf nil)
 899         (active-bufs (delq nil (mapcar #'(lambda (buf)
 900                                            (when (buffer-live-p buf) buf))
 901                                        bufs))))
 902     ;; Handle the case where one of the buffers we're searching is the
 903     ;; *Occur* buffer itself.
 904     (when (memq occur-buf bufs)
 905       (setq occur-buf (with-current-buffer occur-buf
 906                         (clone-buffer "*Occur-temp*"))
 907             made-temp-buf t))
 908     (with-current-buffer occur-buf
 909       (setq buffer-read-only nil)
 910       (occur-mode)
 911       (erase-buffer)
 912       (let ((count (occur-engine
 913                     regexp active-bufs occur-buf
 914                     (or nlines list-matching-lines-default-context-lines)
 915                     (and case-fold-search
 916                          (isearch-no-upper-case-p regexp t))
 917                     list-matching-lines-buffer-name-face
 918                     nil list-matching-lines-face nil)))
 919         (let* ((bufcount (length active-bufs))
 920                (diff (- (length bufs) bufcount)))
 921           (message "Searched %d buffer%s%s; %s match%s for `%s'"
 922                    bufcount (if (= bufcount 1) "" "s")
 923                    (if (zerop diff) "" (format " (%d killed)" diff))
 924                    (if (zerop count) "no" (format "%d" count))
 925                    (if (= count 1) "" "es")
 926                    regexp))
 927         ;; If we had to make a temporary buffer, make it the *Occur*
 928         ;; buffer now.
 929         (when made-temp-buf
 930           (with-current-buffer (get-buffer buf-name)
 931             (kill-buffer (current-buffer)))
 932           (rename-buffer buf-name))
 933         (setq occur-revert-arguments (list regexp nlines bufs)
 934               buffer-read-only t)
 935         (if (> count 0)
 936             (progn
 937               (display-buffer occur-buf)
 938               (setq next-error-last-buffer occur-buf))
 939           (kill-buffer occur-buf)))
 940       (run-hooks 'occur-hook))))
 941
 942 (defun occur-engine-add-prefix (lines)
 943   (mapcar
 944    #'(lambda (line)
 945        (concat "       :" line "\n"))
 946    lines))
 947
 948 (defun occur-engine (regexp buffers out-buf nlines case-fold-search
 949                             title-face prefix-face match-face keep-props)
 950   (with-current-buffer out-buf
 951     (setq buffer-read-only nil)
 952     (let ((globalcount 0)
 953           (coding nil))
 954       ;; Map over all the buffers
 955       (dolist (buf buffers)
 956         (when (buffer-live-p buf)
 957           (let ((matches 0)     ;; count of matched lines
 958                 (lines 1)       ;; line count
 959                 (matchbeg 0)
 960                 (origpt nil)
 961                 (begpt nil)
 962                 (endpt nil)
 963                 (marker nil)
 964                 (curstring "")
 965                 (headerpt (with-current-buffer out-buf (point))))
 966             (save-excursion
 967               (set-buffer buf)
 968               (or coding
 969                   ;; Set CODING only if the current buffer locally
 970                   ;; binds buffer-file-coding-system.
 971                   (not (local-variable-p 'buffer-file-coding-system))
 972                   (setq coding buffer-file-coding-system))
 973               (save-excursion
 974                 (goto-char (point-min)) ;; begin searching in the buffer
 975                 (while (not (eobp))
 976                   (setq origpt (point))
 977                   (when (setq endpt (re-search-forward regexp nil t))
 978                     (setq matches (1+ matches)) ;; increment match count
 979                     (setq matchbeg (match-beginning 0))
 980                     (setq begpt (save-excursion
 981                                   (goto-char matchbeg)
 982                                   (line-beginning-position)))
 983                     (setq lines (+ lines (1- (count-lines origpt endpt))))
 984                     (setq marker (make-marker))
 985                     (set-marker marker matchbeg)
 986                     (setq curstring (buffer-substring begpt
 987                                                       (line-end-position)))
 988                     ;; Depropertize the string, and maybe
 989                     ;; highlight the matches
 990                     (let ((len (length curstring))
 991                           (start 0))
 992                       (unless keep-props
 993                         (set-text-properties 0 len nil curstring))
 994                       (while (and (< start len)
 995                                   (string-match regexp curstring start))
 996                         (add-text-properties (match-beginning 0)
 997                                              (match-end 0)
 998                                              (append
 999                                               `(occur-match t)
1000                                               (when match-face
1001                                                 `(font-lock-face ,match-face)))
1002                                              curstring)
1003                         (setq start (match-end 0))))
1004                     ;; Generate the string to insert for this match
1005                     (let* ((out-line
1006                             (concat
1007                              ;; Using 7 digits aligns tabs properly.
1008                              (apply #'propertize (format "%7d:" lines)
1009                                     (append
1010                                      (when prefix-face
1011                                        `(font-lock-face prefix-face))
1012                                      '(occur-prefix t)))
1013                              curstring
1014                              "\n"))
1015                            (data
1016                             (if (= nlines 0)
1017                                 ;; The simple display style
1018                                 out-line
1019                               ;; The complex multi-line display
1020                               ;; style.  Generate a list of lines,
1021                               ;; concatenate them all together.
1022                               (apply #'concat
1023                                      (nconc
1024                                       (occur-engine-add-prefix (nreverse (cdr (occur-accumulate-lines (- (1+ (abs nlines))) keep-props))))
1025                                       (list out-line)
1026                                       (if (> nlines 0)
1027                                           (occur-engine-add-prefix
1028                                            (cdr (occur-accumulate-lines (1+ nlines) keep-props)))))))))
1029                       ;; Actually insert the match display data
1030                       (with-current-buffer out-buf
1031                         (let ((beg (point))
1032                               (end (progn (insert data) (point))))
1033                           (unless (= nlines 0)
1034                             (insert "-------\n"))
1035                           (add-text-properties
1036                            beg end
1037                            `(occur-target ,marker help-echo "mouse-2: go to this occurrence"))
1038                           ;; We don't put `mouse-face' on the newline,
1039                           ;; because that loses.
1040                           (add-text-properties beg (1- end) '(mouse-face highlight)))))
1041                     (goto-char endpt))
1042                   (if endpt
1043                       (progn
1044                         (setq lines (1+ lines))
1045                         ;; On to the next match...
1046                         (forward-line 1))
1047                     (goto-char (point-max))))))
1048             (when (not (zerop matches)) ;; is the count zero?
1049               (setq globalcount (+ globalcount matches))
1050               (with-current-buffer out-buf
1051                 (goto-char headerpt)
1052                 (let ((beg (point))
1053                       end)
1054                   (insert (format "%d match%s for \"%s\" in buffer: %s\n"
1055                                   matches (if (= matches 1) "" "es")
1056                                   regexp (buffer-name buf)))
1057                   (setq end (point))
1058                   (add-text-properties beg end
1059                                        (append
1060                                         (when title-face
1061                                           `(font-lock-face ,title-face))
1062                                         `(occur-title ,buf))))
1063                 (goto-char (point-min)))))))
1064       (if coding
1065           ;; CODING is buffer-file-coding-system of the first buffer
1066           ;; that locally binds it.  Let's use it also for the output
1067           ;; buffer.
1068           (set-buffer-file-coding-system coding))
1069       ;; Return the number of matches
1070       globalcount)))
1071
1072 \f
1073 ;; It would be nice to use \\[...], but there is no reasonable way
1074 ;; to make that display both SPC and Y.
1075 (defconst query-replace-help
1076   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
1077 RET or `q' to exit, Period to replace one match and exit,
1078 Comma to replace but not move point immediately,
1079 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
1080 C-w to delete match and recursive edit,
1081 C-l to clear the screen, redisplay, and offer same replacement again,
1082 ! to replace all remaining matches with no more questions,
1083 ^ to move point back to previous match,
1084 E to edit the replacement string"
1085   "Help message while in `query-replace'.")
1086
1087 (defvar query-replace-map (make-sparse-keymap)
1088   "Keymap that defines the responses to questions in `query-replace'.
1089 The \"bindings\" in this map are not commands; they are answers.
1090 The valid answers include `act', `skip', `act-and-show',
1091 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
1092 `automatic', `backup', `exit-prefix', and `help'.")
1093
1094 (define-key query-replace-map " " 'act)
1095 (define-key query-replace-map "\d" 'skip)
1096 (define-key query-replace-map [delete] 'skip)
1097 (define-key query-replace-map [backspace] 'skip)
1098 (define-key query-replace-map "y" 'act)
1099 (define-key query-replace-map "n" 'skip)
1100 (define-key query-replace-map "Y" 'act)
1101 (define-key query-replace-map "N" 'skip)
1102 (define-key query-replace-map "e" 'edit-replacement)
1103 (define-key query-replace-map "E" 'edit-replacement)
1104 (define-key query-replace-map "," 'act-and-show)
1105 (define-key query-replace-map "q" 'exit)
1106 (define-key query-replace-map "\r" 'exit)
1107 (define-key query-replace-map [return] 'exit)
1108 (define-key query-replace-map "." 'act-and-exit)
1109 (define-key query-replace-map "\C-r" 'edit)
1110 (define-key query-replace-map "\C-w" 'delete-and-edit)
1111 (define-key query-replace-map "\C-l" 'recenter)
1112 (define-key query-replace-map "!" 'automatic)
1113 (define-key query-replace-map "^" 'backup)
1114 (define-key query-replace-map "\C-h" 'help)
1115 (define-key query-replace-map [f1] 'help)
1116 (define-key query-replace-map [help] 'help)
1117 (define-key query-replace-map "?" 'help)
1118 (define-key query-replace-map "\C-g" 'quit)
1119 (define-key query-replace-map "\C-]" 'quit)
1120 (define-key query-replace-map "\e" 'exit-prefix)
1121 (define-key query-replace-map [escape] 'exit-prefix)
1122
1123 (defun replace-match-string-symbols (n)
1124   "Process a list (and any sub-lists), expanding certain symbols.
1125 Symbol  Expands To
1126 N     (match-string N)           (where N is a string of digits)
1127 #N    (string-to-number (match-string N))
1128 &     (match-string 0)
1129 #&    (string-to-number (match-string 0))
1130 #     replace-count
1131
1132 Note that these symbols must be preceeded by a backslash in order to
1133 type them."
1134   (while n
1135     (cond
1136      ((consp (car n))
1137       (replace-match-string-symbols (car n))) ;Process sub-list
1138      ((symbolp (car n))
1139       (let ((name (symbol-name (car n))))
1140         (cond
1141          ((string-match "^[0-9]+$" name)
1142           (setcar n (list 'match-string (string-to-number name))))
1143          ((string-match "^#[0-9]+$" name)
1144           (setcar n (list 'string-to-number
1145                           (list 'match-string
1146                                 (string-to-number (substring name 1))))))
1147          ((string= "&" name)
1148           (setcar n '(match-string 0)))
1149          ((string= "#&" name)
1150           (setcar n '(string-to-number (match-string 0))))
1151          ((string= "#" name)
1152           (setcar n 'replace-count))))))
1153     (setq n (cdr n))))
1154
1155 (defun replace-eval-replacement (expression replace-count)
1156   (let ((replacement (eval expression)))
1157     (if (stringp replacement)
1158         replacement
1159       (prin1-to-string replacement t))))
1160
1161 (defun replace-quote (replacement)
1162   "Quote a replacement string.
1163 This just doubles all backslashes in REPLACEMENT and
1164 returns the resulting string.  If REPLACEMENT is not
1165 a string, it is first passed through `prin1-to-string'
1166 with the `noescape' argument set.
1167
1168 `match-data' is preserved across the call."
1169   (save-match-data
1170     (replace-regexp-in-string "\\\\" "\\\\"
1171                               (if (stringp replacement)
1172                                   replacement
1173                                 (prin1-to-string replacement t))
1174                               t t)))
1175
1176 (defun replace-loop-through-replacements (data replace-count)
1177   ;; DATA is a vector contaning the following values:
1178   ;;   0 next-rotate-count
1179   ;;   1 repeat-count
1180   ;;   2 next-replacement
1181   ;;   3 replacements
1182   (if (= (aref data 0) replace-count)
1183       (progn
1184         (aset data 0 (+ replace-count (aref data 1)))
1185         (let ((next (cdr (aref data 2))))
1186           (aset data 2 (if (consp next) next (aref data 3))))))
1187   (car (aref data 2)))
1188
1189 (defun replace-match-data (integers reuse &optional new)
1190   "Like `match-data', but markers in REUSE get invalidated.
1191 If NEW is non-NIL, it is set and returned instead of fresh data,
1192 but coerced to the correct value of INTEGERS."
1193   (or (and new
1194            (progn
1195              (set-match-data new)
1196              (and (eq new reuse)
1197                   (eq (null integers) (markerp (car reuse)))
1198                   new)))
1199       (match-data integers
1200                   (prog1 reuse
1201                     (while reuse
1202                       (if (markerp (car reuse))
1203                           (set-marker (car reuse) nil))
1204                       (setq reuse (cdr reuse)))))))
1205
1206 (defun replace-match-maybe-edit (newtext fixedcase literal noedit match-data)
1207   "Make a replacement with `replace-match', editing `\\?'.
1208 NEXTEXT, FIXEDCASE, LITERAL are just passed on.  If NOEDIT is true, no
1209 check for `\\?' is made to save time.  MATCH-DATA is used for the
1210 replacement.  In case editing is done, it is changed to use markers.
1211
1212 The return value is non-NIL if there has been no `\\?' or NOEDIT was
1213 passed in.  If LITERAL is set, no checking is done, anyway."
1214   (unless (or literal noedit)
1215     (setq noedit t)
1216     (while (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\\\?\\)"
1217                          newtext)
1218       (setq newtext
1219             (read-input "Edit replacement string: "
1220                         (prog1
1221                             (cons
1222                              (replace-match "" t t newtext 3)
1223                              (1+ (match-beginning 3)))
1224                           (setq match-data
1225                                 (replace-match-data
1226                                  nil match-data match-data))))
1227             noedit nil)))
1228   (set-match-data match-data)
1229   (replace-match newtext fixedcase literal)
1230   noedit)
1231
1232 (defun perform-replace (from-string replacements
1233                         query-flag regexp-flag delimited-flag
1234                         &optional repeat-count map start end)
1235   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
1236 Don't use this in your own program unless you want to query and set the mark
1237 just as `query-replace' does.  Instead, write a simple loop like this:
1238
1239   (while (re-search-forward \"foo[ \\t]+bar\" nil t)
1240     (replace-match \"foobar\" nil nil))
1241
1242 which will run faster and probably do exactly what you want.  Please
1243 see the documentation of `replace-match' to find out how to simulate
1244 `case-replace'.
1245
1246 This function returns nil if and only if there were no matches to
1247 make, or the user didn't cancel the call."
1248   (or map (setq map query-replace-map))
1249   (and query-flag minibuffer-auto-raise
1250        (raise-frame (window-frame (minibuffer-window))))
1251   (let ((nocasify (not (and case-fold-search case-replace
1252                             (string-equal from-string
1253                                           (downcase from-string)))))
1254         (case-fold-search (and case-fold-search
1255                                (string-equal from-string
1256                                              (downcase from-string))))
1257         (literal (or (not regexp-flag) (eq regexp-flag 'literal)))
1258         (search-function (if regexp-flag 're-search-forward 'search-forward))
1259         (search-string from-string)
1260         (real-match-data nil)           ; the match data for the current match
1261         (next-replacement nil)
1262         (noedit nil)
1263         (keep-going t)
1264         (stack nil)
1265         (replace-count 0)
1266         (nonempty-match nil)
1267
1268         ;; If non-nil, it is marker saying where in the buffer to stop.
1269         (limit nil)
1270
1271         ;; Data for the next match.  If a cons, it has the same format as
1272         ;; (match-data); otherwise it is t if a match is possible at point.
1273         (match-again t)
1274
1275         (message
1276          (if query-flag
1277              (substitute-command-keys
1278               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
1279
1280     ;; If region is active, in Transient Mark mode, operate on region.
1281     (when start
1282       (setq limit (copy-marker (max start end)))
1283       (goto-char (min start end))
1284       (deactivate-mark))
1285
1286     ;; REPLACEMENTS is either a string, a list of strings, or a cons cell
1287     ;; containing a function and its first argument.  The function is
1288     ;; called to generate each replacement like this:
1289     ;;   (funcall (car replacements) (cdr replacements) replace-count)
1290     ;; It must return a string.
1291     (cond
1292      ((stringp replacements)
1293       (setq next-replacement replacements
1294             replacements     nil))
1295      ((stringp (car replacements)) ; If it isn't a string, it must be a cons
1296       (or repeat-count (setq repeat-count 1))
1297       (setq replacements (cons 'replace-loop-through-replacements
1298                                (vector repeat-count repeat-count
1299                                        replacements replacements)))))
1300
1301     (if delimited-flag
1302         (setq search-function 're-search-forward
1303               search-string (concat "\\b"
1304                                     (if regexp-flag from-string
1305                                       (regexp-quote from-string))
1306                                     "\\b")))
1307     (push-mark)
1308     (undo-boundary)
1309     (unwind-protect
1310         ;; Loop finding occurrences that perhaps should be replaced.
1311         (while (and keep-going
1312                     (not (or (eobp) (and limit (>= (point) limit))))
1313                     ;; Use the next match if it is already known;
1314                     ;; otherwise, search for a match after moving forward
1315                     ;; one char if progress is required.
1316                     (setq real-match-data
1317                           (if (consp match-again)
1318                               (progn (goto-char (nth 1 match-again))
1319                                      (replace-match-data t
1320                                       real-match-data
1321                                       match-again))
1322                             (and (or match-again
1323                                      ;; MATCH-AGAIN non-nil means we
1324                                      ;; accept an adjacent match.  If
1325                                      ;; we don't, move one char to the
1326                                      ;; right.  This takes us a
1327                                      ;; character too far at the end,
1328                                      ;; but this is undone after the
1329                                      ;; while-loop.
1330                                      (progn
1331                                        (forward-char 1)
1332                                        (not (or (eobp)
1333                                                 (and limit (>= (point) limit))))))
1334                                  (funcall search-function search-string limit t)
1335                                  ;; For speed, use only integers and
1336                                  ;; reuse the list used last time.
1337                                  (replace-match-data t real-match-data)))))
1338           ;; Optionally ignore matches that have a read-only property.
1339           (unless (and query-replace-skip-read-only
1340                        (text-property-not-all
1341                         (match-beginning 0) (match-end 0)
1342                         'read-only nil))
1343
1344             ;; Record whether the match is nonempty, to avoid an infinite loop
1345             ;; repeatedly matching the same empty string.
1346             (setq nonempty-match
1347                   (/= (nth 0 real-match-data) (nth 1 real-match-data)))
1348
1349             ;; If the match is empty, record that the next one can't be
1350             ;; adjacent.
1351
1352             ;; Otherwise, if matching a regular expression, do the next
1353             ;; match now, since the replacement for this match may
1354             ;; affect whether the next match is adjacent to this one.
1355             ;; If that match is empty, don't use it.
1356             (setq match-again
1357                   (and nonempty-match
1358                        (or (not regexp-flag)
1359                            (and (looking-at search-string)
1360                                 (let ((match (match-data)))
1361                                   (and (/= (nth 0 match) (nth 1 match))
1362                                        match))))))
1363
1364             ;; Calculate the replacement string, if necessary.
1365             (when replacements
1366               (set-match-data real-match-data)
1367               (setq next-replacement
1368                     (funcall (car replacements) (cdr replacements)
1369                              replace-count)
1370                     noedit nil))
1371             (if (not query-flag)
1372                 (let ((inhibit-read-only
1373                        query-replace-skip-read-only))
1374                   (unless noedit
1375                     (replace-highlight (nth 0 real-match-data)
1376                                        (nth 1 real-match-data)))
1377                   (setq noedit
1378                         (replace-match-maybe-edit
1379                          next-replacement nocasify literal
1380                          noedit real-match-data)
1381                         replace-count (1+ replace-count)))
1382               (undo-boundary)
1383               (let (done replaced key def)
1384                 ;; Loop reading commands until one of them sets done,
1385                 ;; which means it has finished handling this
1386                 ;; occurrence.  Any command that sets `done' should
1387                 ;; leave behind proper match data for the stack.
1388                 ;; Commands not setting `done' need to adjust
1389                 ;; `real-match-data'.
1390                 (while (not done)
1391                   (set-match-data real-match-data)
1392                   (replace-highlight (match-beginning 0) (match-end 0))
1393                   ;; Bind message-log-max so we don't fill up the message log
1394                   ;; with a bunch of identical messages.
1395                   (let ((message-log-max nil))
1396                     (message message
1397                              (query-replace-descr from-string)
1398                              (query-replace-descr next-replacement)))
1399                   (setq key (read-event))
1400                   ;; Necessary in case something happens during read-event
1401                   ;; that clobbers the match data.
1402                   (set-match-data real-match-data)
1403                   (setq key (vector key))
1404                   (setq def (lookup-key map key))
1405                   ;; Restore the match data while we process the command.
1406                   (cond ((eq def 'help)
1407                          (with-output-to-temp-buffer "*Help*"
1408                            (princ
1409                             (concat "Query replacing "
1410                                     (if regexp-flag "regexp " "")
1411                                     from-string " with "
1412                                     next-replacement ".\n\n"
1413                                     (substitute-command-keys
1414                                      query-replace-help)))
1415                            (with-current-buffer standard-output
1416                              (help-mode))))
1417                         ((eq def 'exit)
1418                          (setq keep-going nil)
1419                          (setq done t))
1420                         ((eq def 'backup)
1421                          (if stack
1422                              (let ((elt (pop stack)))
1423                                (goto-char (nth 0 elt))
1424                                (setq replaced (nth 1 elt)
1425                                      real-match-data
1426                                      (replace-match-data
1427                                       t real-match-data
1428                                       (nth 2 elt))))
1429                            (message "No previous match")
1430                            (ding 'no-terminate)
1431                            (sit-for 1)))
1432                         ((eq def 'act)
1433                          (or replaced
1434                              (setq noedit
1435                                    (replace-match-maybe-edit
1436                                     next-replacement nocasify literal
1437                                     noedit real-match-data)
1438                                    replace-count (1+ replace-count)))
1439                          (setq done t replaced t))
1440                         ((eq def 'act-and-exit)
1441                          (or replaced
1442                              (setq noedit
1443                                    (replace-match-maybe-edit
1444                                     next-replacement nocasify literal
1445                                     noedit real-match-data)
1446                                    replace-count (1+ replace-count)))
1447                          (setq keep-going nil)
1448                          (setq done t replaced t))
1449                         ((eq def 'act-and-show)
1450                          (if (not replaced)
1451                              (setq noedit
1452                                    (replace-match-maybe-edit
1453                                     next-replacement nocasify literal
1454                                     noedit real-match-data)
1455                                    replace-count (1+ replace-count)
1456                                    real-match-data (replace-match-data
1457                                                     t real-match-data)
1458                                    replaced t)))
1459                         ((eq def 'automatic)
1460                          (or replaced
1461                              (setq noedit
1462                                    (replace-match-maybe-edit
1463                                     next-replacement nocasify literal
1464                                     noedit real-match-data)
1465                                    replace-count (1+ replace-count)))
1466                          (setq done t query-flag nil replaced t))
1467                         ((eq def 'skip)
1468                          (setq done t))
1469                         ((eq def 'recenter)
1470                          (recenter nil))
1471                         ((eq def 'edit)
1472                          (let ((opos (point-marker)))
1473                            (setq real-match-data (replace-match-data
1474                                                   nil real-match-data
1475                                                   real-match-data))
1476                            (goto-char (match-beginning 0))
1477                            (save-excursion
1478                              (save-window-excursion
1479                                (recursive-edit)))
1480                            (goto-char opos)
1481                            (set-marker opos nil))
1482                          ;; Before we make the replacement,
1483                          ;; decide whether the search string
1484                          ;; can match again just after this match.
1485                          (if (and regexp-flag nonempty-match)
1486                              (setq match-again (and (looking-at search-string)
1487                                                     (match-data)))))
1488                         ;; Edit replacement.
1489                         ((eq def 'edit-replacement)
1490                          (setq real-match-data (replace-match-data
1491                                                 nil real-match-data
1492                                                 real-match-data)
1493                                next-replacement
1494                                (read-input "Edit replacement string: "
1495                                            next-replacement)
1496                                noedit nil)
1497                          (if replaced
1498                              (set-match-data real-match-data)
1499                            (setq noedit
1500                                  (replace-match-maybe-edit
1501                                   next-replacement nocasify literal noedit
1502                                   real-match-data)
1503                                  replaced t))
1504                          (setq done t))
1505
1506                         ((eq def 'delete-and-edit)
1507                          (replace-match "" t t)
1508                          (setq real-match-data (replace-match-data
1509                                                 nil real-match-data))
1510                          (replace-dehighlight)
1511                          (save-excursion (recursive-edit))
1512                          (setq replaced t))
1513                         ;; Note: we do not need to treat `exit-prefix'
1514                         ;; specially here, since we reread
1515                         ;; any unrecognized character.
1516                         (t
1517                          (setq this-command 'mode-exited)
1518                          (setq keep-going nil)
1519                          (setq unread-command-events
1520                                (append (listify-key-sequence key)
1521                                        unread-command-events))
1522                          (setq done t))))
1523                 ;; Record previous position for ^ when we move on.
1524                 ;; Change markers to numbers in the match data
1525                 ;; since lots of markers slow down editing.
1526                 (push (list (point) replaced
1527 ;;; If the replacement has already happened, all we need is the
1528 ;;; current match start and end.  We could get this with a trivial
1529 ;;; match like
1530 ;;; (save-excursion (goto-char (match-beginning 0))
1531 ;;;                 (search-forward (match-string 0))
1532 ;;;                 (match-data t))
1533 ;;; if we really wanted to avoid manually constructing match data.
1534 ;;; Adding current-buffer is necessary so that match-data calls can
1535 ;;; return markers which are appropriate for editing.
1536                             (if replaced
1537                                 (list
1538                                  (match-beginning 0)
1539                                  (match-end 0)
1540                                  (current-buffer))
1541                               (match-data t)))
1542                       stack)))))
1543
1544       ;; The code preventing adjacent regexp matches in the condition
1545       ;; of the while-loop above will haven taken us one character
1546       ;; beyond the last replacement.  Undo that.
1547       (when (and regexp-flag (not match-again) (> replace-count 0))
1548         (backward-char 1))
1549
1550       (replace-dehighlight))
1551     (or unread-command-events
1552         (message "Replaced %d occurrence%s"
1553                  replace-count
1554                  (if (= replace-count 1) "" "s")))
1555     (and keep-going stack)))
1556
1557 (defcustom query-replace-highlight t
1558   "*Non-nil means to highlight words during query replacement."
1559   :type 'boolean
1560   :group 'matching)
1561
1562 (defvar replace-overlay nil)
1563
1564 (defun replace-dehighlight ()
1565   (and replace-overlay
1566        (progn
1567          (delete-overlay replace-overlay)
1568          (setq replace-overlay nil))))
1569
1570 (defun replace-highlight (start end)
1571   (and query-replace-highlight
1572        (if replace-overlay
1573            (move-overlay replace-overlay start end (current-buffer))
1574          (setq replace-overlay (make-overlay start end))
1575          (overlay-put replace-overlay 'face
1576                       (if (facep 'query-replace)
1577                           'query-replace 'region)))))
1578
1579 ;; arch-tag: 16b4cd61-fd40-497b-b86f-b667c4cf88e4
1580 ;;; replace.el ends here