lisp/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is a mercurial version control backend
  26
  27 ;;; Thanks:
  28
  29 ;;; Bugs:
  30
  31 ;;; Installation:
  32
  33 ;;; Todo:
  34
  35 ;; 1) Implement the rest of the vc interface. See the comment at the
  36 ;; beginning of vc.el. The current status is:
  37
  38 ;; FUNCTION NAME                               STATUS
  39 ;; BACKEND PROPERTIES
  40 ;; * revision-granularity                      OK
  41 ;; STATE-QUERYING FUNCTIONS
  42 ;; * registered (file)                         OK
  43 ;; * state (file)                              OK
  44 ;; - state-heuristic (file)                    NOT NEEDED
  45 ;; - dir-status (dir update-function)          OK
  46 ;; - dir-status-files (dir files ds uf)        OK
  47 ;; - dir-extra-headers (dir)                   OK
  48 ;; - dir-printer (fileinfo)                    OK
  49 ;; * working-revision (file)                   OK
  50 ;; - latest-on-branch-p (file)                 ??
  51 ;; * checkout-model (files)                    OK
  52 ;; - workfile-unchanged-p (file)               OK
  53 ;; - mode-line-string (file)                   NOT NEEDED
  54 ;; STATE-CHANGING FUNCTIONS
  55 ;; * register (files &optional rev comment)    OK
  56 ;; * create-repo ()                            OK
  57 ;; - init-revision ()                          NOT NEEDED
  58 ;; - responsible-p (file)                      OK
  59 ;; - could-register (file)                     OK
  60 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  61 ;; - unregister (file)                         COMMENTED OUT, MAY BE INCORRECT
  62 ;; * checkin (files rev comment)               OK
  63 ;; * find-revision (file rev buffer)           OK
  64 ;; * checkout (file &optional editable rev)    OK
  65 ;; * revert (file &optional contents-done)     OK
  66 ;; - rollback (files)                          ?? PROBABLY NOT NEEDED
  67 ;; - merge (file rev1 rev2)                    NEEDED
  68 ;; - merge-news (file)                         NEEDED
  69 ;; - steal-lock (file &optional revision)      NOT NEEDED
  70 ;; HISTORY FUNCTIONS
  71 ;; * print-log (files &optional buffer)        OK
  72 ;; - log-view-mode ()                          OK
  73 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  74 ;; - comment-history (file)                    NOT NEEDED
  75 ;; - update-changelog (files)                  NOT NEEDED
  76 ;; * diff (files &optional rev1 rev2 buffer)   OK
  77 ;; - revision-completion-table (files)         OK?
  78 ;; - annotate-command (file buf &optional rev) OK
  79 ;; - annotate-time ()                          OK
  80 ;; - annotate-current-time ()                  NOT NEEDED
  81 ;; - annotate-extract-revision-at-line ()      OK
  82 ;; TAG SYSTEM
  83 ;; - create-tag (dir name branchp)             NEEDED
  84 ;; - retrieve-tag (dir name update)            NEEDED
  85 ;; MISCELLANEOUS
  86 ;; - make-version-backups-p (file)             ??
  87 ;; - repository-hostname (dirname)             ??
  88 ;; - previous-revision (file rev)              OK
  89 ;; - next-revision (file rev)                  OK
  90 ;; - check-headers ()                          ??
  91 ;; - clear-headers ()                          ??
  92 ;; - delete-file (file)                        TEST IT
  93 ;; - rename-file (old new)                     OK
  94 ;; - find-file-hook ()                         PROBABLY NOT NEEDED
  95 ;; - find-file-not-found-hook ()               PROBABLY NOT NEEDED
  96
  97 ;; 2) Implement Stefan Monnier's advice:
  98 ;; vc-hg-registered and vc-hg-state
  99 ;; Both of those functions should be super extra careful to fail gracefully in
 100 ;; unexpected circumstances. The reason this is important is that any error
 101 ;; there will prevent the user from even looking at the file :-(
 102 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
 103 ;; mercurial's control and extracting the current revision should be done
 104 ;; without even using `hg' (this way even if you don't have `hg' installed,
 105 ;; Emacs is able to tell you this file is under mercurial's control).
 106
 107 ;;; History:
 108 ;;
 109
 110 ;;; Code:
 111
 112 (eval-when-compile
 113   (require 'cl)
 114   (require 'vc)
 115   (require 'vc-dir))
 116
 117 ;;; Customization options
 118
 119 (defcustom vc-hg-global-switches nil
 120   "Global switches to pass to any Hg command."
 121   :type '(choice (const :tag "None" nil)
 122          (string :tag "Argument String")
 123          (repeat :tag "Argument List" :value ("") string))
 124   :version "22.2"
 125   :group 'vc)
 126
 127 (defcustom vc-hg-diff-switches t ; Hg doesn't support common args like -u
 128   "String or list of strings specifying switches for Hg diff under VC.
 129 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 130   :type '(choice (const :tag "Unspecified" nil)
 131                  (const :tag "None" t)
 132                  (string :tag "Argument String")
 133                  (repeat :tag "Argument List" :value ("") string))
 134   :version "23.1"
 135   :group 'vc)
 136
 137 \f
 138 ;;; Properties of the backend
 139
 140 (defun vc-hg-revision-granularity () 'repository)
 141 (defun vc-hg-checkout-model (files) 'implicit)
 142
 143 ;;; State querying functions
 144
 145 ;;;###autoload (defun vc-hg-registered (file)
 146 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 147 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 148 ;;;###autoload       (progn
 149 ;;;###autoload         (load "vc-hg")
 150 ;;;###autoload         (vc-hg-registered file))))
 151
 152 ;; Modeled after the similar function in vc-bzr.el
 153 (defun vc-hg-registered (file)
 154   "Return non-nil if FILE is registered with hg."
 155   (when (vc-hg-root file)           ; short cut
 156     (let ((state (vc-hg-state file)))  ; expensive
 157       (and state (not (memq state '(ignored unregistered)))))))
 158
 159 (defun vc-hg-state (file)
 160   "Hg-specific version of `vc-state'."
 161   (let*
 162       ((status nil)
 163        (out
 164         (with-output-to-string
 165           (with-current-buffer
 166               standard-output
 167             (setq status
 168                   (condition-case nil
 169                       ;; Ignore all errors.
 170                       (call-process
 171                        "hg" nil t nil "--cwd" (file-name-directory file)
 172                        "status" "-A" (file-name-nondirectory file))
 173                     ;; Some problem happened.  E.g. We can't find an `hg'
 174                     ;; executable.
 175                     (error nil)))))))
 176     (when (eq 0 status)
 177         (when (null (string-match ".*: No such file or directory$" out))
 178           (let ((state (aref out 0)))
 179             (cond
 180              ((eq state ?=) 'up-to-date)
 181              ((eq state ?A) 'added)
 182              ((eq state ?M) 'edited)
 183              ((eq state ?I) 'ignored)
 184              ((eq state ?R) 'removed)
 185              ((eq state ?!) 'missing)
 186              ((eq state ??) 'unregistered)
 187              ((eq state ?C) 'up-to-date) ;; Older mercurials use this
 188              (t 'up-to-date)))))))
 189
 190 (defun vc-hg-working-revision (file)
 191   "Hg-specific version of `vc-working-revision'."
 192   (let*
 193       ((status nil)
 194        (out
 195         (with-output-to-string
 196           (with-current-buffer
 197               standard-output
 198             (setq status
 199                   (condition-case nil
 200                       ;; Ignore all errors.
 201                       (call-process
 202                        "hg" nil t nil "--cwd" (file-name-directory file)
 203                        "log" "-l1" (file-name-nondirectory file))
 204                     ;; Some problem happened.  E.g. We can't find an `hg'
 205                     ;; executable.
 206                     (error nil)))))))
 207     (when (eq 0 status)
 208       (if (string-match "changeset: *\\([0-9]*\\)" out)
 209           (match-string 1 out)
 210         "0"))))
 211
 212 ;;; History functions
 213
 214 (defun vc-hg-print-log (files &optional buffer)
 215   "Get change log associated with FILES."
 216   ;; `log-view-mode' needs to have the file names in order to function
 217   ;; correctly. "hg log" does not print it, so we insert it here by
 218   ;; hand.
 219
 220   ;; `vc-do-command' creates the buffer, but we need it before running
 221   ;; the command.
 222   (vc-setup-buffer buffer)
 223   ;; If the buffer exists from a previous invocation it might be
 224   ;; read-only.
 225   (let ((inhibit-read-only t))
 226     (with-current-buffer
 227         buffer
 228       (vc-hg-command buffer 0 files "log"))))
 229
 230 (defvar log-view-message-re)
 231 (defvar log-view-file-re)
 232 (defvar log-view-font-lock-keywords)
 233 (defvar log-view-per-file-logs)
 234
 235 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 236   (require 'add-log) ;; we need the add-log faces
 237   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 238   (set (make-local-variable 'log-view-per-file-logs) nil)
 239   (set (make-local-variable 'log-view-message-re)
 240        "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)")
 241   (set (make-local-variable 'log-view-font-lock-keywords)
 242        (append
 243         log-view-font-lock-keywords
 244         '(
 245           ;; Handle the case:
 246           ;; user: FirstName LastName <foo@bar>
 247           ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 248            (1 'change-log-name)
 249            (2 'change-log-email))
 250           ;; Handle the cases:
 251           ;; user: foo@bar
 252           ;; and
 253           ;; user: foo
 254           ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 255            (1 'change-log-email))
 256           ("^date: \\(.+\\)" (1 'change-log-date))
 257           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 258
 259 (defun vc-hg-diff (files &optional oldvers newvers buffer)
 260   "Get a difference report using hg between two revisions of FILES."
 261   (let* ((firstfile (car files))
 262          (cwd (if firstfile (file-name-directory firstfile)
 263                 (expand-file-name default-directory)))
 264          (working (and firstfile (vc-working-revision firstfile))))
 265     (when (and (equal oldvers working) (not newvers))
 266       (setq oldvers nil))
 267     (when (and (not oldvers) newvers)
 268       (setq oldvers working))
 269     (apply #'vc-hg-command (or buffer "*vc-diff*") nil
 270            (mapcar (lambda (file) (file-relative-name file cwd)) files)
 271            "--cwd" cwd
 272            "diff"
 273            (append
 274             (vc-switches 'hg 'diff)
 275             (when oldvers
 276               (if newvers
 277                   (list "-r" oldvers "-r" newvers)
 278                 (list "-r" oldvers)))))))
 279
 280 (defun vc-hg-revision-table (files)
 281   (let ((default-directory (file-name-directory (car files))))
 282     (with-temp-buffer
 283       (vc-hg-command t nil files "log" "--template" "{rev} ")
 284       (split-string
 285        (buffer-substring-no-properties (point-min) (point-max))))))
 286
 287 ;; Modeled after the similar function in vc-cvs.el
 288 (defun vc-hg-revision-completion-table (files)
 289   (lexical-let ((files files)
 290                 table)
 291     (setq table (lazy-completion-table
 292                  table (lambda () (vc-hg-revision-table files))))
 293     table))
 294
 295 (defun vc-hg-annotate-command (file buffer &optional revision)
 296   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 297 Optional arg REVISION is a revision to annotate from."
 298   (vc-hg-command buffer 0 file "annotate" "-d" "-n"
 299                  (when revision (concat "-r" revision)))
 300   (with-current-buffer buffer
 301     (goto-char (point-min))
 302     (re-search-forward "^[ \t]*[0-9]")
 303     (delete-region (point-min) (match-beginning 0))))
 304
 305 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 306
 307 ;; The format for one line output by "hg annotate -d -n" looks like this:
 308 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 309 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 310 ;; If the user has set the "--follow" option, the output looks like:
 311 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 312 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 313 (defconst vc-hg-annotate-re
 314   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)[^:\n]*\\(:[^ \n][^:\n]*\\)*: ")
 315
 316 (defun vc-hg-annotate-time ()
 317   (when (looking-at vc-hg-annotate-re)
 318     (goto-char (match-end 0))
 319     (vc-annotate-convert-time
 320      (date-to-time (match-string-no-properties 2)))))
 321
 322 (defun vc-hg-annotate-extract-revision-at-line ()
 323   (save-excursion
 324     (beginning-of-line)
 325     (when (looking-at vc-hg-annotate-re) (match-string-no-properties 1))))
 326
 327 (defun vc-hg-previous-revision (file rev)
 328   (let ((newrev (1- (string-to-number rev))))
 329     (when (>= newrev 0)
 330       (number-to-string newrev))))
 331
 332 (defun vc-hg-next-revision (file rev)
 333   (let ((newrev (1+ (string-to-number rev)))
 334         (tip-revision
 335          (with-temp-buffer
 336            (vc-hg-command t 0 nil "tip")
 337            (goto-char (point-min))
 338            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 339            (string-to-number (match-string-no-properties 1)))))
 340     ;; We don't want to exceed the maximum possible revision number, ie
 341     ;; the tip revision.
 342     (when (<= newrev tip-revision)
 343       (number-to-string newrev))))
 344
 345 ;; Modeled after the similar function in vc-bzr.el
 346 (defun vc-hg-delete-file (file)
 347   "Delete FILE and delete it in the hg repository."
 348   (condition-case ()
 349       (delete-file file)
 350     (file-error nil))
 351   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 352
 353 ;; Modeled after the similar function in vc-bzr.el
 354 (defun vc-hg-rename-file (old new)
 355   "Rename file from OLD to NEW using `hg mv'."
 356   (vc-hg-command nil 0 new "mv" old))
 357
 358 (defun vc-hg-register (files &optional rev comment)
 359   "Register FILES under hg.
 360 REV is ignored.
 361 COMMENT is ignored."
 362   (vc-hg-command nil 0 files "add"))
 363
 364 (defun vc-hg-create-repo ()
 365   "Create a new Mercurial repository."
 366   (vc-hg-command nil 0 nil "init"))
 367
 368 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 369
 370 ;; Modeled after the similar function in vc-bzr.el
 371 (defun vc-hg-could-register (file)
 372   "Return non-nil if FILE could be registered under hg."
 373   (and (vc-hg-responsible-p file)      ; shortcut
 374        (condition-case ()
 375            (with-temp-buffer
 376              (vc-hg-command t nil file "add" "--dry-run"))
 377              ;; The command succeeds with no output if file is
 378              ;; registered.
 379          (error))))
 380
 381 ;; FIXME: This would remove the file. Is that correct?
 382 ;; (defun vc-hg-unregister (file)
 383 ;;   "Unregister FILE from hg."
 384 ;;   (vc-hg-command nil nil file "remove"))
 385
 386 (defun vc-hg-checkin (files rev comment)
 387   "Hg-specific version of `vc-backend-checkin'.
 388 REV is ignored."
 389   (vc-hg-command nil 0 files  "commit" "-m" comment))
 390
 391 (defun vc-hg-find-revision (file rev buffer)
 392   (let ((coding-system-for-read 'binary)
 393         (coding-system-for-write 'binary))
 394     (if rev
 395         (vc-hg-command buffer 0 file "cat" "-r" rev)
 396       (vc-hg-command buffer 0 file "cat"))))
 397
 398 ;; Modeled after the similar function in vc-bzr.el
 399 (defun vc-hg-checkout (file &optional editable rev)
 400   "Retrieve a revision of FILE.
 401 EDITABLE is ignored.
 402 REV is the revision to check out into WORKFILE."
 403   (let ((coding-system-for-read 'binary)
 404         (coding-system-for-write 'binary))
 405   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 406     (if rev
 407         (vc-hg-command t 0 file "cat" "-r" rev)
 408       (vc-hg-command t 0 file "cat")))))
 409
 410 ;; Modeled after the similar function in vc-bzr.el
 411 (defun vc-hg-workfile-unchanged-p (file)
 412   (eq 'up-to-date (vc-hg-state file)))
 413
 414 ;; Modeled after the similar function in vc-bzr.el
 415 (defun vc-hg-revert (file &optional contents-done)
 416   (unless contents-done
 417     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 418
 419 ;;; Hg specific functionality.
 420
 421 (defvar vc-hg-extra-menu-map
 422   (let ((map (make-sparse-keymap)))
 423     (define-key map [incoming] '(menu-item "Show incoming" vc-hg-incoming))
 424     (define-key map [outgoing] '(menu-item "Show outgoing" vc-hg-outgoing))
 425     map))
 426
 427 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 428
 429 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 430
 431 (define-derived-mode vc-hg-outgoing-mode vc-hg-log-view-mode "Hg-Outgoing")
 432
 433 (define-derived-mode vc-hg-incoming-mode vc-hg-log-view-mode "Hg-Incoming")
 434
 435 (defstruct (vc-hg-extra-fileinfo
 436             (:copier nil)
 437             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 438             (:conc-name vc-hg-extra-fileinfo->))
 439   rename-state        ;; rename or copy state
 440   extra-name)         ;; original name for copies and rename targets, new name for
 441
 442 (declare-function vc-default-dir-printer "vc-dir" (backend fileentry))
 443
 444 (defun vc-hg-dir-printer (info)
 445   "Pretty-printer for the vc-dir-fileinfo structure."
 446   (let ((extra (vc-dir-fileinfo->extra info)))
 447     (vc-default-dir-printer 'Hg info)
 448     (when extra
 449       (insert (propertize
 450                (format "   (%s %s)"
 451                        (case (vc-hg-extra-fileinfo->rename-state extra)
 452                          ('copied "copied from")
 453                          ('renamed-from "renamed from")
 454                          ('renamed-to "renamed to"))
 455                        (vc-hg-extra-fileinfo->extra-name extra))
 456                'face 'font-lock-comment-face)))))
 457
 458 (defun vc-hg-after-dir-status (update-function)
 459   (let ((status-char nil)
 460         (file nil)
 461         (translation '((?= . up-to-date)
 462                        (?C . up-to-date)
 463                        (?A . added)
 464                        (?R . removed)
 465                        (?M . edited)
 466                        (?I . ignored)
 467                        (?! . missing)
 468                        (?  . copy-rename-line)
 469                        (?? . unregistered)))
 470         (translated nil)
 471         (result nil)
 472         (last-added nil)
 473         (last-line-copy nil))
 474       (goto-char (point-min))
 475       (while (not (eobp))
 476         (setq translated (cdr (assoc (char-after) translation)))
 477         (setq file
 478               (buffer-substring-no-properties (+ (point) 2)
 479                                               (line-end-position)))
 480         (cond ((not translated)
 481                (setq last-line-copy nil))
 482               ((eq translated 'up-to-date)
 483                (setq last-line-copy nil))
 484               ((eq translated 'copy-rename-line)
 485                ;; For copied files the output looks like this:
 486                ;; A COPIED_FILE_NAME
 487                ;;   ORIGINAL_FILE_NAME
 488                (setf (nth 2 last-added)
 489                      (vc-hg-create-extra-fileinfo 'copied file))
 490                (setq last-line-copy t))
 491               ((and last-line-copy (eq translated 'removed))
 492                ;; For renamed files the output looks like this:
 493                ;; A NEW_FILE_NAME
 494                ;;   ORIGINAL_FILE_NAME
 495                ;; R ORIGINAL_FILE_NAME
 496                ;; We need to adjust the previous entry to not think it is a copy.
 497                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 498                      'renamed-from)
 499                (push (list file translated
 500                            (vc-hg-create-extra-fileinfo
 501                             'renamed-to (nth 0 last-added))) result)
 502                (setq last-line-copy nil))
 503               (t
 504                (setq last-added (list file translated nil))
 505                (push last-added result)
 506                (setq last-line-copy nil)))
 507         (forward-line))
 508       (funcall update-function result)))
 509
 510 (defun vc-hg-dir-status (dir update-function)
 511   (vc-hg-command (current-buffer) 'async dir "status" "-C")
 512   (vc-exec-after
 513    `(vc-hg-after-dir-status (quote ,update-function))))
 514
 515 (defun vc-hg-dir-status-files (dir files default-state update-function)
 516   (apply 'vc-hg-command (current-buffer) 'async dir "status" "-C" files)
 517   (vc-exec-after
 518    `(vc-hg-after-dir-status (quote ,update-function))))
 519
 520 (defun vc-hg-dir-extra-header (name &rest commands)
 521   (concat (propertize name 'face 'font-lock-type-face)
 522           (propertize
 523            (with-temp-buffer
 524              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 525              (buffer-substring-no-properties (point-min) (1- (point-max))))
 526            'face 'font-lock-variable-name-face)))
 527
 528 (defun vc-hg-dir-extra-headers (dir)
 529   "Generate extra status headers for a Mercurial tree."
 530   (let ((default-directory dir))
 531     (concat
 532      (vc-hg-dir-extra-header "Root       : " "root") "\n"
 533      (vc-hg-dir-extra-header "Branch     : " "id" "-b") "\n"
 534      (vc-hg-dir-extra-header "Tags       : " "id" "-t") ; "\n"
 535      ;; these change after each commit
 536      ;; (vc-hg-dir-extra-header "Local num  : " "id" "-n") "\n"
 537      ;; (vc-hg-dir-extra-header "Global id  : " "id" "-i")
 538      )))
 539
 540 ;; FIXME: this adds another top level menu, instead figure out how to
 541 ;; replace the Log-View menu.
 542 (easy-menu-define log-view-mode-menu vc-hg-outgoing-mode-map
 543   "Hg-outgoing Display Menu"
 544   `("Hg-outgoing"
 545     ["Push selected"  vc-hg-push]))
 546
 547 (easy-menu-define log-view-mode-menu vc-hg-incoming-mode-map
 548   "Hg-incoming Display Menu"
 549   `("Hg-incoming"
 550     ["Pull selected"  vc-hg-pull]))
 551
 552 (defun vc-hg-outgoing ()
 553   (interactive)
 554   (let ((bname "*Hg outgoing*"))
 555     (vc-hg-command bname 0 nil "outgoing" "-n")
 556     (pop-to-buffer bname)
 557     (vc-hg-outgoing-mode)))
 558
 559 (defun vc-hg-incoming ()
 560   (interactive)
 561   (let ((bname "*Hg incoming*"))
 562     (vc-hg-command bname 0 nil "incoming" "-n")
 563     (pop-to-buffer bname)
 564     (vc-hg-incoming-mode)))
 565
 566 (declare-function log-view-get-marked "log-view" ())
 567
 568 ;; XXX maybe also add key bindings for these functions.
 569 (defun vc-hg-push ()
 570   (interactive)
 571   (let ((marked-list (log-view-get-marked)))
 572     (if marked-list
 573         (vc-hg-command
 574          nil 0 nil
 575          (cons "push"
 576                (apply 'nconc
 577                       (mapcar (lambda (arg) (list "-r" arg)) marked-list))))
 578          (error "No log entries selected for push"))))
 579
 580 (defun vc-hg-pull ()
 581   (interactive)
 582   (let ((marked-list (log-view-get-marked)))
 583     (if marked-list
 584         (vc-hg-command
 585          nil 0 nil
 586          (cons "pull"
 587                (apply 'nconc
 588                       (mapcar (lambda (arg) (list "-r" arg)) marked-list))))
 589       (error "No log entries selected for pull"))))
 590
 591 ;;; Internal functions
 592
 593 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 594   "A wrapper around `vc-do-command' for use in vc-hg.el.
 595 The difference to vc-do-command is that this function always invokes `hg',
 596 and that it passes `vc-hg-global-switches' to it before FLAGS."
 597   (apply 'vc-do-command (or buffer "*vc*") okstatus "hg" file-or-list
 598          (if (stringp vc-hg-global-switches)
 599              (cons vc-hg-global-switches flags)
 600            (append vc-hg-global-switches
 601                    flags))))
 602
 603 (defun vc-hg-root (file)
 604   (vc-find-root file ".hg"))
 605
 606 (provide 'vc-hg)
 607
 608 ;; arch-tag: bd094dc5-715a-434f-a331-37b9fb7cd954
 609 ;;; vc-hg.el ends here