lisp/buff-menu.el

   1 ;;; buff-menu.el --- buffer menu main function and support functions -*- coding:utf-8 -*-
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 2000, 2001, 2002, 2003,
   4 ;;   2004  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Edit, delete, or change attributes of all currently active Emacs
  29 ;; buffers from a list summarizing their state.  A good way to browse
  30 ;; any special or scratch buffers you have loaded, since you can't find
  31 ;; them by filename.  The single entry point is `list-buffers',
  32 ;; normally bound to C-x C-b.
  33
  34 ;;; Change Log:
  35
  36 ;; Buffer-menu-view: New function
  37 ;; Buffer-menu-view-other-window: New function
  38
  39 ;; Merged by esr with recent mods to Emacs 19 buff-menu, 23 Mar 1993
  40 ;;
  41 ;; Modified by Bob Weiner, Motorola, Inc., 4/14/89
  42 ;;
  43 ;; Added optional backup argument to 'Buffer-menu-unmark' to make it undelete
  44 ;; current entry and then move to previous one.
  45 ;;
  46 ;; Based on FSF code dating back to 1985.
  47
  48 ;;; Code:
  49
  50 ;;Trying to preserve the old window configuration works well in
  51 ;;simple scenarios, when you enter the buffer menu, use it, and exit it.
  52 ;;But it does strange things when you switch back to the buffer list buffer
  53 ;;with C-x b, later on, when the window configuration is different.
  54 ;;The choice seems to be, either restore the window configuration
  55 ;;in all cases, or in no cases.
  56 ;;I decided it was better not to restore the window config at all. -- rms.
  57
  58 ;;But since then, I changed buffer-menu to use the selected window,
  59 ;;so q now once again goes back to the previous window configuration.
  60
  61 ;;(defvar Buffer-menu-window-config nil
  62 ;;  "Window configuration saved from entry to `buffer-menu'.")
  63
  64 ;; Put buffer *Buffer List* into proper mode right away
  65 ;; so that from now on even list-buffers is enough to get a buffer menu.
  66
  67 (defgroup Buffer-menu nil
  68   "Show a menu of all buffers in a buffer."
  69   :group 'tools
  70   :group 'convenience)
  71
  72 (defcustom Buffer-menu-use-header-line t
  73   "*Non-nil means to use an immovable header-line."
  74   :type 'boolean
  75   :group 'Buffer-menu)
  76
  77 (defface Buffer-menu-buffer-face
  78   '((t (:weight bold)))
  79   "Face used to highlight buffer name."
  80   :group 'Buffer-menu
  81   :group 'font-lock-highlighting-faces)
  82
  83 (defcustom Buffer-menu-buffer+size-width 26
  84   "*How wide to jointly make the buffer name and size columns."
  85   :type 'number
  86   :group 'Buffer-menu)
  87
  88 (defcustom Buffer-menu-mode-width 16
  89   "*How wide to make the mode name column."
  90   :type 'number
  91   :group 'Buffer-menu)
  92
  93 ;; This should get updated & resorted when you click on a column heading
  94 (defvar Buffer-menu-sort-column nil
  95   "*2 for sorting by buffer names.  5 for sorting by file names.
  96 nil for default sorting by visited order.")
  97
  98 (defconst Buffer-menu-buffer-column 4)
  99
 100 (defvar Buffer-menu-mode-map nil
 101   "Local keymap for `Buffer-menu-mode' buffers.")
 102
 103 (defvar Buffer-menu-files-only nil
 104   "Non-nil if the current buffer-menu lists only file buffers.
 105 This variable determines whether reverting the buffer lists only
 106 file buffers.  It affects both manual reverting and reverting by
 107 Auto Revert Mode.")
 108
 109 (make-variable-buffer-local 'Buffer-menu-files-only)
 110
 111 (if Buffer-menu-mode-map
 112     ()
 113   (setq Buffer-menu-mode-map (make-keymap))
 114   (suppress-keymap Buffer-menu-mode-map t)
 115   (define-key Buffer-menu-mode-map "q" 'quit-window)
 116   (define-key Buffer-menu-mode-map "v" 'Buffer-menu-select)
 117   (define-key Buffer-menu-mode-map "2" 'Buffer-menu-2-window)
 118   (define-key Buffer-menu-mode-map "1" 'Buffer-menu-1-window)
 119   (define-key Buffer-menu-mode-map "f" 'Buffer-menu-this-window)
 120   (define-key Buffer-menu-mode-map "e" 'Buffer-menu-this-window)
 121   (define-key Buffer-menu-mode-map "\C-m" 'Buffer-menu-this-window)
 122   (define-key Buffer-menu-mode-map "o" 'Buffer-menu-other-window)
 123   (define-key Buffer-menu-mode-map "\C-o" 'Buffer-menu-switch-other-window)
 124   (define-key Buffer-menu-mode-map "s" 'Buffer-menu-save)
 125   (define-key Buffer-menu-mode-map "d" 'Buffer-menu-delete)
 126   (define-key Buffer-menu-mode-map "k" 'Buffer-menu-delete)
 127   (define-key Buffer-menu-mode-map "\C-d" 'Buffer-menu-delete-backwards)
 128   (define-key Buffer-menu-mode-map "\C-k" 'Buffer-menu-delete)
 129   (define-key Buffer-menu-mode-map "x" 'Buffer-menu-execute)
 130   (define-key Buffer-menu-mode-map " " 'next-line)
 131   (define-key Buffer-menu-mode-map "n" 'next-line)
 132   (define-key Buffer-menu-mode-map "p" 'previous-line)
 133   (define-key Buffer-menu-mode-map "\177" 'Buffer-menu-backup-unmark)
 134   (define-key Buffer-menu-mode-map "~" 'Buffer-menu-not-modified)
 135   (define-key Buffer-menu-mode-map "?" 'describe-mode)
 136   (define-key Buffer-menu-mode-map "u" 'Buffer-menu-unmark)
 137   (define-key Buffer-menu-mode-map "m" 'Buffer-menu-mark)
 138   (define-key Buffer-menu-mode-map "t" 'Buffer-menu-visit-tags-table)
 139   (define-key Buffer-menu-mode-map "%" 'Buffer-menu-toggle-read-only)
 140   (define-key Buffer-menu-mode-map "b" 'Buffer-menu-bury)
 141   (define-key Buffer-menu-mode-map "g" 'Buffer-menu-revert)
 142   (define-key Buffer-menu-mode-map "V" 'Buffer-menu-view)
 143   (define-key Buffer-menu-mode-map "T" 'Buffer-menu-toggle-files-only)
 144   (define-key Buffer-menu-mode-map [mouse-2] 'Buffer-menu-mouse-select)
 145   (define-key Buffer-menu-mode-map [follow-link] 'mouse-face)
 146 )
 147
 148 ;; Buffer Menu mode is suitable only for specially formatted data.
 149 (put 'Buffer-menu-mode 'mode-class 'special)
 150
 151 (defun Buffer-menu-mode ()
 152   "Major mode for editing a list of buffers.
 153 Each line describes one of the buffers in Emacs.
 154 Letters do not insert themselves; instead, they are commands.
 155 \\<Buffer-menu-mode-map>
 156 \\[Buffer-menu-mouse-select] -- select buffer you click on, in place of the buffer menu.
 157 \\[Buffer-menu-this-window] -- select current line's buffer in place of the buffer menu.
 158 \\[Buffer-menu-other-window] -- select that buffer in another window,
 159   so the buffer menu buffer remains visible in its window.
 160 \\[Buffer-menu-view] -- select current line's buffer, but in view-mode.
 161 \\[Buffer-menu-view-other-window] -- select that buffer in
 162   another window, in view-mode.
 163 \\[Buffer-menu-switch-other-window] -- make another window display that buffer.
 164 \\[Buffer-menu-mark] -- mark current line's buffer to be displayed.
 165 \\[Buffer-menu-select] -- select current line's buffer.
 166   Also show buffers marked with m, in other windows.
 167 \\[Buffer-menu-1-window] -- select that buffer in full-frame window.
 168 \\[Buffer-menu-2-window] -- select that buffer in one window,
 169   together with buffer selected before this one in another window.
 170 \\[Buffer-menu-visit-tags-table] -- visit-tags-table this buffer.
 171 \\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
 172 \\[Buffer-menu-save] -- mark that buffer to be saved, and move down.
 173 \\[Buffer-menu-delete] -- mark that buffer to be deleted, and move down.
 174 \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted, and move up.
 175 \\[Buffer-menu-execute] -- delete or save marked buffers.
 176 \\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
 177   With prefix argument, also move up one line.
 178 \\[Buffer-menu-backup-unmark] -- back up a line and remove marks.
 179 \\[Buffer-menu-toggle-read-only] -- toggle read-only status of buffer on this line.
 180 \\[Buffer-menu-revert] -- update the list of buffers.
 181 \\[Buffer-menu-toggle-files-only] -- toggle whether the menu displays only file buffers.
 182 \\[Buffer-menu-bury] -- bury the buffer listed on this line."
 183   (kill-all-local-variables)
 184   (use-local-map Buffer-menu-mode-map)
 185   (setq major-mode 'Buffer-menu-mode)
 186   (setq mode-name "Buffer Menu")
 187   (set (make-local-variable 'revert-buffer-function)
 188        'Buffer-menu-revert-function)
 189   (set (make-local-variable 'buffer-stale-function)
 190        #'(lambda (&optional noconfirm) 'fast))
 191   (setq truncate-lines t)
 192   (setq buffer-read-only t)
 193   (run-hooks 'buffer-menu-mode-hook))
 194
 195 ;; This function exists so we can make the doc string of Buffer-menu-mode
 196 ;; look nice.
 197 (defun Buffer-menu-revert ()
 198   "Update the list of buffers."
 199   (interactive)
 200   (revert-buffer))
 201
 202 (defun Buffer-menu-revert-function (ignore1 ignore2)
 203   (or (eq buffer-undo-list t)
 204       (setq buffer-undo-list nil))
 205   ;; We can not use save-excursion here.  The buffer gets erased.
 206   (let ((ocol (current-column))
 207         (oline (progn (move-to-column 4)
 208                       (get-text-property (point) 'buffer)))
 209         (prop (point-min))
 210         ;; do not make undo records for the reversion.
 211         (buffer-undo-list t))
 212     (list-buffers-noselect Buffer-menu-files-only)
 213     (while (setq prop (next-single-property-change prop 'buffer))
 214       (when (eq (get-text-property prop 'buffer) oline)
 215         (goto-char prop)
 216         (move-to-column ocol)))))
 217
 218 (defun Buffer-menu-toggle-files-only (arg)
 219   "Toggle whether the current buffer-menu displays only file buffers.
 220 With a positive ARG display only file buffers.  With zero or
 221 negative ARG, display other buffers as well."
 222   (interactive "P")
 223   (setq Buffer-menu-files-only
 224         (cond ((not arg) (not Buffer-menu-files-only))
 225               ((> (prefix-numeric-value arg) 0) t)))
 226   (revert-buffer))
 227
 228 \f
 229 (defun Buffer-menu-buffer (error-if-non-existent-p)
 230   "Return buffer described by this line of buffer menu."
 231   (let* ((where (save-excursion
 232                   (beginning-of-line)
 233                   (+ (point) Buffer-menu-buffer-column)))
 234          (name (and (not (eobp)) (get-text-property where 'buffer-name)))
 235          (buf (and (not (eobp)) (get-text-property where 'buffer))))
 236     (if name
 237         (or (get-buffer name)
 238             (and buf (buffer-name buf) buf)
 239             (if error-if-non-existent-p
 240                 (error "No buffer named `%s'" name)
 241               nil))
 242       (or (and buf (buffer-name buf) buf)
 243           (if error-if-non-existent-p
 244               (error "No buffer on this line")
 245             nil)))))
 246 \f
 247 (defun buffer-menu (&optional arg)
 248   "Make a menu of buffers so you can save, delete or select them.
 249 With argument, show only buffers that are visiting files.
 250 Type ? after invocation to get help on commands available.
 251 Type q to remove the buffer menu from the display.
 252
 253 The first column shows `>' for a buffer you have
 254 marked to be displayed, `D' for one you have marked for
 255 deletion, and `.' for the current buffer.
 256
 257 The C column has a `.' for the buffer from which you came.
 258 The R column has a `%' if the buffer is read-only.
 259 The M column has a `*' if it is modified,
 260 or `S' if you have marked it for saving.
 261 After this come the buffer name, its size in characters,
 262 its major mode, and the visited file name (if any)."
 263   (interactive "P")
 264 ;;;  (setq Buffer-menu-window-config (current-window-configuration))
 265   (switch-to-buffer (list-buffers-noselect arg))
 266   (message
 267    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 268
 269 (defun buffer-menu-other-window (&optional arg)
 270   "Display a list of buffers in another window.
 271 With the buffer list buffer, you can save, delete or select the buffers.
 272 With argument, show only buffers that are visiting files.
 273 Type ? after invocation to get help on commands available.
 274 Type q to remove the buffer menu from the display.
 275 For more information, see the function `buffer-menu'."
 276   (interactive "P")
 277 ;;;  (setq Buffer-menu-window-config (current-window-configuration))
 278   (switch-to-buffer-other-window (list-buffers-noselect arg))
 279   (message
 280    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 281
 282 (defun Buffer-menu-no-header ()
 283   (beginning-of-line)
 284   (if (or Buffer-menu-use-header-line
 285           (not (eq (char-after) ?C)))
 286       t
 287     (ding)
 288     (forward-line 1)
 289     nil))
 290
 291 (defun Buffer-menu-mark ()
 292   "Mark buffer on this line for being displayed by \\<Buffer-menu-mode-map>\\[Buffer-menu-select] command."
 293   (interactive)
 294   (when (Buffer-menu-no-header)
 295     (let ((buffer-read-only nil))
 296       (delete-char 1)
 297       (insert ?>)
 298       (forward-line 1))))
 299
 300 (defun Buffer-menu-unmark (&optional backup)
 301   "Cancel all requested operations on buffer on this line and move down.
 302 Optional ARG means move up."
 303   (interactive "P")
 304   (when (Buffer-menu-no-header)
 305     (let* ((buf (Buffer-menu-buffer t))
 306            (mod (buffer-modified-p buf))
 307            (readonly (save-excursion (set-buffer buf) buffer-read-only))
 308            (buffer-read-only nil))
 309       (delete-char 3)
 310       (insert (if readonly (if mod " %*" " % ") (if mod "  *" "   ")))))
 311   (forward-line (if backup -1 1)))
 312
 313 (defun Buffer-menu-backup-unmark ()
 314   "Move up and cancel all requested operations on buffer on line above."
 315   (interactive)
 316   (forward-line -1)
 317   (Buffer-menu-unmark)
 318   (forward-line -1))
 319
 320 (defun Buffer-menu-delete (&optional arg)
 321   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command.
 322 Prefix arg is how many buffers to delete.
 323 Negative arg means delete backwards."
 324   (interactive "p")
 325   (when (Buffer-menu-no-header)
 326     (let ((buffer-read-only nil))
 327       (if (or (null arg) (= arg 0))
 328           (setq arg 1))
 329       (while (> arg 0)
 330         (delete-char 1)
 331         (insert ?D)
 332         (forward-line 1)
 333         (setq arg (1- arg)))
 334       (while (and (< arg 0)
 335                   (Buffer-menu-no-header))
 336         (delete-char 1)
 337         (insert ?D)
 338         (forward-line -1)
 339         (setq arg (1+ arg))))))
 340
 341 (defun Buffer-menu-delete-backwards (&optional arg)
 342   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command
 343 and then move up one line.  Prefix arg means move that many lines."
 344   (interactive "p")
 345   (Buffer-menu-delete (- (or arg 1))))
 346
 347 (defun Buffer-menu-save ()
 348   "Mark buffer on this line to be saved by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command."
 349   (interactive)
 350   (when (Buffer-menu-no-header)
 351     (let ((buffer-read-only nil))
 352       (forward-char 2)
 353       (delete-char 1)
 354       (insert ?S)
 355       (forward-line 1))))
 356
 357 (defun Buffer-menu-not-modified (&optional arg)
 358   "Mark buffer on this line as unmodified (no changes to save)."
 359   (interactive "P")
 360   (save-excursion
 361     (set-buffer (Buffer-menu-buffer t))
 362     (set-buffer-modified-p arg))
 363   (save-excursion
 364    (beginning-of-line)
 365    (forward-char 2)
 366    (if (= (char-after) (if arg ?  ?*))
 367        (let ((buffer-read-only nil))
 368          (delete-char 1)
 369          (insert (if arg ?* ? ))))))
 370
 371 (defun Buffer-menu-beginning ()
 372   (goto-char (point-min))
 373   (unless Buffer-menu-use-header-line
 374     (forward-line)))
 375
 376 (defun Buffer-menu-execute ()
 377   "Save and/or delete buffers marked with \\<Buffer-menu-mode-map>\\[Buffer-menu-save] or \\<Buffer-menu-mode-map>\\[Buffer-menu-delete] commands."
 378   (interactive)
 379   (save-excursion
 380     (Buffer-menu-beginning)
 381     (while (re-search-forward "^..S" nil t)
 382       (let ((modp nil))
 383         (save-excursion
 384           (set-buffer (Buffer-menu-buffer t))
 385           (save-buffer)
 386           (setq modp (buffer-modified-p)))
 387         (let ((buffer-read-only nil))
 388           (delete-char -1)
 389           (insert (if modp ?* ? ))))))
 390   (save-excursion
 391     (Buffer-menu-beginning)
 392     (let ((buff-menu-buffer (current-buffer))
 393           (buffer-read-only nil))
 394       (while (re-search-forward "^D" nil t)
 395         (forward-char -1)
 396         (let ((buf (Buffer-menu-buffer nil)))
 397           (or (eq buf nil)
 398               (eq buf buff-menu-buffer)
 399               (save-excursion (kill-buffer buf)))
 400           (if (and buf (buffer-name buf))
 401             (progn (delete-char 1)
 402                    (insert ? ))
 403           (delete-region (point) (progn (forward-line 1) (point)))
 404             (unless (bobp)
 405               (forward-char -1))))))))
 406
 407 (defun Buffer-menu-select ()
 408   "Select this line's buffer; also display buffers marked with `>'.
 409 You can mark buffers with the \\<Buffer-menu-mode-map>\\[Buffer-menu-mark] command.
 410 This command deletes and replaces all the previously existing windows
 411 in the selected frame."
 412   (interactive)
 413   (let ((buff (Buffer-menu-buffer t))
 414         (menu (current-buffer))
 415         (others ())
 416         tem)
 417     (Buffer-menu-beginning)
 418     (while (re-search-forward "^>" nil t)
 419       (setq tem (Buffer-menu-buffer t))
 420       (let ((buffer-read-only nil))
 421         (delete-char -1)
 422         (insert ?\ ))
 423       (or (eq tem buff) (memq tem others) (setq others (cons tem others))))
 424     (setq others (nreverse others)
 425           tem (/ (1- (frame-height)) (1+ (length others))))
 426     (delete-other-windows)
 427     (switch-to-buffer buff)
 428     (or (eq menu buff)
 429         (bury-buffer menu))
 430     (if (equal (length others) 0)
 431         (progn
 432 ;;;       ;; Restore previous window configuration before displaying
 433 ;;;       ;; selected buffers.
 434 ;;;       (if Buffer-menu-window-config
 435 ;;;           (progn
 436 ;;;             (set-window-configuration Buffer-menu-window-config)
 437 ;;;             (setq Buffer-menu-window-config nil)))
 438           (switch-to-buffer buff))
 439       (while others
 440         (split-window nil tem)
 441         (other-window 1)
 442         (switch-to-buffer (car others))
 443         (setq others (cdr others)))
 444       (other-window 1)                          ;back to the beginning!
 445 )))
 446
 447
 448 \f
 449 (defun Buffer-menu-visit-tags-table ()
 450   "Visit the tags table in the buffer on this line.  See `visit-tags-table'."
 451   (interactive)
 452   (let ((file (buffer-file-name (Buffer-menu-buffer t))))
 453     (if file
 454         (visit-tags-table file)
 455       (error "Specified buffer has no file"))))
 456
 457 (defun Buffer-menu-1-window ()
 458   "Select this line's buffer, alone, in full frame."
 459   (interactive)
 460   (switch-to-buffer (Buffer-menu-buffer t))
 461   (bury-buffer (other-buffer))
 462   (delete-other-windows))
 463
 464 (defun Buffer-menu-mouse-select (event)
 465   "Select the buffer whose line you click on."
 466   (interactive "e")
 467   (let (buffer)
 468     (save-excursion
 469       (set-buffer (window-buffer (posn-window (event-end event))))
 470       (save-excursion
 471         (goto-char (posn-point (event-end event)))
 472         (setq buffer (Buffer-menu-buffer t))))
 473     (select-window (posn-window (event-end event)))
 474     (if (and (window-dedicated-p (selected-window))
 475              (eq (selected-window) (frame-root-window)))
 476         (switch-to-buffer-other-frame buffer)
 477       (switch-to-buffer buffer))))
 478
 479 (defun Buffer-menu-this-window ()
 480   "Select this line's buffer in this window."
 481   (interactive)
 482   (switch-to-buffer (Buffer-menu-buffer t)))
 483
 484 (defun Buffer-menu-other-window ()
 485   "Select this line's buffer in other window, leaving buffer menu visible."
 486   (interactive)
 487   (switch-to-buffer-other-window (Buffer-menu-buffer t)))
 488
 489 (defun Buffer-menu-switch-other-window ()
 490   "Make the other window select this line's buffer.
 491 The current window remains selected."
 492   (interactive)
 493   (let ((pop-up-windows t)
 494         same-window-buffer-names
 495         same-window-regexps)
 496     (display-buffer (Buffer-menu-buffer t))))
 497
 498 (defun Buffer-menu-2-window ()
 499   "Select this line's buffer, with previous buffer in second window."
 500   (interactive)
 501   (let ((buff (Buffer-menu-buffer t))
 502         (menu (current-buffer))
 503         (pop-up-windows t)
 504         same-window-buffer-names
 505         same-window-regexps)
 506     (delete-other-windows)
 507     (switch-to-buffer (other-buffer))
 508     (pop-to-buffer buff)
 509     (bury-buffer menu)))
 510
 511 (defun Buffer-menu-toggle-read-only ()
 512   "Toggle read-only status of buffer on this line, perhaps via version control."
 513   (interactive)
 514   (let (char)
 515     (save-excursion
 516       (set-buffer (Buffer-menu-buffer t))
 517       (vc-toggle-read-only)
 518       (setq char (if buffer-read-only ?% ? )))
 519     (save-excursion
 520       (beginning-of-line)
 521       (forward-char 1)
 522       (if (/= (following-char) char)
 523           (let (buffer-read-only)
 524             (delete-char 1)
 525             (insert char))))))
 526
 527 (defun Buffer-menu-bury ()
 528   "Bury the buffer listed on this line."
 529   (interactive)
 530   (when (Buffer-menu-no-header)
 531     (save-excursion
 532       (beginning-of-line)
 533       (bury-buffer (Buffer-menu-buffer t))
 534       (let ((line (buffer-substring (point) (progn (forward-line 1) (point))))
 535             (buffer-read-only nil))
 536         (delete-region (point) (progn (forward-line -1) (point)))
 537         (goto-char (point-max))
 538         (insert line))
 539       (message "Buried buffer moved to the end"))))
 540
 541
 542 (defun Buffer-menu-view ()
 543   "View this line's buffer in View mode."
 544   (interactive)
 545   (view-buffer (Buffer-menu-buffer t)))
 546
 547
 548 (defun Buffer-menu-view-other-window ()
 549   "View this line's buffer in View mode in another window."
 550   (interactive)
 551   (view-buffer-other-window (Buffer-menu-buffer t)))
 552 \f
 553
 554 (define-key ctl-x-map "\C-b" 'list-buffers)
 555
 556 (defun list-buffers (&optional files-only)
 557   "Display a list of names of existing buffers.
 558 The list is displayed in a buffer named `*Buffer List*'.
 559 Note that buffers with names starting with spaces are omitted.
 560 Non-null optional arg FILES-ONLY means mention only file buffers.
 561
 562 For more information, see the function `buffer-menu'."
 563   (interactive "P")
 564   (display-buffer (list-buffers-noselect files-only)))
 565
 566 (defun Buffer-menu-buffer+size (name size &optional name-props size-props)
 567   (if (> (+ (length name) (length size) 2) Buffer-menu-buffer+size-width)
 568       (setq name
 569             (if (string-match "<[0-9]+>$" name)
 570                 (concat (substring name 0
 571                                    (- Buffer-menu-buffer+size-width
 572                                       (max (length size) 3)
 573                                       (match-end 0)
 574                                       (- (match-beginning 0))
 575                                       2))
 576                         ":"             ; narrow ellipsis
 577                         (match-string 0 name))
 578               (concat (substring name 0
 579                                  (- Buffer-menu-buffer+size-width
 580                                     (max (length size) 3)
 581                                     2))
 582                       ":")))            ; narrow ellipsis
 583     ;; Don't put properties on (buffer-name).
 584     (setq name (copy-sequence name)))
 585   (add-text-properties 0 (length name) name-props name)
 586   (add-text-properties 0 (length size) size-props size)
 587   (concat name
 588           (make-string (- Buffer-menu-buffer+size-width
 589                           (length name)
 590                           (length size))
 591                        ? )
 592           size))
 593
 594 (defun Buffer-menu-sort (column)
 595   "Sort the buffer menu by COLUMN."
 596   (interactive "P")
 597   (when column
 598     (setq column (prefix-numeric-value column))
 599     (if (< column 2) (setq column 2))
 600     (if (> column 5) (setq column 5)))
 601   (setq Buffer-menu-sort-column column)
 602   (let (buffer-read-only l buf m1 m2)
 603     (save-excursion
 604       (Buffer-menu-beginning)
 605       (while (not (eobp))
 606         (when (buffer-live-p (setq buf (get-text-property (+ (point) 4) 'buffer)))
 607           (setq m1 (char-after)
 608                 m1 (if (memq m1 '(?> ?D)) m1)
 609                 m2 (char-after (+ (point) 2))
 610                 m2 (if (eq m2 ?S) m2))
 611           (if (or m1 m2)
 612               (push (list buf m1 m2) l)))
 613         (forward-line)))
 614     (Buffer-menu-revert)
 615     (setq buffer-read-only)
 616     (save-excursion
 617       (Buffer-menu-beginning)
 618       (while (not (eobp))
 619         (when (setq buf (assq (get-text-property (+ (point) 4) 'buffer) l))
 620           (setq m1 (cadr buf)
 621                 m2 (cadr (cdr buf)))
 622           (when m1
 623             (delete-char 1)
 624             (insert m1)
 625             (backward-char 1))
 626           (when m2
 627             (forward-char 2)
 628             (delete-char 1)
 629             (insert m2)))
 630         (forward-line)))))
 631
 632 (defun Buffer-menu-make-sort-button (name column)
 633   (if (equal column Buffer-menu-sort-column) (setq column nil))
 634   (propertize name
 635               'help-echo (if column
 636                              (concat "mouse-2: sort by " (downcase name))
 637                            "mouse-2: sort by visited order")
 638               'mouse-face 'highlight
 639               'keymap (let ((map (make-sparse-keymap)))
 640                         (define-key map [header-line mouse-2]
 641                           `(lambda (e)
 642                              (interactive "e")
 643                              (save-window-excursion
 644                                (if e (mouse-select-window e))
 645                                (Buffer-menu-sort ,column))))
 646                         map)))
 647
 648 (defun list-buffers-noselect (&optional files-only buffer-list)
 649   "Create and return a buffer with a list of names of existing buffers.
 650 The buffer is named `*Buffer List*'.
 651 Note that buffers with names starting with spaces are omitted.
 652 Non-null optional arg FILES-ONLY means mention only file buffers.
 653
 654 If BUFFER-LIST is non-nil, it should be a list of buffers;
 655 it means list those buffers and no others.
 656
 657 For more information, see the function `buffer-menu'."
 658   (let* ((old-buffer (current-buffer))
 659          (standard-output standard-output)
 660          (mode-end (make-string (- Buffer-menu-mode-width 2) ? ))
 661          (header (concat "CRM "
 662                          (Buffer-menu-buffer+size
 663                           (Buffer-menu-make-sort-button "Buffer" 2)
 664                           (Buffer-menu-make-sort-button "Size" 3))
 665                          "  "
 666                          (Buffer-menu-make-sort-button "Mode" 4) mode-end
 667                          (Buffer-menu-make-sort-button "File" 5) "\n"))
 668          list desired-point)
 669     (when Buffer-menu-use-header-line
 670       (let ((pos 0))
 671         ;; Turn spaces in the header into stretch specs so they work
 672         ;; regardless of the header-line face.
 673         (while (string-match "[ \t]+" header pos)
 674           (setq pos (match-end 0))
 675           (put-text-property (match-beginning 0) pos 'display
 676                              ;; Assume fixed-size chars in the buffer.
 677                              (list 'space :align-to pos)
 678                              header)))
 679       ;; Try to better align the one-char headers.
 680       (put-text-property 0 3 'face 'fixed-pitch header)
 681       ;; Add a "dummy" leading space to align the beginning of the header
 682       ;; line with the beginning of the text (rather than with the left
 683       ;; scrollbar or the left fringe).  –-Stef
 684       (setq header (concat (propertize " " 'display '(space :align-to 0))
 685                            header)))
 686     (with-current-buffer (get-buffer-create "*Buffer List*")
 687       (setq buffer-read-only nil)
 688       (erase-buffer)
 689       (setq standard-output (current-buffer))
 690       (unless Buffer-menu-use-header-line
 691         (let ((underline (if (char-displayable-p ?—) ?— ?-)))
 692           (insert header
 693                   (apply 'string
 694                          (mapcar (lambda (c)
 695                                    (if (memq c '(?\n ?\ )) c underline))
 696                                  header)))))
 697       ;; Collect info for every buffer we're interested in.
 698       (dolist (buffer (or buffer-list (buffer-list)))
 699         (with-current-buffer buffer
 700           (let ((name (buffer-name))
 701                 (file buffer-file-name))
 702             (unless (and (not buffer-list)
 703                          (or
 704                           ;; Don't mention internal buffers.
 705                           (and (string= (substring name 0 1) " ") (null file))
 706                           ;; Maybe don't mention buffers without files.
 707                           (and files-only (not file))
 708                           (string= name "*Buffer List*")))
 709               ;; Otherwise output info.
 710               (let ((mode (concat (format-mode-line mode-name nil nil buffer)
 711                                   (if mode-line-process
 712                                       (format-mode-line mode-line-process
 713                                                         nil nil buffer))))
 714                     (bits (string
 715                            (if (eq buffer old-buffer) ?. ?\ )
 716                            ;; Handle readonly status.  The output buffer
 717                            ;; is special cased to appear readonly; it is
 718                            ;; actually made so at a later date.
 719                            (if (or (eq buffer standard-output)
 720                                    buffer-read-only)
 721                                ?% ?\ )
 722                            ;; Identify modified buffers.
 723                            (if (buffer-modified-p) ?* ?\ )
 724                            ;; Space separator.
 725                            ?\ )))
 726                 (unless file
 727                   ;; No visited file.  Check local value of
 728                   ;; list-buffers-directory.
 729                   (when (and (boundp 'list-buffers-directory)
 730                              list-buffers-directory)
 731                     (setq file list-buffers-directory)))
 732                 (push (list buffer bits name (buffer-size) mode file)
 733                       list))))))
 734       ;; Preserve the original buffer-list ordering, just in case.
 735       (setq list (nreverse list))
 736       ;; Place the buffers's info in the output buffer, sorted if necessary.
 737       (dolist (buffer
 738                (if Buffer-menu-sort-column
 739                    (sort list
 740                          (if (eq Buffer-menu-sort-column 3)
 741                              (lambda (a b)
 742                                (< (nth Buffer-menu-sort-column a)
 743                                   (nth Buffer-menu-sort-column b)))
 744                            (lambda (a b)
 745                              (string< (nth Buffer-menu-sort-column a)
 746                                       (nth Buffer-menu-sort-column b)))))
 747                  list))
 748         (if (eq (car buffer) old-buffer)
 749             (setq desired-point (point)))
 750         (insert (cadr buffer)
 751                 ;; Put the buffer name into a text property
 752                 ;; so we don't have to extract it from the text.
 753                 ;; This way we avoid problems with unusual buffer names.
 754                 (Buffer-menu-buffer+size (nth 2 buffer)
 755                                          (int-to-string (nth 3 buffer))
 756                                          `(buffer-name ,(nth 2 buffer)
 757                                            buffer ,(car buffer)
 758                                            font-lock-face Buffer-menu-buffer-face
 759                                            mouse-face highlight
 760                                            help-echo "mouse-2: select this buffer"))
 761                 "  "
 762                 (if (> (length (nth 4 buffer)) Buffer-menu-mode-width)
 763                     (substring (nth 4 buffer) 0 Buffer-menu-mode-width)
 764                   (nth 4 buffer)))
 765         (when (nth 5 buffer)
 766           (indent-to (+ Buffer-menu-buffer-column Buffer-menu-buffer+size-width
 767                         Buffer-menu-mode-width 4) 1)
 768           (princ (abbreviate-file-name (nth 5 buffer))))
 769         (princ "\n"))
 770       (Buffer-menu-mode)
 771       (when Buffer-menu-use-header-line
 772         (setq header-line-format header))
 773       ;; DESIRED-POINT doesn't have to be set; it is not when the
 774       ;; current buffer is not displayed for some reason.
 775       (and desired-point
 776            (goto-char desired-point))
 777       (setq Buffer-menu-files-only files-only)
 778       (set-buffer-modified-p nil)
 779       (current-buffer))))
 780
 781 ;; arch-tag: e7dfcfc9-6cb2-46e4-bf55-8ef1936d83c6
 782 ;;; buff-menu.el ends here