lisp/url/url.el

   1 ;;; url.el --- Uniform Resource Locator retrieval tool
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2001, 2004,
   4 ;;   2005, 2006  Free Software Foundation, Inc.
   5
   6 ;; Author: Bill Perry <wmperry@gnu.org>
   7 ;; Keywords: comm, data, processes, hypermedia
   8
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Registered URI schemes: http://www.iana.org/assignments/uri-schemes
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (eval-when-compile
  35   (require 'mm-decode)
  36   (require 'mm-view))
  37
  38 (require 'mailcap)
  39 (require 'url-vars)
  40 (require 'url-cookie)
  41 (require 'url-history)
  42 (require 'url-expand)
  43 (require 'url-privacy)
  44 (require 'url-methods)
  45 (require 'url-proxy)
  46 (require 'url-parse)
  47 (require 'url-util)
  48
  49 ;; Fixme: customize? convert-standard-filename?
  50 (defvar url-configuration-directory
  51   (cond
  52    ((file-directory-p "~/.url") "~/.url")
  53    ((file-directory-p "~/.emacs.d") "~/.emacs.d/url")
  54    (t "~/.url")))
  55
  56 (defun url-do-setup ()
  57   "Setup the url package.
  58 This is to avoid conflict with user settings if URL is dumped with
  59 Emacs."
  60   (unless url-setup-done
  61
  62     ;; Make OS/2 happy
  63     ;;(push '("http" "80") tcp-binary-process-input-services)
  64
  65     (mailcap-parse-mailcaps)
  66     (mailcap-parse-mimetypes)
  67
  68     ;; Register all the authentication schemes we can handle
  69     (url-register-auth-scheme "basic" nil 4)
  70     (url-register-auth-scheme "digest" nil 7)
  71
  72     (setq url-cookie-file
  73           (or url-cookie-file
  74               (expand-file-name "cookies" url-configuration-directory)))
  75
  76     (setq url-history-file
  77           (or url-history-file
  78               (expand-file-name "history" url-configuration-directory)))
  79
  80     ;; Parse the global history file if it exists, so that it can be used
  81     ;; for URL completion, etc.
  82     (url-history-parse-history)
  83     (url-history-setup-save-timer)
  84
  85     ;; Ditto for cookies
  86     (url-cookie-setup-save-timer)
  87     (url-cookie-parse-file url-cookie-file)
  88
  89     ;; Read in proxy gateways
  90     (let ((noproxy (and (not (assoc "no_proxy" url-proxy-services))
  91                         (or (getenv "NO_PROXY")
  92                             (getenv "no_PROXY")
  93                             (getenv "no_proxy")))))
  94       (if noproxy
  95           (setq url-proxy-services
  96                 (cons (cons "no_proxy"
  97                             (concat "\\("
  98                                     (mapconcat
  99                                      (lambda (x)
 100                                        (cond
 101                                         ((= x ?,) "\\|")
 102                                         ((= x ? ) "")
 103                                         ((= x ?.) (regexp-quote "."))
 104                                         ((= x ?*) ".*")
 105                                         ((= x ??) ".")
 106                                         (t (char-to-string x))))
 107                                      noproxy "") "\\)"))
 108                       url-proxy-services))))
 109
 110     (url-setup-privacy-info)
 111     (run-hooks 'url-load-hook)
 112     (setq url-setup-done t)))
 113
 114 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 115 ;;; Retrieval functions
 116 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 117 ;;;###autoload
 118 (defun url-retrieve (url callback &optional cbargs)
 119   "Retrieve URL asynchronously and call CALLBACK with CBARGS when finished.
 120 URL is either a string or a parsed URL.
 121
 122 CALLBACK is called when the object has been completely retrieved, with
 123 the current buffer containing the object, and any MIME headers associated
 124 with it.  Normally it gets the arguments in the list CBARGS.
 125 However, if what we find is a redirect, CALLBACK is given
 126 two additional args, `:redirect' and the redirected URL,
 127 followed by CBARGS.
 128
 129 Return the buffer URL will load into, or nil if the process has
 130 already completed."
 131   (url-do-setup)
 132   (url-gc-dead-buffers)
 133   (if (stringp url)
 134        (set-text-properties 0 (length url) nil url))
 135   (if (not (vectorp url))
 136       (setq url (url-generic-parse-url url)))
 137   (if (not (functionp callback))
 138       (error "Must provide a callback function to url-retrieve"))
 139   (unless (url-type url)
 140     (error "Bad url: %s" (url-recreate-url url)))
 141   (let ((loader (url-scheme-get-property (url-type url) 'loader))
 142         (url-using-proxy (if (url-host url)
 143                              (url-find-proxy-for-url url (url-host url))))
 144         (buffer nil)
 145         (asynch (url-scheme-get-property (url-type url) 'asynchronous-p)))
 146     (if url-using-proxy
 147         (setq asynch t
 148               loader 'url-proxy))
 149     (if asynch
 150         (setq buffer (funcall loader url callback cbargs))
 151       (setq buffer (funcall loader url))
 152       (if buffer
 153           (with-current-buffer buffer
 154             (apply callback cbargs))))
 155     (if url-history-track
 156         (url-history-update-url url (current-time)))
 157     buffer))
 158
 159 ;;;###autoload
 160 (defun url-retrieve-synchronously (url)
 161   "Retrieve URL synchronously.
 162 Return the buffer containing the data, or nil if there are no data
 163 associated with it (the case for dired, info, or mailto URLs that need
 164 no further processing).  URL is either a string or a parsed URL."
 165   (url-do-setup)
 166
 167   (lexical-let ((retrieval-done nil)
 168                 (asynch-buffer nil))
 169     (setq asynch-buffer
 170           (url-retrieve url (lambda (&rest ignored)
 171                               (url-debug 'retrieval "Synchronous fetching done (%S)" (current-buffer))
 172                               (setq retrieval-done t
 173                                     asynch-buffer (current-buffer)))))
 174     (if (null asynch-buffer)
 175         ;; We do not need to do anything, it was a mailto or something
 176         ;; similar that takes processing completely outside of the URL
 177         ;; package.
 178         nil
 179       (let ((proc (get-buffer-process asynch-buffer)))
 180         ;; If the access method was synchronous, `retrieval-done' should
 181         ;; hopefully already be set to t.  If it is nil, and `proc' is also
 182         ;; nil, it implies that the async process is not running in
 183         ;; asynch-buffer.  This happens e.g. for FTP files.  In such a case
 184         ;; url-file.el should probably set something like a `url-process'
 185         ;; buffer-local variable so we can find the exact process that we
 186         ;; should be waiting for.  In the mean time, we'll just wait for any
 187         ;; process output.
 188         (while (not retrieval-done)
 189           (url-debug 'retrieval
 190                      "Spinning in url-retrieve-synchronously: %S (%S)"
 191                      retrieval-done asynch-buffer)
 192           (if (and proc (memq (process-status proc)
 193                               '(closed exit signal failed)))
 194               ;; FIXME: It's not clear whether url-retrieve's callback is
 195               ;; guaranteed to be called or not.  It seems that url-http
 196               ;; decides sometimes consciously not to call it, so it's not
 197               ;; clear that it's a bug, but even if we need to decide how
 198               ;; url-http can then warn us that the download has completed.
 199               ;; In the mean time, we use this here workaround.
 200               (setq retrieval-done t)
 201             ;; We used to use `sit-for' here, but in some cases it wouldn't
 202             ;; work because apparently pending keyboard input would always
 203             ;; interrupt it before it got a chance to handle process input.
 204             ;; `sleep-for' was tried but it lead to other forms of
 205             ;; hanging.  --Stef
 206             (unless (or (accept-process-output proc) (null proc))
 207               ;; accept-process-output returned nil, maybe because the process
 208               ;; exited (and may have been replaced with another).
 209               (setq proc (get-buffer-process asynch-buffer))))))
 210       asynch-buffer)))
 211
 212 (defun url-mm-callback (&rest ignored)
 213   (let ((handle (mm-dissect-buffer t)))
 214     (url-mark-buffer-as-dead (current-buffer))
 215     (with-current-buffer
 216         (generate-new-buffer (url-recreate-url url-current-object))
 217       (if (eq (mm-display-part handle) 'external)
 218           (progn
 219             (set-process-sentinel
 220              ;; Fixme: this shouldn't have to know the form of the
 221              ;; undisplayer produced by `mm-display-part'.
 222              (get-buffer-process (cdr (mm-handle-undisplayer handle)))
 223              `(lambda (proc event)
 224                 (mm-destroy-parts (quote ,handle))))
 225             (message "Viewing externally")
 226             (kill-buffer (current-buffer)))
 227         (display-buffer (current-buffer))
 228         (add-hook 'kill-buffer-hook
 229                   `(lambda () (mm-destroy-parts ',handle))
 230                   nil
 231                   t)))))
 232
 233 (defun url-mm-url (url)
 234   "Retrieve URL and pass to the appropriate viewing application."
 235   ;; These requires could advantageously be moved to url-mm-callback or
 236   ;; turned into autoloads, but I suspect that it would introduce some bugs
 237   ;; because loading those files from a process sentinel or filter may
 238   ;; result in some undesirable carner cases.
 239   (require 'mm-decode)
 240   (require 'mm-view)
 241   (url-retrieve url 'url-mm-callback nil))
 242
 243 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 244 ;;; Miscellaneous
 245 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 246 (defvar url-dead-buffer-list nil)
 247
 248 (defun url-mark-buffer-as-dead (buff)
 249   (push buff url-dead-buffer-list))
 250
 251 (defun url-gc-dead-buffers ()
 252   (let ((buff))
 253     (while (setq buff (pop url-dead-buffer-list))
 254       (if (buffer-live-p buff)
 255           (kill-buffer buff)))))
 256
 257 (cond
 258  ((fboundp 'display-warning)
 259   (defalias 'url-warn 'display-warning))
 260  ((fboundp 'warn)
 261   (defun url-warn (class message &optional level)
 262     (warn "(%s/%s) %s" class (or level 'warning) message)))
 263  (t
 264   (defun url-warn (class message &optional level)
 265     (with-current-buffer (get-buffer-create "*URL-WARNINGS*")
 266       (goto-char (point-max))
 267       (save-excursion
 268         (insert (format "(%s/%s) %s\n" class (or level 'warning) message)))
 269       (display-buffer (current-buffer))))))
 270
 271 (provide 'url)
 272
 273 ;; arch-tag: bc182f1f-d187-4f10-b961-47af2066579a
 274 ;;; url.el ends here