lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Introduction:
  30 ;;
  31 ;; Whenever a file that Emacs is editing has been changed by another
  32 ;; program the user normally has to execute the command `revert-buffer'
  33 ;; to load the new content of the file into Emacs.
  34 ;;
  35 ;; This package contains two minor modes: Global Auto-Revert Mode and
  36 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  37 ;; whenever the corresponding files have been changed on disk.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.
  40 ;; Global Auto-Revert Mode applies to all file buffers.
  41 ;;
  42 ;; Both modes operate by checking the time stamp of all files at
  43 ;; intervals of `auto-revert-interval'.  The default is every five
  44 ;; seconds.  The check is aborted whenever the user actually uses
  45 ;; Emacs.  You should never even notice that this package is active
  46 ;; (except that your buffers will be reverted, of course).
  47
  48 ;; Usage:
  49 ;;
  50 ;; Go to the appropriate buffer and press:
  51 ;;   M-x auto-revert-mode RET
  52 ;;
  53 ;; To activate Global Auto-Revert Mode, press:
  54 ;;   M-x global-auto-revert-mode RET
  55 ;;
  56 ;; To activate Global Auto-Revert Mode every time Emacs is started
  57 ;; customise the option `global-auto-revert-mode' or the following
  58 ;; line could be added to your ~/.emacs:
  59 ;;   (global-auto-revert-mode 1)
  60 ;;
  61 ;; The function `turn-on-auto-revert-mode' could be added to any major
  62 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  63 ;; mode.  For example, the following line will activate Auto-Revert
  64 ;; Mode in all C mode buffers:
  65 ;;
  66 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  67
  68 ;;; Code:
  69
  70 ;; Dependencies:
  71
  72 (require 'timer)
  73 (eval-when-compile (require 'cl))
  74
  75
  76 ;; Custom Group:
  77 ;;
  78 ;; The two modes will be placed next to Auto Save Mode under the
  79 ;; Files group under Emacs.
  80
  81 (defgroup auto-revert nil
  82   "Revert individual buffers when files on disk change.
  83
  84 Auto-Revert Mode can be activated for individual buffer.
  85 Global Auto-Revert Mode applies to all buffers."
  86   :group 'files
  87   :group 'convenience)
  88
  89
  90 ;; Variables:
  91
  92 ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
  93 ;;;###autoload
  94 (defvar auto-revert-mode nil
  95   "*Non-nil when Auto-Revert Mode is active.
  96 Never set this variable directly, use the command `auto-revert-mode' instead.")
  97 (put 'auto-revert-mode 'permanent-local t)
  98
  99 (defcustom auto-revert-interval 5
 100   "Time, in seconds, between Auto-Revert Mode file checks."
 101   :group 'auto-revert
 102   :type 'integer)
 103
 104 (defcustom auto-revert-stop-on-user-input t
 105   "When non-nil Auto-Revert Mode stops checking files on user input."
 106   :group 'auto-revert
 107   :type 'boolean)
 108
 109 (defcustom auto-revert-verbose t
 110   "When nil, Auto-Revert Mode will not generate any messages.
 111
 112 Currently, messages are generated when the mode is activated or
 113 deactivated, and whenever a file is reverted."
 114   :group 'auto-revert
 115   :type 'boolean)
 116
 117 (defcustom auto-revert-mode-text " ARev"
 118   "String to display in the mode line when Auto-Revert Mode is active.
 119
 120 \(When the string is not empty, make sure that it has a leading space.)"
 121   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 122   :group 'auto-revert
 123   :type 'string)
 124
 125 (defcustom auto-revert-mode-hook nil
 126   "Functions to run when Auto-Revert Mode is activated."
 127   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 128   :group 'auto-revert
 129   :type 'hook)
 130
 131 (defcustom global-auto-revert-mode-text ""
 132   "String to display when Global Auto-Revert Mode is active.
 133
 134 The default is nothing since when this mode is active this text doesn't
 135 vary over time, or between buffers.  Hence mode line text
 136 would only waste precious space."
 137   :group 'auto-revert
 138   :type 'string)
 139
 140 (defcustom global-auto-revert-mode-hook nil
 141   "Hook called when Global Auto-Revert Mode is activated."
 142   :group 'auto-revert
 143   :type 'hook)
 144
 145 (defcustom global-auto-revert-non-file-buffers nil
 146   "When nil only file buffers are reverted by Global Auto-Revert Mode.
 147
 148 When non-nil, both file buffers and buffers with a custom
 149 `revert-buffer-function' are reverted by Global Auto-Revert Mode.
 150
 151 Use this option with care since it could lead to excessive reverts."
 152   :group 'auto-revert
 153   :type 'boolean)
 154
 155 (defcustom global-auto-revert-ignore-modes '()
 156   "List of major modes Global Auto-Revert Mode should not check."
 157   :group 'auto-revert
 158   :type '(repeat sexp))
 159
 160 (defcustom auto-revert-load-hook nil
 161   "Functions to run when Auto-Revert Mode is first loaded."
 162   :tag "Load Hook"
 163   :group 'auto-revert
 164   :type 'hook)
 165
 166 (defvar global-auto-revert-ignore-buffer nil
 167   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 168
 169 This variable becomes buffer local when set in any fashion.")
 170 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 171
 172
 173 ;; Internal variables:
 174
 175 (defvar auto-revert-buffer-list '()
 176   "List of buffers in Auto-Revert Mode.
 177
 178 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 179 buffers to this list.
 180
 181 The timer function `auto-revert-buffers' is responsible for purging
 182 the list of old buffers.")
 183
 184 (defvar auto-revert-timer nil
 185   "Timer used by Auto-Revert Mode.")
 186
 187 (defvar auto-revert-remaining-buffers '()
 188   "Buffers not checked when user input stopped execution.")
 189
 190
 191 ;; Functions:
 192
 193 ;;;###autoload
 194 (define-minor-mode auto-revert-mode
 195   "Toggle reverting buffer when file on disk changes.
 196
 197 With arg, turn Auto Revert mode on if and only if arg is positive.
 198 This is a minor mode that affects only the current buffer.
 199 Use `global-auto-revert-mode' to automatically revert all buffers."
 200   nil auto-revert-mode-text nil
 201   (if auto-revert-mode
 202       (if (not (memq (current-buffer) auto-revert-buffer-list))
 203           (push (current-buffer) auto-revert-buffer-list))
 204     (setq auto-revert-buffer-list
 205           (delq (current-buffer) auto-revert-buffer-list)))
 206   (auto-revert-set-timer)
 207   (when auto-revert-mode
 208     (auto-revert-buffers)))
 209
 210
 211 ;;;###autoload
 212 (defun turn-on-auto-revert-mode ()
 213   "Turn on Auto-Revert Mode.
 214
 215 This function is designed to be added to hooks, for example:
 216   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 217   (auto-revert-mode 1))
 218
 219
 220 ;;;###autoload
 221 (define-minor-mode global-auto-revert-mode
 222   "Revert any buffer when file on disk change.
 223
 224 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 225 This is a minor mode that affects all buffers.
 226 Use `auto-revert-mode' to revert a particular buffer."
 227   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 228   (auto-revert-set-timer)
 229   (when global-auto-revert-mode
 230     (auto-revert-buffers)))
 231
 232
 233 (defun auto-revert-set-timer ()
 234   "Restart or cancel the timer."
 235   (if (timerp auto-revert-timer)
 236       (cancel-timer auto-revert-timer))
 237   (setq auto-revert-timer
 238         (if (or global-auto-revert-mode auto-revert-buffer-list)
 239             (run-with-timer auto-revert-interval
 240                             auto-revert-interval
 241                             'auto-revert-buffers)
 242           nil)))
 243
 244 (defun auto-revert-buffers ()
 245   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 246
 247 Should `global-auto-revert-mode' be active all file buffers are checked.
 248
 249 Should `auto-revert-mode' be active in some buffers, those buffers
 250 are checked.
 251
 252 Non-file buffers that have a custom `revert-buffer-function' are
 253 reverted either when Auto-Revert Mode is active in that buffer, or
 254 when the variable `global-auto-revert-non-file-buffers' is non-nil
 255 and Global Auto-Revert Mode is active.
 256
 257 This function stops whenever there is user input.  The buffers not
 258 checked are stored in the variable `auto-revert-remaining-buffers'.
 259
 260 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 261 are checked first the next time this function is called.
 262
 263 This function is also responsible for removing buffers no longer in
 264 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 265 the timer when no buffers need to be checked."
 266   (let ((bufs (if global-auto-revert-mode
 267                   (buffer-list)
 268                 auto-revert-buffer-list))
 269         (remaining '())
 270         (new '()))
 271     ;; Partition `bufs' into two halves depending on whether or not
 272     ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 273     ;; halves are then re-joined with the "remaining" buffers at the
 274     ;; head of the list.
 275     (dolist (buf auto-revert-remaining-buffers)
 276       (if (memq buf bufs)
 277           (push buf remaining)))
 278     (dolist (buf bufs)
 279       (if (not (memq buf remaining))
 280           (push buf new)))
 281     (setq bufs (nreverse (nconc new remaining)))
 282     (while (and bufs
 283                 (not (and auto-revert-stop-on-user-input
 284                           (input-pending-p))))
 285       (let ((buf (car bufs)))
 286         (if (buffer-name buf)           ; Buffer still alive?
 287             (with-current-buffer buf
 288               ;; Test if someone has turned off Auto-Revert Mode in a
 289               ;; non-standard way, for example by changing major mode.
 290               (if (and (not auto-revert-mode)
 291                        (memq buf auto-revert-buffer-list))
 292                   (setq auto-revert-buffer-list
 293                         (delq buf auto-revert-buffer-list)))
 294               (when (and
 295                      (or auto-revert-mode
 296                          (and
 297                           global-auto-revert-mode
 298                           (not global-auto-revert-ignore-buffer)
 299                           (not (memq major-mode
 300                                      global-auto-revert-ignore-modes))))
 301                      (not (buffer-modified-p))
 302                      (if (buffer-file-name)
 303                          (and (file-readable-p (buffer-file-name))
 304                               (not (verify-visited-file-modtime buf)))
 305                        (and revert-buffer-function
 306                             (or (and global-auto-revert-mode
 307                                      global-auto-revert-non-file-buffers)
 308                                 auto-revert-mode))))
 309                 (if auto-revert-verbose
 310                     (message "Reverting buffer `%s'." buf))
 311                 (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)
 312                 ;; `preserve-modes' avoids changing the (minor) modes.  But we
 313                 ;; do want to reset the mode for VC, so we do it explicitly.
 314                 (vc-find-file-hook)))
 315           ;; Remove dead buffer from `auto-revert-buffer-list'.
 316           (setq auto-revert-buffer-list
 317                 (delq buf auto-revert-buffer-list))))
 318       (setq bufs (cdr bufs)))
 319     (setq auto-revert-remaining-buffers bufs)
 320     ;; Check if we should cancel the timer.
 321     (when (and (not global-auto-revert-mode)
 322                (null auto-revert-buffer-list))
 323       (cancel-timer auto-revert-timer)
 324       (setq auto-revert-timer nil))))
 325
 326
 327 ;; The end:
 328 (provide 'autorevert)
 329
 330 (run-hooks 'auto-revert-load-hook)
 331
 332 ;;; autorevert.el ends here