lisp/timezone.el

   1 ;;; timezone.el --- time zone package for GNU Emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu Umeda
   6 ;; Maintainer: umerin@mse.kyutech.ac.jp
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (provide 'timezone)
  29
  30 (defvar timezone-world-timezones
  31   '(("PST" .  -800)
  32     ("PDT" .  -700)
  33     ("MST" .  -700)
  34     ("MDT" .  -600)
  35     ("CST" .  -600)
  36     ("CDT" .  -500)
  37     ("EST" .  -500)
  38     ("EDT" .  -400)
  39     ("AST" .  -400)                     ;by <clamen@CS.CMU.EDU>
  40     ("NST" .  -330)                     ;by <clamen@CS.CMU.EDU>
  41     ("UT"  .  +000)
  42     ("GMT" .  +000)
  43     ("BST" .  +100)
  44     ("MET" .  +100)
  45     ("EET" .  +200)
  46     ("JST" .  +900)
  47     ("GMT+1"  .  +100) ("GMT+2"  .  +200) ("GMT+3"  .  +300)
  48     ("GMT+4"  .  +400) ("GMT+5"  .  +500) ("GMT+6"  .  +600)
  49     ("GMT+7"  .  +700) ("GMT+8"  .  +800) ("GMT+9"  .  +900)
  50     ("GMT+10" . +1000) ("GMT+11" . +1100) ("GMT+12" . +1200) ("GMT+13" . +1300)
  51     ("GMT-1"  .  -100) ("GMT-2"  .  -200) ("GMT-3"  .  -300)
  52     ("GMT-4"  .  -400) ("GMT-5"  .  -500) ("GMT-6"  .  -600)
  53     ("GMT-7"  .  -700) ("GMT-8"  .  -800) ("GMT-9"  .  -900)
  54     ("GMT-10" . -1000) ("GMT-11" . -1100) ("GMT-12" . -1200))
  55   "*Time differentials of timezone from GMT in +-HHMM form.
  56 This list is obsolescent, and is present only for backwards compatibility,
  57 because time zone names are ambiguous in practice.
  58 Use `current-time-zone' instead.")
  59
  60 (defvar timezone-months-assoc
  61   '(("JAN" .  1)("FEB" .  2)("MAR" .  3)
  62     ("APR" .  4)("MAY" .  5)("JUN" .  6)
  63     ("JUL" .  7)("AUG" .  8)("SEP" .  9)
  64     ("OCT" . 10)("NOV" . 11)("DEC" . 12))
  65   "Alist of first three letters of a month and its numerical representation.")
  66
  67 (defun timezone-make-date-arpa-standard (date &optional local timezone)
  68   "Convert DATE to an arpanet standard date.
  69 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  70 if nil, GMT is assumed.
  71 Optional 2nd argument TIMEZONE specifies a time zone to be represented in;
  72 if nil, the local time zone is assumed."
  73   (let ((new (timezone-fix-time date local timezone)))
  74     (timezone-make-arpa-date (aref new 0) (aref new 1) (aref new 2)
  75                              (timezone-make-time-string
  76                               (aref new 3) (aref new 4) (aref new 5))
  77                              (aref new 6))
  78     ))
  79
  80 (defun timezone-make-date-sortable (date &optional local timezone)
  81   "Convert DATE to a sortable date string.
  82 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  83 if nil, GMT is assumed.
  84 Optional 2nd argument TIMEZONE specifies a timezone to be represented in;
  85 if nil, the local time zone is assumed."
  86   (let ((new (timezone-fix-time date local timezone)))
  87     (timezone-make-sortable-date (aref new 0) (aref new 1) (aref new 2)
  88                                  (timezone-make-time-string
  89                                   (aref new 3) (aref new 4) (aref new 5)))
  90     ))
  91
  92 \f
  93 ;;
  94 ;; Parsers and Constructors of Date and Time
  95 ;;
  96
  97 (defun timezone-make-arpa-date (year month day time &optional timezone)
  98   "Make arpanet standard date string from YEAR, MONTH, DAY, and TIME.
  99 Optional argument TIMEZONE specifies a time zone."
 100   (let ((zone
 101          (if (listp timezone)
 102              (let* ((m (timezone-zone-to-minute timezone))
 103                     (absm (if (< m 0) (- m) m)))
 104                (format "%c%02d%02d"
 105                        (if (< m 0) ?- ?+) (/ absm 60) (% absm 60)))
 106            timezone)))
 107     (format "%02d %s %04d %s %s"
 108             day
 109             (capitalize (car (rassq month timezone-months-assoc)))
 110             year
 111             time
 112             zone)))
 113
 114 (defun timezone-make-sortable-date (year month day time)
 115   "Make sortable date string from YEAR, MONTH, DAY, and TIME."
 116   (format "%4d%02d%02d%s"
 117           year month day time))
 118
 119 (defun timezone-make-time-string (hour minute second)
 120   "Make time string from HOUR, MINUTE, and SECOND."
 121   (format "%02d:%02d:%02d" hour minute second))
 122
 123 (defun timezone-parse-date (date)
 124   "Parse DATE and return a vector [YEAR MONTH DAY TIME TIMEZONE].
 125 19 is prepended to year if necessary.  Timezone may be nil if nothing.
 126 Understands the following styles:
 127  (1) 14 Apr 89 03:20[:12] [GMT]
 128  (2) Fri, 17 Mar 89 4:01[:33] [GMT]
 129  (3) Mon Jan 16 16:12[:37] [GMT] 1989
 130  (4) 6 May 1992 1641-JST (Wednesday)
 131  (5) 22-AUG-1993 10:59:12.82
 132  (6) Thu, 11 Apr 16:17:12 91 [MET]
 133  (7) Mon, 6  Jul 16:47:20 T 1992 [MET]
 134  (8) 1996-06-24 21:13:12 [GMT]"
 135  ;; Get rid of any text properties.
 136   (and (stringp date)
 137        (or (text-properties-at 0 date)
 138            (next-property-change 0 date))
 139        (setq date (copy-sequence date))
 140        (set-text-properties 0 (length date) nil date))
 141   (let ((date (or date ""))
 142         (year nil)
 143         (month nil)
 144         (day nil)
 145         (time nil)
 146         (zone nil))                     ;This may be nil.
 147     (cond ((string-match
 148             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\'" date)
 149            ;; Styles: (6) and (7) without timezone
 150            (setq year 6 month 3 day 2 time 4 zone nil))
 151           ((string-match
 152             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 153            ;; Styles: (6) and (7) with timezone and buggy timezone
 154            (setq year 6 month 3 day 2 time 4 zone 7))
 155           ((string-match
 156             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\'" date)
 157            ;; Styles: (1) and (2) without timezone
 158            (setq year 3 month 2 day 1 time 4 zone nil))
 159           ((string-match
 160             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 161            ;; Styles: (1) and (2) with timezone and buggy timezone
 162            (setq year 3 month 2 day 1 time 4 zone 5))
 163           ((string-match
 164             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([0-9]+\\)" date)
 165            ;; Styles: (3) without timezone
 166            (setq year 4 month 1 day 2 time 3 zone nil))
 167           ((string-match
 168             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)[ \t]+\\([0-9]+\\)" date)
 169            ;; Styles: (3) with timezone
 170            (setq year 5 month 1 day 2 time 3 zone 4))
 171           ((string-match
 172             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 173            ;; Styles: (4) with timezone
 174            (setq year 3 month 2 day 1 time 4 zone 5))
 175           ((string-match
 176             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\.[0-9]+" date)
 177            ;; Styles: (5) without timezone.
 178            (setq year 3 month 2 day 1 time 4 zone nil))
 179           ((string-match
 180             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 181            ;; Styles: (8) with timezone.
 182            (setq year 1 month 2 day 3 time 4 zone 5))
 183           ((string-match
 184             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)" date)
 185            ;; Styles: (8) without timezone.
 186            (setq year 1 month 2 day 3 time 4 zone nil))
 187           )
 188     (if year
 189         (progn
 190           (setq year
 191                 (substring date (match-beginning year) (match-end year)))
 192           ;; It is now Dec 1992.  8 years before the end of the World.
 193           (if (< (length year) 4)
 194               (setq year (concat "19" (substring year -2 nil))))
 195           (setq month
 196                 (if (= (aref date (+ (match-beginning month) 2)) ?-)
 197                     ;; Handle numeric months, spanning exactly two digits.
 198                     (substring date
 199                                (match-beginning month)
 200                                (+ (match-beginning month) 2))
 201                   (let ((string (substring date
 202                                  (match-beginning month)
 203                                  (+ (match-beginning month) 3))))
 204                     (int-to-string
 205                      (cdr (assoc (upcase string) timezone-months-assoc))))))
 206           (setq day
 207                 (substring date (match-beginning day) (match-end day)))
 208           (setq time
 209                 (substring date (match-beginning time) (match-end time)))))
 210     (if zone
 211         (setq zone
 212               (substring date (match-beginning zone) (match-end zone))))
 213     ;; Return a vector.
 214     (if year
 215         (vector year month day time zone)
 216       (vector "0" "0" "0" "0" nil))
 217     ))
 218
 219 (defun timezone-parse-time (time)
 220   "Parse TIME (HH:MM:SS) and return a vector [hour minute second].
 221 Recognize HH:MM:SS, HH:MM, HHMMSS, HHMM."
 222   (let ((time (or time ""))
 223         (hour nil)
 224         (minute nil)
 225         (second nil))
 226     (cond ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 227            ;; HH:MM:SS
 228            (setq hour 1 minute 2 second 3))
 229           ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 230            ;; HH:MM
 231            (setq hour 1 minute 2 second nil))
 232           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 233            ;; HHMMSS
 234            (setq hour 1 minute 2 second 3))
 235           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 236            ;; HHMM
 237            (setq hour 1 minute 2 second nil))
 238           )
 239     ;; Return [hour minute second]
 240     (vector
 241      (if hour
 242          (substring time (match-beginning hour) (match-end hour)) "0")
 243      (if minute
 244          (substring time (match-beginning minute) (match-end minute)) "0")
 245      (if second
 246          (substring time (match-beginning second) (match-end second)) "0"))
 247     ))
 248
 249 \f
 250 ;; Miscellaneous
 251
 252 (defun timezone-zone-to-minute (timezone)
 253   "Translate TIMEZONE to an integer minute offset from GMT.
 254 TIMEZONE can be a cons cell containing the output of current-time-zone,
 255 or an integer of the form +-HHMM, or a time zone name."
 256   (cond
 257      ((consp timezone)
 258       (/ (car timezone) 60))
 259      (timezone
 260       (progn
 261         (setq timezone
 262               (or (cdr (assoc (upcase timezone) timezone-world-timezones))
 263                   ;; +900
 264                   timezone))
 265         (if (stringp timezone)
 266             (setq timezone (string-to-int timezone)))
 267         ;; Taking account of minute in timezone.
 268         ;; HHMM -> MM
 269         (let* ((abszone (abs timezone))
 270                (minutes (+ (* 60 (/ abszone 100)) (% abszone 100))))
 271           (if (< timezone 0) (- minutes) minutes))))
 272      (t 0)))
 273
 274 (defun timezone-time-from-absolute (date seconds)
 275   "Compute the UTC time equivalent to DATE at time SECONDS after midnight.
 276 Return a list suitable as an argument to current-time-zone,
 277 or nil if the date cannot be thus represented.
 278 DATE is the number of days elapsed since the (imaginary)
 279 Gregorian date Sunday, December 31, 1 BC."
 280   (let* ((current-time-origin 719162)
 281             ;; (timezone-absolute-from-gregorian 1 1 1970)
 282          (days (- date current-time-origin))
 283          (seconds-per-day (float 86400))
 284          (seconds (+ seconds (* days seconds-per-day)))
 285          (current-time-arithmetic-base (float 65536))
 286          (hi (floor (/ seconds current-time-arithmetic-base)))
 287          (hibase (* hi current-time-arithmetic-base))
 288          (lo (floor (- seconds hibase))))
 289      (and (< (abs (- seconds (+ hibase lo))) 2) ;; Check for integer overflow.
 290           (cons hi lo))))
 291
 292 (defun timezone-time-zone-from-absolute (date seconds)
 293   "Compute the local time zone for DATE at time SECONDS after midnight.
 294 Return a list in the same format as current-time-zone's result,
 295 or nil if the local time zone could not be computed.
 296 DATE is the number of days elapsed since the (imaginary)
 297 Gregorian date Sunday, December 31, 1 BC."
 298    (and (fboundp 'current-time-zone)
 299         (let ((utc-time (timezone-time-from-absolute date seconds)))
 300           (and utc-time
 301                (let ((zone (current-time-zone utc-time)))
 302                  (and (car zone) zone))))))
 303
 304 (defun timezone-fix-time (date local timezone)
 305   "Convert DATE (default timezone LOCAL) to YYYY-MM-DD-HH-MM-SS-ZONE vector.
 306 If LOCAL is nil, it is assumed to be GMT.
 307 If TIMEZONE is nil, use the local time zone."
 308   (let* ((date   (timezone-parse-date date))
 309          (year   (string-to-int (aref date 0)))
 310          (year   (cond ((< year 50)
 311                         (+ year 2000))
 312                        ((< year 100)
 313                         (+ year 1900))
 314                        (t year)))
 315          (month  (string-to-int (aref date 1)))
 316          (day    (string-to-int (aref date 2)))
 317          (time   (timezone-parse-time (aref date 3)))
 318          (hour   (string-to-int (aref time 0)))
 319          (minute (string-to-int (aref time 1)))
 320          (second (string-to-int (aref time 2)))
 321          (local  (or (aref date 4) local)) ;Use original if defined
 322          (timezone
 323           (or timezone
 324               (timezone-time-zone-from-absolute
 325                (timezone-absolute-from-gregorian month day year)
 326                (+ second (* 60 (+ minute (* 60 hour)))))))
 327          (diff   (- (timezone-zone-to-minute timezone)
 328                     (timezone-zone-to-minute local)))
 329          (minute (+ minute diff))
 330          (hour-fix (floor minute 60)))
 331     (setq hour (+ hour hour-fix))
 332     (setq minute (- minute (* 60 hour-fix)))
 333     ;; HOUR may be larger than 24 or smaller than 0.
 334     (cond ((<= 24 hour)                 ;24 -> 00
 335            (setq hour (- hour 24))
 336            (setq day  (1+ day))
 337            (if (< (timezone-last-day-of-month month year) day)
 338                (progn
 339                  (setq month (1+ month))
 340                  (setq day 1)
 341                  (if (< 12 month)
 342                      (progn
 343                        (setq month 1)
 344                        (setq year (1+ year))
 345                        ))
 346                  )))
 347           ((> 0 hour)
 348            (setq hour (+ hour 24))
 349            (setq day  (1- day))
 350            (if (> 1 day)
 351                (progn
 352                  (setq month (1- month))
 353                  (if (> 1 month)
 354                      (progn
 355                        (setq month 12)
 356                        (setq year (1- year))
 357                        ))
 358                  (setq day (timezone-last-day-of-month month year))
 359                  )))
 360           )
 361     (vector year month day hour minute second timezone)))
 362
 363 ;; Partly copied from Calendar program by Edward M. Reingold.
 364 ;; Thanks a lot.
 365
 366 (defun timezone-last-day-of-month (month year)
 367   "The last day in MONTH during YEAR."
 368   (if (and (= month 2) (timezone-leap-year-p year))
 369       29
 370     (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 371
 372 (defun timezone-leap-year-p (year)
 373   "Returns t if YEAR is a Gregorian leap year."
 374   (or (and (zerop  (% year 4))
 375            (not (zerop (% year 100))))
 376       (zerop (% year 400))))
 377
 378 (defun timezone-day-number (month day year)
 379   "Return the day number within the year of the date month/day/year."
 380   (let ((day-of-year (+ day (* 31 (1- month)))))
 381     (if (> month 2)
 382         (progn
 383           (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 384           (if (timezone-leap-year-p year)
 385               (setq day-of-year (1+ day-of-year)))))
 386     day-of-year))
 387
 388 (defun timezone-absolute-from-gregorian (month day year)
 389   "The number of days between the Gregorian date 12/31/1 BC and month/day/year.
 390 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 391   (+ (timezone-day-number month day year);; Days this year
 392      (* 365 (1- year));;        + Days in prior years
 393      (/ (1- year) 4);;          + Julian leap years
 394      (- (/ (1- year) 100));;    - century years
 395      (/ (1- year) 400)));;      + Gregorian leap years
 396
 397 ;;; timezone.el ends here