lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992,1993,1994,1995,1996,1998,1999,2000,2001,2002,2004
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   ;; Warning suppression -- can't require x-win in batch:
  33   (autoload 'xw-defined-colors "x-win"))
  34
  35 \f
  36 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  37 ;;; Font selection.
  38 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  39
  40 (defgroup font-selection nil
  41   "Influencing face font selection."
  42   :group 'faces)
  43
  44
  45 (defcustom face-font-selection-order
  46   '(:width :height :weight :slant)
  47   "*A list specifying how face font selection chooses fonts.
  48 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  49 must appear once in the list, and the list must not contain any other
  50 elements.  Font selection tries to find a best matching font for
  51 those face attributes first that appear first in the list.  For
  52 example, if `:slant' appears before `:height', font selection first
  53 tries to find a font with a suitable slant, even if this results in
  54 a font height that isn't optimal."
  55   :tag "Font selection order"
  56   :type '(list symbol symbol symbol symbol)
  57   :group 'font-selection
  58   :set #'(lambda (symbol value)
  59            (set-default symbol value)
  60            (internal-set-font-selection-order value)))
  61
  62
  63 ;; This is defined originally in xfaces.c.
  64 (defcustom face-font-family-alternatives
  65   '(("courier" "fixed")
  66     ("helv" "helvetica" "arial" "fixed"))
  67   "*Alist of alternative font family names.
  68 Each element has the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  69 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  70 ALTERNATIVE2 etc."
  71   :tag "Alternative font families to try"
  72   :type '(repeat (repeat string))
  73   :group 'font-selection
  74   :set #'(lambda (symbol value)
  75            (set-default symbol value)
  76            (internal-set-alternative-font-family-alist value)))
  77
  78
  79 ;; This is defined originally in xfaces.c.
  80 (defcustom face-font-registry-alternatives
  81   (if (eq system-type 'windows-nt)
  82       '(("iso8859-1" "ms-oemlatin")
  83         ("gb2312.1980" "gb2312")
  84         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  85         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  86         ("muletibetan-2" "muletibetan-0"))
  87     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  88       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  89       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  90       ("muletibetan-2" "muletibetan-0")))
  91   "*Alist of alternative font registry names.
  92 Each element has the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  93 If fonts of registry REGISTRY can be loaded, font selection
  94 tries to find a best matching font among all fonts of registry
  95 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  96   :tag "Alternative font registries to try"
  97   :type '(repeat (repeat string))
  98   :version "21.1"
  99   :group 'font-selection
 100   :set #'(lambda (symbol value)
 101            (set-default symbol value)
 102            (internal-set-alternative-font-registry-alist value)))
 103
 104
 105 \f
 106 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 107 ;;; Creation, copying.
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110
 111 (defun face-list ()
 112   "Return a list of all defined face names."
 113   (mapcar #'car face-new-frame-defaults))
 114
 115
 116 ;;; ### If not frame-local initialize by what X resources?
 117
 118 (defun make-face (face &optional no-init-from-resources)
 119   "Define a new face with name FACE, a symbol.
 120 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 121 variants of FACE from X resources.  (X resources recognized are found
 122 in the global variable `face-x-resources'.)  If FACE is already known
 123 as a face, leave it unmodified.  Value is FACE."
 124   (interactive "SMake face: ")
 125   (unless (facep face)
 126     ;; Make frame-local faces (this also makes the global one).
 127     (dolist (frame (frame-list))
 128       (internal-make-lisp-face face frame))
 129     ;; Add the face to the face menu.
 130     (when (fboundp 'facemenu-add-new-face)
 131       (facemenu-add-new-face face))
 132     ;; Define frame-local faces for all frames from X resources.
 133     (unless no-init-from-resources
 134       (make-face-x-resource-internal face)))
 135   face)
 136
 137
 138 (defun make-empty-face (face)
 139   "Define a new, empty face with name FACE.
 140 If the face already exists, it is left unmodified.  Value is FACE."
 141   (interactive "SMake empty face: ")
 142   (make-face face 'no-init-from-resources))
 143
 144
 145 (defun copy-face (old-face new-face &optional frame new-frame)
 146   "Define a face just like OLD-FACE, with name NEW-FACE.
 147
 148 If NEW-FACE already exists as a face, it is modified to be like
 149 OLD-FACE.  If it doesn't already exist, it is created.
 150
 151 If the optional argument FRAME is given as a frame, NEW-FACE is
 152 changed on FRAME only.
 153 If FRAME is t, the frame-independent default specification for OLD-FACE
 154 is copied to NEW-FACE.
 155 If FRAME is nil, copying is done for the frame-independent defaults
 156 and for each existing frame.
 157
 158 If the optional fourth argument NEW-FRAME is given,
 159 copy the information from face OLD-FACE on frame FRAME
 160 to NEW-FACE on frame NEW-FRAME."
 161   (let ((inhibit-quit t))
 162     (if (null frame)
 163         (progn
 164           (dolist (frame (frame-list))
 165             (copy-face old-face new-face frame))
 166           (copy-face old-face new-face t))
 167       (internal-copy-lisp-face old-face new-face frame new-frame))
 168     new-face))
 169
 170
 171 \f
 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 173 ;;; Obsolete functions
 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 175
 176 ;; The functions in this section are defined because Lisp packages use
 177 ;; them, despite the prefix `internal-' suggesting that they are
 178 ;; private to the face implementation.
 179
 180 (defun internal-find-face (name &optional frame)
 181   "Retrieve the face named NAME.
 182 Return nil if there is no such face.
 183 If the optional argument FRAME is given, this gets the face NAME for
 184 that frame; otherwise, it uses the selected frame.
 185 If FRAME is the symbol t, then the global, non-frame face is returned.
 186 If NAME is already a face, it is simply returned.
 187
 188 This function is defined for compatibility with Emacs 20.2.  It
 189 should not be used anymore."
 190   (facep name))
 191 (make-obsolete 'internal-find-face 'facep "21.1")
 192
 193
 194 (defun internal-get-face (name &optional frame)
 195   "Retrieve the face named NAME; error if there is none.
 196 If the optional argument FRAME is given, this gets the face NAME for
 197 that frame; otherwise, it uses the selected frame.
 198 If FRAME is the symbol t, then the global, non-frame face is returned.
 199 If NAME is already a face, it is simply returned."
 200   (or (facep name)
 201       (check-face name)))
 202 (make-obsolete 'internal-get-face "see `facep' and `check-face'." "21.1")
 203
 204 \f
 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 206 ;;; Predicates, type checks.
 207 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 208
 209 (defun facep (face)
 210   "Return non-nil if FACE is a face name."
 211   (internal-lisp-face-p face))
 212
 213
 214 (defun check-face (face)
 215   "Signal an error if FACE doesn't name a face.
 216 Value is FACE."
 217   (unless (facep face)
 218     (error "Not a face: %s" face))
 219   face)
 220
 221
 222 ;; The ID returned is not to be confused with the internally used IDs
 223 ;; of realized faces.  The ID assigned to Lisp faces is used to
 224 ;; support faces in display table entries.
 225
 226 (defun face-id (face &optional frame)
 227   "Return the internal ID of face with name FACE.
 228 The optional argument FRAME is ignored, since the internal face ID
 229 of a face name is the same for all frames."
 230   (check-face face)
 231   (get face 'face))
 232
 233
 234 (defun face-equal (face1 face2 &optional frame)
 235   "Non-nil if faces FACE1 and FACE2 are equal.
 236 Faces are considered equal if all their attributes are equal.
 237 If the optional argument FRAME is given, report on face FACE in that frame.
 238 If FRAME is t, report on the defaults for face FACE (for new frames).
 239 If FRAME is omitted or nil, use the selected frame."
 240   (internal-lisp-face-equal-p face1 face2 frame))
 241
 242
 243 (defun face-differs-from-default-p (face &optional frame)
 244   "Return non-nil if FACE displays differently from the default face.
 245 If the optional argument FRAME is given, report on face FACE in that frame.
 246 If FRAME is t, report on the defaults for face FACE (for new frames).
 247 If FRAME is omitted or nil, use the selected frame."
 248   (let ((attrs
 249          '(:family :width :height :weight :slant :foreground
 250            :foreground :background :underline :overline
 251            :strike-through :box :inverse-video))
 252         (differs nil))
 253     (while (and attrs (not differs))
 254       (let* ((attr (pop attrs))
 255              (attr-val (face-attribute face attr frame t)))
 256         (when (and
 257                (not (eq attr-val 'unspecified))
 258                (display-supports-face-attributes-p (list attr attr-val)
 259                                                    frame))
 260           (setq differs attr))))
 261     differs))
 262
 263
 264 (defun face-nontrivial-p (face &optional frame)
 265   "True if face FACE has some non-nil attribute.
 266 If the optional argument FRAME is given, report on face FACE in that frame.
 267 If FRAME is t, report on the defaults for face FACE (for new frames).
 268 If FRAME is omitted or nil, use the selected frame."
 269   (not (internal-lisp-face-empty-p face frame)))
 270
 271
 272 \f
 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 274 ;;; Setting face attributes from X resources.
 275 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 276
 277 (defcustom face-x-resources
 278   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 279     (:width (".attributeWidth" . "Face.AttributeWidth"))
 280     (:height (".attributeHeight" . "Face.AttributeHeight"))
 281     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 282     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 283     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 284     (:background (".attributeBackground" . "Face.AttributeBackground"))
 285     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 286     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 287     (:box (".attributeBox" . "Face.AttributeBox"))
 288     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 289     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 290     (:stipple
 291      (".attributeStipple" . "Face.AttributeStipple")
 292      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 293     (:bold (".attributeBold" . "Face.AttributeBold"))
 294     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 295     (:font (".attributeFont" . "Face.AttributeFont"))
 296     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 297   "*List of X resources and classes for face attributes.
 298 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 299 the name of a face attribute, and each ENTRY is a cons of the form
 300 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 301 X resource class for the attribute."
 302   :type '(repeat (cons symbol (repeat (cons string string))))
 303   :group 'faces)
 304
 305
 306 (defun set-face-attribute-from-resource (face attribute resource class frame)
 307   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 308 Value is the attribute value specified by the resource, or nil
 309 if not present.  This function displays a message if the resource
 310 specifies an invalid attribute."
 311   (let* ((face-name (face-name face))
 312          (value (internal-face-x-get-resource (concat face-name resource)
 313                                               class frame)))
 314     (when value
 315       (condition-case ()
 316           (internal-set-lisp-face-attribute-from-resource
 317            face attribute (downcase value) frame)
 318         (error
 319          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 320                   face-name frame attribute value))))
 321     value))
 322
 323
 324 (defun set-face-attributes-from-resources (face frame)
 325   "Set attributes of FACE from X resources for FRAME."
 326   (when (memq (framep frame) '(x w32 mac))
 327     (dolist (definition face-x-resources)
 328       (let ((attribute (car definition)))
 329         (dolist (entry (cdr definition))
 330           (set-face-attribute-from-resource face attribute (car entry)
 331                                             (cdr entry) frame))))))
 332
 333
 334 (defun make-face-x-resource-internal (face &optional frame)
 335   "Fill frame-local FACE on FRAME from X resources.
 336 FRAME nil or not specified means do it for all frames."
 337   (if (null frame)
 338       (dolist (frame (frame-list))
 339         (set-face-attributes-from-resources face frame))
 340     (set-face-attributes-from-resources face frame)))
 341
 342
 343 \f
 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 345 ;;; Retrieving face attributes.
 346 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 347
 348 (defun face-name (face)
 349   "Return the name of face FACE."
 350   (symbol-name (check-face face)))
 351
 352
 353 (defun face-attribute (face attribute &optional frame inherit)
 354   "Return the value of FACE's ATTRIBUTE on FRAME.
 355 If the optional argument FRAME is given, report on face FACE in that frame.
 356 If FRAME is t, report on the defaults for face FACE (for new frames).
 357 If FRAME is omitted or nil, use the selected frame.
 358
 359 If INHERIT is nil, only attributes directly defined by FACE are considered,
 360   so the return value may be `unspecified', or a relative value.
 361 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 362   faces specified by its `:inherit' attribute; however the return value
 363   may still be `unspecified' or relative.
 364 If INHERIT is a face or a list of faces, then the result is further merged
 365   with that face (or faces), until it becomes specified and absolute.
 366
 367 To ensure that the return value is always specified and absolute, use a
 368 value of `default' for INHERIT; this will resolve any unspecified or
 369 relative values by merging with the `default' face (which is always
 370 completely specified)."
 371   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 372     (when (and inherit (face-attribute-relative-p attribute value))
 373       ;; VALUE is relative, so merge with inherited faces
 374       (let ((inh-from (face-attribute face :inherit frame)))
 375         (unless (or (null inh-from) (eq inh-from 'unspecified))
 376           (setq value
 377                 (face-attribute-merged-with attribute value inh-from frame)))))
 378     (when (and inherit
 379                (not (eq inherit t))
 380                (face-attribute-relative-p attribute value))
 381       ;; We should merge with INHERIT as well
 382       (setq value (face-attribute-merged-with attribute value inherit frame)))
 383     value))
 384
 385 (defun face-attribute-merged-with (attribute value faces &optional frame)
 386   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 387 FACES may be either a single face or a list of faces.
 388 \[This is an internal function]"
 389   (cond ((not (face-attribute-relative-p attribute value))
 390          value)
 391         ((null faces)
 392          value)
 393         ((consp faces)
 394          (face-attribute-merged-with
 395           attribute
 396           (face-attribute-merged-with attribute value (car faces) frame)
 397           (cdr faces)
 398           frame))
 399         (t
 400          (merge-face-attribute attribute
 401                                value
 402                                (face-attribute faces attribute frame t)))))
 403
 404
 405 (defmacro face-attribute-specified-or (value &rest body)
 406   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 407   (let ((temp (make-symbol "value")))
 408     `(let ((,temp ,value))
 409        (if (not (eq ,temp 'unspecified))
 410            ,temp
 411          ,@body))))
 412
 413 (defun face-foreground (face &optional frame inherit)
 414   "Return the foreground color name of FACE, or nil if unspecified.
 415 If the optional argument FRAME is given, report on face FACE in that frame.
 416 If FRAME is t, report on the defaults for face FACE (for new frames).
 417 If FRAME is omitted or nil, use the selected frame.
 418
 419 If INHERIT is nil, only a foreground color directly defined by FACE is
 420   considered, so the return value may be nil.
 421 If INHERIT is t, and FACE doesn't define a foreground color, then any
 422   foreground color that FACE inherits through its `:inherit' attribute
 423   is considered as well; however the return value may still be nil.
 424 If INHERIT is a face or a list of faces, then it is used to try to
 425   resolve an unspecified foreground color.
 426
 427 To ensure that a valid color is always returned, use a value of
 428 `default' for INHERIT; this will resolve any unspecified values by
 429 merging with the `default' face (which is always completely specified)."
 430   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 431                                nil))
 432
 433 (defun face-background (face &optional frame inherit)
 434   "Return the background color name of FACE, or nil if unspecified.
 435 If the optional argument FRAME is given, report on face FACE in that frame.
 436 If FRAME is t, report on the defaults for face FACE (for new frames).
 437 If FRAME is omitted or nil, use the selected frame.
 438
 439 If INHERIT is nil, only a background color directly defined by FACE is
 440   considered, so the return value may be nil.
 441 If INHERIT is t, and FACE doesn't define a background color, then any
 442   background color that FACE inherits through its `:inherit' attribute
 443   is considered as well; however the return value may still be nil.
 444 If INHERIT is a face or a list of faces, then it is used to try to
 445   resolve an unspecified background color.
 446
 447 To ensure that a valid color is always returned, use a value of
 448 `default' for INHERIT; this will resolve any unspecified values by
 449 merging with the `default' face (which is always completely specified)."
 450   (face-attribute-specified-or (face-attribute face :background frame inherit)
 451                                nil))
 452
 453 (defun face-stipple (face &optional frame inherit)
 454  "Return the stipple pixmap name of FACE, or nil if unspecified.
 455 If the optional argument FRAME is given, report on face FACE in that frame.
 456 If FRAME is t, report on the defaults for face FACE (for new frames).
 457 If FRAME is omitted or nil, use the selected frame.
 458
 459 If INHERIT is nil, only a stipple directly defined by FACE is
 460   considered, so the return value may be nil.
 461 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 462   that FACE inherits through its `:inherit' attribute is considered as
 463   well; however the return value may still be nil.
 464 If INHERIT is a face or a list of faces, then it is used to try to
 465   resolve an unspecified stipple.
 466
 467 To ensure that a valid stipple or nil is always returned, use a value of
 468 `default' for INHERIT; this will resolve any unspecified values by merging
 469 with the `default' face (which is always completely specified)."
 470   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 471                                nil))
 472
 473
 474 (defalias 'face-background-pixmap 'face-stipple)
 475
 476
 477 (defun face-underline-p (face &optional frame)
 478  "Return non-nil if FACE is underlined.
 479 If the optional argument FRAME is given, report on face FACE in that frame.
 480 If FRAME is t, report on the defaults for face FACE (for new frames).
 481 If FRAME is omitted or nil, use the selected frame."
 482  (eq (face-attribute face :underline frame) t))
 483
 484
 485 (defun face-inverse-video-p (face &optional frame)
 486  "Return non-nil if FACE is in inverse video on FRAME.
 487 If the optional argument FRAME is given, report on face FACE in that frame.
 488 If FRAME is t, report on the defaults for face FACE (for new frames).
 489 If FRAME is omitted or nil, use the selected frame."
 490  (eq (face-attribute face :inverse-video frame) t))
 491
 492
 493 (defun face-bold-p (face &optional frame)
 494   "Return non-nil if the font of FACE is bold on FRAME.
 495 If the optional argument FRAME is given, report on face FACE in that frame.
 496 If FRAME is t, report on the defaults for face FACE (for new frames).
 497 If FRAME is omitted or nil, use the selected frame.
 498 Use `face-attribute' for finer control."
 499   (let ((bold (face-attribute face :weight frame)))
 500     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 501
 502
 503 (defun face-italic-p (face &optional frame)
 504   "Return non-nil if the font of FACE is italic on FRAME.
 505 If the optional argument FRAME is given, report on face FACE in that frame.
 506 If FRAME is t, report on the defaults for face FACE (for new frames).
 507 If FRAME is omitted or nil, use the selected frame.
 508 Use `face-attribute' for finer control."
 509   (let ((italic (face-attribute face :slant frame)))
 510     (memq italic '(italic oblique))))
 511
 512
 513 \f
 514 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 515 ;;; Face documentation.
 516 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 517
 518 (defun face-documentation (face)
 519   "Get the documentation string for FACE."
 520   (get face 'face-documentation))
 521
 522
 523 (defun set-face-documentation (face string)
 524   "Set the documentation string for FACE to STRING."
 525   ;; Perhaps the text should go in DOC.
 526   (put face 'face-documentation (purecopy string)))
 527
 528
 529 (defalias 'face-doc-string 'face-documentation)
 530 (defalias 'set-face-doc-string 'set-face-documentation)
 531
 532
 533 \f
 534 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 535 ;; Setting face attributes.
 536 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 537
 538
 539 (defun set-face-attribute (face frame &rest args)
 540   "Set attributes of FACE on FRAME from ARGS.
 541
 542 FRAME nil means change attributes on all frames.  FRAME t means change
 543 the default for new frames (this is done automatically each time an
 544 attribute is changed on all frames).
 545
 546 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 547 face attribute name.  All attributes can be set to `unspecified';
 548 this fact is not further mentioned below.
 549
 550 The following attributes are recognized:
 551
 552 `:family'
 553
 554 VALUE must be a string specifying the font family, e.g. ``courier'',
 555 or a fontset alias name.  If a font family is specified, wild-cards `*'
 556 and `?' are allowed.
 557
 558 `:width'
 559
 560 VALUE specifies the relative proportionate width of the font to use.
 561 It must be one of the symbols `ultra-condensed', `extra-condensed',
 562 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 563 `extra-expanded', or `ultra-expanded'.
 564
 565 `:height'
 566
 567 VALUE must be either an integer specifying the height of the font to use
 568 in 1/10 pt, a floating point number specifying the amount by which to
 569 scale any underlying face, or a function, which is called with the old
 570 height (from the underlying face), and should return the new height.
 571
 572 `:weight'
 573
 574 VALUE specifies the weight of the font to use.  It must be one of the
 575 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 576 `semi-light', `light', `extra-light', `ultra-light'.
 577
 578 `:slant'
 579
 580 VALUE specifies the slant of the font to use.  It must be one of the
 581 symbols `italic', `oblique', `normal', `reverse-italic', or
 582 `reverse-oblique'.
 583
 584 `:foreground', `:background'
 585
 586 VALUE must be a color name, a string.
 587
 588 `:underline'
 589
 590 VALUE specifies whether characters in FACE should be underlined.  If
 591 VALUE is t, underline with foreground color of the face.  If VALUE is
 592 a string, underline with that color.  If VALUE is nil, explicitly
 593 don't underline.
 594
 595 `:overline'
 596
 597 VALUE specifies whether characters in FACE should be overlined.  If
 598 VALUE is t, overline with foreground color of the face.  If VALUE is a
 599 string, overline with that color.  If VALUE is nil, explicitly don't
 600 overline.
 601
 602 `:strike-through'
 603
 604 VALUE specifies whether characters in FACE should be drawn with a line
 605 striking through them.  If VALUE is t, use the foreground color of the
 606 face.  If VALUE is a string, strike-through with that color.  If VALUE
 607 is nil, explicitly don't strike through.
 608
 609 `:box'
 610
 611 VALUE specifies whether characters in FACE should have a box drawn
 612 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 613 VALUE is t, draw a box with lines of width 1 in the foreground color
 614 of the face.  If VALUE is a string, the string must be a color name,
 615 and the box is drawn in that color with a line width of 1.  Otherwise,
 616 VALUE must be a property list of the form `(:line-width WIDTH
 617 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 618 the property list, a default value will be used for the value, as
 619 specified below.  WIDTH specifies the width of the lines to draw; it
 620 defaults to 1.  If WIDTH is negative, the absolute value is the width
 621 of the lines, and draw top/bottom lines inside the characters area,
 622 not around it.  COLOR is the name of the color to draw in, default is
 623 the foreground color of the face for simple boxes, and the background
 624 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 625 should be draw.  If STYLE is `released-button', draw a box looking
 626 like a released 3D button.  If STYLE is `pressed-button' draw a box
 627 that appears like a pressed button.  If STYLE is nil, the default if
 628 the property list doesn't contain a style specification, draw a 2D
 629 box.
 630
 631 `:inverse-video'
 632
 633 VALUE specifies whether characters in FACE should be displayed in
 634 inverse video.  VALUE must be one of t or nil.
 635
 636 `:stipple'
 637
 638 If VALUE is a string, it must be the name of a file of pixmap data.
 639 The directories listed in the `x-bitmap-file-path' variable are
 640 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 641 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 642 is a string containing the raw bits of the bitmap.  VALUE nil means
 643 explicitly don't use a stipple pattern.
 644
 645 For convenience, attributes `:family', `:width', `:height', `:weight',
 646 and `:slant' may also be set in one step from an X font name:
 647
 648 `:font'
 649
 650 Set font-related face attributes from VALUE.  VALUE must be a valid
 651 XLFD font name.  If it is a font name pattern, the first matching font
 652 will be used.
 653
 654 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 655 be used to specify that a bold or italic font should be used.  VALUE
 656 must be t or nil in that case.  A value of `unspecified' is not allowed.
 657
 658 `:inherit'
 659
 660 VALUE is the name of a face from which to inherit attributes, or a list
 661 of face names.  Attributes from inherited faces are merged into the face
 662 like an underlying face would be, with higher priority than underlying faces."
 663   (let ((where (if (null frame) 0 frame)))
 664     (setq args (purecopy args))
 665     ;; If we set the new-frame defaults, this face is modified outside Custom.
 666     (if (memq where '(0 t))
 667         (put face 'face-modified t))
 668     (while args
 669       (internal-set-lisp-face-attribute face (car args)
 670                                         (purecopy (cadr args))
 671                                         where)
 672       (setq args (cdr (cdr args))))))
 673
 674
 675 (defun make-face-bold (face &optional frame noerror)
 676   "Make the font of FACE be bold, if possible.
 677 FRAME nil or not specified means change face on all frames.
 678 Argument NOERROR is ignored and retained for compatibility.
 679 Use `set-face-attribute' for finer control of the font weight."
 680   (interactive (list (read-face-name "Make which face bold")))
 681   (set-face-attribute face frame :weight 'bold))
 682
 683
 684 (defun make-face-unbold (face &optional frame noerror)
 685   "Make the font of FACE be non-bold, if possible.
 686 FRAME nil or not specified means change face on all frames.
 687 Argument NOERROR is ignored and retained for compatibility."
 688   (interactive (list (read-face-name "Make which face non-bold")))
 689   (set-face-attribute face frame :weight 'normal))
 690
 691
 692 (defun make-face-italic (face &optional frame noerror)
 693   "Make the font of FACE be italic, if possible.
 694 FRAME nil or not specified means change face on all frames.
 695 Argument NOERROR is ignored and retained for compatibility.
 696 Use `set-face-attribute' for finer control of the font slant."
 697   (interactive (list (read-face-name "Make which face italic")))
 698   (set-face-attribute face frame :slant 'italic))
 699
 700
 701 (defun make-face-unitalic (face &optional frame noerror)
 702   "Make the font of FACE be non-italic, if possible.
 703 FRAME nil or not specified means change face on all frames.
 704 Argument NOERROR is ignored and retained for compatibility."
 705   (interactive (list (read-face-name "Make which face non-italic")))
 706   (set-face-attribute face frame :slant 'normal))
 707
 708
 709 (defun make-face-bold-italic (face &optional frame noerror)
 710   "Make the font of FACE be bold and italic, if possible.
 711 FRAME nil or not specified means change face on all frames.
 712 Argument NOERROR is ignored and retained for compatibility.
 713 Use `set-face-attribute' for finer control of font weight and slant."
 714   (interactive (list (read-face-name "Make which face bold-italic")))
 715   (set-face-attribute face frame :weight 'bold :slant 'italic))
 716
 717
 718 (defun set-face-font (face font &optional frame)
 719   "Change font-related attributes of FACE to those of FONT (a string).
 720 FRAME nil or not specified means change face on all frames.
 721 This sets the attributes `:family', `:width', `:height', `:weight',
 722 and `:slant'.  When called interactively, prompt for the face and font."
 723   (interactive (read-face-and-attribute :font))
 724   (set-face-attribute face frame :font font))
 725
 726
 727 ;; Implementation note: Emulating gray background colors with a
 728 ;; stipple pattern is now part of the face realization process, and is
 729 ;; done in C depending on the frame on which the face is realized.
 730
 731 (defun set-face-background (face color &optional frame)
 732   "Change the background color of face FACE to COLOR (a string).
 733 FRAME nil or not specified means change face on all frames.
 734 COLOR can be a system-defined color name (see `list-colors-display')
 735 or a hex spec of the form #RRGGBB.
 736 When called interactively, prompts for the face and color."
 737   (interactive (read-face-and-attribute :background))
 738   (set-face-attribute face frame :background (or color 'unspecified)))
 739
 740
 741 (defun set-face-foreground (face color &optional frame)
 742   "Change the foreground color of face FACE to COLOR (a string).
 743 FRAME nil or not specified means change face on all frames.
 744 COLOR can be a system-defined color name (see `list-colors-display')
 745 or a hex spec of the form #RRGGBB.
 746 When called interactively, prompts for the face and color."
 747   (interactive (read-face-and-attribute :foreground))
 748   (set-face-attribute face frame :foreground (or color 'unspecified)))
 749
 750
 751 (defun set-face-stipple (face stipple &optional frame)
 752   "Change the stipple pixmap of face FACE to STIPPLE.
 753 FRAME nil or not specified means change face on all frames.
 754 STIPPLE should be a string, the name of a file of pixmap data.
 755 The directories listed in the `x-bitmap-file-path' variable are searched.
 756
 757 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 758 where WIDTH and HEIGHT are the size in pixels,
 759 and DATA is a string, containing the raw bits of the bitmap."
 760   (interactive (read-face-and-attribute :stipple))
 761   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 762
 763
 764 (defun set-face-underline (face underline &optional frame)
 765   "Specify whether face FACE is underlined.
 766 UNDERLINE nil means FACE explicitly doesn't underline.
 767 UNDERLINE non-nil means FACE explicitly does underlining
 768 with the same of the foreground color.
 769 If UNDERLINE is a string, underline with the color named UNDERLINE.
 770 FRAME nil or not specified means change face on all frames.
 771 Use `set-face-attribute' to ``unspecify'' underlining."
 772   (interactive
 773    (let ((list (read-face-and-attribute :underline)))
 774      (list (car list) (eq (car (cdr list)) t))))
 775   (set-face-attribute face frame :underline underline))
 776
 777
 778 (defun set-face-underline-p (face underline-p &optional frame)
 779   "Specify whether face FACE is underlined.
 780 UNDERLINE-P nil means FACE explicitly doesn't underline.
 781 UNDERLINE-P non-nil means FACE explicitly does underlining.
 782 FRAME nil or not specified means change face on all frames.
 783 Use `set-face-attribute' to ``unspecify'' underlining."
 784   (interactive
 785    (let ((list (read-face-and-attribute :underline)))
 786      (list (car list) (eq (car (cdr list)) t))))
 787   (set-face-attribute face frame :underline underline-p))
 788
 789
 790 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 791   "Specify whether face FACE is in inverse video.
 792 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 793 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 794 FRAME nil or not specified means change face on all frames.
 795 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 796   (interactive
 797    (let ((list (read-face-and-attribute :inverse-video)))
 798      (list (car list) (eq (car (cdr list)) t))))
 799   (set-face-attribute face frame :inverse-video inverse-video-p))
 800
 801
 802 (defun set-face-bold-p (face bold-p &optional frame)
 803   "Specify whether face FACE is bold.
 804 BOLD-P non-nil means FACE should explicitly display bold.
 805 BOLD-P nil means FACE should explicitly display non-bold.
 806 FRAME nil or not specified means change face on all frames.
 807 Use `set-face-attribute' or `modify-face' for finer control."
 808   (if (null bold-p)
 809       (make-face-unbold face frame)
 810     (make-face-bold face frame)))
 811
 812
 813 (defun set-face-italic-p (face italic-p &optional frame)
 814   "Specify whether face FACE is italic.
 815 ITALIC-P non-nil means FACE should explicitly display italic.
 816 ITALIC-P nil means FACE should explicitly display non-italic.
 817 FRAME nil or not specified means change face on all frames.
 818 Use `set-face-attribute' or `modify-face' for finer control."
 819   (if (null italic-p)
 820       (make-face-unitalic face frame)
 821     (make-face-italic face frame)))
 822
 823
 824 (defalias 'set-face-background-pixmap 'set-face-stipple)
 825
 826
 827 (defun invert-face (face &optional frame)
 828   "Swap the foreground and background colors of FACE.
 829 If FRAME is omitted or nil, it means change face on all frames.
 830 If FACE specifies neither foreground nor background color,
 831 set its foreground and background to the background and foreground
 832 of the default face.  Value is FACE."
 833   (interactive (list (read-face-name "Invert face")))
 834   (let ((fg (face-attribute face :foreground frame))
 835         (bg (face-attribute face :background frame)))
 836     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 837         (set-face-attribute face frame :foreground bg :background fg)
 838       (set-face-attribute face frame
 839                           :foreground
 840                           (face-attribute 'default :background frame)
 841                           :background
 842                           (face-attribute 'default :foreground frame))))
 843   face)
 844
 845 \f
 846 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 847 ;;; Interactively modifying faces.
 848 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 849
 850 (defun read-face-name (prompt &optional string-describing-default multiple)
 851   "Read a face, defaulting to the face or faces on the char after point.
 852 If it has a `read-face-name' property, that overrides the `face' property.
 853 PROMPT describes what you will do with the face (don't end in a space).
 854 STRING-DESCRIBING-DEFAULT describes what default you will use
 855 if this function returns nil.
 856 If MULTIPLE is non-nil, return a list of faces (possibly only one).
 857 Otherwise, return a single face."
 858   (let ((faceprop (or (get-char-property (point) 'read-face-name)
 859                       (get-char-property (point) 'face)))
 860         faces)
 861     ;; Make a list of the named faces that the `face' property uses.
 862     (if (and (listp faceprop)
 863              ;; Don't treat an attribute spec as a list of faces.
 864              (not (keywordp (car faceprop)))
 865              (not (memq (car faceprop) '(foreground-color background-color))))
 866         (dolist (f faceprop)
 867           (if (symbolp f)
 868               (push f faces)))
 869       (if (symbolp faceprop)
 870           (push faceprop faces)))
 871     ;; If there are none, try to get a face name from the buffer.
 872     (if (and (null faces)
 873              (memq (intern-soft (thing-at-point 'symbol)) (face-list)))
 874         (setq faces (list (intern-soft (thing-at-point 'symbol)))))
 875
 876     ;; If we only want one, and the default is more than one,
 877     ;; discard the unwanted ones now.
 878     (unless multiple
 879       (if faces
 880           (setq faces (list (car faces)))))
 881     (let* ((input
 882             ;; Read the input.
 883             (completing-read
 884              (if (or faces string-describing-default)
 885                  (format "%s (default %s): " prompt
 886                          (if faces (mapconcat 'symbol-name faces ", ")
 887                            string-describing-default))
 888                (format "%s: " prompt))
 889              obarray 'custom-facep t))
 890            ;; Canonicalize the output.
 891            (output
 892             (if (equal input "")
 893                 faces
 894               (if (stringp input)
 895                   (list (intern input))
 896                 input))))
 897       ;; Return either a list of faces or just one face.
 898       (if multiple
 899           output
 900         (car output)))))
 901
 902
 903 (defun face-valid-attribute-values (attribute &optional frame)
 904   "Return valid values for face attribute ATTRIBUTE.
 905 The optional argument FRAME is used to determine available fonts
 906 and colors.  If it is nil or not specified, the selected frame is
 907 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 908 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 909 an integer value."
 910   (let ((valid
 911          (case attribute
 912            (:family
 913             (if window-system
 914                 (mapcar #'(lambda (x) (cons (car x) (car x)))
 915                         (x-font-family-list))
 916               ;; Only one font on TTYs.
 917               (list (cons "default" "default"))))
 918            ((:width :weight :slant :inverse-video)
 919             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 920                     (internal-lisp-face-attribute-values attribute)))
 921            ((:underline :overline :strike-through :box)
 922             (if window-system
 923                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 924                                (internal-lisp-face-attribute-values attribute))
 925                        (mapcar #'(lambda (c) (cons c c))
 926                                (x-defined-colors frame)))
 927               (mapcar #'(lambda (x) (cons (symbol-name x) x))
 928                       (internal-lisp-face-attribute-values attribute))))
 929            ((:foreground :background)
 930             (mapcar #'(lambda (c) (cons c c))
 931                     (defined-colors frame)))
 932            ((:height)
 933             'integerp)
 934            (:stipple
 935             (and (memq window-system '(x w32 mac))
 936                  (mapcar #'list
 937                          (apply #'nconc
 938                                 (mapcar (lambda (dir)
 939                                           (and (file-readable-p dir)
 940                                                (file-directory-p dir)
 941                                                (directory-files dir)))
 942                                         x-bitmap-file-path)))))
 943            (:inherit
 944             (cons '("none" . nil)
 945                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
 946                           (face-list))))
 947            (t
 948             (error "Internal error")))))
 949     (if (and (listp valid) (not (memq attribute '(:inherit))))
 950         (nconc (list (cons "unspecified" 'unspecified)) valid)
 951       valid)))
 952
 953
 954 (defvar face-attribute-name-alist
 955   '((:family . "font family")
 956     (:width . "character set width")
 957     (:height . "height in 1/10 pt")
 958     (:weight . "weight")
 959     (:slant . "slant")
 960     (:underline . "underline")
 961     (:overline . "overline")
 962     (:strike-through . "strike-through")
 963     (:box . "box")
 964     (:inverse-video . "inverse-video display")
 965     (:foreground . "foreground color")
 966     (:background . "background color")
 967     (:stipple . "background stipple")
 968     (:inherit . "inheritance"))
 969   "An alist of descriptive names for face attributes.
 970 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 971 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 972 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 973
 974
 975 (defun face-descriptive-attribute-name (attribute)
 976   "Return a descriptive name for ATTRIBUTE."
 977   (cdr (assq attribute face-attribute-name-alist)))
 978
 979
 980 (defun face-read-string (face default name &optional completion-alist)
 981   "Interactively read a face attribute string value.
 982 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 983 default string to return if no new value is entered.  NAME is a
 984 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 985 alist of valid values, if non-nil.
 986
 987 Entering nothing accepts the default string DEFAULT.
 988 Value is the new attribute value."
 989   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 990   ;; each word in a string separately).
 991   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 992   (let* ((completion-ignore-case t)
 993          (value (completing-read
 994                  (if default
 995                      (format "%s for face `%s' (default %s): "
 996                              name face default)
 997                    (format "%s for face `%s': " name face))
 998                  completion-alist)))
 999     (if (equal value "") default value)))
1000
1001
1002 (defun face-read-integer (face default name)
1003   "Interactively read an integer face attribute value.
1004 FACE is the face whose attribute is read.  DEFAULT is the default
1005 value to return if no new value is entered.  NAME is a descriptive
1006 name of the attribute for prompting.  Value is the new attribute value."
1007   (let ((new-value
1008          (face-read-string face
1009                            (format "%s" default)
1010                            name
1011                            (list (cons "unspecified" 'unspecified)))))
1012     (cond ((equal new-value "unspecified")
1013            'unspecified)
1014           ((member new-value '("unspecified-fg" "unspecified-bg"))
1015            new-value)
1016           (t
1017            (string-to-number new-value)))))
1018
1019
1020 (defun read-face-attribute (face attribute &optional frame)
1021   "Interactively read a new value for FACE's ATTRIBUTE.
1022 Optional argument FRAME nil or unspecified means read an attribute value
1023 of a global face.  Value is the new attribute value."
1024   (let* ((old-value (face-attribute face attribute frame))
1025          (attribute-name (face-descriptive-attribute-name attribute))
1026          (valid (face-valid-attribute-values attribute frame))
1027          new-value)
1028     ;; Represent complex attribute values as strings by printing them
1029     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
1030     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
1031     ;; SHADOW)'.
1032     (when (and (or (eq attribute :stipple)
1033                    (eq attribute :box))
1034                (or (consp old-value)
1035                    (vectorp old-value)))
1036       (setq old-value (prin1-to-string old-value)))
1037     (cond ((listp valid)
1038            (let ((default
1039                    (or (car (rassoc old-value valid))
1040                        (format "%s" old-value))))
1041              (setq new-value
1042                    (face-read-string face default attribute-name valid))
1043              (if (equal new-value default)
1044                  ;; Nothing changed, so don't bother with all the stuff
1045                  ;; below.  In particular, this avoids a non-tty color
1046                  ;; from being canonicalized for a tty when the user
1047                  ;; just uses the default.
1048                  (setq new-value old-value)
1049                ;; Terminal frames can support colors that don't appear
1050                ;; explicitly in VALID, using color approximation code
1051                ;; in tty-colors.el.
1052                (when (and (memq attribute '(:foreground :background))
1053                           (not (memq window-system '(x w32 mac)))
1054                           (not (member new-value
1055                                        '("unspecified"
1056                                          "unspecified-fg" "unspecified-bg"))))
1057                  (setq new-value (car (tty-color-desc new-value frame))))
1058                (when (assoc new-value valid)
1059                  (setq new-value (cdr (assoc new-value valid)))))))
1060           ((eq valid 'integerp)
1061            (setq new-value (face-read-integer face old-value attribute-name)))
1062           (t (error "Internal error")))
1063     ;; Convert stipple and box value text we read back to a list or
1064     ;; vector if it looks like one.  This makes the assumption that a
1065     ;; pixmap file name won't start with an open-paren.
1066     (when (and (or (eq attribute :stipple)
1067                    (eq attribute :box))
1068                (stringp new-value)
1069                (string-match "^[[(]" new-value))
1070       (setq new-value (read new-value)))
1071     new-value))
1072
1073
1074 (defun read-face-font (face &optional frame)
1075   "Read the name of a font for FACE on FRAME.
1076 If optional argument FRAME Is nil or omitted, use the selected frame."
1077   (let ((completion-ignore-case t))
1078     (completing-read (format "Set font attributes of face `%s' from font: " face)
1079                      (x-list-fonts "*" nil frame))))
1080
1081
1082 (defun read-all-face-attributes (face &optional frame)
1083   "Interactively read all attributes for FACE.
1084 If optional argument FRAME Is nil or omitted, use the selected frame.
1085 Value is a property list of attribute names and new values."
1086   (let (result)
1087     (dolist (attribute face-attribute-name-alist result)
1088       (setq result (cons (car attribute)
1089                          (cons (read-face-attribute face (car attribute) frame)
1090                                result))))))
1091
1092 (defun modify-face (&optional face foreground background stipple
1093                               bold-p italic-p underline-p inverse-p frame)
1094   "Modify attributes of faces interactively.
1095 If optional argument FRAME is nil or omitted, modify the face used
1096 for newly created frame, i.e. the global face.
1097 For non-interactive use, `set-face-attribute' is preferred.
1098 When called from elisp, if FACE is nil, all arguments but FRAME are ignored
1099 and the face and its settings are obtained by querying the user."
1100   (interactive)
1101   (if face
1102       (set-face-attribute face frame
1103                           :foreground (or foreground 'unspecified)
1104                           :background (or background 'unspecified)
1105                           :stipple stipple
1106                           :bold bold-p
1107                           :italic italic-p
1108                           :underline underline-p
1109                           :inverse-video inverse-p)
1110     (setq face (read-face-name "Modify face"))
1111     (apply #'set-face-attribute face frame
1112            (read-all-face-attributes face frame))))
1113
1114 (defun read-face-and-attribute (attribute &optional frame)
1115   "Read face name and face attribute value.
1116 ATTRIBUTE is the attribute whose new value is read.
1117 FRAME nil or unspecified means read attribute value of global face.
1118 Value is a list (FACE NEW-VALUE) where FACE is the face read
1119 \(a symbol), and NEW-VALUE is value read."
1120   (cond ((eq attribute :font)
1121          (let* ((prompt "Set font-related attributes of face")
1122                 (face (read-face-name prompt))
1123                 (font (read-face-font face frame)))
1124            (list face font)))
1125         (t
1126          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1127                 (prompt (format "Set %s of face" attribute-name))
1128                 (face (read-face-name prompt))
1129                 (new-value (read-face-attribute face attribute frame)))
1130            (list face new-value)))))
1131
1132
1133 \f
1134 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1135 ;;; Listing faces.
1136 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1137
1138 (defvar list-faces-sample-text
1139   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1140   "*Text string to display as the sample text for `list-faces-display'.")
1141
1142
1143 ;; The name list-faces would be more consistent, but let's avoid a
1144 ;; conflict with Lucid, which uses that name differently.
1145
1146 (defvar help-xref-stack)
1147 (defun list-faces-display (&optional regexp)
1148   "List all faces, using the same sample text in each.
1149 The sample text is a string that comes from the variable
1150 `list-faces-sample-text'.
1151
1152 If REGEXP is non-nil, list only those faces with names matching
1153 this regular expression.  When called interactively with a prefix
1154 arg, prompt for a regular expression."
1155   (interactive (list (and current-prefix-arg
1156                           (read-string "List faces matching regexp: "))))
1157   (let ((faces (sort (face-list) #'string-lessp))
1158         (frame (selected-frame))
1159         disp-frame window face-name)
1160     (when (> (length regexp) 0)
1161       (setq faces
1162             (delq nil
1163                   (mapcar (lambda (f)
1164                             (when (string-match regexp (symbol-name f))
1165                               f))
1166                           faces))))
1167     (with-output-to-temp-buffer "*Faces*"
1168       (save-excursion
1169         (set-buffer standard-output)
1170         (setq truncate-lines t)
1171         (insert
1172          (substitute-command-keys
1173           (concat
1174            "Use "
1175            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1176            "\\[help-follow] on a face name to customize it\n"
1177            "or on its sample text for a description of the face.\n\n")))
1178         (setq help-xref-stack nil)
1179         (dolist (face faces)
1180           (setq face-name (symbol-name face))
1181           (insert (format "%25s " face-name))
1182           ;; Hyperlink to a customization buffer for the face.  Using
1183           ;; the help xref mechanism may not be the best way.
1184           (save-excursion
1185             (save-match-data
1186               (search-backward face-name)
1187               (setq help-xref-stack-item `(list-faces-display ,regexp))
1188               (help-xref-button 0 'help-customize-face face)))
1189           (let ((beg (point))
1190                 (line-beg (line-beginning-position)))
1191             (insert list-faces-sample-text)
1192             ;; Hyperlink to a help buffer for the face.
1193             (save-excursion
1194               (save-match-data
1195                 (search-backward list-faces-sample-text)
1196                 (help-xref-button 0 'help-face face)))
1197             (insert "\n")
1198             (put-text-property beg (1- (point)) 'face face)
1199             ;; Make all face commands default to the proper face
1200             ;; anywhere in the line.
1201             (put-text-property line-beg (1- (point)) 'read-face-name face)
1202             ;; If the sample text has multiple lines, line up all of them.
1203             (goto-char beg)
1204             (forward-line 1)
1205             (while (not (eobp))
1206               (insert "                          ")
1207               (forward-line 1))))
1208         (goto-char (point-min)))
1209       (print-help-return-message))
1210     ;; If the *Faces* buffer appears in a different frame,
1211     ;; copy all the face definitions from FRAME,
1212     ;; so that the display will reflect the frame that was selected.
1213     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1214     (setq disp-frame (if window (window-frame window)
1215                        (car (frame-list))))
1216     (or (eq frame disp-frame)
1217         (let ((faces (face-list)))
1218           (while faces
1219             (copy-face (car faces) (car faces) frame disp-frame)
1220             (setq faces (cdr faces)))))))
1221
1222
1223 (defun describe-face (face &optional frame)
1224   "Display the properties of face FACE on FRAME.
1225 Interactively, FACE defaults to the faces of the character after point
1226 and FRAME defaults to the selected frame.
1227
1228 If the optional argument FRAME is given, report on face FACE in that frame.
1229 If FRAME is t, report on the defaults for face FACE (for new frames).
1230 If FRAME is omitted or nil, use the selected frame."
1231   (interactive (list (read-face-name "Describe face" "= `default' face" t)))
1232   (let* ((attrs '((:family . "Family")
1233                   (:width . "Width")
1234                   (:height . "Height")
1235                   (:weight . "Weight")
1236                   (:slant . "Slant")
1237                   (:foreground . "Foreground")
1238                   (:background . "Background")
1239                   (:underline . "Underline")
1240                   (:overline . "Overline")
1241                   (:strike-through . "Strike-through")
1242                   (:box . "Box")
1243                   (:inverse-video . "Inverse")
1244                   (:stipple . "Stipple")
1245                   (:font . "Font or fontset")
1246                   (:inherit . "Inherit")))
1247         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1248                                         attrs))))
1249     (help-setup-xref (list #'describe-face face) (interactive-p))
1250     (unless face
1251       (setq face 'default))
1252     (if (not (listp face))
1253         (setq face (list face)))
1254     (with-output-to-temp-buffer (help-buffer)
1255       (save-excursion
1256         (set-buffer standard-output)
1257         (dolist (f face)
1258           (insert "Face: " (symbol-name f))
1259           (if (not (facep f))
1260               (insert "   undefined face.\n")
1261             (let ((customize-label "customize this face")
1262                   file-name)
1263               (princ (concat " (" customize-label ")\n"))
1264               (insert "Documentation: "
1265                       (or (face-documentation f)
1266                           "Not documented as a face.")
1267                       "\n")
1268               (with-current-buffer standard-output
1269                 (save-excursion
1270                   (re-search-backward
1271                    (concat "\\(" customize-label "\\)") nil t)
1272                   (help-xref-button 1 'help-customize-face f)))
1273               ;; The next 4 sexps are copied from describe-function-1
1274               ;; and simplified.
1275               (setq file-name (symbol-file f 'defface))
1276               (when file-name
1277                 (princ "Defined in `")
1278                 (princ file-name)
1279                 (princ "'")
1280                 ;; Make a hyperlink to the library.
1281                 (save-excursion
1282                   (re-search-backward "`\\([^`']+\\)'" nil t)
1283                   (help-xref-button 1 'help-face-def f file-name))
1284                 (princ ".")
1285                 (terpri)
1286                 (terpri))
1287               (dolist (a attrs)
1288                 (let ((attr (face-attribute f (car a) frame)))
1289                   (insert (make-string (- max-width (length (cdr a))) ?\ )
1290                           (cdr a) ": " (format "%s" attr) "\n")))))
1291           (terpri)))
1292       (print-help-return-message))))
1293
1294 \f
1295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1296 ;;; Face specifications (defface).
1297 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1298
1299 ;; Parameter FRAME Is kept for call compatibility to with previous
1300 ;; face implementation.
1301
1302 (defun face-attr-construct (face &optional frame)
1303   "Return a defface-style attribute list for FACE on FRAME.
1304 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1305 face attributes of FACE where ATTRIBUTE is the attribute name and
1306 VALUE is the specified value of that attribute."
1307   (let (result)
1308     (dolist (entry face-attribute-name-alist result)
1309       (let* ((attribute (car entry))
1310              (value (face-attribute face attribute)))
1311         (unless (eq value 'unspecified)
1312           (setq result (nconc (list attribute value) result)))))))
1313
1314
1315 (defun face-spec-set-match-display (display frame)
1316   "Non-nil if DISPLAY matches FRAME.
1317 DISPLAY is part of a spec such as can be used in `defface'.
1318 If FRAME is nil, the current FRAME is used."
1319   (let* ((conjuncts display)
1320          conjunct req options
1321          ;; t means we have succeeded against all the conjuncts in
1322          ;; DISPLAY that have been tested so far.
1323          (match t))
1324     (if (eq conjuncts t)
1325         (setq conjuncts nil))
1326     (while (and conjuncts match)
1327       (setq conjunct (car conjuncts)
1328             conjuncts (cdr conjuncts)
1329             req (car conjunct)
1330             options (cdr conjunct)
1331             match (cond ((eq req 'type)
1332                          (or (memq window-system options)
1333                              ;; FIXME: This should be revisited to use
1334                              ;; display-graphic-p, provided that the
1335                              ;; color selection depends on the number
1336                              ;; of supported colors, and all defface's
1337                              ;; are changed to look at number of colors
1338                              ;; instead of (type graphic) etc.
1339                              (and (null window-system)
1340                                   (memq 'tty options))
1341                              (and (memq 'motif options)
1342                                   (featurep 'motif))
1343                              (and (memq 'gtk options)
1344                                   (featurep 'gtk))
1345                              (and (memq 'lucid options)
1346                                   (featurep 'x-toolkit)
1347                                   (not (featurep 'motif))
1348                                   (not (featurep 'gtk)))
1349                              (and (memq 'x-toolkit options)
1350                                   (featurep 'x-toolkit))))
1351                         ((eq req 'min-colors)
1352                          (>= (display-color-cells frame) (car options)))
1353                         ((eq req 'class)
1354                          (memq (frame-parameter frame 'display-type) options))
1355                         ((eq req 'background)
1356                          (memq (frame-parameter frame 'background-mode)
1357                                options))
1358                         ((eq req 'supports)
1359                          (display-supports-face-attributes-p options frame))
1360                         (t (error "Unknown req `%S' with options `%S'"
1361                                   req options)))))
1362     match))
1363
1364
1365 (defun face-spec-choose (spec &optional frame)
1366   "Choose the proper attributes for FRAME, out of SPEC.
1367 If SPEC is nil, return nil."
1368   (unless frame
1369     (setq frame (selected-frame)))
1370   (let ((tail spec)
1371         result defaults)
1372     (while tail
1373       (let* ((entry (pop tail))
1374              (display (car entry))
1375              (attrs (cdr entry))
1376              thisval)
1377         ;; Get the attributes as actually specified by this alternative.
1378         (setq thisval
1379               (if (null (cdr attrs)) ;; was (listp (car attrs))
1380                   ;; Old-style entry, the attribute list is the
1381                   ;; first element.
1382                   (car attrs)
1383                 attrs))
1384
1385         ;; If the condition is `default', that sets the default
1386         ;; for following conditions.
1387         (if (eq display 'default)
1388             (setq defaults thisval)
1389           ;; Otherwise, if it matches, use it.
1390           (when (face-spec-set-match-display display frame)
1391             (setq result thisval)
1392             (setq tail nil)))))
1393     (if defaults (append result defaults) result)))
1394
1395
1396 (defun face-spec-reset-face (face &optional frame)
1397   "Reset all attributes of FACE on FRAME to unspecified."
1398   (let ((attrs face-attribute-name-alist))
1399     (while attrs
1400       (let ((attr-and-name (car attrs)))
1401         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1402       (setq attrs (cdr attrs)))))
1403
1404
1405 (defun face-spec-set (face spec &optional frame)
1406   "Set FACE's attributes according to the first matching entry in SPEC.
1407 FRAME is the frame whose frame-local face is set.  FRAME nil means
1408 do it on all frames.  See `defface' for information about SPEC.
1409 If SPEC is nil, do nothing."
1410   (let ((attrs (face-spec-choose spec frame)))
1411     (when attrs
1412       (face-spec-reset-face face frame))
1413     (while attrs
1414       (let ((attribute (car attrs))
1415             (value (car (cdr attrs))))
1416         ;; Support some old-style attribute names and values.
1417         (case attribute
1418           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1419           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1420           ((:foreground :background)
1421            ;; Compatibility with 20.x.  Some bogus face specs seem to
1422            ;; exist containing things like `:foreground nil'.
1423            (if (null value) (setq value 'unspecified)))
1424           (t (unless (assq attribute face-x-resources)
1425                (setq attribute nil))))
1426         (when attribute
1427           (set-face-attribute face frame attribute value)))
1428       (setq attrs (cdr (cdr attrs)))))
1429   ;; When we reset the face based on its spec, then it is unmodified
1430   ;; as far as Custom is concerned.
1431   (if (null frame)
1432       (put face 'face-modified nil)))
1433
1434
1435 (defun face-attr-match-p (face attrs &optional frame)
1436   "Return t if attributes of FACE match values in plist ATTRS.
1437 Optional parameter FRAME is the frame whose definition of FACE
1438 is used.  If nil or omitted, use the selected frame."
1439   (unless frame
1440     (setq frame (selected-frame)))
1441   (let ((list face-attribute-name-alist)
1442         (match t))
1443     (while (and match (not (null list)))
1444       (let* ((attr (car (car list)))
1445              (specified-value
1446               (if (plist-member attrs attr)
1447                   (plist-get attrs attr)
1448                 'unspecified))
1449              (value-now (face-attribute face attr frame)))
1450         (setq match (equal specified-value value-now))
1451         (setq list (cdr list))))
1452     match))
1453
1454 (defun face-spec-match-p (face spec &optional frame)
1455   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1456   (face-attr-match-p face (face-spec-choose spec frame) frame))
1457
1458 (defsubst face-default-spec (face)
1459   "Return the default face-spec for FACE, ignoring any user customization.
1460 If there is no default for FACE, return nil."
1461   (get face 'face-defface-spec))
1462
1463 (defsubst face-user-default-spec (face)
1464   "Return the user's customized face-spec for FACE, or the default if none.
1465 If there is neither a user setting nor a default for FACE, return nil."
1466   (or (get face 'saved-face)
1467       (face-default-spec face)))
1468
1469 \f
1470 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1471 ;;; Frame-type independent color support.
1472 ;;; We keep the old x-* names as aliases for back-compatibility.
1473 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1474
1475 (defun defined-colors (&optional frame)
1476   "Return a list of colors supported for a particular frame.
1477 The argument FRAME specifies which frame to try.
1478 The value may be different for frames on different display types.
1479 If FRAME doesn't support colors, the value is nil."
1480   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1481       (xw-defined-colors frame)
1482     (mapcar 'car (tty-color-alist frame))))
1483 (defalias 'x-defined-colors 'defined-colors)
1484
1485 (defun color-defined-p (color &optional frame)
1486   "Return non-nil if color COLOR is supported on frame FRAME.
1487 If FRAME is omitted or nil, use the selected frame.
1488 If COLOR is the symbol `unspecified' or one of the strings
1489 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1490   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1491       nil
1492     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1493         (xw-color-defined-p color frame)
1494       (numberp (tty-color-translate color frame)))))
1495 (defalias 'x-color-defined-p 'color-defined-p)
1496
1497 (defun color-values (color &optional frame)
1498   "Return a description of the color named COLOR on frame FRAME.
1499 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1500 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1501 If FRAME is omitted or nil, use the selected frame.
1502 If FRAME cannot display COLOR, the value is nil.
1503 If COLOR is the symbol `unspecified' or one of the strings
1504 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1505   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1506       nil
1507     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1508         (xw-color-values color frame)
1509       (tty-color-values color frame))))
1510 (defalias 'x-color-values 'color-values)
1511
1512 (defun display-color-p (&optional display)
1513   "Return t if DISPLAY supports color.
1514 The optional argument DISPLAY specifies which display to ask about.
1515 DISPLAY should be either a frame or a display name (a string).
1516 If omitted or nil, that stands for the selected frame's display."
1517   (if (memq (framep-on-display display) '(x w32 mac))
1518       (xw-display-color-p display)
1519     (tty-display-color-p display)))
1520 (defalias 'x-display-color-p 'display-color-p)
1521
1522 (defun display-grayscale-p (&optional display)
1523   "Return non-nil if frames on DISPLAY can display shades of gray."
1524   (let ((frame-type (framep-on-display display)))
1525     (cond
1526      ((memq frame-type '(x w32 mac))
1527       (x-display-grayscale-p display))
1528      (t
1529       (> (tty-color-gray-shades display) 2)))))
1530
1531 \f
1532 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1533 ;;; Background mode.
1534 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1535
1536 (defcustom frame-background-mode nil
1537   "*The brightness of the background.
1538 Set this to the symbol `dark' if your background color is dark, `light' if
1539 your background is light, or nil (default) if you want Emacs to
1540 examine the brightness for you.  Don't set this variable with `setq';
1541 this won't have the expected effect."
1542   :group 'faces
1543   :set #'(lambda (var value)
1544            (set-default var value)
1545            (mapc 'frame-set-background-mode (frame-list)))
1546   :initialize 'custom-initialize-changed
1547   :type '(choice (choice-item dark)
1548                  (choice-item light)
1549                  (choice-item :tag "default" nil)))
1550
1551
1552 (defun frame-set-background-mode (frame)
1553   "Set up display-dependent faces on FRAME.
1554 Display-dependent faces are those which have different definitions
1555 according to the `background-mode' and `display-type' frame parameters."
1556   (let* ((bg-resource
1557           (and window-system
1558                (x-get-resource "backgroundMode" "BackgroundMode")))
1559          (bg-color (frame-parameter frame 'background-color))
1560          (bg-mode
1561           (cond (frame-background-mode)
1562                 (bg-resource
1563                  (intern (downcase bg-resource)))
1564                 ((and (null window-system) (null bg-color))
1565                  ;; No way to determine this automatically (?).
1566                  'dark)
1567                 ;; Unspecified frame background color can only happen
1568                 ;; on tty's.
1569                 ((member bg-color '(unspecified "unspecified-bg"))
1570                  'dark)
1571                 ((equal bg-color "unspecified-fg") ; inverted colors
1572                  'light)
1573                 ((>= (apply '+ (x-color-values bg-color frame))
1574                     ;; Just looking at the screen, colors whose
1575                     ;; values add up to .6 of the white total
1576                     ;; still look dark to me.
1577                     (* (apply '+ (x-color-values "white" frame)) .6))
1578                  'light)
1579                 (t 'dark)))
1580          (display-type
1581           (cond ((null window-system)
1582                  (if (tty-display-color-p frame) 'color 'mono))
1583                 ((x-display-color-p frame)
1584                  'color)
1585                 ((x-display-grayscale-p frame)
1586                  'grayscale)
1587                 (t 'mono)))
1588          (old-bg-mode
1589           (frame-parameter frame 'background-mode))
1590          (old-display-type
1591           (frame-parameter frame 'display-type)))
1592
1593     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1594       (let ((locally-modified-faces nil))
1595         ;; Before modifying the frame parameters, we collect a list of
1596         ;; faces that don't match what their face-spec says they should
1597         ;; look like; we then avoid changing these faces below.  A
1598         ;; negative list is used on the assumption that most faces will
1599         ;; be unmodified, so we can avoid consing in the common case.
1600         (dolist (face (face-list))
1601           (when (not (face-spec-match-p face
1602                                         (face-user-default-spec face)
1603                                         (selected-frame)))
1604             (push face locally-modified-faces)))
1605         ;; Now change to the new frame parameters
1606         (modify-frame-parameters frame
1607                                  (list (cons 'background-mode bg-mode)
1608                                        (cons 'display-type display-type)))
1609         ;; For all named faces, choose face specs matching the new frame
1610         ;; parameters, unless they have been locally modified.
1611         (dolist (face (face-list))
1612           (unless (memq face locally-modified-faces)
1613             (face-spec-set face (face-user-default-spec face) frame)))))))
1614
1615 \f
1616 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1617 ;;; Frame creation.
1618 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1619
1620 (defun x-handle-named-frame-geometry (parameters)
1621   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1622 Value is the new parameter list."
1623   (let* ((name (or (cdr (assq 'name parameters))
1624                    (cdr (assq 'name default-frame-alist))))
1625          (x-resource-name name)
1626          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1627     (when res-geometry
1628       (let ((parsed (x-parse-geometry res-geometry)))
1629         ;; If the resource specifies a position, call the position
1630         ;; and size "user-specified".
1631         (when (or (assq 'top parsed)
1632                   (assq 'left parsed))
1633           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1634         ;; Put the geometry parameters at the end.  Copy
1635         ;; default-frame-alist so that they go after it.
1636         (setq parameters (append parameters default-frame-alist parsed))))
1637     parameters))
1638
1639
1640 (defun x-handle-reverse-video (frame parameters)
1641   "Handle the reverse-video frame parameter and X resource.
1642 `x-create-frame' does not handle this one."
1643   (when (cdr (or (assq 'reverse parameters)
1644                  (assq 'reverse default-frame-alist)
1645                  (let ((resource (x-get-resource "reverseVideo"
1646                                                  "ReverseVideo")))
1647                    (if resource
1648                        (cons nil (member (downcase resource)
1649                                          '("on" "true")))))))
1650       (let* ((params (frame-parameters frame))
1651              (bg (cdr (assq 'foreground-color params)))
1652              (fg (cdr (assq 'background-color params))))
1653         (modify-frame-parameters frame
1654                                  (list (cons 'foreground-color fg)
1655                                        (cons 'background-color bg)))
1656         (if (equal bg (cdr (assq 'border-color params)))
1657             (modify-frame-parameters frame
1658                                      (list (cons 'border-color fg))))
1659         (if (equal bg (cdr (assq 'mouse-color params)))
1660             (modify-frame-parameters frame
1661                                      (list (cons 'mouse-color fg))))
1662         (if (equal bg (cdr (assq 'cursor-color params)))
1663             (modify-frame-parameters frame
1664                                      (list (cons 'cursor-color fg)))))))
1665
1666
1667 (defun x-create-frame-with-faces (&optional parameters)
1668   "Create a frame from optional frame parameters PARAMETERS.
1669 Parameters not specified by PARAMETERS are taken from
1670 `default-frame-alist'.  If PARAMETERS specify a frame name,
1671 handle X geometry resources for that name.  If either PARAMETERS
1672 or `default-frame-alist' contains a `reverse' parameter, or
1673 the X resource ``reverseVideo'' is present, handle that.
1674 Value is the new frame created."
1675   (setq parameters (x-handle-named-frame-geometry parameters))
1676   (let ((visibility-spec (assq 'visibility parameters))
1677         (frame-list (frame-list))
1678         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1679         success)
1680     (unwind-protect
1681         (progn
1682           (x-handle-reverse-video frame parameters)
1683           (frame-set-background-mode frame)
1684           (face-set-after-frame-default frame)
1685           (if (or (null frame-list) (null visibility-spec))
1686               (make-frame-visible frame)
1687             (modify-frame-parameters frame (list visibility-spec)))
1688           (setq success t))
1689       (unless success
1690         (delete-frame frame)))
1691     frame))
1692
1693
1694 (defun face-set-after-frame-default (frame)
1695   "Set frame-local faces of FRAME from face specs and resources.
1696 Initialize colors of certain faces from frame parameters."
1697   (if (face-attribute 'default :font t)
1698       (set-face-attribute 'default frame :font
1699                           (face-attribute 'default :font t))
1700     (set-face-attribute 'default frame :family
1701                         (face-attribute 'default :family t))
1702     (set-face-attribute 'default frame :height
1703                         (face-attribute 'default :height t))
1704     (set-face-attribute 'default frame :slant
1705                         (face-attribute 'default :slant t))
1706     (set-face-attribute 'default frame :weight
1707                         (face-attribute 'default :weight t))
1708     (set-face-attribute 'default frame :width
1709                         (face-attribute 'default :width t)))
1710   (dolist (face (face-list))
1711     ;; Don't let frame creation fail because of an invalid face spec.
1712     (condition-case ()
1713         (when (not (equal face 'default))
1714           (face-spec-set face (face-user-default-spec face) frame)
1715           (internal-merge-in-global-face face frame)
1716           (when (and (memq window-system '(x w32 mac))
1717                      (or (not (boundp 'inhibit-default-face-x-resources))
1718                          (not (eq face 'default))))
1719             (make-face-x-resource-internal face frame)))
1720       (error nil)))
1721   ;; Initialize attributes from frame parameters.
1722   (let ((params '((foreground-color default :foreground)
1723                   (background-color default :background)
1724                   (border-color border :background)
1725                   (cursor-color cursor :background)
1726                   (scroll-bar-foreground scroll-bar :foreground)
1727                   (scroll-bar-background scroll-bar :background)
1728                   (mouse-color mouse :background))))
1729     (dolist (param params)
1730       (let ((frame-param (frame-parameter frame (nth 0 param)))
1731             (face (nth 1 param))
1732             (attr (nth 2 param)))
1733         (when (and frame-param
1734                    ;; Don't override face attributes explicitly
1735                    ;; specified for new frames.
1736                    (eq (face-attribute face attr t) 'unspecified))
1737           (set-face-attribute face frame attr frame-param))))))
1738
1739
1740 (defun tty-handle-reverse-video (frame parameters)
1741   "Handle the reverse-video frame parameter for terminal frames."
1742   (when (cdr (or (assq 'reverse parameters)
1743                  (assq 'reverse default-frame-alist)))
1744     (let* ((params (frame-parameters frame))
1745            (bg (cdr (assq 'foreground-color params)))
1746            (fg (cdr (assq 'background-color params))))
1747       (modify-frame-parameters frame
1748                                (list (cons 'foreground-color fg)
1749                                      (cons 'background-color bg)))
1750       (if (equal bg (cdr (assq 'mouse-color params)))
1751           (modify-frame-parameters frame
1752                                    (list (cons 'mouse-color fg))))
1753       (if (equal bg (cdr (assq 'cursor-color params)))
1754           (modify-frame-parameters frame
1755                                    (list (cons 'cursor-color fg)))))))
1756
1757
1758 (defun tty-create-frame-with-faces (&optional parameters)
1759   "Create a frame from optional frame parameters PARAMETERS.
1760 Parameters not specified by PARAMETERS are taken from
1761 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1762 contains a `reverse' parameter, handle that.  Value is the new frame
1763 created."
1764   (let ((frame (make-terminal-frame parameters))
1765         success)
1766     (unwind-protect
1767         (progn
1768           (tty-handle-reverse-video frame (frame-parameters frame))
1769           (frame-set-background-mode frame)
1770           (face-set-after-frame-default frame)
1771           (setq success t))
1772       (unless success
1773         (delete-frame frame)))
1774     frame))
1775
1776
1777 ;; Called from C function init_display to initialize faces of the
1778 ;; dumped terminal frame on startup.
1779
1780 (defun tty-set-up-initial-frame-faces ()
1781   (let ((frame (selected-frame)))
1782     (frame-set-background-mode frame)
1783     (face-set-after-frame-default frame)))
1784
1785
1786
1787 \f
1788 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1789 ;;; Compatiblity with 20.2
1790 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1791
1792 ;; Update a frame's faces when we change its default font.
1793
1794 (defalias 'frame-update-faces 'ignore "")
1795 (make-obsolete 'frame-update-faces "no longer necessary." "21.1")
1796
1797 ;; Update the colors of FACE, after FRAME's own colors have been
1798 ;; changed.
1799
1800 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1801 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1802
1803 \f
1804 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1805 ;;; Standard faces.
1806 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1807
1808 (defgroup basic-faces nil
1809   "The standard faces of Emacs."
1810   :group 'faces)
1811
1812
1813 (defface default
1814   '((t nil))
1815   "Basic default face."
1816   :group 'basic-faces)
1817
1818
1819 (defface mode-line
1820   '((((class color) (min-colors 88))
1821      :box (:line-width -1 :style released-button)
1822      :background "grey75" :foreground "black")
1823     (t
1824      :inverse-video t))
1825   "Basic mode line face for selected window."
1826   :version "21.1"
1827   :group 'modeline
1828   :group 'basic-faces)
1829
1830 (defface mode-line-inactive
1831   '((default
1832      :inherit mode-line)
1833     (((class color) (min-colors 88) (background light))
1834      :weight light
1835      :box (:line-width -1 :color "grey75" :style nil)
1836      :foreground "grey20" :background "grey90")
1837     (((class color) (min-colors 88) (background dark) )
1838      :weight light
1839      :box (:line-width -1 :color "grey40" :style nil)
1840      :foreground "grey80" :background "grey30"))
1841   "Basic mode line face for non-selected windows."
1842   :version "22.1"
1843   :group 'modeline
1844   :group 'basic-faces)
1845
1846 ;; Make `modeline' an alias for `mode-line', for compatibility.
1847 (put 'modeline 'face-alias 'mode-line)
1848 (put 'modeline-inactive 'face-alias 'mode-line-inactive)
1849
1850 (defface header-line
1851   '((default
1852      :inherit mode-line)
1853     (((type tty))
1854      ;; This used to be `:inverse-video t', but that doesn't look very
1855      ;; good when combined with inverse-video mode-lines and multiple
1856      ;; windows.  Underlining looks better, and is more consistent with
1857      ;; the window-system face variants, which deemphasize the
1858      ;; header-line in relation to the mode-line face.  If a terminal
1859      ;; can't underline, then the header-line will end up without any
1860      ;; highlighting; this may be too confusing in general, although it
1861      ;; happens to look good with the only current use of header-lines,
1862      ;; the info browser. XXX
1863      :inverse-video nil        ;Override the value inherited from mode-line.
1864      :underline t)
1865     (((class color grayscale) (background light))
1866      :background "grey90" :foreground "grey20"
1867      :box nil)
1868     (((class color grayscale) (background dark))
1869      :background "grey20" :foreground "grey90"
1870      :box nil)
1871     (((class mono) (background light))
1872      :background "white" :foreground "black"
1873      :inverse-video nil
1874      :box nil
1875      :underline t)
1876     (((class mono) (background dark))
1877      :background "black" :foreground "white"
1878      :inverse-video nil
1879      :box nil
1880      :underline t))
1881   "Basic header-line face."
1882   :version "21.1"
1883   :group 'basic-faces)
1884
1885
1886 (defface tool-bar
1887   '((default
1888      :box (:line-width 1 :style released-button)
1889      :foreground "black")
1890     (((type x w32 mac) (class color))
1891      :background "grey75")
1892     (((type x) (class mono))
1893      :background "grey"))
1894   "Basic tool-bar face."
1895   :version "21.1"
1896   :group 'basic-faces)
1897
1898
1899 (defface minibuffer-prompt '((((background dark)) :foreground "cyan")
1900                              ;; Don't use blue because many users of
1901                              ;; the MS-DOS port customize their
1902                              ;; foreground color to be blue.
1903                              (((type pc)) :foreground "magenta")
1904                              (t :foreground "dark blue"))
1905   "Face for minibuffer prompts."
1906   :version "22.1"
1907   :group 'basic-faces)
1908
1909 (setq minibuffer-prompt-properties
1910       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
1911
1912 (defface region
1913   '((((class color) (min-colors 88) (background dark))
1914      :background "blue3")
1915     (((class color) (min-colors 88) (background light))
1916      :background "lightgoldenrod2")
1917     (((class color) (min-colors 16) (background dark))
1918      :background "blue3")
1919     (((class color) (min-colors 16) (background light))
1920      :background "lightgoldenrod2")
1921     (((class color) (min-colors 8))
1922      :background "blue" :foreground "white")
1923     (((type tty) (class mono))
1924      :inverse-video t)
1925     (t :background "gray"))
1926   "Basic face for highlighting the region."
1927   :version "21.1"
1928   :group 'basic-faces)
1929
1930
1931 (defface fringe
1932   '((((class color) (background light))
1933      :background "grey95")
1934     (((class color) (background dark))
1935      :background "grey10")
1936     (t
1937      :background "gray"))
1938   "Basic face for the fringes to the left and right of windows under X."
1939   :version "21.1"
1940   :group 'frames
1941   :group 'basic-faces)
1942
1943
1944 (defface scroll-bar '()
1945   "Basic face for the scroll bar colors under X."
1946   :version "21.1"
1947   :group 'frames
1948   :group 'basic-faces)
1949
1950
1951 (defface menu
1952   '((((type tty))
1953      :inverse-video t)
1954     (((type x-toolkit))
1955      )
1956     (t
1957      :inverse-video t))
1958   "Basic face for the font and colors of the menu bar and popup menus."
1959   :version "21.1"
1960   :group 'menu
1961   :group 'basic-faces)
1962
1963
1964 (defface border '()
1965   "Basic face for the frame border under X."
1966   :version "21.1"
1967   :group 'frames
1968   :group 'basic-faces)
1969
1970
1971 (defface cursor '()
1972   "Basic face for the cursor color under X.
1973 Note: Other faces cannot inherit from the cursor face."
1974   :version "21.1"
1975   :group 'cursor
1976   :group 'basic-faces)
1977
1978 (put 'cursor 'face-no-inherit t)
1979
1980 (defface mouse '()
1981   "Basic face for the mouse color under X."
1982   :version "21.1"
1983   :group 'mouse
1984   :group 'basic-faces)
1985
1986
1987 (defface bold '((t :weight bold))
1988   "Basic bold face."
1989   :group 'basic-faces)
1990
1991
1992 (defface italic
1993   '((((supports :slant italic))
1994      :slant italic)
1995     (((supports :underline t))
1996      :underline t)
1997     (t
1998      ;; default to italic, even it doesn't appear to be supported,
1999      ;; because in some cases the display engine will do it's own
2000      ;; workaround (to `dim' on ttys)
2001      :slant italic))
2002   "Basic italic font."
2003   :group 'basic-faces)
2004
2005
2006 (defface bold-italic '((t :weight bold :slant italic))
2007   "Basic bold-italic face."
2008   :group 'basic-faces)
2009
2010
2011 (defface underline '((t :underline t))
2012   "Basic underlined face."
2013   :group 'basic-faces)
2014
2015
2016 (defface highlight
2017   '((((class color) (min-colors 88) (background light))
2018      :background "darkseagreen2")
2019     (((class color) (min-colors 88) (background dark))
2020      :background "darkolivegreen")
2021     (((class color) (min-colors 16) (background light))
2022      :background "darkseagreen2")
2023     (((class color) (min-colors 16) (background dark))
2024      :background "darkolivegreen")
2025     (((class color) (min-colors 8))
2026      :background "green" :foreground "black")
2027     (t :inverse-video t))
2028   "Basic face for highlighting."
2029   :group 'basic-faces)
2030
2031
2032 (defface secondary-selection
2033   '((((class color) (min-colors 88) (background light))
2034      :background "yellow1")
2035     (((class color) (min-colors 88) (background dark))
2036      :background "SkyBlue4")
2037     (((class color) (min-colors 16) (background light))
2038      :background "yellow")
2039     (((class color) (min-colors 16) (background dark))
2040      :background "SkyBlue4")
2041     (((class color) (min-colors 8))
2042      :background "cyan" :foreground "black")
2043     (t :inverse-video t))
2044   "Basic face for displaying the secondary selection."
2045   :group 'basic-faces)
2046
2047
2048 (defface fixed-pitch '((t :family "courier"))
2049   "The basic fixed-pitch face."
2050   :group 'basic-faces)
2051
2052
2053 (defface variable-pitch '((t :family "helv"))
2054   "The basic variable-pitch face."
2055   :group 'basic-faces)
2056
2057
2058 (defface trailing-whitespace
2059   '((((class color) (background light))
2060      :background "red1")
2061     (((class color) (background dark))
2062      :background "red1")
2063     (t :inverse-video t))
2064   "Basic face for highlighting trailing whitespace."
2065   :version "21.1"
2066   :group 'whitespace            ; like `show-trailing-whitespace'
2067   :group 'basic-faces)
2068
2069 (defface escape-glyph '((((background dark)) :foreground "cyan")
2070                         ;; See the comment in minibuffer-prompt for
2071                         ;; the reason not to use blue on MS-DOS.
2072                         (((type pc)) :foreground "magenta")
2073                         (t :foreground "blue"))
2074   "Face for characters displayed as ^-sequences or \-sequences."
2075   :group 'basic-faces)
2076 \f
2077 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2078 ;;; Manipulating font names.
2079 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2080
2081 ;; This is here for compatibilty with Emacs 20.2.  For example,
2082 ;; international/fontset.el uses x-resolve-font-name.  The following
2083 ;; functions are not used in the face implementation itself.
2084
2085 (defvar x-font-regexp nil)
2086 (defvar x-font-regexp-head nil)
2087 (defvar x-font-regexp-weight nil)
2088 (defvar x-font-regexp-slant nil)
2089
2090 (defconst x-font-regexp-weight-subnum 1)
2091 (defconst x-font-regexp-slant-subnum 2)
2092 (defconst x-font-regexp-swidth-subnum 3)
2093 (defconst x-font-regexp-adstyle-subnum 4)
2094
2095 ;;; Regexps matching font names in "Host Portable Character Representation."
2096 ;;;
2097 (let ((-                "[-?]")
2098       (foundry          "[^-]+")
2099       (family           "[^-]+")
2100       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
2101 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
2102       (weight\?         "\\([^-]*\\)")                                  ; 1
2103       (slant            "\\([ior]\\)")                                  ; 2
2104 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
2105       (slant\?          "\\([^-]?\\)")                                  ; 2
2106 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
2107       (swidth           "\\([^-]*\\)")                                  ; 3
2108 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
2109       (adstyle          "\\([^-]*\\)")                                  ; 4
2110       (pixelsize        "[0-9]+")
2111       (pointsize        "[0-9][0-9]+")
2112       (resx             "[0-9][0-9]+")
2113       (resy             "[0-9][0-9]+")
2114       (spacing          "[cmp?*]")
2115       (avgwidth         "[0-9]+")
2116       (registry         "[^-]+")
2117       (encoding         "[^-]+")
2118       )
2119   (setq x-font-regexp
2120         (concat "\\`\\*?[-?*]"
2121                 foundry - family - weight\? - slant\? - swidth - adstyle -
2122                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
2123                 registry - encoding "\\*?\\'"
2124                 ))
2125   (setq x-font-regexp-head
2126         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
2127                 "\\([-*?]\\|\\'\\)"))
2128   (setq x-font-regexp-slant (concat - slant -))
2129   (setq x-font-regexp-weight (concat - weight -))
2130   nil)
2131
2132
2133 (defun x-resolve-font-name (pattern &optional face frame)
2134   "Return a font name matching PATTERN.
2135 All wildcards in PATTERN are instantiated.
2136 If PATTERN is nil, return the name of the frame's base font, which never
2137 contains wildcards.
2138 Given optional arguments FACE and FRAME, return a font which is
2139 also the same size as FACE on FRAME, or fail."
2140   (or (symbolp face)
2141       (setq face (face-name face)))
2142   (and (eq frame t)
2143        (setq frame nil))
2144   (if pattern
2145       ;; Note that x-list-fonts has code to handle a face with nil as its font.
2146       (let ((fonts (x-list-fonts pattern face frame 1)))
2147         (or fonts
2148             (if face
2149                 (if (string-match "\\*" pattern)
2150                     (if (null (face-font face))
2151                         (error "No matching fonts are the same height as the frame default font")
2152                       (error "No matching fonts are the same height as face `%s'" face))
2153                   (if (null (face-font face))
2154                       (error "Height of font `%s' doesn't match the frame default font"
2155                              pattern)
2156                     (error "Height of font `%s' doesn't match face `%s'"
2157                            pattern face)))
2158               (error "No fonts match `%s'" pattern)))
2159         (car fonts))
2160     (cdr (assq 'font (frame-parameters (selected-frame))))))
2161
2162
2163 (defun x-frob-font-weight (font which)
2164   (let ((case-fold-search t))
2165     (cond ((string-match x-font-regexp font)
2166            (concat (substring font 0
2167                               (match-beginning x-font-regexp-weight-subnum))
2168                    which
2169                    (substring font (match-end x-font-regexp-weight-subnum)
2170                               (match-beginning x-font-regexp-adstyle-subnum))
2171                    ;; Replace the ADD_STYLE_NAME field with *
2172                    ;; because the info in it may not be the same
2173                    ;; for related fonts.
2174                    "*"
2175                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2176           ((string-match x-font-regexp-head font)
2177            (concat (substring font 0 (match-beginning 1)) which
2178                    (substring font (match-end 1))))
2179           ((string-match x-font-regexp-weight font)
2180            (concat (substring font 0 (match-beginning 1)) which
2181                    (substring font (match-end 1)))))))
2182 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
2183
2184 (defun x-frob-font-slant (font which)
2185   (let ((case-fold-search t))
2186     (cond ((string-match x-font-regexp font)
2187            (concat (substring font 0
2188                               (match-beginning x-font-regexp-slant-subnum))
2189                    which
2190                    (substring font (match-end x-font-regexp-slant-subnum)
2191                               (match-beginning x-font-regexp-adstyle-subnum))
2192                    ;; Replace the ADD_STYLE_NAME field with *
2193                    ;; because the info in it may not be the same
2194                    ;; for related fonts.
2195                    "*"
2196                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2197           ((string-match x-font-regexp-head font)
2198            (concat (substring font 0 (match-beginning 2)) which
2199                    (substring font (match-end 2))))
2200           ((string-match x-font-regexp-slant font)
2201            (concat (substring font 0 (match-beginning 1)) which
2202                    (substring font (match-end 1)))))))
2203 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
2204
2205 ;; These aliases are here so that we don't get warnings about obsolete
2206 ;; functions from the byte compiler.
2207 (defalias 'internal-frob-font-weight 'x-frob-font-weight)
2208 (defalias 'internal-frob-font-slant 'x-frob-font-slant)
2209
2210 (defun x-make-font-bold (font)
2211   "Given an X font specification, make a bold version of it.
2212 If that can't be done, return nil."
2213   (internal-frob-font-weight font "bold"))
2214 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
2215
2216 (defun x-make-font-demibold (font)
2217   "Given an X font specification, make a demibold version of it.
2218 If that can't be done, return nil."
2219   (internal-frob-font-weight font "demibold"))
2220 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
2221
2222 (defun x-make-font-unbold (font)
2223   "Given an X font specification, make a non-bold version of it.
2224 If that can't be done, return nil."
2225   (internal-frob-font-weight font "medium"))
2226 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
2227
2228 (defun x-make-font-italic (font)
2229   "Given an X font specification, make an italic version of it.
2230 If that can't be done, return nil."
2231   (internal-frob-font-slant font "i"))
2232 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
2233
2234 (defun x-make-font-oblique (font) ; you say tomayto...
2235   "Given an X font specification, make an oblique version of it.
2236 If that can't be done, return nil."
2237   (internal-frob-font-slant font "o"))
2238 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
2239
2240 (defun x-make-font-unitalic (font)
2241   "Given an X font specification, make a non-italic version of it.
2242 If that can't be done, return nil."
2243   (internal-frob-font-slant font "r"))
2244 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
2245
2246 (defun x-make-font-bold-italic (font)
2247   "Given an X font specification, make a bold and italic version of it.
2248 If that can't be done, return nil."
2249   (and (setq font (internal-frob-font-weight font "bold"))
2250        (internal-frob-font-slant font "i")))
2251 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
2252
2253 (provide 'faces)
2254
2255 ;;; arch-tag: 19a4759f-2963-445f-b004-425b9aadd7d6
2256 ;;; faces.el ends here