lisp/face-remap.el

   1 ;;; face-remap.el --- Functions for managing `face-remapping-alist'
   2 ;;
   3 ;; Copyright (C) 2008, 2009 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Miles Bader <miles@gnu.org>
   6 ;; Keywords: faces face remapping display user commands
   7 ;;
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14 ;;
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22 ;;
  23
  24 ;;; Commentary:
  25
  26 ;;
  27 ;; This file defines some simple operations that can be used for
  28 ;; maintaining the `face-remapping-alist' in a cooperative way.  This is
  29 ;; especially important for the `default' face.
  30 ;;
  31 ;; Each face-remapping definition in `face-remapping-alist' added by
  32 ;; this code uses the form:
  33 ;;
  34 ;;   (face RELATIVE_SPECS_1 RELATIVE_SPECS_2 ... BASE_SPECS)
  35 ;;
  36 ;; The "specs" values are a lists of face names or face attribute-value
  37 ;; pairs, and are merged together, with earlier values taking precedence.
  38 ;;
  39 ;; The RELATIVE_SPECS_* values are added by `face-remap-add-relative'
  40 ;; (and removed by `face-remap-remove-relative', and are intended for
  41 ;; face "modifications" (such as increasing the size).  Typical users of
  42 ;; relative specs would be minor modes.
  43 ;;
  44 ;; BASE_SPECS is the lowest-priority value, and by default is just the
  45 ;; face name, which causes the global definition of that face to be used.
  46 ;;
  47 ;; A non-default value of BASE_SPECS may also be set using
  48 ;; `face-remap-set-base'.  Because this _overwrites_ the default
  49 ;; value inheriting from the global face definition, it is up to the
  50 ;; caller of face-remap-set-base to add such inheritance if it is
  51 ;; desired.  A typical use of face-remap-set-base would be a major
  52 ;; mode setting face remappings, e.g., of the default face.
  53 ;;
  54 ;; All modifications cause face-remapping-alist to be made buffer-local.
  55 ;;
  56
  57
  58 ;;; Code:
  59
  60 \f
  61 ;; ----------------------------------------------------------------
  62 ;; Utility functions
  63
  64 ;; Names of face attributes corresponding to lisp face-vector positions.
  65 ;; This variable should probably be defined in C code where the actual
  66 ;; definitions are available.
  67 ;;
  68 (defvar internal-lisp-face-attributes
  69   [nil
  70    :family :foundry :swidth :height :weight :slant :underline :inverse
  71    :foreground :background :stipple :overline :strike :box
  72    :font :inherit :fontset :vector])
  73
  74 (defun face-attrs-more-relative-p (attrs1 attrs2)
  75 "Return true if ATTRS1 contains a greater number of relative
  76 face-attributes than ATTRS2.  A face attribute is considered
  77 relative if `face-attribute-relative-p' returns non-nil.
  78
  79 ATTRS1 and ATTRS2 may be any value suitable for a `face' text
  80 property, including face names, lists of face names,
  81 face-attribute plists, etc.
  82
  83 This function can be used as a predicate with `sort', to sort
  84 face lists so that more specific faces are located near the end."
  85   (unless (vectorp attrs1)
  86     (setq attrs1 (face-attributes-as-vector attrs1)))
  87   (unless (vectorp attrs2)
  88     (setq attrs2 (face-attributes-as-vector attrs2)))
  89   (let ((rel1-count 0) (rel2-count 0))
  90     (dotimes (i (length attrs1))
  91       (let ((attr (aref internal-lisp-face-attributes i)))
  92         (when attr
  93           (when (face-attribute-relative-p attr (aref attrs1 i))
  94             (setq rel1-count (+ rel1-count 1)))
  95           (when (face-attribute-relative-p attr (aref attrs2 i))
  96             (setq rel2-count (+ rel2-count 1))))))
  97     (< rel1-count rel2-count)))
  98
  99 (defun face-remap-order (entry)
 100   "Order ENTRY so that more relative face specs are near the beginning.
 101 The list structure of ENTRY may be destructively modified."
 102   (setq entry (nreverse entry))
 103   (setcdr entry (sort (cdr entry) 'face-attrs-more-relative-p))
 104   (nreverse entry))
 105
 106 ;;;###autoload
 107 (defun face-remap-add-relative (face &rest specs)
 108   "Add a face remapping entry of FACE to SPECS in the current buffer.
 109
 110 Return a cookie which can be used to delete the remapping with
 111 `face-remap-remove-relative'.
 112
 113 SPECS can be any value suitable for the `face' text property,
 114 including a face name, a list of face names, or a face-attribute
 115 property list.  The attributes given by SPECS will be merged with
 116 any other currently active face remappings of FACE, and with the
 117 global definition of FACE.  An attempt is made to sort multiple
 118 entries so that entries with relative face-attributes are applied
 119 after entries with absolute face-attributes.
 120
 121 The base (lowest priority) remapping may be set to a specific
 122 value, instead of the default of the global face definition,
 123 using `face-remap-set-base'."
 124   (while (and (consp specs) (null (cdr specs)))
 125     (setq specs (car specs)))
 126   (make-local-variable 'face-remapping-alist)
 127   (let ((entry (assq face face-remapping-alist)))
 128     (when (null entry)
 129       (setq entry (list face face))     ; explicitly merge with global def
 130       (push entry face-remapping-alist))
 131     (setcdr entry (face-remap-order (cons specs (cdr entry))))
 132     (cons face specs)))
 133
 134 (defun face-remap-remove-relative (cookie)
 135   "Remove a face remapping previously added by `face-remap-add-relative'.
 136 COOKIE should be the return value from that function."
 137   (let ((remapping (assq (car cookie) face-remapping-alist)))
 138     (when remapping
 139       (let ((updated-entries (remq (cdr cookie) (cdr remapping))))
 140         (unless (eq updated-entries (cdr remapping))
 141           (setcdr remapping updated-entries)
 142           (when (or (null updated-entries)
 143                     (and (eq (car-safe updated-entries) (car cookie))
 144                          (null (cdr updated-entries))))
 145             (setq face-remapping-alist
 146                   (remq remapping face-remapping-alist)))
 147           (cdr cookie))))))
 148
 149 ;;;###autoload
 150 (defun face-remap-reset-base (face)
 151   "Set the base remapping of FACE to inherit from FACE's global definition."
 152   (let ((entry (assq face face-remapping-alist)))
 153     (when entry
 154       ;; If there's nothing except a base remapping, we simply remove
 155       ;; the entire remapping entry, as setting the base to the default
 156       ;; would be the same as the global definition.  Otherwise, we
 157       ;; modify the base remapping.
 158       (if (null (cddr entry))           ; nothing except base remapping
 159           (setq face-remapping-alist    ; so remove entire entry
 160                 (remq entry face-remapping-alist))
 161         (setcar (last entry) face)))))  ; otherwise, just inherit global def
 162
 163 ;;;###autoload
 164 (defun face-remap-set-base (face &rest specs)
 165   "Set the base remapping of FACE in the current buffer to SPECS.
 166 If SPECS is empty, the default base remapping is restored, which
 167 inherits from the global definition of FACE; note that this is
 168 different from SPECS containing a single value `nil', which does
 169 not inherit from the global definition of FACE."
 170   (while (and (consp specs) (not (null (car specs))) (null (cdr specs)))
 171     (setq specs (car specs)))
 172   (if (or (null specs)
 173           (and (eq (car specs) face) (null (cdr specs)))) ; default
 174       ;; Set entry back to default
 175       (face-remap-reset-base face)
 176     ;; Set the base remapping
 177     (make-local-variable 'face-remapping-alist)
 178     (let ((entry (assq face face-remapping-alist)))
 179       (if entry
 180           (setcar (last entry) specs)   ; overwrite existing base entry
 181         (push (list face specs) face-remapping-alist)))))
 182
 183 \f
 184 ;; ----------------------------------------------------------------
 185 ;; text-scale-mode
 186
 187 (defcustom text-scale-mode-step 1.2
 188   "Scale factor used by `text-scale-mode'.
 189 Each positive or negative step scales the default face height by this amount."
 190   :group 'display
 191   :type 'number
 192   :version "23.1")
 193
 194 ;; current remapping cookie for text-scale-mode
 195 (defvar text-scale-mode-remapping nil)
 196 (make-variable-buffer-local 'text-scale-mode-remapping)
 197
 198 ;; Lighter displayed for text-scale-mode in mode-line minor-mode list
 199 (defvar text-scale-mode-lighter "+0")
 200 (make-variable-buffer-local 'text-scale-mode-lighter)
 201
 202 ;; Number of steps that text-scale-mode will increase/decrease text height
 203 (defvar text-scale-mode-amount 0)
 204 (make-variable-buffer-local 'text-scale-mode-amount)
 205
 206 (define-minor-mode text-scale-mode
 207   "Minor mode for displaying buffer text in a larger/smaller font than usual.
 208
 209 The amount of scaling is determined by the variable
 210 `text-scale-mode-amount': one step scales the global default
 211 face size by the value of the variable `text-scale-mode-step'
 212 \(a negative amount shrinks the text).
 213
 214 The `text-scale-increase' and `text-scale-decrease' functions may
 215 be used to interactively modify the variable
 216 `text-scale-mode-amount' (they also enable or disable
 217 `text-scale-mode' as necessary)."
 218   :lighter (" " text-scale-mode-lighter)
 219   (when text-scale-mode-remapping
 220     (face-remap-remove-relative text-scale-mode-remapping))
 221   (setq text-scale-mode-lighter
 222         (format (if (>= text-scale-mode-amount 0) "+%d" "%d")
 223                 text-scale-mode-amount))
 224   (setq text-scale-mode-remapping
 225         (and text-scale-mode
 226              (face-remap-add-relative 'default
 227                                           :height
 228                                           (expt text-scale-mode-step
 229                                                 text-scale-mode-amount))))
 230   (force-window-update (current-buffer)))
 231
 232 ;;;###autoload
 233 (defun text-scale-increase (inc)
 234   "Increase the height of the default face in the current buffer by INC steps.
 235 If the new height is other than the default, `text-scale-mode' is enabled.
 236
 237 Each step scales the height of the default face by the variable
 238 `text-scale-mode-step' (a negative number of steps decreases the
 239 height by the same amount).  As a special case, an argument of 0
 240 will remove any scaling currently active."
 241   (interactive "p")
 242   (setq text-scale-mode-amount
 243         (if (= inc 0) 0 (+ (if text-scale-mode text-scale-mode-amount 0) inc)))
 244   (text-scale-mode (if (zerop text-scale-mode-amount) -1 1)))
 245
 246 ;;;###autoload
 247 (defun text-scale-decrease (dec)
 248   "Decrease the height of the default face in the current buffer by DEC steps.
 249 See `text-scale-increase' for more details."
 250   (interactive "p")
 251   (text-scale-increase (- dec)))
 252
 253 ;;;###autoload (define-key ctl-x-map [(control ?+)] 'text-scale-adjust)
 254 ;;;###autoload (define-key ctl-x-map [(control ?-)] 'text-scale-adjust)
 255 ;;;###autoload (define-key ctl-x-map [(control ?=)] 'text-scale-adjust)
 256 ;;;###autoload (define-key ctl-x-map [(control ?0)] 'text-scale-adjust)
 257 ;;;###autoload
 258 (defun text-scale-adjust (inc)
 259   "Increase or decrease the height of the default face in the current buffer.
 260
 261 The actual adjustment made depends on the final component of the
 262 key-binding used to invoke the command, with all modifiers removed:
 263
 264    +, =   Increase the default face height by one step
 265    -      Decrease the default face height by one step
 266    0      Reset the default face height to the global default
 267
 268 Then, continue to read input events and further adjust the face
 269 height as long as the input event read (with all modifiers removed)
 270 is one of the above.
 271
 272 Each step scales the height of the default face by the variable
 273 `text-scale-mode-step' (a negative number of steps decreases the
 274 height by the same amount).  As a special case, an argument of 0
 275 will remove any scaling currently active.
 276
 277 This command is a special-purpose wrapper around the
 278 `text-scale-increase' command which makes repetition convenient
 279 even when it is bound in a non-top-level keymap.  For binding in
 280 a top-level keymap, `text-scale-increase' or
 281 `text-scale-decrease' may be more appropriate."
 282   (interactive "p")
 283   (let ((first t)
 284         (step t)
 285         (ev last-command-event)
 286         (echo-keystrokes nil))
 287     (while step
 288       (let ((base (event-basic-type ev)))
 289         (cond ((or (eq base ?+) (eq base ?=))
 290                (setq step inc))
 291               ((eq base ?-)
 292                (setq step (- inc)))
 293               ((eq base ?0)
 294                (setq step 0))
 295               (first
 296                (setq step inc))
 297               (t
 298                (setq step nil))))
 299       (when step
 300         (text-scale-increase step)
 301         (setq inc 1 first nil)
 302         (setq ev (read-event))))
 303     (push ev unread-command-events)))
 304
 305 \f
 306 ;; ----------------------------------------------------------------
 307 ;; buffer-face-mode
 308
 309 (defcustom buffer-face-mode-face 'variable-pitch
 310   "The face specification used by `buffer-face-mode'.
 311 It may contain any value suitable for a `face' text property,
 312 including a face name, a list of face names, a face-attribute
 313 plist, etc."
 314   :group 'display
 315   :version "23.1")
 316
 317 ;; current remapping cookie for  buffer-face-mode
 318 (defvar buffer-face-mode-remapping nil)
 319 (make-variable-buffer-local 'buffer-face-mode-remapping)
 320
 321 ;;;###autoload
 322 (define-minor-mode buffer-face-mode
 323   "Minor mode for a buffer-specific default face.
 324 When enabled, the face specified by the variable
 325 `buffer-face-mode-face' is used to display the buffer text."
 326   :lighter " BufFace"
 327   (when buffer-face-mode-remapping
 328     (face-remap-remove-relative buffer-face-mode-remapping))
 329   (setq buffer-face-mode-remapping
 330         (and buffer-face-mode
 331              (face-remap-add-relative 'default buffer-face-mode-face)))
 332   (force-window-update (current-buffer)))
 333
 334 ;;;###autoload
 335 (defun buffer-face-set (&rest specs)
 336   "Enable `buffer-face-mode', using face specs SPECS.
 337 SPECS can be any value suitable for the `face' text property,
 338 including a face name, a list of face names, or a face-attribute
 339 If SPECS is nil, then `buffer-face-mode' is disabled.
 340
 341 This function will make the variable `buffer-face-mode-face'
 342 buffer local, and set it to FACE."
 343   (interactive (list (read-face-name "Set buffer face")))
 344   (while (and (consp specs) (null (cdr specs)))
 345     (setq specs (car specs)))
 346   (if (null specs)
 347       (buffer-face-mode 0)
 348     (set (make-local-variable 'buffer-face-mode-face) specs)
 349     (buffer-face-mode t)))
 350
 351 ;;;###autoload
 352 (defun buffer-face-toggle (&rest specs)
 353   "Toggle `buffer-face-mode', using face specs SPECS.
 354 SPECS can be any value suitable for the `face' text property,
 355 including a face name, a list of face names, or a face-attribute
 356
 357 If `buffer-face-mode' is already enabled, and is currently using
 358 the face specs SPECS, then it is disabled; if buffer-face-mode is
 359 disabled, or is enabled and currently displaying some other face,
 360 then is left enabled, but the face changed to reflect SPECS.
 361
 362 This function will make the variable `buffer-face-mode-face'
 363 buffer local, and set it to SPECS."
 364   (interactive (list buffer-face-mode-face))
 365   (while (and (consp specs) (null (cdr specs)))
 366     (setq specs (car specs)))
 367   (if (or (null specs)
 368           (and buffer-face-mode (equal buffer-face-mode-face specs)))
 369       (buffer-face-mode 0)
 370     (set (make-local-variable 'buffer-face-mode-face) specs)
 371     (buffer-face-mode t)))
 372
 373 (defun buffer-face-mode-invoke (specs arg &optional interactive)
 374   "Enable or disable `buffer-face-mode' using face specs SPECS, and argument ARG.
 375 ARG controls whether the mode is enabled or disabled, and is
 376 interpreted in the usual manner for minor-mode commands.
 377
 378 SPECS can be any value suitable for the `face' text property,
 379 including a face name, a list of face names, or a face-attribute
 380
 381 If INTERACTIVE is non-nil, a message will be displayed describing the result.
 382
 383 This is a wrapper function which calls `buffer-face-set' or
 384 `buffer-face-toggle' (depending on ARG), and prints a status
 385 message in the echo area.  In many cases one of those functions
 386 may be more appropriate."
 387   (let ((last-message (current-message)))
 388     (if (or (eq arg 'toggle) (not arg))
 389         (buffer-face-toggle specs)
 390       (buffer-face-set (and (> (prefix-numeric-value arg) 0) specs)))
 391     (when interactive
 392       (unless (and (current-message)
 393                    (not (equal last-message (current-message))))
 394         (message "Buffer-Face mode %sabled"
 395                  (if buffer-face-mode "en" "dis"))))))
 396
 397 \f
 398 ;; ----------------------------------------------------------------
 399 ;; variable-pitch-mode
 400
 401 ;;;###autoload
 402 (defun variable-pitch-mode (&optional arg)
 403   "Variable-pitch default-face mode.
 404 An interface to `buffer-face-mode' which uses the `variable-pitch' face.
 405 Besides the choice of face, it is the same as `buffer-face-mode'."
 406   (interactive (list (or current-prefix-arg 'toggle)))
 407   (buffer-face-mode-invoke 'variable-pitch arg (interactive-p)))
 408
 409
 410 (provide 'face-remap)
 411
 412 ;; arch-tag: 5c5f034b-8d58-4967-82bd-d61fd364e686
 413 ;;; face-remap.el ends here