lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar comint-prompt-regexp)
  31
  32 (defgroup tooltip nil
  33   "Customization group for the `tooltip' package."
  34   :group 'help
  35   :group 'gud
  36   :group 'mouse
  37   :group 'tools
  38   :version "21.1"
  39   :tag "Tool Tips")
  40 \f
  41 ;;; Switching tooltips on/off
  42
  43 (define-minor-mode tooltip-mode
  44   "Toggle Tooltip mode.
  45 With ARG, turn Tooltip mode on if and only if ARG is positive.
  46 When this minor mode is enabled, Emacs displays help text
  47 in a pop-up window for buttons and menu items that you put the mouse on.
  48 \(However, if `tooltip-use-echo-area' is non-nil, this and
  49 all pop-up help appears in the echo area.)
  50
  51 When Tooltip mode is disabled, Emacs displays one line of
  52 the help text in the echo area, and does not make a pop-up window."
  53   :global t
  54   :init-value (not (or noninteractive
  55                        emacs-basic-display
  56                        (not (display-graphic-p))
  57                        (not (fboundp 'x-show-tip))))
  58   :initialize 'custom-initialize-safe-default
  59   :group 'tooltip
  60   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
  61     (error "Sorry, tooltips are not yet available on this system"))
  62   (if tooltip-mode
  63       (progn
  64         (add-hook 'pre-command-hook 'tooltip-hide)
  65         (add-hook 'tooltip-hook 'tooltip-help-tips))
  66     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
  67       (remove-hook 'pre-command-hook 'tooltip-hide))
  68     (remove-hook 'tooltip-hook 'tooltip-help-tips))
  69   (setq show-help-function
  70         (if tooltip-mode 'tooltip-show-help 'tooltip-show-help-non-mode)))
  71
  72 \f
  73 ;;; Customizable settings
  74
  75 (defcustom tooltip-delay 0.7
  76   "Seconds to wait before displaying a tooltip the first time."
  77   :type 'number
  78   :group 'tooltip)
  79
  80 (defcustom tooltip-short-delay 0.1
  81   "Seconds to wait between subsequent tooltips on different items."
  82   :type 'number
  83   :group 'tooltip)
  84
  85 (defcustom tooltip-recent-seconds 1
  86   "Display tooltips if changing tip items within this many seconds.
  87 Do so after `tooltip-short-delay'."
  88   :type 'number
  89   :group 'tooltip)
  90
  91 (defcustom tooltip-hide-delay 10
  92   "Hide tooltips automatically after this many seconds."
  93   :type 'number
  94   :group 'tooltip)
  95
  96 (defcustom tooltip-x-offset 5
  97   "X offset, in pixels, for the display of tooltips.
  98 The offset is the distance between the X position of the mouse and
  99 the left border of the tooltip window.  It must be chosen so that the
 100 tooltip window doesn't contain the mouse when it pops up, or it may
 101 interfere with clicking where you wish.
 102
 103 If `tooltip-frame-parameters' includes the `left' parameter,
 104 the value of `tooltip-x-offset' is ignored."
 105   :type 'integer
 106   :group 'tooltip)
 107
 108 (defcustom tooltip-y-offset +20
 109   "Y offset, in pixels, for the display of tooltips.
 110 The offset is the distance between the Y position of the mouse and
 111 the top border of the tooltip window.  It must be chosen so that the
 112 tooltip window doesn't contain the mouse when it pops up, or it may
 113 interfere with clicking where you wish.
 114
 115 If `tooltip-frame-parameters' includes the `top' parameter,
 116 the value of `tooltip-y-offset' is ignored."
 117   :type 'integer
 118   :group 'tooltip)
 119
 120 (defcustom tooltip-frame-parameters
 121   '((name . "tooltip")
 122     (internal-border-width . 2)
 123     (border-width . 1))
 124   "Frame parameters used for tooltips.
 125
 126 If `left' or `top' parameters are included, they specify the absolute
 127 position to pop up the tooltip."
 128   :type 'sexp
 129   :group 'tooltip)
 130
 131 (defface tooltip
 132   '((((class color))
 133      :background "lightyellow"
 134      :foreground "black"
 135      :inherit variable-pitch)
 136     (t
 137      :inherit variable-pitch))
 138   "Face for tooltips."
 139   :group 'tooltip
 140   :group 'basic-faces)
 141
 142 (defcustom tooltip-use-echo-area nil
 143   "Use the echo area instead of tooltip frames for help and GUD tooltips.
 144 To display multi-line help text in the echo area, set this to t
 145 and enable `tooltip-mode'."
 146   :type 'boolean
 147   :group 'tooltip)
 148
 149 \f
 150 ;;; Variables that are not customizable.
 151
 152 (defvar tooltip-hook nil
 153   "Functions to call to display tooltips.
 154 Each function is called with one argument EVENT which is a copy of
 155 the last mouse movement event that occurred.")
 156
 157 (defvar tooltip-timeout-id nil
 158   "The id of the timeout started when Emacs becomes idle.")
 159
 160 (defvar tooltip-last-mouse-motion-event nil
 161   "A copy of the last mouse motion event seen.")
 162
 163 (defvar tooltip-hide-time nil
 164   "Time when the last tooltip was hidden.")
 165
 166 (defvar gud-tooltip-mode) ;; Prevent warning.
 167
 168 ;;; Event accessors
 169
 170 (defun tooltip-event-buffer (event)
 171   "Return the buffer over which event EVENT occurred.
 172 This might return nil if the event did not occur over a buffer."
 173   (let ((window (posn-window (event-end event))))
 174     (and window (window-buffer window))))
 175
 176 \f
 177 ;;; Timeout for tooltip display
 178
 179 (defun tooltip-delay ()
 180   "Return the delay in seconds for the next tooltip."
 181   (if (and tooltip-hide-time
 182            (< (- (float-time) tooltip-hide-time) tooltip-recent-seconds))
 183       tooltip-short-delay
 184     tooltip-delay))
 185
 186 (defun tooltip-cancel-delayed-tip ()
 187   "Disable the tooltip timeout."
 188   (when tooltip-timeout-id
 189     (disable-timeout tooltip-timeout-id)
 190     (setq tooltip-timeout-id nil)))
 191
 192 (defun tooltip-start-delayed-tip ()
 193   "Add a one-shot timeout to call function `tooltip-timeout'."
 194   (setq tooltip-timeout-id
 195         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 196
 197 (defun tooltip-timeout (object)
 198   "Function called when timer with id `tooltip-timeout-id' fires."
 199   (run-hook-with-args-until-success 'tooltip-hook
 200                                     tooltip-last-mouse-motion-event))
 201
 202 \f
 203 ;;; Displaying tips
 204
 205 (defun tooltip-set-param (alist key value)
 206   "Change the value of KEY in alist ALIST to VALUE.
 207 If there's no association for KEY in ALIST, add one, otherwise
 208 change the existing association.  Value is the resulting alist."
 209   (let ((param (assq key alist)))
 210     (if (consp param)
 211         (setcdr param value)
 212       (push (cons key value) alist))
 213     alist))
 214
 215 (defun tooltip-show (text &optional use-echo-area)
 216   "Show a tooltip window displaying TEXT.
 217
 218 Text larger than `x-max-tooltip-size' is clipped.
 219
 220 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 221 parameters, they determine the x and y position where the tooltip
 222 is displayed.  Otherwise, the tooltip pops at offsets specified by
 223 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 224 position.
 225
 226 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 227 in echo area."
 228   (if use-echo-area
 229       (tooltip-show-help-non-mode text)
 230     (condition-case error
 231         (let ((params (copy-sequence tooltip-frame-parameters))
 232               (fg (face-attribute 'tooltip :foreground))
 233               (bg (face-attribute 'tooltip :background)))
 234           (when (stringp fg)
 235             (setq params (tooltip-set-param params 'foreground-color fg))
 236             (setq params (tooltip-set-param params 'border-color fg)))
 237           (when (stringp bg)
 238             (setq params (tooltip-set-param params 'background-color bg)))
 239           (x-show-tip (propertize text 'face 'tooltip)
 240                       (selected-frame)
 241                       params
 242                       tooltip-hide-delay
 243                       tooltip-x-offset
 244                       tooltip-y-offset))
 245       (error
 246        (message "Error while displaying tooltip: %s" error)
 247        (sit-for 1)
 248        (message "%s" text)))))
 249
 250 (defun tooltip-hide (&optional ignored-arg)
 251   "Hide a tooltip, if one is displayed.
 252 Value is non-nil if tooltip was open."
 253   (tooltip-cancel-delayed-tip)
 254   (when (x-hide-tip)
 255     (setq tooltip-hide-time (float-time))))
 256
 257 \f
 258 ;;; Debugger-related functions
 259
 260 (defun tooltip-identifier-from-point (point)
 261   "Extract the identifier at POINT, if any.
 262 Value is nil if no identifier exists at point.  Identifier extraction
 263 is based on the current syntax table."
 264   (save-excursion
 265     (goto-char point)
 266     (let ((start (progn (skip-syntax-backward "w_") (point))))
 267       (unless (looking-at "[0-9]")
 268         (skip-syntax-forward "w_")
 269         (when (> (point) start)
 270           (buffer-substring start (point)))))))
 271
 272 (defmacro tooltip-region-active-p ()
 273   "Value is non-nil if the region should override command actions."
 274   `(use-region-p))
 275
 276 (defun tooltip-expr-to-print (event)
 277   "Return an expression that should be printed for EVENT.
 278 If a region is active and the mouse is inside the region, print
 279 the region.  Otherwise, figure out the identifier around the point
 280 where the mouse is."
 281   (with-current-buffer (tooltip-event-buffer event)
 282     (let ((point (posn-point (event-end event))))
 283       (if (tooltip-region-active-p)
 284           (when (and (<= (region-beginning) point) (<= point (region-end)))
 285             (buffer-substring (region-beginning) (region-end)))
 286         (tooltip-identifier-from-point point)))))
 287
 288 (defun tooltip-process-prompt-regexp (process)
 289   "Return regexp matching the prompt of PROCESS at the end of a string.
 290 The prompt is taken from the value of `comint-prompt-regexp' in
 291 the buffer of PROCESS."
 292   (let ((prompt-regexp (with-current-buffer (process-buffer process)
 293                          comint-prompt-regexp)))
 294     (concat "\n*"
 295             ;; Most start with `^' but the one for `sdb' cannot be easily
 296             ;; stripped.  Code the prompt for `sdb' fixed here.
 297             (if (= (aref prompt-regexp 0) ?^)
 298                 (substring prompt-regexp 1)
 299               "\\*")
 300             "$")))
 301
 302 (defun tooltip-strip-prompt (process output)
 303   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 304   (save-match-data
 305     (if (string-match (tooltip-process-prompt-regexp process) output)
 306         (substring output 0 (match-beginning 0))
 307       output)))
 308
 309 \f
 310 ;;; Tooltip help.
 311
 312 (defvar tooltip-help-message nil
 313   "The last help message received via `tooltip-show-help'.")
 314
 315 (defvar tooltip-previous-message nil
 316   "The previous content of the echo area.")
 317
 318 (defun tooltip-show-help-non-mode (help)
 319   "Function installed as `show-help-function' when tooltip is off."
 320   (when (and (not (window-minibuffer-p)) ;Don't overwrite minibuffer contents.
 321              ;; Don't know how to reproduce it in Elisp:
 322              ;; Don't overwrite a keystroke echo.
 323              ;; (NILP (echo_message_buffer) || ok_to_overwrite_keystroke_echo)
 324              (not cursor-in-echo-area)) ;Don't overwrite a prompt.
 325     (cond
 326      ((stringp help)
 327       (unless tooltip-previous-message
 328         (setq tooltip-previous-message (current-message)))
 329       (let ((message-truncate-lines t)
 330             (message-log-max nil))
 331         (message "%s" (replace-regexp-in-string "\n" ", " help))))
 332      ((stringp tooltip-previous-message)
 333       (let ((message-log-max nil))
 334         (message "%s" tooltip-previous-message)
 335         (setq tooltip-previous-message nil)))
 336      (t
 337       (message nil)))))
 338
 339
 340 (defun tooltip-show-help (msg)
 341   "Function installed as `show-help-function'.
 342 MSG is either a help string to display, or nil to cancel the display."
 343   (let ((previous-help tooltip-help-message))
 344     (setq tooltip-help-message msg)
 345     (cond ((null msg)
 346            ;; Cancel display.  This also cancels a delayed tip, if
 347            ;; there is one.
 348            (tooltip-hide))
 349           ((equal previous-help msg)
 350            ;; Same help as before (but possibly the mouse has moved).
 351            ;; Keep what we have.
 352            )
 353           (t
 354            ;; A different help.  Remove a previous tooltip, and
 355            ;; display a new one, with some delay.
 356            (tooltip-hide)
 357            (tooltip-start-delayed-tip)))))
 358
 359 (defun tooltip-help-tips (event)
 360   "Hook function to display a help tooltip.
 361 This is installed on the hook `tooltip-hook', which is run when
 362 the timer with id `tooltip-timeout-id' fires.
 363 Value is non-nil if this function handled the tip."
 364   (when (stringp tooltip-help-message)
 365     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 366     t))
 367
 368 (provide 'tooltip)
 369
 370 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 371 ;;; tooltip.el ends here