lisp/autoinsert.el

   1 ;;; autoinsert.el --- automatic mode-dependent insertion of text into new files
   2
   3 ;; Copyright (C) 1985, 86, 87, 94, 95, 98, 2000 Free Software Foundation, Inc.
   4
   5 ;; Author: Charlie Martin <crm@cs.duke.edu>
   6 ;; Adapted-By: Daniel Pfeiffer <occitan@esperanto.org>
   7 ;; Keywords: convenience
   8 ;; Maintainer: FSF
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;  The following defines an association list for text to be
  30 ;;  automatically inserted when a new file is created, and a function
  31 ;;  which automatically inserts these files; the idea is to insert
  32 ;;  default text much as the mode is automatically set using
  33 ;;  auto-mode-alist.
  34 ;;
  35 ;;  To use:
  36 ;;     (add-hook 'find-file-hooks 'auto-insert)
  37 ;;     setq auto-insert-directory to an appropriate slash-terminated value
  38 ;;
  39 ;;  You can also customize the variable `auto-insert-mode' to load the
  40 ;;  package.  Alternatively, add the following to your .emacs file:
  41 ;;  (auto-insert-mode 1)
  42 ;;
  43 ;;  Author:  Charlie Martin
  44 ;;           Department of Computer Science and
  45 ;;           National Biomedical Simulation Resource
  46 ;;           Box 3709
  47 ;;           Duke University Medical Center
  48 ;;           Durham, NC 27710
  49 ;;            (crm@cs.duke.edu,mcnc!duke!crm)
  50
  51 ;;; Code:
  52
  53 (defgroup auto-insert nil
  54   "Automatic mode-dependent insertion of text into new files."
  55   :prefix "auto-insert-"
  56   :group 'files
  57   :group 'convenience)
  58
  59
  60 (defcustom auto-insert 'not-modified
  61   "*Controls automatic insertion into newly found empty files.
  62 Possible values:
  63         nil     do nothing
  64         t       insert if possible
  65         other   insert if possible, but mark as unmodified.
  66 Insertion is possible when something appropriate is found in
  67 `auto-insert-alist'.  When the insertion is marked as unmodified, you can
  68 save it with  \\[write-file] RET.
  69 This variable is used when the function `auto-insert' is called, e.g.
  70 when you do (add-hook 'find-file-hooks 'auto-insert).
  71 With \\[auto-insert], this is always treated as if it were t."
  72   :type '(choice (const :tag "Insert if possible" t)
  73                  (const :tag "Do nothing" nil)
  74                  (other :tag "insert if possible, mark as unmodified."
  75                         not-modified))
  76   :group 'auto-insert)
  77
  78 (defcustom auto-insert-query 'function
  79   "*Non-nil means ask user before auto-inserting.
  80 When this is `function', only ask when called non-interactively."
  81   :type '(choice (const :tag "Don't ask" nil)
  82                  (const :tag "Ask if called non-interactively" function)
  83                  (other :tag "Ask" t))
  84   :group 'auto-insert)
  85
  86 (defcustom auto-insert-prompt "Perform %s auto-insertion? "
  87   "*Prompt to use when querying whether to auto-insert.
  88 If this contains a %s, that will be replaced by the matching rule."
  89   :type 'string
  90   :group 'auto-insert)
  91
  92
  93 (defcustom auto-insert-alist
  94   '((("\\.\\([Hh]\\|hh\\|hpp\\)\\'" . "C / C++ header")
  95      (upcase (concat (file-name-nondirectory
  96                       (substring buffer-file-name 0 (match-beginning 0)))
  97                      "_"
  98                      (substring buffer-file-name (1+ (match-beginning 0)))))
  99      "#ifndef " str \n
 100      "#define " str "\n\n"
 101      _ "\n\n#endif")
 102
 103     (("\\.\\([Cc]\\|cc\\|cpp\\)\\'" . "C / C++ program")
 104      nil
 105      "#include \""
 106      (let ((stem (file-name-sans-extension buffer-file-name)))
 107        (cond ((file-exists-p (concat stem ".h"))
 108               (file-name-nondirectory (concat stem ".h")))
 109              ((file-exists-p (concat stem ".hh"))
 110               (file-name-nondirectory (concat stem ".hh")))))
 111      & ?\" | -10)
 112
 113     (("[Mm]akefile\\'" . "Makefile") . "makefile.inc")
 114
 115     (html-mode . (lambda () (sgml-tag "html")))
 116
 117     (plain-tex-mode . "tex-insert.tex")
 118     (bibtex-mode . "tex-insert.tex")
 119     (latex-mode
 120      ;; should try to offer completing read for these
 121      "options, RET: "
 122      "\\documentclass[" str & ?\] | -1
 123      ?{ (read-string "class: ") "}\n"
 124      ("package, %s: "
 125       "\\usepackage[" (read-string "options, RET: ") & ?\] | -1 ?{ str "}\n")
 126      _ "\n\\begin{document}\n" _
 127      "\n\\end{document}")
 128
 129     (("/bin/.*[^/]\\'" . "Shell-Script mode magic number")
 130      lambda ()
 131        (if (eq major-mode default-major-mode)
 132          (sh-mode)))
 133
 134     (ada-mode . ada-header)
 135
 136     (("\\.el\\'" . "Emacs Lisp header")
 137      "Short description: "
 138      ";;; " (file-name-nondirectory (buffer-file-name)) " --- " str "
 139
 140 ;; Copyright (C) " (substring (current-time-string) -4) "  "
 141  (getenv "ORGANIZATION") | "Free Software Foundation, Inc." "
 142
 143 ;; Author: " (user-full-name)
 144 '(if (search-backward "&" (line-beginning-position) t)
 145      (replace-match (capitalize (user-login-name)) t t))
 146 '(end-of-line 1) " <" (progn user-mail-address) ">
 147 ;; Keywords: "
 148  '(require 'finder)
 149  ;;'(setq v1 (apply 'vector (mapcar 'car finder-known-keywords)))
 150  '(setq v1 (mapcar (lambda (x) (list (symbol-name (car x))))
 151                    finder-known-keywords)
 152         v2 (mapconcat (lambda (x) (format "%10.0s:  %s" (car x) (cdr x)))
 153            finder-known-keywords
 154            "\n"))
 155  ((let ((minibuffer-help-form v2))
 156     (completing-read "Keyword, C-h: " v1 nil t))
 157     str ", ") & -2 "
 158
 159 ;; This file is free software; you can redistribute it and/or modify
 160 ;; it under the terms of the GNU General Public License as published by
 161 ;; the Free Software Foundation; either version 2, or (at your option)
 162 ;; any later version.
 163
 164 ;; This file is distributed in the hope that it will be useful,
 165 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
 166 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 167 ;; GNU General Public License for more details.
 168
 169 ;; You should have received a copy of the GNU General Public License
 170 ;; along with GNU Emacs; see the file COPYING.  If not, write to
 171 ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
 172 ;; Boston, MA 02111-1307, USA.
 173
 174 ;;; Commentary:
 175
 176 ;; " _ "
 177
 178 ;;; Code:
 179
 180
 181
 182 \(provide '"
 183        (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
 184        ")
 185 ;;; " (file-name-nondirectory (buffer-file-name)) " ends here\n"))
 186   "A list specifying text to insert by default into a new file.
 187 Elements look like (CONDITION . ACTION) or ((CONDITION . DESCRIPTION) . ACTION).
 188 CONDITION maybe a regexp that must match the new file's name, or it may be
 189 a symbol that must match the major mode for this element to apply.
 190 Only the first matching element is effective.
 191 Optional DESCRIPTION is a string for filling `auto-insert-prompt'.
 192 ACTION may be a skeleton to insert (see `skeleton-insert'), an absolute
 193 file-name or one relative to `auto-insert-directory' or a function to call.
 194 ACTION may also be a vector containing several successive single actions as
 195 described above, e.g. [\"header.insert\" date-and-author-update]."
 196   :type 'sexp
 197   :group 'auto-insert)
 198
 199
 200 ;; Establish a default value for auto-insert-directory
 201 (defcustom auto-insert-directory "~/insert/"
 202   "*Directory from which auto-inserted files are taken.
 203 The value must be an absolute directory name;
 204 thus, on a GNU or Unix system, it must end in a slash."
 205   :type 'directory
 206   :group 'auto-insert)
 207
 208
 209 ;;;###autoload
 210 (defun auto-insert ()
 211   "Insert default contents into new files if variable `auto-insert' is non-nil.
 212 Matches the visited file name against the elements of `auto-insert-alist'."
 213   (interactive)
 214   (and (not buffer-read-only)
 215        (or (eq this-command 'auto-insert)
 216            (and auto-insert
 217                 (bobp) (eobp)))
 218        (let ((alist auto-insert-alist)
 219              case-fold-search cond desc action)
 220          (goto-char 1)
 221          ;; find first matching alist entry
 222          (while alist
 223            (if (atom (setq cond (car (car alist))))
 224                (setq desc cond)
 225              (setq desc (cdr cond)
 226                    cond (car cond)))
 227            (if (if (symbolp cond)
 228                    (eq cond major-mode)
 229                  (and buffer-file-name
 230                       (string-match cond buffer-file-name)))
 231                (setq action (cdr (car alist))
 232                      alist nil)
 233              (setq alist (cdr alist))))
 234
 235          ;; Now, if we found something, do it
 236          (and action
 237               (if (stringp action)
 238                   (file-readable-p (concat auto-insert-directory action))
 239                 t)
 240               (if auto-insert-query
 241                   (or (if (eq auto-insert-query 'function)
 242                           (eq this-command 'auto-insert))
 243                       (y-or-n-p (format auto-insert-prompt desc)))
 244                 t)
 245               (mapcar
 246                (lambda (action)
 247                  (if (stringp action)
 248                      (if (file-readable-p
 249                           (setq action (concat auto-insert-directory action)))
 250                          (insert-file-contents action))
 251                    (save-window-excursion
 252                      ;; make buffer visible before skeleton or function
 253                      ;; which might ask the user for something
 254                      (switch-to-buffer (current-buffer))
 255                      (if (and (consp action)
 256                               (not (eq (car action) 'lambda)))
 257                          (skeleton-insert action)
 258                        (funcall action)))))
 259                (if (vectorp action)
 260                    action
 261                  (vector action))))
 262          (and (buffer-modified-p)
 263               (not (eq this-command 'auto-insert))
 264               (set-buffer-modified-p (eq auto-insert t)))))
 265   ;; Return nil so that it could be used in
 266   ;; `find-file-not-found-hooks', though that's probably inadvisable.
 267   nil)
 268
 269
 270 ;;;###autoload
 271 (defun define-auto-insert (condition action &optional after)
 272   "Associate CONDITION with (additional) ACTION in `auto-insert-alist'.
 273 Optional AFTER means to insert action after all existing actions for CONDITION,
 274 or if CONDITION had no actions, after all other CONDITIONs."
 275   (let ((elt (assoc condition auto-insert-alist)))
 276     (if elt
 277         (setcdr elt
 278                 (if (vectorp (cdr elt))
 279                     (vconcat (if after (cdr elt))
 280                              (if (vectorp action) action (vector action))
 281                              (if after () (cdr elt)))
 282                   (if after
 283                       (vector (cdr elt) action)
 284                     (vector action (cdr elt)))))
 285       (if after
 286           (nconc auto-insert-alist (list (cons condition action)))
 287         (setq auto-insert-alist (cons (cons condition action)
 288                                       auto-insert-alist))))))
 289
 290 ;;;###autoload
 291 (define-minor-mode auto-insert-mode
 292   "Toggle Auto-insert mode.
 293 With prefix ARG, turn Auto-insert mode on if and only if ARG is positive.
 294 Returns the new status of Auto-insert mode (non-nil means on).
 295
 296 When Auto-insert mode is enabled, when new files are created you can
 297 insert a template for the file depending on the mode of the buffer."
 298   :global t :group 'auto-insert
 299   (if auto-insert-mode
 300       (add-hook 'find-file-hooks 'auto-insert)
 301     (remove-hook 'find-file-hooks 'auto-insert)))
 302
 303 (provide 'autoinsert)
 304
 305 ;;; autoinsert.el ends here