lisp/xt-mouse.el

   1 ;;; xt-mouse.el --- support the mouse when emacs run in an xterm
   2
   3 ;; Copyright (C) 1994, 2000, 2001 Free Software Foundation
   4
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: mouse, terminals
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Enable mouse support when running inside an xterm or Linux console.
  28
  29 ;; This is actually useful when you are running X11 locally, but is
  30 ;; working on remote machine over a modem line or through a gateway.
  31
  32 ;; It works by translating xterm escape codes into generic emacs mouse
  33 ;; events so it should work with any package that uses the mouse.
  34
  35 ;; The xterm mouse escape codes are supposedly also supported by the
  36 ;; Linux console, but I have not been able to verify this.
  37
  38 ;; You don't have to turn off xterm mode to use the normal xterm mouse
  39 ;; functionality, it is still available by holding down the SHIFT key
  40 ;; when you press the mouse button.
  41
  42 ;;; Todo:
  43
  44 ;; Support multi-click -- somehow.
  45
  46 ;; Clicking on the mode-line does not work, although it should.
  47
  48 ;;; Code:
  49
  50 (define-key function-key-map "\e[M" 'xterm-mouse-translate)
  51
  52 (defvar xterm-mouse-last)
  53
  54 (defun xterm-mouse-translate (event)
  55   "Read a click and release event from XTerm."
  56   (save-excursion
  57     (save-window-excursion
  58       (deactivate-mark)
  59       (let* ((xterm-mouse-last)
  60              (down (xterm-mouse-event))
  61              (down-command (nth 0 down))
  62              (down-data (nth 1 down))
  63              (down-where (nth 1 down-data))
  64              (down-binding (key-binding (if (symbolp down-where)
  65                                             (vector down-where down-command)
  66                                           (vector down-command))))
  67              (is-click (string-match "^mouse" (symbol-name (car down)))))
  68
  69         (unless is-click
  70           (unless (and (eq (read-char) ?\e)
  71                        (eq (read-char) ?\[)
  72                        (eq (read-char) ?M))
  73             (error "Unexpected escape sequence from XTerm")))
  74
  75         (let* ((click (if is-click down (xterm-mouse-event)))
  76                (click-command (nth 0 click))
  77                (click-data (nth 1 click))
  78                (click-where (nth 1 click-data)))
  79           (if (memq down-binding '(nil ignore))
  80               (if (and (symbolp click-where)
  81                        (not (eq 'menu-bar click-where)))
  82                   (vector (list click-where click-data) click)
  83                 (vector click))
  84             (setq unread-command-events
  85                   (if (eq down-where click-where)
  86                       (list click)
  87                     (list
  88                      ;; Cheat `mouse-drag-region' with move event.
  89                      (list 'mouse-movement click-data)
  90                      ;; Generate a drag event.
  91                      (if (symbolp down-where)
  92                          0
  93                        (list (intern (format "drag-mouse-%d"
  94                                              (+ 1 xterm-mouse-last)))
  95                              down-data click-data))
  96                      )))
  97             (if (and (symbolp down-where)
  98                      (not (eq 'menu-bar down-where)))
  99                 (vector (list down-where down-data) down)
 100               (vector down))))))))
 101
 102 (defvar xterm-mouse-x 0
 103   "Position of last xterm mouse event relative to the frame.")
 104
 105 (defvar xterm-mouse-y 0
 106   "Position of last xterm mouse event relative to the frame.")
 107
 108 ;; Indicator for the xterm-mouse mode.
 109
 110 (defun xterm-mouse-position-function (pos)
 111   "Bound to `mouse-position-function' in XTerm mouse mode."
 112   (setcdr pos (cons xterm-mouse-x xterm-mouse-y))
 113   pos)
 114
 115 (defun xterm-mouse-event ()
 116   "Convert XTerm mouse event to Emacs mouse event."
 117   (let* ((type (- (read-char) #o40))
 118          (x (- (read-char) #o40 1))
 119          (y (- (read-char) #o40 1))
 120          (point (cons x y))
 121          (window (window-at x y))
 122          (where (if window
 123                     (coordinates-in-window-p point window)
 124                   'menu-bar))
 125          (pos (if (consp where)
 126                   (progn
 127                     (select-window window)
 128                     (goto-char (window-start window))
 129                     (move-to-window-line (-
 130                                           (cdr where)
 131                                           (if (or header-line-format
 132                                                   default-header-line-format)
 133                                               1
 134                                             0)))
 135                     (move-to-column (+ (car where) (current-column)
 136                                        (if (string-match "\\` \\*Minibuf"
 137                                                          (buffer-name))
 138                                            (- (minibuffer-prompt-width))
 139                                          0)
 140                                        (max 0 (1- (window-hscroll)))))
 141                     (point))
 142                 where))
 143          (mouse (intern
 144                  ;; For buttons > 3, the release-event looks
 145                  ;; differently (see xc/programs/xterm/button.c,
 146                  ;; function EditorButton), and there seems to come in
 147                  ;; a release-event only, no down-event.
 148                  (cond ((>= type 64)
 149                         (format "mouse-%d" (- type 60)))
 150                        ((= type 3)
 151                         (format "mouse-%d" (+ 1 xterm-mouse-last)))
 152                        (t
 153                         (setq xterm-mouse-last type)
 154                         (format "down-mouse-%d" (+ 1 type)))))))
 155     (setq xterm-mouse-x x
 156           xterm-mouse-y y)
 157     (list mouse
 158           (list window pos point
 159                 (/ (nth 2 (current-time)) 1000)))))
 160
 161 ;;;###autoload
 162 (define-minor-mode xterm-mouse-mode
 163   "Toggle XTerm mouse mode.
 164 With prefix arg, turn XTerm mouse mode on iff arg is positive.
 165
 166 Turn it on to use emacs mouse commands, and off to use xterm mouse commands."
 167   nil " Mouse" nil :global t
 168   (if xterm-mouse-mode
 169       ;; Turn it on
 170       (unless window-system
 171         (setq mouse-position-function #'xterm-mouse-position-function)
 172         (turn-on-xterm-mouse-tracking))
 173     ;; Turn it off
 174     (turn-off-xterm-mouse-tracking 'force)
 175     (setq mouse-position-function nil)))
 176
 177 (defun turn-on-xterm-mouse-tracking ()
 178   "Enable Emacs mouse tracking in xterm."
 179   (if xterm-mouse-mode
 180       (send-string-to-terminal "\e[?1000h")))
 181
 182 (defun turn-off-xterm-mouse-tracking (&optional force)
 183   "Disable Emacs mouse tracking in xterm."
 184   (if (or force xterm-mouse-mode)
 185       (send-string-to-terminal "\e[?1000l")))
 186
 187 ;; Restore normal mouse behaviour outside Emacs.
 188 (add-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
 189 (add-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
 190 (add-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking)
 191
 192 (provide 'xt-mouse)
 193
 194 ;;; xt-mouse.el ends here