lisp/mail/hashcash.el

   1 ;;; hashcash.el --- Add hashcash payments to email
   2
   3 ;; Copyright (C) 2003, 2004, 2005, 2007 Free Software Foundation
   4
   5 ;; Written by: Paul Foley <mycroft@actrix.gen.nz> (1997-2002)
   6 ;; Maintainer: Paul Foley <mycroft@actrix.gen.nz>
   7 ;; Keywords: mail, hashcash
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The hashcash binary is at http://www.hashcash.org/.
  29 ;;
  30 ;; Call mail-add-payment to add a hashcash payment to a mail message
  31 ;; in the current buffer.
  32 ;;
  33 ;; Call mail-add-payment-async after writing the addresses but before
  34 ;; writing the mail to start calculating the hashcash payment
  35 ;; asynchronously.
  36 ;;
  37 ;; The easiest way to do this automatically for all outgoing mail
  38 ;; is to set `message-generate-hashcash' to t.  If you want more
  39 ;; control, try the following hooks.
  40 ;;
  41 ;; To automatically add payments to all outgoing mail when sending:
  42 ;;    (add-hook 'message-send-hook 'mail-add-payment)
  43 ;;
  44 ;; To start calculations automatically when addresses are prefilled:
  45 ;;    (add-hook 'message-setup-hook 'mail-add-payment-async)
  46 ;;
  47 ;; To check whether calculations are done before sending:
  48 ;;    (add-hook 'message-send-hook 'hashcash-wait-or-cancel)
  49
  50 ;;; Code:
  51
  52 (defgroup hashcash nil
  53   "Hashcash configuration."
  54   :group 'mail)
  55
  56 (defcustom hashcash-default-payment 20
  57   "*The default number of bits to pay to unknown users.
  58 If this is zero, no payment header will be generated.
  59 See `hashcash-payment-alist'."
  60   :type 'integer
  61   :group 'hashcash)
  62
  63 (defcustom hashcash-payment-alist '()
  64   "*An association list mapping email addresses to payment amounts.
  65 Elements may consist of (ADDR AMOUNT) or (ADDR STRING AMOUNT), where
  66 ADDR is the email address of the intended recipient and AMOUNT is
  67 the value of hashcash payment to be made to that user.  STRING, if
  68 present, is the string to be hashed; if not present ADDR will be used."
  69   :type '(repeat (choice (list :tag "Normal"
  70                                (string :name "Address")
  71                                (integer :name "Amount"))
  72                          (list :tag "Replace hash input"
  73                                (string :name "Address")
  74                                (string :name "Hash input")
  75                                (integer :name "Amount"))))
  76   :group 'hashcash)
  77
  78 (defcustom hashcash-default-accept-payment 20
  79   "*The default minimum number of bits to accept on incoming payments."
  80   :type 'integer
  81   :group 'hashcash)
  82
  83 (defcustom hashcash-accept-resources `((,user-mail-address nil))
  84   "*An association list mapping hashcash resources to payment amounts.
  85 Resources named here are to be accepted in incoming payments.  If the
  86 corresponding AMOUNT is NIL, the value of `hashcash-default-accept-payment'
  87 is used instead."
  88   :group 'hashcash)
  89
  90 (defcustom hashcash-path (executable-find "hashcash")
  91   "*The path to the hashcash binary."
  92   :group 'hashcash)
  93
  94 (defcustom hashcash-extra-generate-parameters nil
  95   "*A list of parameter strings passed to `hashcash-path' when minting.
  96 For example, you may want to set this to '(\"-Z2\") to reduce header length."
  97   :type '(repeat string)
  98   :group 'hashcash)
  99
 100 (defcustom hashcash-double-spend-database "hashcash.db"
 101   "*The path to the double-spending database."
 102   :group 'hashcash)
 103
 104 (defcustom hashcash-in-news nil
 105   "*Specifies whether or not hashcash payments should be made to newsgroups."
 106   :type 'boolean
 107   :group 'hashcash)
 108
 109 (defvar hashcash-process-alist nil
 110   "Alist of asynchronous hashcash processes and buffers.")
 111
 112 (require 'mail-utils)
 113
 114 (eval-and-compile
 115  (if (fboundp 'point-at-bol)
 116      (defalias 'hashcash-point-at-bol 'point-at-bol)
 117    (defalias 'hashcash-point-at-bol 'line-beginning-position))
 118
 119  (if (fboundp 'point-at-eol)
 120      (defalias 'hashcash-point-at-eol 'point-at-eol)
 121    (defalias 'hashcash-point-at-eol 'line-end-position)))
 122
 123 (defun hashcash-strip-quoted-names (addr)
 124   (setq addr (mail-strip-quoted-names addr))
 125   (if (and addr (string-match "\\`\\([^+@]+\\)\\+[^@]*\\(@.+\\)" addr))
 126       (concat (match-string 1 addr) (match-string 2 addr))
 127     addr))
 128
 129 (defun hashcash-token-substring ()
 130   (save-excursion
 131     (let ((token ""))
 132       (loop
 133         (setq token
 134           (concat token (buffer-substring (point) (hashcash-point-at-eol))))
 135         (goto-char (hashcash-point-at-eol))
 136         (forward-char 1)
 137         (unless (looking-at "[ \t]") (return token))
 138         (while (looking-at "[ \t]") (forward-char 1))))))
 139
 140 (defun hashcash-payment-required (addr)
 141   "Return the hashcash payment value required for the given address."
 142   (let ((val (assoc addr hashcash-payment-alist)))
 143     (or (nth 2 val) (nth 1 val) hashcash-default-payment)))
 144
 145 (defun hashcash-payment-to (addr)
 146   "Return the string with which hashcash payments should collide."
 147   (let ((val (assoc addr hashcash-payment-alist)))
 148     (or (nth 1 val) (nth 0 val) addr)))
 149
 150 (defun hashcash-generate-payment (str val)
 151   "Generate a hashcash payment by finding a VAL-bit collison on STR."
 152   (if (and (> val 0)
 153            hashcash-path)
 154       (save-excursion
 155         (set-buffer (get-buffer-create " *hashcash*"))
 156         (erase-buffer)
 157         (apply 'call-process hashcash-path nil t nil
 158                "-m" "-q" "-b" (number-to-string val) str
 159                hashcash-extra-generate-parameters)
 160         (goto-char (point-min))
 161         (hashcash-token-substring))
 162     (error "No `hashcash' binary found")))
 163
 164 (defun hashcash-generate-payment-async (str val callback)
 165   "Generate a hashcash payment by finding a VAL-bit collison on STR.
 166 Return immediately.  Call CALLBACK with process and result when ready."
 167   (if (and (> val 0)
 168            hashcash-path)
 169       (let ((process (apply 'start-process "hashcash" nil
 170                             hashcash-path "-m" "-q"
 171                             "-b" (number-to-string val) str
 172                             hashcash-extra-generate-parameters)))
 173         (setq hashcash-process-alist (cons
 174                                       (cons process (current-buffer))
 175                                       hashcash-process-alist))
 176         (set-process-filter process `(lambda (process output)
 177                                        (funcall ,callback process output))))
 178     (funcall callback nil nil)))
 179
 180 (defun hashcash-check-payment (token str val)
 181   "Check the validity of a hashcash payment."
 182   (if hashcash-path
 183       (zerop (call-process hashcash-path nil nil nil "-c"
 184                            "-d" "-f" hashcash-double-spend-database
 185                            "-b" (number-to-string val)
 186                            "-r" str
 187                            token))
 188     (progn
 189       (message "No hashcash binary found")
 190       (sleep-for 1)
 191       nil)))
 192
 193 (defun hashcash-version (token)
 194   "Find the format version of a hashcash token."
 195   ;; Version 1.2 looks like n:yymmdd:rrrrr:xxxxxxxxxxxxxxxx
 196   ;;   This carries its own version number embedded in the token,
 197   ;;   so no further format number changes should be necessary
 198   ;;   in the X-Payment header.
 199   ;;
 200   ;; Version 1.1 looks like yymmdd:rrrrr:xxxxxxxxxxxxxxxx
 201   ;;   You need to upgrade your hashcash binary.
 202   ;;
 203   ;; Version 1.0 looked like nnnnnrrrrrxxxxxxxxxxxxxxxx
 204   ;;   This is no longer supported.
 205   (cond ((equal (aref token 1) ?:) 1.2)
 206         ((equal (aref token 6) ?:) 1.1)
 207         (t (error "Unknown hashcash format version"))))
 208
 209 (defun hashcash-already-paid-p (recipient)
 210   "Check for hashcash token to RECIPIENT in current buffer."
 211   (save-excursion
 212     (save-restriction
 213       (message-narrow-to-headers-or-head)
 214       (let ((token (message-fetch-field "x-hashcash"))
 215             (case-fold-search t))
 216         (and (stringp token)
 217              (string-match (regexp-quote recipient) token))))))
 218
 219 ;;;###autoload
 220 (defun hashcash-insert-payment (arg)
 221   "Insert X-Payment and X-Hashcash headers with a payment for ARG"
 222   (interactive "sPay to: ")
 223   (unless (hashcash-already-paid-p arg)
 224     (let ((pay (hashcash-generate-payment (hashcash-payment-to arg)
 225                                           (hashcash-payment-required arg))))
 226       (when pay
 227         (insert-before-markers "X-Hashcash: " pay "\n")))))
 228
 229 ;;;###autoload
 230 (defun hashcash-insert-payment-async (arg)
 231   "Insert X-Payment and X-Hashcash headers with a payment for ARG
 232 Only start calculation.  Results are inserted when ready."
 233   (interactive "sPay to: ")
 234   (unless (hashcash-already-paid-p arg)
 235     (hashcash-generate-payment-async
 236      (hashcash-payment-to arg)
 237      (hashcash-payment-required arg)
 238      `(lambda (process payment)
 239         (hashcash-insert-payment-async-2 ,(current-buffer) process payment)))))
 240
 241 (defun hashcash-insert-payment-async-2 (buffer process pay)
 242   (when (buffer-live-p buffer)
 243     (with-current-buffer buffer
 244       (save-excursion
 245         (save-restriction
 246           (setq hashcash-process-alist (delq
 247                                         (assq process hashcash-process-alist)
 248                                         hashcash-process-alist))
 249           (message-goto-eoh)
 250           (when pay
 251             (insert-before-markers "X-Hashcash: " pay)))))))
 252
 253 (defun hashcash-cancel-async (&optional buffer)
 254   "Delete any hashcash processes associated with BUFFER.
 255 BUFFER defaults to the current buffer."
 256   (interactive)
 257   (unless buffer (setq buffer (current-buffer)))
 258   (let (entry)
 259     (while (setq entry (rassq buffer hashcash-process-alist))
 260       (delete-process (car entry))
 261       (setq hashcash-process-alist
 262             (delq entry hashcash-process-alist)))))
 263
 264 (defun hashcash-wait-async (&optional buffer)
 265   "Wait for asynchronous hashcash processes in BUFFER to finish.
 266 BUFFER defaults to the current buffer."
 267   (interactive)
 268   (unless buffer (setq buffer (current-buffer)))
 269   (let (entry)
 270     (while (setq entry (rassq buffer hashcash-process-alist))
 271       (accept-process-output (car entry)))))
 272
 273 (defun hashcash-processes-running-p (buffer)
 274   "Return non-nil if hashcash processes in BUFFER are still running."
 275   (rassq buffer hashcash-process-alist))
 276
 277 (defun hashcash-wait-or-cancel ()
 278   "Ask user whether to wait for hashcash processes to finish."
 279   (interactive)
 280   (when (hashcash-processes-running-p (current-buffer))
 281     (if (y-or-n-p
 282           "Hashcash process(es) still running; wait for them to finish? ")
 283         (hashcash-wait-async)
 284       (hashcash-cancel-async))))
 285
 286 ;;;###autoload
 287 (defun hashcash-verify-payment (token &optional resource amount)
 288   "Verify a hashcash payment"
 289   (let* ((split (split-string token ":"))
 290          (key (if (< (hashcash-version token) 1.2)
 291                   (nth 1 split)
 292                   (case (string-to-number (nth 0 split))
 293                     (0 (nth 2 split))
 294                     (1 (nth 3 split))))))
 295     (cond ((null resource)
 296            (let ((elt (assoc key hashcash-accept-resources)))
 297              (and elt (hashcash-check-payment token (car elt)
 298                         (or (cadr elt) hashcash-default-accept-payment)))))
 299           ((equal token key)
 300            (hashcash-check-payment token resource
 301                                 (or amount hashcash-default-accept-payment)))
 302           (t nil))))
 303
 304 ;;;###autoload
 305 (defun mail-add-payment (&optional arg async)
 306   "Add X-Payment: and X-Hashcash: headers with a hashcash payment
 307 for each recipient address.  Prefix arg sets default payment temporarily.
 308 Set ASYNC to t to start asynchronous calculation.  (See
 309 `mail-add-payment-async')."
 310   (interactive "P")
 311   (let ((hashcash-default-payment (if arg (prefix-numeric-value arg)
 312                                     hashcash-default-payment))
 313         (addrlist nil))
 314     (save-excursion
 315       (save-restriction
 316         (message-narrow-to-headers)
 317         (let ((to (hashcash-strip-quoted-names (mail-fetch-field "To" nil t)))
 318               (cc (hashcash-strip-quoted-names (mail-fetch-field "Cc" nil t)))
 319               (ng (hashcash-strip-quoted-names (mail-fetch-field "Newsgroups"
 320                                                                  nil t))))
 321           (when to
 322             (setq addrlist (split-string to ",[ \t\n]*")))
 323           (when cc
 324             (setq addrlist (nconc addrlist (split-string cc ",[ \t\n]*"))))
 325           (when (and hashcash-in-news ng)
 326             (setq addrlist (nconc addrlist (split-string ng ",[ \t\n]*")))))
 327         (when addrlist
 328           (mapc (if async
 329                     #'hashcash-insert-payment-async
 330                   #'hashcash-insert-payment)
 331                 addrlist)))))
 332   t)
 333
 334 ;;;###autoload
 335 (defun mail-add-payment-async (&optional arg)
 336   "Add X-Payment: and X-Hashcash: headers with a hashcash payment
 337 for each recipient address.  Prefix arg sets default payment temporarily.
 338 Calculation is asynchronous."
 339   (interactive "P")
 340   (mail-add-payment arg t))
 341
 342 ;;;###autoload
 343 (defun mail-check-payment (&optional arg)
 344   "Look for a valid X-Payment: or X-Hashcash: header.
 345 Prefix arg sets default accept amount temporarily."
 346   (interactive "P")
 347   (let ((hashcash-default-accept-payment (if arg (prefix-numeric-value arg)
 348                                            hashcash-default-accept-payment))
 349         (version (hashcash-version (hashcash-generate-payment "x" 1))))
 350     (save-excursion
 351       (goto-char (point-min))
 352       (search-forward "\n\n")
 353       (beginning-of-line)
 354       (let ((end (point))
 355             (ok nil))
 356         (goto-char (point-min))
 357         (while (and (not ok) (search-forward "X-Payment: hashcash " end t))
 358           (let ((value (split-string (hashcash-token-substring) " ")))
 359             (when (equal (car value) (number-to-string version))
 360               (setq ok (hashcash-verify-payment (cadr value))))))
 361         (goto-char (point-min))
 362         (while (and (not ok) (search-forward "X-Hashcash: " end t))
 363           (setq ok (hashcash-verify-payment (hashcash-token-substring))))
 364         (when ok
 365           (message "Payment valid"))
 366         ok))))
 367
 368 (provide 'hashcash)
 369
 370 ;;; arch-tag: 0e7fe983-a124-4392-9788-0dbcbd2c4d62