lisp/userlock.el

   1 ;;; userlock.el --- handle file access contention between multiple users
   2
   3 ;; Copyright (C) 1985-1986, 2001-2011 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This file is autoloaded to handle certain conditions
  26 ;; detected by the file-locking code within Emacs.
  27 ;; The two entry points are `ask-user-about-lock' and
  28 ;; `ask-user-about-supersession-threat'.
  29
  30 ;;; Code:
  31
  32 (put 'file-locked 'error-conditions '(file-locked file-error error))
  33 (put 'file-locked 'error-message "File is locked")
  34
  35 ;;;###autoload
  36 (defun ask-user-about-lock (file opponent)
  37   "Ask user what to do when he wants to edit FILE but it is locked by OPPONENT.
  38 This function has a choice of three things to do:
  39   do (signal 'file-locked (list FILE OPPONENT))
  40     to refrain from editing the file
  41   return t (grab the lock on the file)
  42   return nil (edit the file even though it is locked).
  43 You can redefine this function to choose among those three alternatives
  44 in any way you like."
  45   (discard-input)
  46   (save-window-excursion
  47     (let (answer short-opponent short-file)
  48       (setq short-file
  49             (if (> (length file) 22)
  50                 (concat "..." (substring file (- (length file) 22)))
  51               file))
  52       (setq short-opponent
  53             (if (> (length opponent) 25)
  54                 (save-match-data
  55                   (string-match " (pid [0-9]+)" opponent)
  56                   (concat (substring opponent 0 13) "..."
  57                           (match-string 0 opponent)))
  58               opponent))
  59       (while (null answer)
  60         (message "%s locked by %s: (s, q, p, ?)? "
  61                  short-file short-opponent)
  62         (let ((tem (let ((inhibit-quit t)
  63                          (cursor-in-echo-area t))
  64                      (prog1 (downcase (read-char))
  65                             (setq quit-flag nil)))))
  66           (if (= tem help-char)
  67               (ask-user-about-lock-help)
  68             (setq answer (assoc tem '((?s . t)
  69                                       (?q . yield)
  70                                       (?\C-g . yield)
  71                                       (?p . nil)
  72                                       (?? . help))))
  73             (cond ((null answer)
  74                    (beep)
  75                    (message "Please type q, s, or p; or ? for help")
  76                    (sit-for 3))
  77                   ((eq (cdr answer) 'help)
  78                    (ask-user-about-lock-help)
  79                    (setq answer nil))
  80                   ((eq (cdr answer) 'yield)
  81                    (signal 'file-locked (list file opponent)))))))
  82       (cdr answer))))
  83
  84 (defun ask-user-about-lock-help ()
  85   (with-output-to-temp-buffer "*Help*"
  86     (princ "It has been detected that you want to modify a file that someone else has
  87 already started modifying in Emacs.
  88
  89 You can <s>teal the file; the other user becomes the
  90   intruder if (s)he ever unmodifies the file and then changes it again.
  91 You can <p>roceed; you edit at your own (and the other user's) risk.
  92 You can <q>uit; don't modify this file.")
  93     (with-current-buffer standard-output
  94       (help-mode))))
  95
  96 (put
  97  'file-supersession 'error-conditions '(file-supersession file-error error))
  98
  99 ;;;###autoload
 100 (defun ask-user-about-supersession-threat (fn)
 101   "Ask a user who is about to modify an obsolete buffer what to do.
 102 This function has two choices: it can return, in which case the modification
 103 of the buffer will proceed, or it can (signal 'file-supersession (file)),
 104 in which case the proposed buffer modification will not be made.
 105
 106 You can rewrite this to use any criterion you like to choose which one to do.
 107 The buffer in question is current when this function is called."
 108   (discard-input)
 109   (save-window-excursion
 110     (let (answer)
 111       (while (null answer)
 112         (message "%s changed on disk; really edit the buffer? (y, n, r or C-h) "
 113                  (file-name-nondirectory fn))
 114         (let ((tem (downcase (let ((cursor-in-echo-area t))
 115                                (read-char-exclusive)))))
 116           (setq answer
 117                 (if (= tem help-char)
 118                     'help
 119                   (cdr (assoc tem '((?n . yield)
 120                                     (?\C-g . yield)
 121                                     (?y . proceed)
 122                                     (?r . revert)
 123                                     (?? . help))))))
 124           (cond ((null answer)
 125                  (beep)
 126                  (message "Please type y, n or r; or ? for help")
 127                  (sit-for 3))
 128                 ((eq answer 'help)
 129                  (ask-user-about-supersession-help)
 130                  (setq answer nil))
 131                 ((eq answer 'revert)
 132                  (revert-buffer nil (not (buffer-modified-p)))
 133                                         ; ask confirmation if buffer modified
 134                  (signal 'file-supersession
 135                          (list "File reverted" fn)))
 136                 ((eq answer 'yield)
 137                  (signal 'file-supersession
 138                          (list "File changed on disk" fn))))))
 139       (message
 140         "File on disk now will become a backup file if you save these changes.")
 141       (setq buffer-backed-up nil))))
 142
 143 (defun ask-user-about-supersession-help ()
 144   (with-output-to-temp-buffer "*Help*"
 145     (princ "You want to modify a buffer whose disk file has changed
 146 since you last read it in or saved it with this buffer.
 147
 148 If you say `y' to go ahead and modify this buffer,
 149 you risk ruining the work of whoever rewrote the file.
 150 If you say `r' to revert, the contents of the buffer are refreshed
 151 from the file on disk.
 152 If you say `n', the change you started to make will be aborted.
 153
 154 Usually, you should type `n' and then `M-x revert-buffer',
 155 to get the latest version of the file, then make the change again.")
 156     (with-current-buffer standard-output
 157       (help-mode))))
 158
 159 ;;; userlock.el ends here