lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: Colin Walters <walters@verbum.org>
   7 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   8 ;; Created: 2 Dec 2001
   9 ;; Keywords: buffer, convenience
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicity (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'ibuf-macs)
  38   (require 'cl))
  39
  40 ;;; Utility functions
  41 (defun ibuffer-delete-alist (key alist)
  42   "Delete all entries in ALIST that have a key equal to KEY."
  43   (let (entry)
  44     (while (setq entry (assoc key alist))
  45       (setq alist (delete entry alist)))
  46     alist))
  47
  48 ;; borrowed from Gnus
  49 (defun ibuffer-remove-duplicates (list)
  50   "Return a copy of LIST with duplicate elements removed."
  51   (let ((new nil)
  52         (tail list))
  53     (while tail
  54       (or (member (car tail) new)
  55           (setq new (cons (car tail) new)))
  56       (setq tail (cdr tail)))
  57     (nreverse new)))
  58
  59 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  60   (let ((hip-crowd nil)
  61         (lamers nil))
  62     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  63       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  64           (push ibuffer-split-list-elt hip-crowd)
  65         (push ibuffer-split-list-elt lamers)))
  66     ;; Too bad Emacs Lisp doesn't have multiple values.
  67     (list (nreverse hip-crowd) (nreverse lamers))))
  68
  69 (defcustom ibuffer-never-show-predicates nil
  70   "A list of predicates (a regexp or function) for buffers not to display.
  71 If a regexp, then it will be matched against the buffer's name.
  72 If a function, it will be called with the buffer as an argument, and
  73 should return non-nil if this buffer should not be shown."
  74   :type '(repeat (choice regexp function))
  75   :require 'ibuf-ext
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-mode nil
  95   "If non-nil, Ibuffer auto-mode should be enabled for this buffer.
  96 Do not set this variable directly!  Use the function
  97 `ibuffer-auto-mode' instead.")
  98
  99 (defvar ibuffer-auto-buffers-changed nil)
 100
 101 (defcustom ibuffer-saved-filters '(("gnus"
 102                                     ((or (mode . message-mode)
 103                                          (mode . mail-mode)
 104                                          (mode . gnus-group-mode)
 105                                          (mode . gnus-summary-mode)
 106                                          (mode . gnus-article-mode))))
 107                                    ("programming"
 108                                     ((or (mode . emacs-lisp-mode)
 109                                          (mode . cperl-mode)
 110                                          (mode . c-mode)
 111                                          (mode . java-mode)
 112                                          (mode . idl-mode)
 113                                          (mode . lisp-mode)))))
 114
 115   "An alist of filter qualifiers to switch between.
 116
 117 This variable should look like ((\"STRING\" QUALIFIERS)
 118                                 (\"STRING\" QUALIFIERS) ...), where
 119 QUALIFIERS is a list of the same form as
 120 `ibuffer-filtering-qualifiers'.
 121 See also the variables `ibuffer-filtering-qualifiers',
 122 `ibuffer-filtering-alist', and the functions
 123 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 124   :type '(repeat sexp)
 125   :group 'ibuffer)
 126
 127 (defvar ibuffer-filtering-qualifiers nil
 128   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 129 See also `ibuffer-filtering-alist'.")
 130
 131 ;; This is now frobbed by `define-ibuffer-filter'.
 132 (defvar ibuffer-filtering-alist nil
 133   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 134
 135 You most likely do not want to modify this variable directly; see
 136 `define-ibuffer-filter'.
 137
 138 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 139 displaying information to the user.  FUNCTION is given a buffer and
 140 the value of the qualifier, and returns non-nil if and only if the
 141 buffer should be displayed.")
 142
 143 (defcustom ibuffer-filter-format-alist nil
 144   "An alist which has special formats used when a filter is active.
 145 The contents of this variable should look like:
 146  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 147
 148 For example, suppose that when you add a filter for buffers whose
 149 major mode is `emacs-lisp-mode', you only want to see the mark and the
 150 name of the buffer.  You could accomplish that by adding:
 151  (mode ((mark \" \" name)))
 152 to this variable."
 153   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 154                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 155   :group 'ibuffer)
 156
 157 (defvar ibuffer-cached-filter-formats nil)
 158 (defvar ibuffer-compiled-filter-formats nil)
 159
 160 (defvar ibuffer-filter-groups nil
 161   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 162 The SYMBOL should be one from `ibuffer-filtering-alist'.
 163 The QUALIFIER should be the same as QUALIFIER in
 164 `ibuffer-filtering-qualifiers'.")
 165
 166 (defcustom ibuffer-show-empty-filter-groups t
 167   "If non-nil, then show the names of filter groups which are empty."
 168   :type 'boolean
 169   :group 'ibuffer)
 170
 171 (defcustom ibuffer-saved-filter-groups nil
 172   "An alist of filtering groups to switch between.
 173
 174 This variable should look like ((\"STRING\" QUALIFIERS)
 175                                 (\"STRING\" QUALIFIERS) ...), where
 176 QUALIFIERS is a list of the same form as
 177 `ibuffer-filtering-qualifiers'.
 178
 179 See also the variables `ibuffer-filter-groups',
 180 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 181 functions `ibuffer-switch-to-saved-filter-groups',
 182 `ibuffer-save-filter-groups'."
 183   :type '(repeat sexp)
 184   :group 'ibuffer)
 185
 186 (defvar ibuffer-hidden-filter-groups nil
 187   "A list of filtering groups which are currently hidden.")
 188
 189 (defvar ibuffer-filter-group-kill-ring nil)
 190
 191 (defcustom ibuffer-old-time 72
 192   "The number of hours before a buffer is considered \"old\"."
 193   :type '(choice (const :tag "72 hours (3 days)" 72)
 194                  (const :tag "48 hours (2 days)" 48)
 195                  (const :tag "24 hours (1 day)" 24)
 196                  (integer :tag "hours"))
 197   :group 'ibuffer)
 198
 199 (defcustom ibuffer-save-with-custom t
 200   "If non-nil, then use Custom to save interactively changed variables.
 201 Currently, this only applies to `ibuffer-saved-filters' and
 202 `ibuffer-saved-filter-groups'."
 203   :type 'boolean
 204   :group 'ibuffer)
 205
 206 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 207   (or
 208    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 209    (and (not
 210          (or
 211           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 212           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 213         (or all
 214             (not
 215              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 216         (or ibuffer-view-ibuffer
 217             (and ibuffer-buf
 218                  (not (eq ibuffer-buf buf))))
 219         (or
 220          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 221          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 222
 223 (defun ibuffer-auto-update-changed ()
 224   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 225     (dolist (buf (buffer-list))
 226       (ignore-errors
 227         (with-current-buffer buf
 228           (when (and ibuffer-auto-mode
 229                      (derived-mode-p 'ibuffer-mode))
 230             (ibuffer-update nil t)))))))
 231
 232 ;;;###autoload
 233 (defun ibuffer-auto-mode (&optional arg)
 234   "Toggle use of Ibuffer's auto-update facility.
 235 With numeric ARG, enable auto-update if and only if ARG is positive."
 236   (interactive)
 237   (unless (derived-mode-p 'ibuffer-mode)
 238     (error "This buffer is not in Ibuffer mode"))
 239   (set (make-local-variable 'ibuffer-auto-mode)
 240        (if arg
 241            (plusp arg)
 242          (not ibuffer-auto-mode)))
 243   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 244   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 245
 246 ;;;###autoload
 247 (defun ibuffer-mouse-filter-by-mode (event)
 248   "Enable or disable filtering by the major mode chosen via mouse."
 249   (interactive "e")
 250   (ibuffer-interactive-filter-by-mode event))
 251
 252 ;;;###autoload
 253 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 254   "Enable or disable filtering by the major mode at point."
 255   (interactive "d")
 256   (if (eventp event-or-point)
 257       (posn-set-point (event-end event-or-point))
 258     (goto-char event-or-point))
 259   (let ((buf (ibuffer-current-buffer)))
 260     (if (assq 'mode ibuffer-filtering-qualifiers)
 261         (setq ibuffer-filtering-qualifiers
 262               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 263       (ibuffer-push-filter (cons 'mode (buffer-local-value 'major-mode buf)))))
 264   (ibuffer-update nil t))
 265
 266 ;;;###autoload
 267 (defun ibuffer-mouse-toggle-filter-group (event)
 268   "Toggle the display status of the filter group chosen with the mouse."
 269   (interactive "e")
 270   (ibuffer-toggle-filter-group-1 (save-excursion
 271                                    (mouse-set-point event)
 272                                    (point))))
 273
 274 ;;;###autoload
 275 (defun ibuffer-toggle-filter-group ()
 276   "Toggle the display status of the filter group on this line."
 277   (interactive)
 278   (ibuffer-toggle-filter-group-1 (point)))
 279
 280 (defun ibuffer-toggle-filter-group-1 (posn)
 281   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 282     (unless (stringp name)
 283       (error "No filtering group name present"))
 284     (if (member name ibuffer-hidden-filter-groups)
 285         (setq ibuffer-hidden-filter-groups
 286               (delete name ibuffer-hidden-filter-groups))
 287       (push name ibuffer-hidden-filter-groups))
 288     (ibuffer-update nil t)))
 289
 290 ;;;###autoload
 291 (defun ibuffer-forward-filter-group (&optional count)
 292   "Move point forwards by COUNT filtering groups."
 293   (interactive "P")
 294   (unless count
 295     (setq count 1))
 296   (when (> count 0)
 297     (when (get-text-property (point) 'ibuffer-filter-group-name)
 298       (goto-char (next-single-property-change
 299                   (point) 'ibuffer-filter-group-name
 300                   nil (point-max))))
 301     (goto-char (next-single-property-change
 302                 (point) 'ibuffer-filter-group-name
 303                 nil (point-max)))
 304     (ibuffer-forward-filter-group (1- count)))
 305   (ibuffer-forward-line 0))
 306
 307 ;;;###autoload
 308 (defun ibuffer-backward-filter-group (&optional count)
 309   "Move point backwards by COUNT filtering groups."
 310   (interactive "P")
 311   (unless count
 312     (setq count 1))
 313   (when (> count 0)
 314     (when (get-text-property (point) 'ibuffer-filter-group-name)
 315       (goto-char (previous-single-property-change
 316                   (point) 'ibuffer-filter-group-name
 317                   nil (point-min))))
 318     (goto-char (previous-single-property-change
 319                 (point) 'ibuffer-filter-group-name
 320                 nil (point-min)))
 321     (ibuffer-backward-filter-group (1- count)))
 322   (when (= (point) (point-min))
 323     (goto-char (point-max))
 324     (ibuffer-backward-filter-group 1))
 325   (ibuffer-forward-line 0))
 326
 327 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 328 (define-ibuffer-op shell-command-pipe (command)
 329   "Pipe the contents of each marked buffer to shell command COMMAND."
 330   (:interactive "sPipe to shell command: "
 331    :opstring "Shell command executed on"
 332    :modifier-p nil)
 333   (shell-command-on-region
 334    (point-min) (point-max) command
 335    (get-buffer-create "* ibuffer-shell-output*")))
 336
 337 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 338 (define-ibuffer-op shell-command-pipe-replace (command)
 339   "Replace the contents of marked buffers with output of pipe to COMMAND."
 340   (:interactive "sPipe to shell command (replace): "
 341    :opstring "Buffer contents replaced in"
 342    :active-opstring "replace buffer contents in"
 343    :dangerous t
 344    :modifier-p t)
 345   (with-current-buffer buf
 346     (shell-command-on-region (point-min) (point-max)
 347                              command nil t)))
 348
 349 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 350 (define-ibuffer-op shell-command-file (command)
 351   "Run shell command COMMAND separately on files of marked buffers."
 352   (:interactive "sShell command on buffer's file: "
 353    :opstring "Shell command executed on"
 354    :modifier-p nil)
 355   (shell-command (concat command " "
 356                          (shell-quote-argument
 357                           (if buffer-file-name
 358                               buffer-file-name
 359                             (make-temp-file
 360                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 361
 362 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 363 (define-ibuffer-op eval (form)
 364   "Evaluate FORM in each of the buffers.
 365 Does not display the buffer during evaluation. See
 366 `ibuffer-do-view-and-eval' for that."
 367   (:interactive
 368    (list
 369     (read-from-minibuffer
 370      "Eval in buffers (form): "
 371      nil read-expression-map t 'read-expression-history))
 372    :opstring "evaluated in"
 373    :modifier-p :maybe)
 374   (eval form))
 375
 376 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 377 (define-ibuffer-op view-and-eval (form)
 378   "Evaluate FORM while displaying each of the marked buffers.
 379 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 380   (:interactive
 381    (list
 382     (read-from-minibuffer
 383      "Eval viewing in buffers (form): "
 384      nil read-expression-map t 'read-expression-history))
 385    :opstring "evaluated in"
 386    :complex t
 387    :modifier-p :maybe)
 388   (let ((ibuffer-buf (current-buffer)))
 389     (unwind-protect
 390         (progn
 391           (switch-to-buffer buf)
 392           (eval form))
 393       (switch-to-buffer ibuffer-buf))))
 394
 395 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 396 (define-ibuffer-op rename-uniquely ()
 397   "Rename marked buffers as with `rename-uniquely'."
 398   (:opstring "renamed"
 399    :modifier-p t)
 400   (rename-uniquely))
 401
 402 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 403 (define-ibuffer-op revert ()
 404   "Revert marked buffers as with `revert-buffer'."
 405   (:dangerous t
 406    :opstring "reverted"
 407    :active-opstring "revert"
 408    :modifier-p :maybe)
 409   (revert-buffer t t))
 410
 411 ;;;###autoload (autoload 'ibuffer-do-isearch "ibuf-ext")
 412 (define-ibuffer-op ibuffer-do-isearch ()
 413   "Perform a `isearch-forward' in marked buffers."
 414   (:interactive ()
 415    :opstring "searched in"
 416    :complex t
 417    :modifier-p :maybe)
 418   (multi-isearch-buffers (ibuffer-get-marked-buffers)))
 419
 420 ;;;###autoload (autoload 'ibuffer-do-isearch-regexp "ibuf-ext")
 421 (define-ibuffer-op ibuffer-do-isearch-regexp ()
 422   "Perform a `isearch-forward-regexp' in marked buffers."
 423   (:interactive ()
 424    :opstring "searched regexp in"
 425    :complex t
 426    :modifier-p :maybe)
 427   (multi-isearch-buffers-regexp (ibuffer-get-marked-buffers)))
 428
 429 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 430 (define-ibuffer-op replace-regexp (from-str to-str)
 431   "Perform a `replace-regexp' in marked buffers."
 432   (:interactive
 433    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 434           (to-str (read-from-minibuffer (concat "Replace " from-str
 435                                                 " with: "))))
 436      (list from-str to-str))
 437    :opstring "replaced in"
 438    :complex t
 439    :modifier-p :maybe)
 440   (save-window-excursion
 441     (switch-to-buffer buf)
 442     (save-excursion
 443       (goto-char (point-min))
 444       (let ((case-fold-search ibuffer-case-fold-search))
 445         (while (re-search-forward from-str nil t)
 446           (replace-match to-str))))
 447     t))
 448
 449 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 450 (define-ibuffer-op query-replace (&rest args)
 451   "Perform a `query-replace' in marked buffers."
 452   (:interactive
 453    (query-replace-read-args "Query replace" t t)
 454    :opstring "replaced in"
 455    :complex t
 456    :modifier-p :maybe)
 457   (save-window-excursion
 458     (switch-to-buffer buf)
 459     (save-excursion
 460       (let ((case-fold-search ibuffer-case-fold-search))
 461         (goto-char (point-min))
 462         (apply #'query-replace args)))
 463     t))
 464
 465 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 466 (define-ibuffer-op query-replace-regexp (&rest args)
 467   "Perform a `query-replace-regexp' in marked buffers."
 468   (:interactive
 469    (query-replace-read-args "Query replace regexp" t t)
 470    :opstring "replaced in"
 471    :complex t
 472    :modifier-p :maybe)
 473   (save-window-excursion
 474     (switch-to-buffer buf)
 475     (save-excursion
 476       (let ((case-fold-search ibuffer-case-fold-search))
 477         (goto-char (point-min))
 478         (apply #'query-replace-regexp args)))
 479     t))
 480
 481 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 482 (define-ibuffer-op print ()
 483   "Print marked buffers as with `print-buffer'."
 484   (:opstring "printed"
 485    :modifier-p nil)
 486   (print-buffer))
 487
 488 ;;;###autoload
 489 (defun ibuffer-included-in-filters-p (buf filters)
 490   (not
 491    (memq nil ;; a filter will return nil if it failed
 492          (mapcar
 493           ;; filter should be like (TYPE . QUALIFIER), or
 494           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 495           #'(lambda (qual)
 496               (ibuffer-included-in-filter-p buf qual))
 497           filters))))
 498
 499 (defun ibuffer-included-in-filter-p (buf filter)
 500   (if (eq (car filter) 'not)
 501       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 502     (ibuffer-included-in-filter-p-1 buf filter)))
 503
 504 (defun ibuffer-included-in-filter-p-1 (buf filter)
 505   (not
 506    (not
 507     (case (car filter)
 508       (or
 509        (memq t (mapcar #'(lambda (x)
 510                            (ibuffer-included-in-filter-p buf x))
 511                        (cdr filter))))
 512       (saved
 513        (let ((data
 514               (assoc (cdr filter)
 515                      ibuffer-saved-filters)))
 516          (unless data
 517            (ibuffer-filter-disable)
 518            (error "Unknown saved filter %s" (cdr filter)))
 519          (ibuffer-included-in-filters-p buf (cadr data))))
 520       (t
 521        (let ((filterdat (assq (car filter)
 522                               ibuffer-filtering-alist)))
 523          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 524          ;; just a sanity check
 525         (unless filterdat
 526           (ibuffer-filter-disable)
 527           (error "Undefined filter %s" (car filter)))
 528         (not
 529          (not
 530           (funcall (caddr filterdat)
 531                    buf
 532                    (cdr filter))))))))))
 533
 534 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 535   (let ((filter-group-alist (if nodefault
 536                                 ibuffer-filter-groups
 537                               (append ibuffer-filter-groups
 538                                       (list (cons "Default" nil))))))
 539 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 540 ;;       (setq filter-group-alist (ibuffer-delete-alist
 541 ;;                                 hidden filter-group-alist)))
 542     (let ((vec (make-vector (length filter-group-alist) nil))
 543           (i 0))
 544       (dolist (filtergroup filter-group-alist)
 545         (let ((filterset (cdr filtergroup)))
 546           (multiple-value-bind (hip-crowd lamers)
 547               (values-list
 548                (ibuffer-split-list (lambda (bufmark)
 549                                      (ibuffer-included-in-filters-p (car bufmark)
 550                                                                     filterset))
 551                                    bmarklist))
 552             (aset vec i hip-crowd)
 553             (incf i)
 554             (setq bmarklist lamers))))
 555       (let (ret)
 556         (dotimes (j i ret)
 557           (let ((bufs (aref vec j)))
 558             (unless (and noempty (null bufs))
 559               (push (cons (car (nth j filter-group-alist))
 560                           bufs)
 561                     ret))))))))
 562
 563 ;;;###autoload
 564 (defun ibuffer-filters-to-filter-group (name)
 565   "Make the current filters into a filtering group."
 566   (interactive "sName for filtering group: ")
 567   (when (null ibuffer-filtering-qualifiers)
 568     (error "No filters in effect"))
 569   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 570   (ibuffer-filter-disable))
 571
 572 ;;;###autoload
 573 (defun ibuffer-set-filter-groups-by-mode ()
 574   "Set the current filter groups to filter by mode."
 575   (interactive)
 576   (setq ibuffer-filter-groups
 577         (mapcar (lambda (mode)
 578                   (cons (format "%s" mode) `((mode . ,mode))))
 579                 (let ((modes
 580                        (ibuffer-remove-duplicates
 581                         (mapcar (lambda (buf)
 582                                   (buffer-local-value 'major-mode buf))
 583                                 (buffer-list)))))
 584                   (if ibuffer-view-ibuffer
 585                       modes
 586                     (delq 'ibuffer-mode modes)))))
 587   (ibuffer-update nil t))
 588
 589 ;;;###autoload
 590 (defun ibuffer-pop-filter-group ()
 591   "Remove the first filter group."
 592   (interactive)
 593   (when (null ibuffer-filter-groups)
 594     (error "No filter groups active"))
 595   (setq ibuffer-hidden-filter-groups
 596         (delete (pop ibuffer-filter-groups)
 597                 ibuffer-hidden-filter-groups))
 598   (ibuffer-update nil t))
 599
 600 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 601   (when (and (not noerror) (null ibuffer-filter-groups))
 602     (error "No filter groups active"))
 603   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 604   ;; groups, possibly excluding empty groups or Default.
 605   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 606   ;; Default if necessary.
 607   (completing-read msg (nconc
 608                         (ibuffer-generate-filter-groups
 609                          (ibuffer-current-state-list)
 610                          (not ibuffer-show-empty-filter-groups)
 611                          nodefault)
 612                         (if nodefault
 613                             (remove "Default" ibuffer-hidden-filter-groups)
 614                           ibuffer-hidden-filter-groups))
 615                    nil t))
 616
 617 ;;;###autoload
 618 (defun ibuffer-decompose-filter-group (group)
 619   "Decompose the filter group GROUP into active filters."
 620   (interactive
 621    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 622   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 623     (setq ibuffer-filter-groups (ibuffer-delete-alist
 624                                  group ibuffer-filter-groups)
 625           ibuffer-filtering-qualifiers data))
 626   (ibuffer-update nil t))
 627
 628 ;;;###autoload
 629 (defun ibuffer-clear-filter-groups ()
 630   "Remove all filter groups."
 631   (interactive)
 632   (setq ibuffer-filter-groups nil
 633         ibuffer-hidden-filter-groups nil)
 634   (ibuffer-update nil t))
 635
 636 (defun ibuffer-current-filter-groups-with-position ()
 637   (save-excursion
 638     (goto-char (point-min))
 639     (let ((pos nil)
 640           (result nil))
 641       (while (and (not (eobp))
 642                   (setq pos (next-single-property-change
 643                              (point) 'ibuffer-filter-group-name)))
 644         (goto-char pos)
 645         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 646                     pos)
 647               result)
 648         (goto-char (next-single-property-change
 649                     pos 'ibuffer-filter-group-name)))
 650       (nreverse result))))
 651
 652 ;;;###autoload
 653 (defun ibuffer-jump-to-filter-group (name)
 654   "Move point to the filter group whose name is NAME."
 655   (interactive
 656    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 657   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 658       (goto-char (cdr it))
 659     (error "No filter group with name %s" name)))
 660
 661 ;;;###autoload
 662 (defun ibuffer-kill-filter-group (name)
 663   "Kill the filter group named NAME.
 664 The group will be added to `ibuffer-filter-group-kill-ring'."
 665   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 666   (when (equal name "Default")
 667     (error "Can't kill default filter group"))
 668   (ibuffer-aif (assoc name ibuffer-filter-groups)
 669       (progn
 670         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 671         (setq ibuffer-filter-groups (ibuffer-delete-alist
 672                                      name ibuffer-filter-groups))
 673         (setq ibuffer-hidden-filter-groups
 674               (delete name ibuffer-hidden-filter-groups)))
 675     (error "No filter group with name \"%s\"" name))
 676   (ibuffer-update nil t))
 677
 678 ;;;###autoload
 679 (defun ibuffer-kill-line (&optional arg interactive-p)
 680   "Kill the filter group at point.
 681 See also `ibuffer-kill-filter-group'."
 682   (interactive "P\np")
 683   (ibuffer-aif (save-excursion
 684                  (ibuffer-forward-line 0)
 685                  (get-text-property (point) 'ibuffer-filter-group-name))
 686       (progn
 687         (ibuffer-kill-filter-group it))
 688       (funcall (if interactive-p #'call-interactively #'funcall)
 689                #'kill-line arg)))
 690
 691 (defun ibuffer-insert-filter-group-before (newgroup group)
 692   (let* ((found nil)
 693          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 694                     (res 0))
 695                 (while groups
 696                   (if (equal (car groups) group)
 697                       (setq found t
 698                             groups nil)
 699                     (incf res)
 700                     (setq groups (cdr groups))))
 701                 res)))
 702     (cond ((not found)
 703            (setq ibuffer-filter-groups
 704                  (nconc ibuffer-filter-groups (list newgroup))))
 705           ((zerop pos)
 706            (push newgroup ibuffer-filter-groups))
 707           (t
 708            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 709              (setf (cdr cell) (cons (car cell) (cdr cell)))
 710              (setf (car cell) newgroup))))))
 711
 712 ;;;###autoload
 713 (defun ibuffer-yank ()
 714   "Yank the last killed filter group before group at point."
 715   (interactive)
 716   (ibuffer-yank-filter-group
 717    (or (get-text-property (point) 'ibuffer-filter-group-name)
 718        (get-text-property (point) 'ibuffer-filter-group)
 719        (error "No filter group at point"))))
 720
 721 ;;;###autoload
 722 (defun ibuffer-yank-filter-group (name)
 723   "Yank the last killed filter group before group named NAME."
 724   (interactive (list (ibuffer-read-filter-group-name
 725                         "Yank filter group before group: ")))
 726   (unless ibuffer-filter-group-kill-ring
 727     (error "The Ibuffer filter group kill-ring is empty"))
 728   (save-excursion
 729     (ibuffer-forward-line 0)
 730     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 731                                         name))
 732   (ibuffer-update nil t))
 733
 734 ;;;###autoload
 735 (defun ibuffer-save-filter-groups (name groups)
 736   "Save all active filter groups GROUPS as NAME.
 737 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 738 prompt for NAME, and use the current filters."
 739   (interactive
 740    (if (null ibuffer-filter-groups)
 741        (error "No filter groups active")
 742      (list
 743       (read-from-minibuffer "Save current filter groups as: ")
 744       ibuffer-filter-groups)))
 745   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 746       (setcdr it groups)
 747     (push (cons name groups) ibuffer-saved-filter-groups))
 748   (ibuffer-maybe-save-stuff))
 749
 750 ;;;###autoload
 751 (defun ibuffer-delete-saved-filter-groups (name)
 752   "Delete saved filter groups with NAME.
 753 They are removed from `ibuffer-saved-filter-groups'."
 754   (interactive
 755    (list
 756     (if (null ibuffer-saved-filter-groups)
 757         (error "No saved filter groups")
 758       (completing-read "Delete saved filter group: "
 759                        ibuffer-saved-filter-groups nil t))))
 760   (setq ibuffer-saved-filter-groups
 761         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 762   (ibuffer-maybe-save-stuff)
 763   (ibuffer-update nil t))
 764
 765 ;;;###autoload
 766 (defun ibuffer-switch-to-saved-filter-groups (name)
 767   "Set this buffer's filter groups to saved version with NAME.
 768 The value from `ibuffer-saved-filter-groups' is used."
 769   (interactive
 770    (list
 771     (if (null ibuffer-saved-filter-groups)
 772         (error "No saved filters")
 773       (completing-read "Switch to saved filter group: "
 774                        ibuffer-saved-filter-groups nil t))))
 775   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 776         ibuffer-hidden-filter-groups nil)
 777   (ibuffer-update nil t))
 778
 779 ;;;###autoload
 780 (defun ibuffer-filter-disable ()
 781   "Disable all filters currently in effect in this buffer."
 782   (interactive)
 783   (setq ibuffer-filtering-qualifiers nil)
 784   (let ((buf (ibuffer-current-buffer)))
 785     (ibuffer-update nil t)
 786     (when buf
 787       (ibuffer-jump-to-buffer (buffer-name buf)))))
 788
 789 ;;;###autoload
 790 (defun ibuffer-pop-filter ()
 791   "Remove the top filter in this buffer."
 792   (interactive)
 793   (when (null ibuffer-filtering-qualifiers)
 794     (error "No filters in effect"))
 795   (pop ibuffer-filtering-qualifiers)
 796   (let ((buf (ibuffer-current-buffer)))
 797     (ibuffer-update nil t)
 798     (when buf
 799       (ibuffer-jump-to-buffer (buffer-name buf)))))
 800
 801 (defun ibuffer-push-filter (qualifier)
 802   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 803   (push qualifier ibuffer-filtering-qualifiers))
 804
 805 ;;;###autoload
 806 (defun ibuffer-decompose-filter ()
 807   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 808
 809 This means that the topmost filter on the filtering stack, which must
 810 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 811 turned into two separate filters [name: foo] and [mode: bar-mode]."
 812   (interactive)
 813   (when (null ibuffer-filtering-qualifiers)
 814     (error "No filters in effect"))
 815   (let ((lim (pop ibuffer-filtering-qualifiers)))
 816     (case (car lim)
 817       (or
 818        (setq ibuffer-filtering-qualifiers (append
 819                                           (cdr lim)
 820                                           ibuffer-filtering-qualifiers)))
 821       (saved
 822        (let ((data
 823               (assoc (cdr lim)
 824                      ibuffer-saved-filters)))
 825          (unless data
 826            (ibuffer-filter-disable)
 827            (error "Unknown saved filter %s" (cdr lim)))
 828          (setq ibuffer-filtering-qualifiers (append
 829                                             (cadr data)
 830                                             ibuffer-filtering-qualifiers))))
 831       (not
 832        (push (cdr lim)
 833              ibuffer-filtering-qualifiers))
 834       (t
 835        (error "Filter type %s is not compound" (car lim)))))
 836   (ibuffer-update nil t))
 837
 838 ;;;###autoload
 839 (defun ibuffer-exchange-filters ()
 840   "Exchange the top two filters on the stack in this buffer."
 841   (interactive)
 842   (when (< (length ibuffer-filtering-qualifiers)
 843            2)
 844     (error "Need two filters to exchange"))
 845   (let ((first (pop ibuffer-filtering-qualifiers))
 846         (second (pop ibuffer-filtering-qualifiers)))
 847     (push first ibuffer-filtering-qualifiers)
 848     (push second ibuffer-filtering-qualifiers))
 849   (ibuffer-update nil t))
 850
 851 ;;;###autoload
 852 (defun ibuffer-negate-filter ()
 853   "Negate the sense of the top filter in the current buffer."
 854   (interactive)
 855   (when (null ibuffer-filtering-qualifiers)
 856     (error "No filters in effect"))
 857   (let ((lim (pop ibuffer-filtering-qualifiers)))
 858     (push (if (eq (car lim) 'not)
 859               (cdr lim)
 860             (cons 'not lim))
 861           ibuffer-filtering-qualifiers))
 862   (ibuffer-update nil t))
 863
 864 ;;;###autoload
 865 (defun ibuffer-or-filter (&optional reverse)
 866   "Replace the top two filters in this buffer with their logical OR.
 867 If optional argument REVERSE is non-nil, instead break the top OR
 868 filter into parts."
 869   (interactive "P")
 870   (if reverse
 871       (progn
 872         (when (or (null ibuffer-filtering-qualifiers)
 873                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 874           (error "Top filter is not an OR"))
 875         (let ((lim (pop ibuffer-filtering-qualifiers)))
 876           (setq ibuffer-filtering-qualifiers
 877                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 878     (when (< (length ibuffer-filtering-qualifiers) 2)
 879       (error "Need two filters to OR"))
 880     ;; If the second filter is an OR, just add to it.
 881     (let ((first (pop ibuffer-filtering-qualifiers))
 882           (second (pop ibuffer-filtering-qualifiers)))
 883       (if (eq 'or (car second))
 884           (push (nconc (list 'or first) (cdr second))
 885                 ibuffer-filtering-qualifiers)
 886         (push (list 'or first second)
 887               ibuffer-filtering-qualifiers))))
 888   (ibuffer-update nil t))
 889
 890 (defun ibuffer-maybe-save-stuff ()
 891   (when ibuffer-save-with-custom
 892     (if (fboundp 'customize-save-variable)
 893         (progn
 894           (customize-save-variable 'ibuffer-saved-filters
 895                                    ibuffer-saved-filters)
 896           (customize-save-variable 'ibuffer-saved-filter-groups
 897                                    ibuffer-saved-filter-groups))
 898       (message "Not saved permanently: Customize not available"))))
 899
 900 ;;;###autoload
 901 (defun ibuffer-save-filters (name filters)
 902   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 903 Interactively, prompt for NAME, and use the current filters."
 904   (interactive
 905    (if (null ibuffer-filtering-qualifiers)
 906        (error "No filters currently in effect")
 907      (list
 908       (read-from-minibuffer "Save current filters as: ")
 909       ibuffer-filtering-qualifiers)))
 910   (ibuffer-aif (assoc name ibuffer-saved-filters)
 911       (setcdr it filters)
 912     (push (list name filters) ibuffer-saved-filters))
 913   (ibuffer-maybe-save-stuff))
 914
 915 ;;;###autoload
 916 (defun ibuffer-delete-saved-filters (name)
 917   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 918   (interactive
 919    (list
 920     (if (null ibuffer-saved-filters)
 921         (error "No saved filters")
 922       (completing-read "Delete saved filters: "
 923                        ibuffer-saved-filters nil t))))
 924   (setq ibuffer-saved-filters
 925         (ibuffer-delete-alist name ibuffer-saved-filters))
 926   (ibuffer-maybe-save-stuff)
 927   (ibuffer-update nil t))
 928
 929 ;;;###autoload
 930 (defun ibuffer-add-saved-filters (name)
 931   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 932   (interactive
 933    (list
 934     (if (null ibuffer-saved-filters)
 935         (error "No saved filters")
 936       (completing-read "Add saved filters: "
 937                        ibuffer-saved-filters nil t))))
 938   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 939   (ibuffer-update nil t))
 940
 941 ;;;###autoload
 942 (defun ibuffer-switch-to-saved-filters (name)
 943   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 944   (interactive
 945    (list
 946     (if (null ibuffer-saved-filters)
 947         (error "No saved filters")
 948       (completing-read "Switch to saved filters: "
 949                        ibuffer-saved-filters nil t))))
 950   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 951   (ibuffer-update nil t))
 952
 953 (defun ibuffer-format-filter-group-data (filter)
 954   (if (equal filter "Default")
 955       ""
 956     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 957                                  (cdr (assq filter ibuffer-filter-groups))
 958                                  " "))))
 959
 960 (defun ibuffer-format-qualifier (qualifier)
 961   (if (eq (car-safe qualifier) 'not)
 962       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 963     (ibuffer-format-qualifier-1 qualifier)))
 964
 965 (defun ibuffer-format-qualifier-1 (qualifier)
 966   (case (car qualifier)
 967     (saved
 968      (concat " [filter: " (cdr qualifier) "]"))
 969     (or
 970      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 971                                (cdr qualifier) "") "]"))
 972     (t
 973      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 974        (unless qualifier
 975          (error "Ibuffer: bad qualifier %s" qualifier))
 976        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 977
 978
 979 (defun ibuffer-list-buffer-modes ()
 980   "Create an alist of buffer modes currently in use.
 981 The list returned will be of the form (\"MODE-NAME\" . MODE-SYMBOL)."
 982   (let ((bufs (buffer-list))
 983         (modes)
 984         (this-mode))
 985     (while bufs
 986       (setq this-mode (buffer-local-value 'major-mode (car bufs))
 987             bufs (cdr bufs))
 988       (add-to-list
 989        'modes
 990        `(,(symbol-name this-mode) .
 991          ,this-mode)))
 992     modes))
 993
 994
 995 ;;; Extra operation definitions
 996
 997 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 998 (define-ibuffer-filter mode
 999   "Toggle current view to buffers with major mode QUALIFIER."
1000   (:description "major mode"
1001    :reader
1002    (intern
1003     (completing-read "Filter by major mode: " obarray
1004                      #'(lambda (e)
1005                          (string-match "-mode$"
1006                                        (symbol-name e)))
1007                      t
1008                      (let ((buf (ibuffer-current-buffer)))
1009                        (if (and buf (buffer-live-p buf))
1010                            (symbol-name (buffer-local-value 'major-mode buf))
1011                          "")))))
1012   (eq qualifier (buffer-local-value 'major-mode buf)))
1013
1014 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1015 (define-ibuffer-filter used-mode
1016   "Toggle current view to buffers with major mode QUALIFIER.
1017 Called interactively, this function allows selection of modes
1018 currently used by buffers."
1019   (:description "major mode in use"
1020                 :reader
1021                 (intern
1022                  (completing-read "Filter by major mode: "
1023                                   (ibuffer-list-buffer-modes)
1024                                   nil
1025                                   t
1026                                   (let ((buf (ibuffer-current-buffer)))
1027                                     (if (and buf (buffer-live-p buf))
1028                                         (symbol-name (buffer-local-value
1029                                                       'major-mode buf))
1030                                       "")))))
1031   (eq qualifier (buffer-local-value 'major-mode buf)))
1032
1033 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1034 (define-ibuffer-filter name
1035   "Toggle current view to buffers with name matching QUALIFIER."
1036   (:description "buffer name"
1037    :reader (read-from-minibuffer "Filter by name (regexp): "))
1038   (string-match qualifier (buffer-name buf)))
1039
1040 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1041 (define-ibuffer-filter filename
1042   "Toggle current view to buffers with filename matching QUALIFIER."
1043   (:description "filename"
1044    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1045   (ibuffer-awhen (buffer-local-value 'buffer-file-name buf)
1046     (string-match qualifier it)))
1047
1048 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1049 (define-ibuffer-filter size-gt
1050   "Toggle current view to buffers with size greater than QUALIFIER."
1051   (:description "size greater than"
1052    :reader
1053    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1054   (> (with-current-buffer buf (buffer-size))
1055      qualifier))
1056
1057 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1058 (define-ibuffer-filter size-lt
1059    "Toggle current view to buffers with size less than QUALIFIER."
1060   (:description "size less than"
1061    :reader
1062    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1063   (< (with-current-buffer buf (buffer-size))
1064      qualifier))
1065
1066 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1067 (define-ibuffer-filter content
1068    "Toggle current view to buffers whose contents match QUALIFIER."
1069   (:description "content"
1070    :reader (read-from-minibuffer "Filter by content (regexp): "))
1071   (with-current-buffer buf
1072     (save-excursion
1073       (goto-char (point-min))
1074       (re-search-forward qualifier nil t))))
1075
1076 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1077 (define-ibuffer-filter predicate
1078    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1079   (:description "predicate"
1080    :reader (read-minibuffer "Filter by predicate (form): "))
1081   (with-current-buffer buf
1082     (eval qualifier)))
1083
1084 ;;; Sorting
1085
1086 ;;;###autoload
1087 (defun ibuffer-toggle-sorting-mode ()
1088   "Toggle the current sorting mode.
1089 Default sorting modes are:
1090  Recency - the last time the buffer was viewed
1091  Name - the name of the buffer
1092  Major Mode - the name of the major mode of the buffer
1093  Size - the size of the buffer"
1094   (interactive)
1095   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1096     (add-to-list 'modes 'recency)
1097     (setq modes (sort modes 'string-lessp))
1098     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1099                     (car modes))))
1100       (setq ibuffer-sorting-mode next)
1101       (message "Sorting by %s" next)))
1102   (ibuffer-redisplay t))
1103
1104 ;;;###autoload
1105 (defun ibuffer-invert-sorting ()
1106   "Toggle whether or not sorting is in reverse order."
1107   (interactive)
1108   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1109   (message "Sorting order %s"
1110            (if ibuffer-sorting-reversep
1111                "reversed"
1112              "normal"))
1113   (ibuffer-redisplay t))
1114
1115 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1116 (define-ibuffer-sorter major-mode
1117   "Sort the buffers by major modes.
1118 Ordering is lexicographic."
1119   (:description "major mode")
1120   (string-lessp (downcase
1121                  (symbol-name (buffer-local-value 'major-mode (car a))))
1122                 (downcase
1123                  (symbol-name (buffer-local-value 'major-mode (car b))))))
1124
1125 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1126 (define-ibuffer-sorter mode-name
1127   "Sort the buffers by their mode name.
1128 Ordering is lexicographic."
1129   (:description "major mode name")
1130   (string-lessp (downcase
1131                  (with-current-buffer
1132                      (car a)
1133                    (format-mode-line mode-name)))
1134                 (downcase
1135                  (with-current-buffer
1136                      (car b)
1137                    (format-mode-line mode-name)))))
1138
1139 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1140 (define-ibuffer-sorter alphabetic
1141   "Sort the buffers by their names.
1142 Ordering is lexicographic."
1143   (:description "buffer name")
1144   (string-lessp
1145    (buffer-name (car a))
1146    (buffer-name (car b))))
1147
1148 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1149 (define-ibuffer-sorter size
1150  "Sort the buffers by their size."
1151   (:description "size")
1152   (< (with-current-buffer (car a)
1153        (buffer-size))
1154      (with-current-buffer (car b)
1155        (buffer-size))))
1156
1157 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1158 (define-ibuffer-sorter filename/process
1159  "Sort the buffers by their file name/process name."
1160   (:description "file name")
1161   (string-lessp
1162    ;; FIXME: For now just compare the file name and the process name
1163    ;; (if it exists).  Is there a better way to do this?
1164    (or (buffer-file-name (car a))
1165        (let ((pr-a (get-buffer-process (car a))))
1166          (and (processp pr-a) (process-name pr-a))))
1167    (or (buffer-file-name (car b))
1168        (let ((pr-b (get-buffer-process (car b))))
1169          (and (processp pr-b) (process-name pr-b))))))
1170
1171 ;;; Functions to emulate bs.el
1172
1173 ;;;###autoload
1174 (defun ibuffer-bs-show ()
1175   "Emulate `bs-show' from the bs.el package."
1176   (interactive)
1177   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1178   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1179
1180 (defun ibuffer-bs-toggle-all ()
1181   "Emulate `bs-toggle-show-all' from the bs.el package."
1182   (interactive)
1183   (if ibuffer-filtering-qualifiers
1184       (ibuffer-pop-filter)
1185     (progn (ibuffer-push-filter '(filename . ".*"))
1186            (ibuffer-update nil t))))
1187
1188 ;;; Handy functions
1189
1190 ;;;###autoload
1191 (defun ibuffer-add-to-tmp-hide (regexp)
1192   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1193 This means that buffers whose name matches REGEXP will not be shown
1194 for this Ibuffer session."
1195   (interactive
1196    (list
1197     (read-from-minibuffer "Never show buffers matching: "
1198                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1199   (push regexp ibuffer-tmp-hide-regexps))
1200
1201 ;;;###autoload
1202 (defun ibuffer-add-to-tmp-show (regexp)
1203   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1204 This means that buffers whose name matches REGEXP will always be shown
1205 for this Ibuffer session."
1206   (interactive
1207    (list
1208     (read-from-minibuffer "Always show buffers matching: "
1209                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1210   (push regexp ibuffer-tmp-show-regexps))
1211
1212 ;;;###autoload
1213 (defun ibuffer-forward-next-marked (&optional count mark direction)
1214   "Move forward by COUNT marked buffers (default 1).
1215
1216 If MARK is non-nil, it should be a character denoting the type of mark
1217 to move by.  The default is `ibuffer-marked-char'.
1218
1219 If DIRECTION is non-nil, it should be an integer; negative integers
1220 mean move backwards, non-negative integers mean move forwards."
1221   (interactive "P")
1222   (unless count
1223     (setq count 1))
1224   (unless mark
1225     (setq mark ibuffer-marked-char))
1226   (unless direction
1227     (setq direction 1))
1228   ;; Skip the title
1229   (ibuffer-forward-line 0)
1230   (let ((opos (point))
1231         curmark)
1232     (ibuffer-forward-line direction)
1233     (while (not (or (= (point) opos)
1234                     (eq (setq curmark (ibuffer-current-mark))
1235                         mark)))
1236       (ibuffer-forward-line direction))
1237     (when (and (= (point) opos)
1238                (not (eq (ibuffer-current-mark) mark)))
1239       (error "No buffers with mark %c" mark))))
1240
1241 ;;;###autoload
1242 (defun ibuffer-backwards-next-marked (&optional count mark)
1243    "Move backwards by COUNT marked buffers (default 1).
1244
1245 If MARK is non-nil, it should be a character denoting the type of mark
1246 to move by.  The default is `ibuffer-marked-char'."
1247    (interactive "P")
1248    (ibuffer-forward-next-marked count mark -1))
1249
1250 ;;;###autoload
1251 (defun ibuffer-do-kill-lines ()
1252   "Hide all of the currently marked lines."
1253   (interactive)
1254   (if (= (ibuffer-count-marked-lines) 0)
1255       (message "No buffers marked; use 'm' to mark a buffer")
1256     (let ((count
1257            (ibuffer-map-marked-lines
1258             #'(lambda (buf mark)
1259                 'kill))))
1260       (message "Killed %s lines" count))))
1261
1262 ;;;###autoload
1263 (defun ibuffer-jump-to-buffer (name)
1264   "Move point to the buffer whose name is NAME.
1265
1266 If called interactively, prompt for a buffer name and go to the
1267 corresponding line in the Ibuffer buffer.  If said buffer is in a
1268 hidden group filter, open it.
1269
1270 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1271 visible buffers in the completion list.  Calling the command with
1272 a prefix argument reverses the meaning of that variable."
1273   (interactive (list
1274                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1275                   (when current-prefix-arg
1276                     (setq only-visible (not only-visible)))
1277                   (if only-visible
1278                       (let ((table (mapcar #'(lambda (x)
1279                                                (buffer-name (car x)))
1280                                            (ibuffer-current-state-list))))
1281                         (when (null table)
1282                           (error "No buffers!"))
1283                         (completing-read "Jump to buffer: "
1284                                          table nil t))
1285                     (read-buffer "Jump to buffer: " nil t)))))
1286   (when (not (string= "" name))
1287     (let (buf-point)
1288       ;; Blindly search for our buffer: it is very likely that it is
1289       ;; not in a hidden filter group.
1290       (ibuffer-map-lines #'(lambda (buf marks)
1291                              (when (string= (buffer-name buf) name)
1292                                (setq buf-point (point))
1293                                nil))
1294                          t nil)
1295       (when (and
1296              (null buf-point)
1297              (not (null ibuffer-hidden-filter-groups)))
1298         ;; We did not find our buffer.  It must be in a hidden filter
1299         ;; group, so go through all hidden filter groups to find it.
1300         (catch 'found
1301           (dolist (group ibuffer-hidden-filter-groups)
1302             (ibuffer-jump-to-filter-group group)
1303             (ibuffer-toggle-filter-group)
1304             (ibuffer-map-lines #'(lambda (buf marks)
1305                                    (when (string= (buffer-name buf) name)
1306                                      (setq buf-point (point))
1307                                      nil))
1308                                t group)
1309             (if buf-point
1310                 (throw 'found nil)
1311               (ibuffer-toggle-filter-group)))))
1312       (if (null buf-point)
1313           ;; Still not found even though we expanded all hidden filter
1314           ;; groups: that must be because it's hidden by predicate:
1315           ;; we won't bother trying to display it.
1316           (error "No buffer with name %s" name)
1317         (goto-char buf-point)))))
1318
1319 (declare-function diff-sentinel "diff" (code))
1320
1321 (defun ibuffer-diff-buffer-with-file-1 (buffer)
1322   (let ((bufferfile (buffer-local-value 'buffer-file-name buffer))
1323         (tempfile (make-temp-file "buffer-content-")))
1324     (when bufferfile
1325       (unwind-protect
1326           (progn
1327             (with-current-buffer buffer
1328               (write-region nil nil tempfile nil 'nomessage))
1329             (let* ((old (expand-file-name bufferfile))
1330                    (new (expand-file-name tempfile))
1331                    (oldtmp (file-local-copy old))
1332                    (newtmp (file-local-copy new))
1333                    (switches diff-switches)
1334                    (command
1335                     (mapconcat
1336                      'identity
1337                      `(,diff-command
1338                        ;; Use explicitly specified switches
1339                        ,@(if (listp switches) switches (list switches))
1340                        ,@(if (or old new)
1341                              (list "-L" (shell-quote-argument old)
1342                                    "-L" (shell-quote-argument
1343                                          (format "Buffer %s" (buffer-name buffer)))))
1344                        ,(shell-quote-argument (or oldtmp old))
1345                        ,(shell-quote-argument (or newtmp new)))
1346                      " "))
1347                    proc)
1348               (let ((inhibit-read-only t))
1349                 (insert command "\n")
1350                 (diff-sentinel
1351                  (call-process shell-file-name nil
1352                                (current-buffer) nil
1353                                shell-command-switch command)))
1354               (insert "\n"))))
1355       (sit-for 0)
1356       (when (file-exists-p tempfile)
1357         (delete-file tempfile)))))
1358
1359 ;;;###autoload
1360 (defun ibuffer-diff-with-file ()
1361   "View the differences between marked buffers and their associated files.
1362 If no buffers are marked, use buffer at point.
1363 This requires the external program \"diff\" to be in your `exec-path'."
1364   (interactive)
1365   (require 'diff)
1366   (let ((marked-bufs (ibuffer-get-marked-buffers)))
1367     (when (null marked-bufs)
1368       (setq marked-bufs (list (ibuffer-current-buffer t))))
1369     (with-current-buffer (get-buffer-create "*Ibuffer Diff*")
1370       (setq buffer-read-only nil)
1371       (buffer-disable-undo (current-buffer))
1372       (erase-buffer)
1373       (buffer-enable-undo (current-buffer))
1374       (diff-mode)
1375       (dolist (buf marked-bufs)
1376         (unless (buffer-live-p buf)
1377           (error "Buffer %s has been killed" buf))
1378         (ibuffer-diff-buffer-with-file-1 buf))
1379       (setq buffer-read-only t)))
1380   (switch-to-buffer "*Ibuffer Diff*"))
1381
1382 ;;;###autoload
1383 (defun ibuffer-copy-filename-as-kill (&optional arg)
1384   "Copy filenames of marked buffers into the kill ring.
1385
1386 The names are separated by a space.
1387 If a buffer has no filename, it is ignored.
1388
1389 With no prefix arg, use the filename sans its directory of each marked file.
1390 With a zero prefix arg, use the complete filename of each marked file.
1391 With \\[universal-argument], use the filename of each marked file relative
1392 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1393
1394 You can then feed the file name(s) to other commands with \\[yank]."
1395   (interactive "p")
1396   (if (zerop (ibuffer-count-marked-lines))
1397       (message "No buffers marked; use 'm' to mark a buffer")
1398     (let ((ibuffer-copy-filename-as-kill-result "")
1399           (type (cond ((zerop arg)
1400                        'full)
1401                       ((= arg 4)
1402                        'relative)
1403                       (t
1404                        'name))))
1405       (ibuffer-map-marked-lines
1406        #'(lambda (buf mark)
1407            (setq ibuffer-copy-filename-as-kill-result
1408                  (concat ibuffer-copy-filename-as-kill-result
1409                          (let ((name (buffer-file-name buf)))
1410                            (if name
1411                                (case type
1412                                  (full
1413                                   name)
1414                                  (relative
1415                                   (file-relative-name
1416                                    name (or ibuffer-default-directory
1417                                             default-directory)))
1418                                  (t
1419                                   (file-name-nondirectory name)))
1420                              ""))
1421                          " "))))
1422       (kill-new ibuffer-copy-filename-as-kill-result))))
1423
1424 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1425   (let ((count
1426          (ibuffer-map-lines
1427           #'(lambda (buf mark)
1428               (when (funcall func buf)
1429                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1430                                         ibuffer-marked-char))
1431                 t))
1432           nil
1433           group)))
1434     (ibuffer-redisplay t)
1435     (unless (eq ibuffer-mark-on-buffer-mark ?\s)
1436       (message "Marked %s buffers" count))))
1437
1438 ;;;###autoload
1439 (defun ibuffer-mark-by-name-regexp (regexp)
1440   "Mark all buffers whose name matches REGEXP."
1441   (interactive "sMark by name (regexp): ")
1442   (ibuffer-mark-on-buffer
1443    #'(lambda (buf)
1444        (string-match regexp (buffer-name buf)))))
1445
1446 ;;;###autoload
1447 (defun ibuffer-mark-by-mode-regexp (regexp)
1448   "Mark all buffers whose major mode matches REGEXP."
1449   (interactive "sMark by major mode (regexp): ")
1450   (ibuffer-mark-on-buffer
1451    #'(lambda (buf)
1452        (with-current-buffer buf
1453          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1454
1455 ;;;###autoload
1456 (defun ibuffer-mark-by-file-name-regexp (regexp)
1457   "Mark all buffers whose file name matches REGEXP."
1458   (interactive "sMark by file name (regexp): ")
1459   (ibuffer-mark-on-buffer
1460    #'(lambda (buf)
1461        (let ((name (or (buffer-file-name buf)
1462                        (with-current-buffer buf
1463                          (and
1464                           (boundp 'dired-directory)
1465                           (stringp dired-directory)
1466                           dired-directory)))))
1467          (when name
1468            (string-match regexp name))))))
1469
1470 ;;;###autoload
1471 (defun ibuffer-mark-by-mode (mode)
1472   "Mark all buffers whose major mode equals MODE."
1473   (interactive
1474    (list (intern (completing-read "Mark by major mode: " obarray
1475                                   #'(lambda (e)
1476                                       ;; kind of a hack...
1477                                       (and (fboundp e)
1478                                            (string-match "-mode$"
1479                                                          (symbol-name e))))
1480                                   t
1481                                   (let ((buf (ibuffer-current-buffer)))
1482                                     (if (and buf (buffer-live-p buf))
1483                                         (with-current-buffer buf
1484                                           (cons (symbol-name major-mode)
1485                                                 0))
1486                                       ""))))))
1487   (ibuffer-mark-on-buffer
1488    #'(lambda (buf)
1489        (eq (buffer-local-value 'major-mode buf) mode))))
1490
1491 ;;;###autoload
1492 (defun ibuffer-mark-modified-buffers ()
1493   "Mark all modified buffers."
1494   (interactive)
1495   (ibuffer-mark-on-buffer
1496    #'(lambda (buf) (buffer-modified-p buf))))
1497
1498 ;;;###autoload
1499 (defun ibuffer-mark-unsaved-buffers ()
1500   "Mark all modified buffers that have an associated file."
1501   (interactive)
1502   (ibuffer-mark-on-buffer
1503    #'(lambda (buf) (and (buffer-local-value 'buffer-file-name buf)
1504                         (buffer-modified-p buf)))))
1505
1506 ;;;###autoload
1507 (defun ibuffer-mark-dissociated-buffers ()
1508   "Mark all buffers whose associated file does not exist."
1509   (interactive)
1510   (ibuffer-mark-on-buffer
1511    #'(lambda (buf)
1512        (with-current-buffer buf
1513          (or
1514           (and buffer-file-name
1515                (not (file-exists-p buffer-file-name)))
1516           (and (eq major-mode 'dired-mode)
1517                (boundp 'dired-directory)
1518                (stringp dired-directory)
1519                (not (file-exists-p (file-name-directory dired-directory)))))))))
1520
1521 ;;;###autoload
1522 (defun ibuffer-mark-help-buffers ()
1523   "Mark buffers like *Help*, *Apropos*, *Info*."
1524   (interactive)
1525   (ibuffer-mark-on-buffer
1526    #'(lambda (buf)
1527        (with-current-buffer buf
1528          (memq major-mode ibuffer-help-buffer-modes)))))
1529
1530 ;;;###autoload
1531 (defun ibuffer-mark-compressed-file-buffers ()
1532   "Mark buffers whose associated file is compressed."
1533   (interactive)
1534   (ibuffer-mark-on-buffer
1535    #'(lambda (buf)
1536        (with-current-buffer buf
1537          (and buffer-file-name
1538               (string-match ibuffer-compressed-file-name-regexp
1539                            buffer-file-name))))))
1540
1541 ;;;###autoload
1542 (defun ibuffer-mark-old-buffers ()
1543   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1544   (interactive)
1545   (ibuffer-mark-on-buffer
1546    #'(lambda (buf)
1547        (with-current-buffer buf
1548          ;; hacked from midnight.el
1549          (when buffer-display-time
1550            (let* ((tm (current-time))
1551                   (now (+ (* (float (ash 1 16)) (car tm))
1552                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1553                   (then (+ (* (float (ash 1 16))
1554                               (car buffer-display-time))
1555                            (float (cadr buffer-display-time))
1556                            (* 0.0000001 (caddr buffer-display-time)))))
1557              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1558
1559 ;;;###autoload
1560 (defun ibuffer-mark-special-buffers ()
1561   "Mark all buffers whose name begins and ends with '*'."
1562   (interactive)
1563   (ibuffer-mark-on-buffer
1564    #'(lambda (buf) (string-match "^\\*.+\\*$"
1565                                  (buffer-name buf)))))
1566
1567 ;;;###autoload
1568 (defun ibuffer-mark-read-only-buffers ()
1569   "Mark all read-only buffers."
1570   (interactive)
1571   (ibuffer-mark-on-buffer
1572    #'(lambda (buf) (buffer-local-value 'buffer-read-only buf))))
1573
1574 ;;;###autoload
1575 (defun ibuffer-mark-dired-buffers ()
1576   "Mark all `dired' buffers."
1577   (interactive)
1578   (ibuffer-mark-on-buffer
1579    #'(lambda (buf) (eq (buffer-local-value 'major-mode buf) 'dired-mode))))
1580
1581 ;;;###autoload
1582 (defun ibuffer-do-occur (regexp &optional nlines)
1583   "View lines which match REGEXP in all marked buffers.
1584 Optional argument NLINES says how many lines of context to display: it
1585 defaults to one."
1586   (interactive (occur-read-primary-args))
1587   (if (or (not (integerp nlines))
1588           (< nlines 0))
1589       (setq nlines 0))
1590   (when (zerop (ibuffer-count-marked-lines))
1591     (ibuffer-set-mark ibuffer-marked-char))
1592   (let ((ibuffer-do-occur-bufs nil))
1593     ;; Accumulate a list of marked buffers
1594     (ibuffer-map-marked-lines
1595      #'(lambda (buf mark)
1596          (push buf ibuffer-do-occur-bufs)))
1597     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1598
1599 (provide 'ibuf-ext)
1600
1601 ;; arch-tag: 9af21953-deda-4c30-b76d-f81d9128e76d
1602 ;;; ibuf-ext.el ends here