lisp/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is a mercurial version control backend
  26
  27 ;;; Thanks:
  28
  29 ;;; Bugs:
  30
  31 ;;; Installation:
  32
  33 ;;; Todo:
  34
  35 ;; 1) Implement the rest of the vc interface. See the comment at the
  36 ;; beginning of vc.el. The current status is:
  37
  38 ;; FUNCTION NAME                               STATUS
  39 ;; BACKEND PROPERTIES
  40 ;; * revision-granularity                      OK
  41 ;; STATE-QUERYING FUNCTIONS
  42 ;; * registered (file)                         OK
  43 ;; * state (file)                              OK
  44 ;; - state-heuristic (file)                    NOT NEEDED
  45 ;; * working-revision (file)                   OK
  46 ;; - latest-on-branch-p (file)                 ??
  47 ;; * checkout-model (files)                    OK
  48 ;; - workfile-unchanged-p (file)               OK
  49 ;; - mode-line-string (file)                   NOT NEEDED
  50 ;; - prettify-state-info (file)                OK
  51 ;; STATE-CHANGING FUNCTIONS
  52 ;; * register (files &optional rev comment)    OK
  53 ;; * create-repo ()                            OK
  54 ;; - init-revision ()                          NOT NEEDED
  55 ;; - responsible-p (file)                      OK
  56 ;; - could-register (file)                     OK
  57 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  58 ;; - unregister (file)                         COMMENTED OUT, MAY BE INCORRECT
  59 ;; * checkin (files rev comment)               OK
  60 ;; * find-revision (file rev buffer)           OK
  61 ;; * checkout (file &optional editable rev)    OK
  62 ;; * revert (file &optional contents-done)     OK
  63 ;; - rollback (files)                          ?? PROBABLY NOT NEEDED
  64 ;; - merge (file rev1 rev2)                    NEEDED
  65 ;; - merge-news (file)                         NEEDED
  66 ;; - steal-lock (file &optional revision)      NOT NEEDED
  67 ;; HISTORY FUNCTIONS
  68 ;; * print-log (files &optional buffer)        OK
  69 ;; - log-view-mode ()                          OK
  70 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  71 ;; - comment-history (file)                    NOT NEEDED
  72 ;; - update-changelog (files)                  NOT NEEDED
  73 ;; * diff (files &optional rev1 rev2 buffer)   OK
  74 ;; - revision-completion-table (files)         OK?
  75 ;; - annotate-command (file buf &optional rev) OK
  76 ;; - annotate-time ()                          OK
  77 ;; - annotate-current-time ()                  NOT NEEDED
  78 ;; - annotate-extract-revision-at-line ()      OK
  79 ;; TAG SYSTEM
  80 ;; - create-tag (dir name branchp)       NEEDED
  81 ;; - retrieve-tag (dir name update)       NEEDED
  82 ;; MISCELLANEOUS
  83 ;; - make-version-backups-p (file)             ??
  84 ;; - repository-hostname (dirname)             ??
  85 ;; - previous-revision (file rev)              OK
  86 ;; - next-revision (file rev)                  OK
  87 ;; - check-headers ()                          ??
  88 ;; - clear-headers ()                          ??
  89 ;; - delete-file (file)                        TEST IT
  90 ;; - rename-file (old new)                     OK
  91 ;; - find-file-hook ()                         PROBABLY NOT NEEDED
  92 ;; - find-file-not-found-hook ()               PROBABLY NOT NEEDED
  93
  94 ;; 2) Implement Stefan Monnier's advice:
  95 ;; vc-hg-registered and vc-hg-state
  96 ;; Both of those functions should be super extra careful to fail gracefully in
  97 ;; unexpected circumstances. The reason this is important is that any error
  98 ;; there will prevent the user from even looking at the file :-(
  99 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
 100 ;; mercurial's control and extracting the current revision should be done
 101 ;; without even using `hg' (this way even if you don't have `hg' installed,
 102 ;; Emacs is able to tell you this file is under mercurial's control).
 103
 104 ;;; History:
 105 ;;
 106
 107 ;;; Code:
 108
 109 (eval-when-compile
 110   (require 'cl)
 111   (require 'vc))
 112
 113 ;;; Customization options
 114
 115 (defcustom vc-hg-global-switches nil
 116   "*Global switches to pass to any Hg command."
 117   :type '(choice (const :tag "None" nil)
 118          (string :tag "Argument String")
 119          (repeat :tag "Argument List"
 120              :value ("")
 121              string))
 122   :version "22.2"
 123   :group 'vc)
 124
 125 \f
 126 ;;; Properties of the backend
 127
 128 (defun vc-hg-revision-granularity () 'repository)
 129 (defun vc-hg-checkout-model (files) 'implicit)
 130
 131 ;;; State querying functions
 132
 133 ;;;###autoload (defun vc-hg-registered (file)
 134 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 135 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 136 ;;;###autoload       (progn
 137 ;;;###autoload         (load "vc-hg")
 138 ;;;###autoload         (vc-hg-registered file))))
 139
 140 ;; Modelled after the similar function in vc-bzr.el
 141 (defun vc-hg-registered (file)
 142   "Return non-nil if FILE is registered with hg."
 143   (when (vc-hg-root file)           ; short cut
 144     (let ((state (vc-hg-state file)))  ; expensive
 145       (vc-file-setprop file 'vc-state state)
 146       (and state (not (memq state '(ignored unregistered)))))))
 147
 148 (defun vc-hg-state (file)
 149   "Hg-specific version of `vc-state'."
 150   (let*
 151       ((status nil)
 152        (out
 153         (with-output-to-string
 154           (with-current-buffer
 155               standard-output
 156             (setq status
 157                   (condition-case nil
 158                       ;; Ignore all errors.
 159                       (call-process
 160                        "hg" nil t nil "--cwd" (file-name-directory file)
 161                        "status" "-A" (file-name-nondirectory file))
 162                     ;; Some problem happened.  E.g. We can't find an `hg'
 163                     ;; executable.
 164                     (error nil)))))))
 165     (when (eq 0 status)
 166         (when (null (string-match ".*: No such file or directory$" out))
 167           (let ((state (aref out 0)))
 168             (cond
 169              ((eq state ?=) 'up-to-date)
 170              ((eq state ?A) 'added)
 171              ((eq state ?M) 'edited)
 172              ((eq state ?I) 'ignored)
 173              ((eq state ?R) 'removed)
 174              ((eq state ?!) 'missing)
 175              ((eq state ??) 'unregistered)
 176              ((eq state ?C) 'up-to-date) ;; Older mercurials use this
 177              (t 'up-to-date)))))))
 178
 179 (defun vc-hg-working-revision (file)
 180   "Hg-specific version of `vc-working-revision'."
 181   (let*
 182       ((status nil)
 183        (out
 184         (with-output-to-string
 185           (with-current-buffer
 186               standard-output
 187             (setq status
 188                   (condition-case nil
 189                       ;; Ignore all errors.
 190                       (call-process
 191                        "hg" nil t nil "--cwd" (file-name-directory file)
 192                        "log" "-l1" (file-name-nondirectory file))
 193                     ;; Some problem happened.  E.g. We can't find an `hg'
 194                     ;; executable.
 195                     (error nil)))))))
 196     (when (eq 0 status)
 197       (if (string-match "changeset: *\\([0-9]*\\)" out)
 198           (match-string 1 out)
 199         "0"))))
 200
 201 ;;; History functions
 202
 203 (defun vc-hg-print-log (files &optional buffer)
 204   "Get change log associated with FILES."
 205   ;; `log-view-mode' needs to have the file names in order to function
 206   ;; correctly. "hg log" does not print it, so we insert it here by
 207   ;; hand.
 208
 209   ;; `vc-do-command' creates the buffer, but we need it before running
 210   ;; the command.
 211   (vc-setup-buffer buffer)
 212   ;; If the buffer exists from a previous invocation it might be
 213   ;; read-only.
 214   (let ((inhibit-read-only t))
 215     ;; We need to loop and call "hg log" on each file separately.
 216     ;; "hg log" with multiple file arguments mashes all the logs
 217     ;; together.  Ironically enough, this puts us back near CVS
 218     ;; which can't generate proper fileset logs either.
 219     (dolist (file files)
 220       (with-current-buffer
 221           buffer
 222         (insert "Working file: " file "\n"))    ;; Like RCS/CVS.
 223       (vc-hg-command buffer 0 file "log"))))
 224
 225 (defvar log-view-message-re)
 226 (defvar log-view-file-re)
 227 (defvar log-view-font-lock-keywords)
 228
 229 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 230   (require 'add-log) ;; we need the add-log faces
 231   (set (make-local-variable 'log-view-file-re) "^Working file:[ \t]+\\(.+\\)")
 232   (set (make-local-variable 'log-view-message-re)
 233        "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)")
 234   (set (make-local-variable 'log-view-font-lock-keywords)
 235        (append
 236         log-view-font-lock-keywords
 237         '(
 238           ;; Handle the case:
 239           ;; user: FirstName LastName <foo@bar>
 240           ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 241            (1 'change-log-name)
 242            (2 'change-log-email))
 243           ;; Handle the cases:
 244           ;; user: foo@bar
 245           ;; and
 246           ;; user: foo
 247           ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 248            (1 'change-log-email))
 249           ("^date: \\(.+\\)" (1 'change-log-date))
 250           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 251
 252 (defun vc-hg-diff (files &optional oldvers newvers buffer)
 253   "Get a difference report using hg between two revisions of FILES."
 254   (let ((working (vc-working-revision (car files))))
 255     (when (and (equal oldvers working) (not newvers))
 256       (setq oldvers nil))
 257     (when (and (not oldvers) newvers)
 258       (setq oldvers working))
 259     (apply #'vc-hg-command (or buffer "*vc-diff*") nil
 260            (mapcar (lambda (file) (file-name-nondirectory file)) files)
 261            "--cwd" (file-name-directory (car files))
 262            "diff"
 263            (append
 264             (when oldvers
 265               (if newvers
 266                   (list "-r" oldvers "-r" newvers)
 267                 (list "-r" oldvers)))))))
 268
 269 (defun vc-hg-revision-table (files)
 270   (let ((default-directory (file-name-directory (car files))))
 271     (with-temp-buffer
 272       (vc-hg-command t nil files "log" "--template" "{rev} ")
 273       (split-string
 274        (buffer-substring-no-properties (point-min) (point-max))))))
 275
 276 ;; Modelled after the similar function in vc-cvs.el
 277 (defun vc-hg-revision-completion-table (files)
 278   (lexical-let ((files files)
 279                 table)
 280     (setq table (lazy-completion-table
 281                  table (lambda () (vc-hg-revision-table files))))
 282     table))
 283
 284 (defun vc-hg-annotate-command (file buffer &optional revision)
 285   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 286 Optional arg REVISION is a revision to annotate from."
 287   (vc-hg-command buffer 0 file "annotate" "-d" "-n"
 288                  (when revision (concat "-r" revision)))
 289   (with-current-buffer buffer
 290     (goto-char (point-min))
 291     (re-search-forward "^[ \t]*[0-9]")
 292     (delete-region (point-min) (match-beginning 0))))
 293
 294
 295 ;; The format for one line output by "hg annotate -d -n" looks like this:
 296 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 297 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 298 ;; If the user has set the "--follow" option, the output looks like:
 299 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 300 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 301 (defconst vc-hg-annotate-re
 302   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)[^:\n]*\\(:[^ \n][^:\n]*\\)*: ")
 303
 304 (defun vc-hg-annotate-time ()
 305   (when (looking-at vc-hg-annotate-re)
 306     (goto-char (match-end 0))
 307     (vc-annotate-convert-time
 308      (date-to-time (match-string-no-properties 2)))))
 309
 310 (defun vc-hg-annotate-extract-revision-at-line ()
 311   (save-excursion
 312     (beginning-of-line)
 313     (when (looking-at vc-hg-annotate-re) (match-string-no-properties 1))))
 314
 315 (defun vc-hg-previous-revision (file rev)
 316   (let ((newrev (1- (string-to-number rev))))
 317     (when (>= newrev 0)
 318       (number-to-string newrev))))
 319
 320 (defun vc-hg-next-revision (file rev)
 321   (let ((newrev (1+ (string-to-number rev)))
 322         (tip-revision
 323          (with-temp-buffer
 324            (vc-hg-command t 0 nil "tip")
 325            (goto-char (point-min))
 326            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 327            (string-to-number (match-string-no-properties 1)))))
 328     ;; We don't want to exceed the maximum possible revision number, ie
 329     ;; the tip revision.
 330     (when (<= newrev tip-revision)
 331       (number-to-string newrev))))
 332
 333 ;; Modelled after the similar function in vc-bzr.el
 334 (defun vc-hg-delete-file (file)
 335   "Delete FILE and delete it in the hg repository."
 336   (condition-case ()
 337       (delete-file file)
 338     (file-error nil))
 339   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 340
 341 ;; Modelled after the similar function in vc-bzr.el
 342 (defun vc-hg-rename-file (old new)
 343   "Rename file from OLD to NEW using `hg mv'."
 344   (vc-hg-command nil 0 new "mv" old))
 345
 346 (defun vc-hg-register (files &optional rev comment)
 347   "Register FILES under hg.
 348 REV is ignored.
 349 COMMENT is ignored."
 350   (vc-hg-command nil 0 files "add"))
 351
 352 (defun vc-hg-create-repo ()
 353   "Create a new Mercurial repository."
 354   (vc-hg-command nil 0 nil "init"))
 355
 356 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 357
 358 ;; Modelled after the similar function in vc-bzr.el
 359 (defun vc-hg-could-register (file)
 360   "Return non-nil if FILE could be registered under hg."
 361   (and (vc-hg-responsible-p file)      ; shortcut
 362        (condition-case ()
 363            (with-temp-buffer
 364              (vc-hg-command t nil file "add" "--dry-run"))
 365              ;; The command succeeds with no output if file is
 366              ;; registered.
 367          (error))))
 368
 369 ;; XXX This would remove the file. Is that correct?
 370 ;; (defun vc-hg-unregister (file)
 371 ;;   "Unregister FILE from hg."
 372 ;;   (vc-hg-command nil nil file "remove"))
 373
 374 (defun vc-hg-checkin (files rev comment)
 375   "Hg-specific version of `vc-backend-checkin'.
 376 REV is ignored."
 377   (vc-hg-command nil 0 files  "commit" "-m" comment))
 378
 379 (defun vc-hg-find-revision (file rev buffer)
 380   (let ((coding-system-for-read 'binary)
 381         (coding-system-for-write 'binary))
 382     (if rev
 383         (vc-hg-command buffer 0 file "cat" "-r" rev)
 384       (vc-hg-command buffer 0 file "cat"))))
 385
 386 ;; Modelled after the similar function in vc-bzr.el
 387 (defun vc-hg-checkout (file &optional editable rev)
 388   "Retrieve a revision of FILE.
 389 EDITABLE is ignored.
 390 REV is the revision to check out into WORKFILE."
 391   (let ((coding-system-for-read 'binary)
 392         (coding-system-for-write 'binary))
 393   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 394     (if rev
 395         (vc-hg-command t 0 file "cat" "-r" rev)
 396       (vc-hg-command t 0 file "cat")))))
 397
 398 ;; Modelled after the similar function in vc-bzr.el
 399 (defun vc-hg-workfile-unchanged-p (file)
 400   (eq 'up-to-date (vc-hg-state file)))
 401
 402 ;; Modelled after the similar function in vc-bzr.el
 403 (defun vc-hg-revert (file &optional contents-done)
 404   (unless contents-done
 405     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 406
 407 ;;; Hg specific functionality.
 408
 409 (defvar vc-hg-extra-menu-map
 410   (let ((map (make-sparse-keymap)))
 411     (define-key map [incoming] '(menu-item "Show incoming" vc-hg-incoming))
 412     (define-key map [outgoing] '(menu-item "Show outgoing" vc-hg-outgoing))
 413     map))
 414
 415 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 416
 417 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 418
 419 (define-derived-mode vc-hg-outgoing-mode vc-hg-log-view-mode "Hg-Outgoing")
 420
 421 (define-derived-mode vc-hg-incoming-mode vc-hg-log-view-mode "Hg-Incoming")
 422
 423 (defstruct (vc-hg-extra-fileinfo
 424             (:copier nil)
 425             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 426             (:conc-name vc-hg-extra-fileinfo->))
 427   rename-state        ;; rename or copy state
 428   extra-name)         ;; original name for copies and rename targets, new name for
 429
 430 (defun vc-hg-status-printer (info)
 431   "Pretty-printer for the vc-dir-fileinfo structure."
 432   (let ((extra (vc-dir-fileinfo->extra info)))
 433     (vc-default-status-printer 'Hg info)
 434     (when extra
 435       (insert (propertize
 436                (format "   (%s %s)"
 437                        (case (vc-hg-extra-fileinfo->rename-state extra)
 438                          ('copied "copied from")
 439                          ('renamed-from "renamed from")
 440                          ('renamed-to "renamed to"))
 441                        (vc-hg-extra-fileinfo->extra-name extra))
 442                'face 'font-lock-comment-face)))))
 443
 444 (defun vc-hg-after-dir-status (update-function)
 445   (let ((status-char nil)
 446         (file nil)
 447         (translation '((?= . up-to-date)
 448                        (?C . up-to-date)
 449                        (?A . added)
 450                        (?R . removed)
 451                        (?M . edited)
 452                        (?I . ignored)
 453                        (?! . missing)
 454                        (?  . copy-rename-line)
 455                        (?? . unregistered)))
 456         (translated nil)
 457         (result nil)
 458         (last-added nil)
 459         (last-line-copy nil))
 460       (goto-char (point-min))
 461       (while (not (eobp))
 462         (setq translated (cdr (assoc (char-after) translation)))
 463         (setq file
 464               (buffer-substring-no-properties (+ (point) 2)
 465                                               (line-end-position)))
 466         (cond ((not translated)
 467                (setq last-line-copy nil))
 468               ((eq translated 'up-to-date)
 469                (setq last-line-copy nil))
 470               ((eq translated 'copy-rename-line)
 471                ;; For copied files the output looks like this:
 472                ;; A COPIED_FILE_NAME
 473                ;;   ORIGINAL_FILE_NAME
 474                (setf (nth 2 last-added)
 475                      (vc-hg-create-extra-fileinfo 'copied file))
 476                (setq last-line-copy t))
 477               ((and last-line-copy (eq translated 'removed))
 478                ;; For renamed files the output looks like this:
 479                ;; A NEW_FILE_NAME
 480                ;;   ORIGINAL_FILE_NAME
 481                ;; R ORIGINAL_FILE_NAME
 482                ;; We need to adjust the previous entry to not think it is a copy.
 483                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 484                      'renamed-from)
 485                (push (list file translated
 486                            (vc-hg-create-extra-fileinfo
 487                             'renamed-to (nth 0 last-added))) result)
 488                (setq last-line-copy nil))
 489               (t
 490                (setq last-added (list file translated nil))
 491                (push last-added result)
 492                (setq last-line-copy nil)))
 493         (forward-line))
 494       (funcall update-function result)))
 495
 496 (defun vc-hg-dir-status (dir update-function)
 497   (vc-hg-command (current-buffer) 'async dir "status" "-C")
 498   (vc-exec-after
 499    `(vc-hg-after-dir-status (quote ,update-function))))
 500
 501 (defun vc-hg-status-extra-header (name &rest commands)
 502   (concat (propertize name 'face 'font-lock-type-face)
 503           (propertize
 504            (with-temp-buffer
 505              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 506              (buffer-substring-no-properties (point-min) (1- (point-max))))
 507            'face 'font-lock-variable-name-face)))
 508
 509 (defun vc-hg-status-extra-headers (dir)
 510   "Generate extra status headers for a Mercurial tree."
 511   (let ((default-directory dir))
 512     (concat
 513      (vc-hg-status-extra-header "Root       : " "root") "\n"
 514      (vc-hg-status-extra-header "Branch     : " "id" "-b") "\n"
 515      (vc-hg-status-extra-header "Tags       : " "id" "-t") ; "\n"
 516      ;; these change after each commit
 517      ;; (vc-hg-status-extra-header "Local num  : " "id" "-n") "\n"
 518      ;; (vc-hg-status-extra-header "Global id  : " "id" "-i")
 519      )))
 520
 521 ;; XXX this adds another top level menu, instead figure out how to
 522 ;; replace the Log-View menu.
 523 (easy-menu-define log-view-mode-menu vc-hg-outgoing-mode-map
 524   "Hg-outgoing Display Menu"
 525   `("Hg-outgoing"
 526     ["Push selected"  vc-hg-push]))
 527
 528 (easy-menu-define log-view-mode-menu vc-hg-incoming-mode-map
 529   "Hg-incoming Display Menu"
 530   `("Hg-incoming"
 531     ["Pull selected"  vc-hg-pull]))
 532
 533 (defun vc-hg-outgoing ()
 534   (interactive)
 535   (let ((bname "*Hg outgoing*"))
 536     (vc-hg-command bname 0 nil "outgoing" "-n")
 537     (pop-to-buffer bname)
 538     (vc-hg-outgoing-mode)))
 539
 540 (defun vc-hg-incoming ()
 541   (interactive)
 542   (let ((bname "*Hg incoming*"))
 543     (vc-hg-command bname 0 nil "incoming" "-n")
 544     (pop-to-buffer bname)
 545     (vc-hg-incoming-mode)))
 546
 547 (declare-function log-view-get-marked "log-view" ())
 548
 549 ;; XXX maybe also add key bindings for these functions.
 550 (defun vc-hg-push ()
 551   (interactive)
 552   (let ((marked-list (log-view-get-marked)))
 553     (if marked-list
 554         (vc-hg-command
 555          nil 0 nil
 556          (cons "push"
 557                (apply 'nconc
 558                       (mapcar (lambda (arg) (list "-r" arg)) marked-list))))
 559          (error "No log entries selected for push"))))
 560
 561 (defun vc-hg-pull ()
 562   (interactive)
 563   (let ((marked-list (log-view-get-marked)))
 564     (if marked-list
 565         (vc-hg-command
 566          nil 0 nil
 567          (cons "pull"
 568                (apply 'nconc
 569                       (mapcar (lambda (arg) (list "-r" arg)) marked-list))))
 570       (error "No log entries selected for pull"))))
 571
 572 ;;; Internal functions
 573
 574 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 575   "A wrapper around `vc-do-command' for use in vc-hg.el.
 576 The difference to vc-do-command is that this function always invokes `hg',
 577 and that it passes `vc-hg-global-switches' to it before FLAGS."
 578   (apply 'vc-do-command (or buffer "*vc*") okstatus "hg" file-or-list
 579          (if (stringp vc-hg-global-switches)
 580              (cons vc-hg-global-switches flags)
 581            (append vc-hg-global-switches
 582                    flags))))
 583
 584 (defun vc-hg-root (file)
 585   (vc-find-root file ".hg"))
 586
 587 (provide 'vc-hg)
 588
 589 ;; arch-tag: bd094dc5-715a-434f-a331-37b9fb7cd954
 590 ;;; vc-hg.el ends here