lisp/resume.el

   1 ;;; resume.el --- process command line args from within a suspended Emacs job
   2
   3 ;; Copyright (C) 1992, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Joe Wells <jbw@bucsf.bu.edu>
   7 ;; Adapted-By: ESR
   8 ;; Keywords: processes
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; The purpose of this library is to handle command line arguments
  28 ;; when you resume an existing Emacs job.
  29
  30 ;; In order to use it, you must put this code in your .emacs file.
  31
  32 ;; (add-hook 'suspend-hook 'resume-suspend-hook)
  33 ;; (add-hook 'suspend-resume-hook 'resume-process-args)
  34
  35 ;; You can't get the benefit of this library by using the `emacs' command,
  36 ;; since that always starts a new Emacs job.  Instead you must use a
  37 ;; command called `edit' which knows how to resume an existing Emacs job
  38 ;; if you have one, or start a new Emacs job if you don't have one.
  39
  40 ;; To define the `edit' command, run the script etc/emacs.csh (if you use CSH),
  41 ;; or etc/emacs.bash if you use BASH.  You would normally do this in your
  42 ;; login script.
  43
  44 ;; Stephan Gildea suggested bug fix (gildea@bbn.com).
  45 ;; Ideas from Michael DeCorte and other people.
  46
  47 ;;; Code:
  48
  49 (defvar resume-emacs-args-file (expand-file-name "~/.emacs_args")
  50   "*This file is where arguments are placed for a suspended Emacs job.")
  51
  52 (defvar resume-emacs-args-buffer " *Command Line Args*"
  53   "Buffer that is used by `resume-process-args'.")
  54
  55 (defun resume-process-args ()
  56   "Handler for command line args given when Emacs is resumed."
  57   (let ((start-buffer (current-buffer))
  58         (args-buffer (get-buffer-create resume-emacs-args-buffer))
  59         length args
  60         (command-line-default-directory default-directory))
  61     (unwind-protect
  62         (progn
  63           (set-buffer args-buffer)
  64           (erase-buffer)
  65           ;; get the contents of resume-emacs-args-file
  66           (condition-case ()
  67               (let ((result (insert-file-contents resume-emacs-args-file)))
  68                 (setq length (car (cdr result))))
  69             ;; the file doesn't exist, ergo no arguments
  70             (file-error
  71               (erase-buffer)
  72               (setq length 0)))
  73           (if (<= length 0)
  74               (setq args nil)
  75             ;; get the arguments from the buffer
  76             (goto-char (point-min))
  77             (while (not (eobp))
  78               (skip-chars-forward " \t\n")
  79               (let ((begin (point)))
  80                 (skip-chars-forward "^ \t\n")
  81                 (setq args (cons (buffer-substring begin (point)) args)))
  82               (skip-chars-forward " \t\n"))
  83             ;; arguments are now in reverse order
  84             (setq args (nreverse args))
  85             ;; make sure they're not read again
  86             (erase-buffer))
  87           (resume-write-buffer-to-file (current-buffer) resume-emacs-args-file)
  88           ;; if nothing was in buffer, args will be null
  89           (or (null args)
  90               (setq command-line-default-directory
  91                     (file-name-as-directory (car args))
  92                     args (cdr args)))
  93           ;; actually process the arguments
  94           (command-line-1 args))
  95       ;; If the command line args don't result in a find-file, the
  96       ;; buffer will be left in args-buffer.  So we change back to the
  97       ;; original buffer.  The reason I don't just use
  98       ;; (let ((default-directory foo))
  99       ;;    (command-line-1 args))
 100       ;; in the context of the original buffer is because let does not
 101       ;; work properly with buffer-local variables.
 102       (if (eq (current-buffer) args-buffer)
 103           (set-buffer start-buffer)))))
 104
 105 ;;;###autoload
 106 (defun resume-suspend-hook ()
 107   "Clear out the file used for transmitting args when Emacs resumes."
 108   (save-excursion
 109     (set-buffer (get-buffer-create resume-emacs-args-buffer))
 110     (erase-buffer)
 111     (resume-write-buffer-to-file (current-buffer) resume-emacs-args-file)))
 112
 113 (defun resume-write-buffer-to-file (buffer file)
 114   "Writes the contents of BUFFER into FILE, if permissions allow."
 115   (if (not (file-writable-p file))
 116       (error "No permission to write file %s" file))
 117   (save-excursion
 118     (set-buffer buffer)
 119     (clear-visited-file-modtime)
 120     (save-restriction
 121       (widen)
 122       (write-region (point-min) (point-max) file nil 'quiet))
 123     (set-buffer-modified-p nil)))
 124
 125 (provide 'resume)
 126
 127 ;; arch-tag: c90b2761-4803-4e58-a0ae-c4721368b628
 128 ;;; resume.el ends here