lisp/org/org-vm.el

   1 ;;; org-vm.el --- Support for links to VM messages from within Org-mode
   2
   3 ;; Copyright (C) 2004-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.7
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27 ;; This file implements links to VM messages and folders from within Org-mode.
  28 ;; Org-mode loads this module by default - if this is not what you want,
  29 ;; configure the variable `org-modules'.
  30
  31 ;;; Code:
  32
  33 (require 'org)
  34
  35 ;; Declare external functions and variables
  36 (declare-function vm-preview-current-message "ext:vm-page" ())
  37 (declare-function vm-follow-summary-cursor "ext:vm-motion" ())
  38 (declare-function vm-get-header-contents "ext:vm-summary"
  39                   (message header-name-regexp &optional clump-sep))
  40 (declare-function vm-isearch-narrow "ext:vm-search" ())
  41 (declare-function vm-isearch-update "ext:vm-search" ())
  42 (declare-function vm-select-folder-buffer "ext:vm-macro" ())
  43 (declare-function vm-su-message-id "ext:vm-summary" (m))
  44 (declare-function vm-su-subject "ext:vm-summary" (m))
  45 (declare-function vm-summarize "ext:vm-summary" (&optional display raise))
  46 (defvar vm-message-pointer)
  47 (defvar vm-folder-directory)
  48
  49 ;; Install the link type
  50 (org-add-link-type "vm" 'org-vm-open)
  51 (add-hook 'org-store-link-functions 'org-vm-store-link)
  52
  53 ;; Implementation
  54 (defun org-vm-store-link ()
  55   "Store a link to a VM folder or message."
  56   (when (and (or (eq major-mode 'vm-summary-mode)
  57                  (eq major-mode 'vm-presentation-mode))
  58              (save-window-excursion
  59                (vm-select-folder-buffer) buffer-file-name))
  60     (and (eq major-mode 'vm-presentation-mode) (vm-summarize))
  61     (vm-follow-summary-cursor)
  62     (save-excursion
  63       (vm-select-folder-buffer)
  64       (let* ((message (car vm-message-pointer))
  65              (folder buffer-file-name)
  66              (subject (vm-su-subject message))
  67              (to (vm-get-header-contents message "To"))
  68              (from (vm-get-header-contents message "From"))
  69              (message-id (vm-su-message-id message))
  70              (date (vm-get-header-contents message "Date"))
  71              (date-ts (and date (format-time-string
  72                                  (org-time-stamp-format t)
  73                                  (date-to-time date))))
  74              (date-ts-ia (and date (format-time-string
  75                                     (org-time-stamp-format t t)
  76                                     (date-to-time date))))
  77              desc link)
  78         (org-store-link-props :type "vm" :from from :to to :subject subject
  79                               :message-id message-id)
  80         (when date
  81           (org-add-link-props :date date :date-timestamp date-ts
  82                               :date-timestamp-inactive date-ts-ia))
  83         (setq message-id (org-remove-angle-brackets message-id))
  84         (setq folder (abbreviate-file-name folder))
  85         (if (and vm-folder-directory
  86                  (string-match (concat "^" (regexp-quote vm-folder-directory))
  87                                folder))
  88             (setq folder (replace-match "" t t folder)))
  89         (setq desc (org-email-link-description))
  90         (setq link (org-make-link "vm:" folder "#" message-id))
  91         (org-add-link-props :link link :description desc)
  92         link))))
  93
  94 (defun org-vm-open (path)
  95   "Follow a VM message link specified by PATH."
  96   (let (folder article)
  97     (if (not (string-match "\\`\\([^#]+\\)\\(#\\(.*\\)\\)?" path))
  98         (error "Error in VM link"))
  99     (setq folder (match-string 1 path)
 100           article (match-string 3 path))
 101     ;; The prefix argument will be interpreted as read-only
 102     (org-vm-follow-link folder article current-prefix-arg)))
 103
 104 (defun org-vm-follow-link (&optional folder article readonly)
 105   "Follow a VM link to FOLDER and ARTICLE."
 106   (require 'vm)
 107   (setq article (org-add-angle-brackets article))
 108   (if (string-match "^//\\([a-zA-Z]+@\\)?\\([^:]+\\):\\(.*\\)" folder)
 109       ;; ange-ftp or efs or tramp access
 110       (let ((user (or (match-string 1 folder) (user-login-name)))
 111             (host (match-string 2 folder))
 112             (file (match-string 3 folder)))
 113         (cond
 114          ((featurep 'tramp)
 115           ;; use tramp to access the file
 116           (if (featurep 'xemacs)
 117               (setq folder (format "[%s@%s]%s" user host file))
 118             (setq folder (format "/%s@%s:%s" user host file))))
 119          (t
 120           ;; use ange-ftp or efs
 121           (require (if (featurep 'xemacs) 'efs 'ange-ftp))
 122           (setq folder (format "/%s@%s:%s" user host file))))))
 123   (when folder
 124     (funcall (cdr (assq 'vm org-link-frame-setup)) folder readonly)
 125     (sit-for 0.1)
 126     (when article
 127       (require 'vm-search)
 128       (vm-select-folder-buffer)
 129       (widen)
 130       (let ((case-fold-search t))
 131         (goto-char (point-min))
 132         (if (not (re-search-forward
 133                   (concat "^" "message-id: *" (regexp-quote article))))
 134             (error "Could not find the specified message in this folder"))
 135         (vm-isearch-update)
 136         (vm-isearch-narrow)
 137         (vm-preview-current-message)
 138         (vm-summarize)))))
 139
 140 (provide 'org-vm)
 141
 142
 143
 144 ;;; org-vm.el ends here