lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer
   2
   3 ;; Copyright (C) 1986, 1987, 1994, 1995, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Howie Kaye
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package provides the sorting facilities documented in the Emacs
  29 ;; user's manual.
  30
  31 ;;; Code:
  32
  33 (defgroup sort nil
  34   "Commands to sort text in an Emacs buffer."
  35   :group 'data)
  36
  37 (defcustom sort-fold-case nil
  38   "*Non-nil if the buffer sort functions should ignore case."
  39   :group 'sort
  40   :type 'boolean)
  41
  42 ;;;###autoload
  43 (defun sort-subr (reverse nextrecfun endrecfun &optional startkeyfun endkeyfun)
  44   "General text sorting routine to divide buffer into records and sort them.
  45
  46 We divide the accessible portion of the buffer into disjoint pieces
  47 called sort records.  A portion of each sort record (perhaps all of
  48 it) is designated as the sort key.  The records are rearranged in the
  49 buffer in order by their sort keys.  The records may or may not be
  50 contiguous.
  51
  52 Usually the records are rearranged in order of ascending sort key.
  53 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  54 The variable `sort-fold-case' determines whether alphabetic case affects
  55 the sort order.
  56
  57 The next four arguments are functions to be called to move point
  58 across a sort record.  They will be called many times from within sort-subr.
  59
  60 NEXTRECFUN is called with point at the end of the previous record.
  61 It moves point to the start of the next record.
  62 It should move point to the end of the buffer if there are no more records.
  63 The first record is assumed to start at the position of point when sort-subr
  64 is called.
  65
  66 ENDRECFUN is called with point within the record.
  67 It should move point to the end of the record.
  68
  69 STARTKEYFUN moves from the start of the record to the start of the key.
  70 It may return either a non-nil value to be used as the key, or
  71 else the key is the substring between the values of point after
  72 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  73 starts at the beginning of the record.
  74
  75 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  76 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  77 same as ENDRECFUN."
  78   ;; Heuristically try to avoid messages if sorting a small amt of text.
  79   (let ((messages (> (- (point-max) (point-min)) 50000)))
  80     (save-excursion
  81       (if messages (message "Finding sort keys..."))
  82       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  83                                            startkeyfun endkeyfun))
  84              (old (reverse sort-lists))
  85              (case-fold-search sort-fold-case))
  86         (if (null sort-lists)
  87             ()
  88           (or reverse (setq sort-lists (nreverse sort-lists)))
  89           (if messages (message "Sorting records..."))
  90           (setq sort-lists
  91                 (if (fboundp 'sortcar)
  92                     (sortcar sort-lists
  93                              (cond ((numberp (car (car sort-lists)))
  94                                     ;; This handles both ints and floats.
  95                                     '<)
  96                                    ((consp (car (car sort-lists)))
  97                                     (function
  98                                      (lambda (a b)
  99                                        (> 0 (compare-buffer-substrings
 100                                              nil (car a) (cdr a)
 101                                              nil (car b) (cdr b))))))
 102                                    (t
 103                                     'string<)))
 104                   (sort sort-lists
 105                         (cond ((numberp (car (car sort-lists)))
 106                                'car-less-than-car)
 107                               ((consp (car (car sort-lists)))
 108                                (function
 109                                 (lambda (a b)
 110                                   (> 0 (compare-buffer-substrings
 111                                         nil (car (car a)) (cdr (car a))
 112                                         nil (car (car b)) (cdr (car b)))))))
 113                               (t
 114                                (function
 115                                 (lambda (a b)
 116                                   (string< (car a) (car b)))))))))
 117           (if reverse (setq sort-lists (nreverse sort-lists)))
 118           (if messages (message "Reordering buffer..."))
 119           (sort-reorder-buffer sort-lists old)))
 120       (if messages (message "Reordering buffer... Done"))))
 121   nil)
 122
 123 ;; Parse buffer into records using the arguments as Lisp expressions;
 124 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
 125 ;; where KEY is the sort key (a number or string),
 126 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
 127
 128 ;; The records appear in the list lastmost first!
 129
 130 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 131   (let ((sort-lists ())
 132         (start-rec nil)
 133         done key)
 134     ;; Loop over sort records.
 135     ;(goto-char (point-min)) -- it is the caller's responsibility to
 136     ;arrange this if necessary
 137     (while (not (eobp))
 138       (setq start-rec (point))          ;save record start
 139       (setq done nil)
 140       ;; Get key value, or move to start of key.
 141       (setq key (catch 'key
 142                   (or (and startkeyfun (funcall startkeyfun))
 143                       ;; If key was not returned as value,
 144                       ;; move to end of key and get key from the buffer.
 145                       (let ((start (point)))
 146                         (funcall (or endkeyfun
 147                                      (prog1 endrecfun (setq done t))))
 148                         (cons start (point))))))
 149       ;; Move to end of this record (start of next one, or end of buffer).
 150       (cond ((prog1 done (setq done nil)))
 151             (endrecfun (funcall endrecfun))
 152             (nextrecfun (funcall nextrecfun) (setq done t)))
 153       (if key (setq sort-lists (cons
 154                                  ;; consing optimization in case in which key
 155                                  ;; is same as record.
 156                                  (if (and (consp key)
 157                                           (equal (car key) start-rec)
 158                                           (equal (cdr key) (point)))
 159                                      (cons key key)
 160                                    (cons key (cons start-rec (point))))
 161                                  sort-lists)))
 162       (and (not done) nextrecfun (funcall nextrecfun)))
 163     sort-lists))
 164
 165 (defun sort-reorder-buffer (sort-lists old)
 166   (let ((last (point-min))
 167         (min (point-min)) (max (point-max))
 168         (old-buffer (current-buffer))
 169         temp-buffer)
 170     (with-temp-buffer
 171       ;; Record the temporary buffer.
 172       (setq temp-buffer (current-buffer))
 173
 174       ;; Copy the sorted text into the temporary buffer.
 175       (while sort-lists
 176         (goto-char (point-max))
 177         (insert-buffer-substring old-buffer
 178                                  last
 179                                  (nth 1 (car old)))
 180         (goto-char (point-max))
 181         (insert-buffer-substring old-buffer
 182                                  (nth 1 (car sort-lists))
 183                                  (cdr (cdr (car sort-lists))))
 184         (setq last (cdr (cdr (car old)))
 185               sort-lists (cdr sort-lists)
 186               old (cdr old)))
 187       (goto-char (point-max))
 188       (insert-buffer-substring old-buffer last max)
 189
 190       ;; Copy the reordered text from the temporary buffer
 191       ;; to the buffer we sorted (OLD-BUFFER).
 192       (set-buffer old-buffer)
 193       (let ((inhibit-quit t))
 194         ;; Make sure insertions done for reordering
 195         ;; saves any markers at the end of the sorted region,
 196         ;; by leaving the last character of the region.
 197         (delete-region min (1- max))
 198         ;; Now replace the one remaining old character with the sorted text.
 199         (goto-char (point-min))
 200         (insert-buffer-substring temp-buffer)
 201         (delete-region max (1+ max))))))
 202
 203 ;;;###autoload
 204 (defun sort-lines (reverse beg end)
 205   "Sort lines in region alphabetically; argument means descending order.
 206 Called from a program, there are three arguments:
 207 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 208 The variable `sort-fold-case' determines whether alphabetic case affects
 209 the sort order."
 210   (interactive "P\nr")
 211   (save-excursion
 212     (save-restriction
 213       (narrow-to-region beg end)
 214       (goto-char (point-min))
 215       (sort-subr reverse 'forward-line 'end-of-line))))
 216
 217 ;;;###autoload
 218 (defun sort-paragraphs (reverse beg end)
 219   "Sort paragraphs in region alphabetically; argument means descending order.
 220 Called from a program, there are three arguments:
 221 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 222 The variable `sort-fold-case' determines whether alphabetic case affects
 223 the sort order."
 224   (interactive "P\nr")
 225   (save-excursion
 226     (save-restriction
 227       (narrow-to-region beg end)
 228       (goto-char (point-min))
 229       (sort-subr reverse
 230                  (function
 231                   (lambda ()
 232                     (while (and (not (eobp)) (looking-at paragraph-separate))
 233                       (forward-line 1))))
 234                  'forward-paragraph))))
 235
 236 ;;;###autoload
 237 (defun sort-pages (reverse beg end)
 238   "Sort pages in region alphabetically; argument means descending order.
 239 Called from a program, there are three arguments:
 240 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 241 The variable `sort-fold-case' determines whether alphabetic case affects
 242 the sort order."
 243   (interactive "P\nr")
 244   (save-excursion
 245     (save-restriction
 246       (narrow-to-region beg end)
 247       (goto-char (point-min))
 248       (sort-subr reverse
 249                  (function (lambda () (skip-chars-forward "\n")))
 250                  'forward-page))))
 251 \f
 252 (defvar sort-fields-syntax-table nil)
 253 (if sort-fields-syntax-table nil
 254   (let ((table (make-syntax-table))
 255         (i 0))
 256     (while (< i 256)
 257       (modify-syntax-entry i "w" table)
 258       (setq i (1+ i)))
 259     (modify-syntax-entry ?\  " " table)
 260     (modify-syntax-entry ?\t " " table)
 261     (modify-syntax-entry ?\n " " table)
 262     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 263     (setq sort-fields-syntax-table table)))
 264
 265 (defcustom sort-numeric-base 10
 266   "*The default base used by `sort-numeric-fields'."
 267   :group 'sort
 268   :type 'integer)
 269
 270 ;;;###autoload
 271 (defun sort-numeric-fields (field beg end)
 272   "Sort lines in region numerically by the ARGth field of each line.
 273 Fields are separated by whitespace and numbered from 1 up.
 274 Specified field must contain a number in each line of the region,
 275 which may begin with \"0x\" or \"0\" for hexadecimal and octal values.
 276 Otherwise, the number is interpreted according to sort-numeric-base.
 277 With a negative arg, sorts by the ARGth field counted from the right.
 278 Called from a program, there are three arguments:
 279 FIELD, BEG and END.  BEG and END specify region to sort."
 280   (interactive "p\nr")
 281   (sort-fields-1 field beg end
 282                  (lambda ()
 283                    (sort-skip-fields field)
 284                    (let* ((case-fold-search t)
 285                           (base
 286                            (if (looking-at "\\(0x\\)[0-9a-f]\\|\\(0\\)[0-7]")
 287                                (cond ((match-beginning 1)
 288                                       (goto-char (match-end 1))
 289                                       16)
 290                                      ((match-beginning 2)
 291                                       (goto-char (match-end 2))
 292                                       8)
 293                                      (t nil)))))
 294                      (string-to-number (buffer-substring (point)
 295                                                          (save-excursion
 296                                                            (forward-sexp 1)
 297                                                            (point)))
 298                                        (or base sort-numeric-base))))
 299                  nil))
 300
 301 ;;;;;###autoload
 302 ;;(defun sort-float-fields (field beg end)
 303 ;;  "Sort lines in region numerically by the ARGth field of each line.
 304 ;;Fields are separated by whitespace and numbered from 1 up.  Specified field
 305 ;;must contain a floating point number in each line of the region.  With a
 306 ;;negative arg, sorts by the ARGth field counted from the right.  Called from a
 307 ;;program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 308 ;;region to sort."
 309 ;;  (interactive "p\nr")
 310 ;;  (sort-fields-1 field beg end
 311 ;;               (function (lambda ()
 312 ;;                           (sort-skip-fields field)
 313 ;;                           (string-to-number
 314 ;;                            (buffer-substring
 315 ;;                             (point)
 316 ;;                             (save-excursion
 317 ;;                               (re-search-forward
 318 ;;                                "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 319 ;;                               (point))))))
 320 ;;               nil))
 321
 322 ;;;###autoload
 323 (defun sort-fields (field beg end)
 324   "Sort lines in region lexicographically by the ARGth field of each line.
 325 Fields are separated by whitespace and numbered from 1 up.
 326 With a negative arg, sorts by the ARGth field counted from the right.
 327 Called from a program, there are three arguments:
 328 FIELD, BEG and END.  BEG and END specify region to sort.
 329 The variable `sort-fold-case' determines whether alphabetic case affects
 330 the sort order."
 331   (interactive "p\nr")
 332   (sort-fields-1 field beg end
 333                  (function (lambda ()
 334                              (sort-skip-fields field)
 335                              nil))
 336                  (function (lambda () (skip-chars-forward "^ \t\n")))))
 337
 338 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 339   (let ((tbl (syntax-table)))
 340     (if (zerop field) (setq field 1))
 341     (unwind-protect
 342         (save-excursion
 343           (save-restriction
 344             (narrow-to-region beg end)
 345             (goto-char (point-min))
 346             (set-syntax-table sort-fields-syntax-table)
 347             (sort-subr nil
 348                        'forward-line 'end-of-line
 349                        startkeyfun endkeyfun)))
 350       (set-syntax-table tbl))))
 351
 352 ;; Position at the beginning of field N on the current line,
 353 ;; assuming point is initially at the beginning of the line.
 354 (defun sort-skip-fields (n)
 355   (if (> n 0)
 356       ;; Skip across N - 1 fields.
 357       (let ((i (1- n)))
 358         (while (> i 0)
 359           (skip-chars-forward " \t")
 360           (skip-chars-forward "^ \t\n")
 361           (setq i (1- i)))
 362         (skip-chars-forward " \t")
 363         (if (eolp)
 364             (error "Line has too few fields: %s"
 365                    (buffer-substring
 366                     (save-excursion (beginning-of-line) (point))
 367                     (save-excursion (end-of-line) (point))))))
 368     (end-of-line)
 369     ;; Skip back across - N - 1 fields.
 370     (let ((i (1- (- n))))
 371       (while (> i 0)
 372         (skip-chars-backward " \t")
 373         (skip-chars-backward "^ \t\n")
 374         (setq i (1- i)))
 375       (skip-chars-backward " \t"))
 376     (if (bolp)
 377         (error "Line has too few fields: %s"
 378                (buffer-substring
 379                 (save-excursion (beginning-of-line) (point))
 380                 (save-excursion (end-of-line) (point)))))
 381     ;; Position at the front of the field
 382     ;; even if moving backwards.
 383     (skip-chars-backward "^ \t\n")))
 384 \f
 385 (defvar sort-regexp-fields-regexp)
 386 (defvar sort-regexp-record-end)
 387
 388 ;; Move to the beginning of the next match for record-regexp,
 389 ;; and set sort-regexp-record-end to the end of that match.
 390 ;; If the next match is empty and does not advance point,
 391 ;; skip one character and try again.
 392 (defun sort-regexp-fields-next-record ()
 393   (let ((oldpos (point)))
 394     (and (re-search-forward sort-regexp-fields-regexp nil 'move)
 395          (setq sort-regexp-record-end (match-end 0))
 396          (if (= sort-regexp-record-end oldpos)
 397              (progn
 398                (forward-char 1)
 399                (re-search-forward sort-regexp-fields-regexp nil 'move)
 400                (setq sort-regexp-record-end (match-end 0)))
 401            t)
 402          (goto-char (match-beginning 0)))))
 403
 404 ;;;###autoload
 405 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 406   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
 407 RECORD-REGEXP specifies the textual units which should be sorted.
 408   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 409 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 410   is to be used for sorting.
 411   If it is \"\\\\digit\" then the digit'th \"\\\\(...\\\\)\" match field from
 412   RECORD-REGEXP is used.
 413   If it is \"\\\\&\" then the whole record is used.
 414   Otherwise, it is a regular-expression for which to search within the record.
 415 If a match for KEY is not found within a record then that record is ignored.
 416
 417 With a negative prefix arg sorts in reverse order.
 418
 419 The variable `sort-fold-case' determines whether alphabetic case affects
 420 the sort order.
 421
 422 For example: to sort lines in the region by the first word on each line
 423  starting with the letter \"f\",
 424  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\\\=\\<f\\\\w*\\\\>\""
 425   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 426   ;; other sort-.*fields functions but then again this was before, since it
 427   ;; didn't use the magnitude of the arg to specify anything.
 428   (interactive "P\nsRegexp specifying records to sort:
 429 sRegexp specifying key within record: \nr")
 430   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 431          (setq key-regexp 0))
 432         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 433          (setq key-regexp (- (aref key-regexp 1) ?0))))
 434   (save-excursion
 435     (save-restriction
 436       (narrow-to-region beg end)
 437       (goto-char (point-min))
 438       (let (sort-regexp-record-end
 439             (sort-regexp-fields-regexp record-regexp))
 440         (re-search-forward sort-regexp-fields-regexp nil t)
 441         (setq sort-regexp-record-end (point))
 442         (goto-char (match-beginning 0))
 443         (sort-subr reverse
 444                    'sort-regexp-fields-next-record
 445                    (function (lambda ()
 446                                (goto-char sort-regexp-record-end)))
 447                    (function (lambda ()
 448                                (let ((n 0))
 449                                  (cond ((numberp key-regexp)
 450                                         (setq n key-regexp))
 451                                        ((re-search-forward
 452                                           key-regexp sort-regexp-record-end t)
 453                                         (setq n 0))
 454                                        (t (throw 'key nil)))
 455                                  (condition-case ()
 456                                      (cons (match-beginning n)
 457                                            (match-end n))
 458                                    ;; if there was no such register
 459                                    (error (throw 'key nil)))))))))))
 460
 461 \f
 462 (defvar sort-columns-subprocess t)
 463
 464 ;;;###autoload
 465 (defun sort-columns (reverse &optional beg end)
 466   "Sort lines in region alphabetically by a certain range of columns.
 467 For the purpose of this command, the region BEG...END includes
 468 the entire line that point is in and the entire line the mark is in.
 469 The column positions of point and mark bound the range of columns to sort on.
 470 A prefix argument means sort into REVERSE order.
 471 The variable `sort-fold-case' determines whether alphabetic case affects
 472 the sort order.
 473
 474 Note that `sort-columns' rejects text that contains tabs,
 475 because tabs could be split across the specified columns
 476 and it doesn't know how to handle that.  Also, when possible,
 477 it uses the `sort' utility program, which doesn't understand tabs.
 478 Use \\[untabify] to convert tabs to spaces before sorting."
 479   (interactive "P\nr")
 480   (save-excursion
 481     (let (beg1 end1 col-beg1 col-end1 col-start col-end)
 482       (goto-char (min beg end))
 483       (setq col-beg1 (current-column))
 484       (beginning-of-line)
 485       (setq beg1 (point))
 486       (goto-char (max beg end))
 487       (setq col-end1 (current-column))
 488       (forward-line)
 489       (setq end1 (point))
 490       (setq col-start (min col-beg1 col-end1))
 491       (setq col-end (max col-beg1 col-end1))
 492       (if (search-backward "\t" beg1 t)
 493           (error "sort-columns does not work with tabs -- use M-x untabify"))
 494       (if (not (or (eq system-type 'vax-vms)
 495                    (text-properties-at beg1)
 496                    (< (next-property-change beg1 nil end1) end1)))
 497           ;; Use the sort utility if we can; it is 4 times as fast.
 498           ;; Do not use it if there are any properties in the region,
 499           ;; since the sort utility would lose the properties.
 500           (let ((sort-args (list (if reverse "-rt\n" "-t\n")
 501                                  (concat "+0." (int-to-string col-start))
 502                                  (concat "-0." (int-to-string col-end)))))
 503             (when sort-fold-case
 504               (push "-f" sort-args))
 505             (apply #'call-process-region beg1 end1 "sort" t t nil sort-args))
 506         ;; On VMS, use Emacs's own facilities.
 507         (save-excursion
 508           (save-restriction
 509             (narrow-to-region beg1 end1)
 510             (goto-char beg1)
 511             (sort-subr reverse 'forward-line 'end-of-line
 512                        #'(lambda () (move-to-column col-start) nil)
 513                        #'(lambda () (move-to-column col-end) nil))))))))
 514
 515 ;;;###autoload
 516 (defun reverse-region (beg end)
 517   "Reverse the order of lines in a region.
 518 From a program takes two point or marker arguments, BEG and END."
 519   (interactive "r")
 520   (if (> beg end)
 521       (let (mid) (setq mid end end beg beg mid)))
 522   (save-excursion
 523     ;; put beg at the start of a line and end and the end of one --
 524     ;; the largest possible region which fits this criteria
 525     (goto-char beg)
 526     (or (bolp) (forward-line 1))
 527     (setq beg (point))
 528     (goto-char end)
 529     ;; the test for bolp is for those times when end is on an empty line;
 530     ;; it is probably not the case that the line should be included in the
 531     ;; reversal; it isn't difficult to add it afterward.
 532     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 533     (setq end (point-marker))
 534     ;; the real work.  this thing cranks through memory on large regions.
 535     (let (ll (do t))
 536       (while do
 537         (goto-char beg)
 538         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 539                        ll))
 540         (setq do (/= (point) end))
 541         (delete-region beg (if do (1+ (point)) (point))))
 542       (while (cdr ll)
 543         (insert (car ll) "\n")
 544         (setq ll (cdr ll)))
 545       (insert (car ll)))))
 546
 547 (provide 'sort)
 548
 549 ;;; sort.el ends here