lisp/progmodes/which-func.el

   1 ;;; which-func.el --- print current function in mode line
   2
   3 ;; Copyright (C) 1994, 1997-1998, 2001-2016 Free Software Foundation,
   4 ;; Inc.
   5
   6 ;; Author:   Alex Rezinsky <alexr@msil.sps.mot.com>
   7 ;;           (doesn't seem to be responsive any more)
   8 ;; Keywords: mode-line, imenu, tools
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package prints name of function where your current point is
  28 ;; located in mode line. It assumes that you work with imenu package
  29 ;; and imenu--index-alist is up to date.
  30
  31 ;; KNOWN BUGS
  32 ;; ----------
  33 ;; Really this package shows not "function where the current point is
  34 ;; located now", but "nearest function which defined above the current
  35 ;; point". So if your current point is located after end of function
  36 ;; FOO but before begin of function BAR, FOO will be displayed in mode
  37 ;; line.
  38 ;; - if two windows display the same buffer, both windows
  39 ;;   show the same `which-func' information.
  40
  41 ;; TODO LIST
  42 ;; ---------
  43 ;;     1. Dependence on imenu package should be removed.  Separate
  44 ;; function determination mechanism should be used to determine the end
  45 ;; of a function as well as the beginning of a function.
  46 ;;     2. This package should be realized with the help of overlay
  47 ;; properties instead of imenu--index-alist variable.
  48
  49 ;;; History:
  50
  51 ;; THANKS TO
  52 ;; ---------
  53 ;; Per Abrahamsen   <abraham@iesd.auc.dk>
  54 ;;     Some ideas (inserting  in mode-line,  using of post-command  hook
  55 ;;     and toggling this  mode) have  been   borrowed from  his  package
  56 ;;     column.el
  57 ;; Peter Eisenhauer <pipe@fzi.de>
  58 ;;     Bug fixing in case nested indexes.
  59 ;; Terry Tateyama   <ttt@ursa0.cs.utah.edu>
  60 ;;     Suggestion to use find-file-hook for first imenu
  61 ;;     index building.
  62
  63 ;;; Code:
  64
  65 ;; Variables for customization
  66 ;; ---------------------------
  67 ;;
  68 (defvar which-func-unknown "???"
  69   "String to display in the mode line when current function is unknown.")
  70
  71 (defgroup which-func nil
  72   "Display the current function name in the mode line."
  73   :group 'tools
  74   :version "20.3")
  75
  76 (defcustom which-func-modes t
  77   ;; '(emacs-lisp-mode c-mode c++-mode objc-mode perl-mode cperl-mode python-mode
  78   ;;                makefile-mode sh-mode fortran-mode f90-mode ada-mode
  79   ;;                diff-mode)
  80   "List of major modes for which Which Function mode should be used.
  81 For other modes it is disabled.  If this is equal to t,
  82 then Which Function mode is enabled in any major mode that supports it."
  83   :group 'which-func
  84   :version "24.3"                       ; explicit list -> t
  85   :type '(choice (const :tag "All modes" t)
  86                  (repeat (symbol :tag "Major mode"))))
  87
  88 (defcustom which-func-non-auto-modes nil
  89   "List of major modes where Which Function mode is inactive till Imenu is used.
  90 This means that Which Function mode won't really do anything
  91 until you use Imenu, in these modes.  Note that files
  92 larger than `which-func-maxout' behave in this way too;
  93 Which Function mode doesn't do anything until you use Imenu."
  94   :group 'which-func
  95   :type '(repeat (symbol :tag "Major mode")))
  96
  97 (defcustom which-func-maxout 500000
  98   "Don't automatically compute the Imenu menu if buffer is this big or bigger.
  99 Zero means compute the Imenu menu regardless of size."
 100   :group 'which-func
 101   :type 'integer)
 102
 103 (defvar which-func-keymap
 104   (let ((map (make-sparse-keymap)))
 105     (define-key map [mode-line mouse-1] 'beginning-of-defun)
 106     (define-key map [mode-line mouse-2]
 107       (lambda ()
 108         (interactive)
 109         (if (eq (point-min) 1)
 110             (narrow-to-defun)
 111           (widen))))
 112     (define-key map [mode-line mouse-3] 'end-of-defun)
 113     map)
 114   "Keymap to display on mode line which-func.")
 115
 116 (defface which-func
 117   ;; Whether `font-lock-function-name-face' is an appropriate face to
 118   ;; inherit depends on the mode-line face; define several variants based
 119   ;; on the default mode-line face.
 120   '(;; The default mode-line face on a high-color display is a relatively
 121     ;; light color ("grey75"), and only the light-background variant of
 122     ;; `font-lock-function-name-face' is visible against it.
 123     (((class color) (min-colors 88) (background light))
 124      :inherit font-lock-function-name-face)
 125     ;; The default mode-line face on other display types is inverse-video;
 126     ;; it seems that only in the dark-background case is
 127     ;; `font-lock-function-name-face' visible against it.
 128     (((class grayscale mono) (background dark))
 129      :inherit font-lock-function-name-face)
 130     (((class color) (background light))
 131      :inherit font-lock-function-name-face)
 132     ;; If none of the above cases, use an explicit color chosen to contrast
 133     ;; well with the default mode-line face.
 134     (((class color) (min-colors 88) (background dark))
 135      :foreground "Blue1")
 136     (((background dark))
 137      :foreground "Blue1")
 138     (t
 139      :foreground "LightSkyBlue"))
 140   "Face used to highlight mode line function names."
 141   :group 'which-func)
 142
 143 (defcustom which-func-format
 144   `("["
 145     (:propertize which-func-current
 146                  local-map ,which-func-keymap
 147                  face which-func
 148                  mouse-face mode-line-highlight
 149                  help-echo "mouse-1: go to beginning\n\
 150 mouse-2: toggle rest visibility\n\
 151 mouse-3: go to end")
 152     "]")
 153   "Format for displaying the function in the mode line."
 154   :version "24.2"                  ; added mouse-face; 24point2 is correct
 155   :group 'which-func
 156   :type 'sexp)
 157 ;;;###autoload (put 'which-func-format 'risky-local-variable t)
 158
 159 (defvar which-func-imenu-joiner-function (lambda (x) (car (last x)))
 160   "Function to join together multiple levels of imenu nomenclature.
 161 Called with a single argument, a list of strings giving the names
 162 of the menus we had to traverse to get to the item.  Returns a
 163 single string, the new name of the item.")
 164
 165 (defvar which-func-cleanup-function nil
 166   "Function to transform a string before displaying it in the mode line.
 167 The function is called with one argument, the string to display.
 168 Its return value is displayed in the mode line.
 169 If nil, no function is called.  The default value is nil.
 170
 171 This feature can be useful if Imenu is set up to make more
 172 detailed entries (e.g., containing the argument list of a function),
 173 and you want to simplify them for the mode line
 174 \(e.g., removing the parameter list to just have the function name.)")
 175
 176 ;;; Code, nothing to customize below here
 177 ;;; -------------------------------------
 178 ;;;
 179 (require 'imenu)
 180
 181 (defvar which-func-table (make-hash-table :test 'eq :weakness 'key))
 182
 183 (defconst which-func-current
 184   '(:eval (replace-regexp-in-string
 185            "%" "%%"
 186            (or (gethash (selected-window) which-func-table)
 187                which-func-unknown))))
 188 ;;;###autoload (put 'which-func-current 'risky-local-variable t)
 189
 190 (defvar-local which-func-mode nil
 191   "Non-nil means display current function name in mode line.
 192 This makes a difference only if `which-function-mode' is non-nil.")
 193
 194 (add-hook 'find-file-hook 'which-func-ff-hook t)
 195
 196 (defun which-func-ff-hook ()
 197   "File find hook for Which Function mode.
 198 It creates the Imenu index for the buffer, if necessary."
 199   (unless (local-variable-p 'which-func-mode)
 200     (setq which-func-mode
 201           (and which-function-mode
 202                (or (eq which-func-modes t)
 203                    (member major-mode which-func-modes)))))
 204
 205   (condition-case err
 206       (if (and which-func-mode
 207                (not (member major-mode which-func-non-auto-modes))
 208                (or (null which-func-maxout)
 209                    (< buffer-saved-size which-func-maxout)
 210                    (= which-func-maxout 0)))
 211           (setq imenu--index-alist
 212                 (save-excursion (funcall imenu-create-index-function))))
 213     (imenu-unavailable
 214      (setq which-func-mode nil))
 215     (error
 216      (message "which-func-ff-hook error: %S" err)
 217      (setq which-func-mode nil))))
 218
 219 (defun which-func-update ()
 220   ;; "Update the Which-Function mode display for all windows."
 221   ;; (walk-windows 'which-func-update-1 nil 'visible))
 222   (which-func-update-1 (selected-window)))
 223
 224 (defun which-func-update-1 (window)
 225   "Update the Which Function mode display for window WINDOW."
 226   (with-selected-window window
 227     (when which-func-mode
 228       (condition-case info
 229           (let ((current (which-function)))
 230             (unless (equal current (gethash window which-func-table))
 231               (puthash window current which-func-table)
 232               (force-mode-line-update)))
 233         (error
 234          (setq which-func-mode nil)
 235          (error "Error in which-func-update: %S" info))))))
 236
 237 ;;;###autoload
 238 (define-obsolete-function-alias 'which-func-mode 'which-function-mode "24.1")
 239
 240 (defvar which-func-update-timer nil)
 241
 242 ;; This is the name people would normally expect.
 243 ;;;###autoload
 244 (define-minor-mode which-function-mode
 245   "Toggle mode line display of current function (Which Function mode).
 246 With a prefix argument ARG, enable Which Function mode if ARG is
 247 positive, and disable it otherwise.  If called from Lisp, enable
 248 the mode if ARG is omitted or nil.
 249
 250 Which Function mode is a global minor mode.  When enabled, the
 251 current function name is continuously displayed in the mode line,
 252 in certain major modes."
 253   :global t :group 'which-func
 254   (when (timerp which-func-update-timer)
 255     (cancel-timer which-func-update-timer))
 256   (setq which-func-update-timer nil)
 257   (if which-function-mode
 258       ;;Turn it on
 259       (progn
 260         (setq which-func-update-timer
 261               (run-with-idle-timer idle-update-delay t #'which-func-update))
 262         (dolist (buf (buffer-list))
 263           (with-current-buffer buf
 264             (unless (local-variable-p 'which-func-mode)
 265               (setq which-func-mode
 266                     (or (eq which-func-modes t)
 267                         (member major-mode which-func-modes)))))))))
 268
 269 (defvar which-function-imenu-failed nil
 270   "Locally t in a buffer if `imenu--make-index-alist' found nothing there.")
 271
 272 (defvar which-func-functions nil
 273   "List of functions for `which-function' to call with no arguments.
 274 It calls them sequentially, and if any returns non-nil,
 275 `which-function' uses that name and stops looking for the name.")
 276
 277 (defun which-function ()
 278   "Return current function name based on point.
 279 Uses `which-func-functions', `imenu--index-alist'
 280 or `add-log-current-defun'.
 281 If no function name is found, return nil."
 282   (let ((name
 283          ;; Try the `which-func-functions' functions first.
 284          (run-hook-with-args-until-success 'which-func-functions)))
 285
 286     ;; If Imenu is loaded, try to make an index alist with it.
 287     (when (and (null name)
 288                (boundp 'imenu--index-alist) (null imenu--index-alist)
 289                (null which-function-imenu-failed))
 290       (ignore-errors (imenu--make-index-alist t))
 291       (unless imenu--index-alist
 292         (set (make-local-variable 'which-function-imenu-failed) t)))
 293     ;; If we have an index alist, use it.
 294     (when (and (null name)
 295                (boundp 'imenu--index-alist) imenu--index-alist)
 296       (let ((alist imenu--index-alist)
 297             (minoffset (point-max))
 298             offset pair mark imstack namestack)
 299         ;; Elements of alist are either ("name" . marker), or
 300         ;; ("submenu" ("name" . marker) ... ). The list can be
 301         ;; arbitrarily nested.
 302         (while (or alist imstack)
 303           (if (null alist)
 304               (setq alist     (car imstack)
 305                     namestack (cdr namestack)
 306                     imstack   (cdr imstack))
 307
 308             (setq pair (car-safe alist)
 309                   alist (cdr-safe alist))
 310
 311             (cond
 312              ((atom pair))              ; Skip anything not a cons.
 313
 314              ((imenu--subalist-p pair)
 315               (setq imstack   (cons alist imstack)
 316                     namestack (cons (car pair) namestack)
 317                     alist     (cdr pair)))
 318
 319              ((or (number-or-marker-p (setq mark (cdr pair)))
 320                   (and (overlayp mark)
 321                        (setq mark (overlay-start mark))))
 322               (when (and (>= (setq offset (- (point) mark)) 0)
 323                          (< offset minoffset)) ; Find the closest item.
 324                 (setq minoffset offset
 325                       name (if (null which-func-imenu-joiner-function)
 326                                (car pair)
 327                              (funcall
 328                               which-func-imenu-joiner-function
 329                               (reverse (cons (car pair) namestack))))))))))))
 330
 331     ;; Try using add-log support.
 332     (when (null name)
 333       (setq name (add-log-current-defun)))
 334     ;; Filter the name if requested.
 335     (when name
 336       (if which-func-cleanup-function
 337           (funcall which-func-cleanup-function name)
 338         name))))
 339
 340 \f
 341 ;;; Integration with other packages
 342
 343 (defvar ediff-window-A)
 344 (defvar ediff-window-B)
 345 (defvar ediff-window-C)
 346
 347 ;; FIXME: Why does ediff require special support?
 348 (defun which-func-update-ediff-windows ()
 349   "Update Which-Function mode display for Ediff windows.
 350 This function is meant to be called from `ediff-select-hook'."
 351   (when (and (derived-mode-p 'ediff-mode) which-function-mode)
 352     (when ediff-window-A
 353       (which-func-update-1 ediff-window-A))
 354     (when ediff-window-B
 355       (which-func-update-1 ediff-window-B))
 356     (when ediff-window-C
 357       (which-func-update-1 ediff-window-C))))
 358
 359 (add-hook 'ediff-select-hook 'which-func-update-ediff-windows)
 360
 361 (provide 'which-func)
 362
 363 ;;; which-func.el ends here