lisp/textmodes/nroff-mode.el

   1 ;;; nroff-mode.el --- GNU Emacs major mode for editing nroff source
   2
   3 ;; Copyright (C) 1985, 1986 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: wp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This package is a major mode for editing nroff source code.  It knows
  27 ;; about various nroff constructs, ms, mm, and me macros, and will fill
  28 ;; and indent paragraphs properly in their presence.  It also includes
  29 ;; a command to count text lines (excluding nroff constructs), a command
  30 ;; to center a line, and movement commands that know how to skip macros.
  31
  32 ;;; Code:
  33
  34 (defvar nroff-mode-abbrev-table nil
  35   "Abbrev table used while in nroff mode.")
  36
  37 (defvar nroff-mode-map nil
  38      "Major mode keymap for nroff mode.")
  39 (if (not nroff-mode-map)
  40     (progn
  41       (setq nroff-mode-map (make-sparse-keymap))
  42       (define-key nroff-mode-map "\t"  'tab-to-tab-stop)
  43       (define-key nroff-mode-map "\es" 'center-line)
  44       (define-key nroff-mode-map "\e?" 'count-text-lines)
  45       (define-key nroff-mode-map "\n"  'electric-nroff-newline)
  46       (define-key nroff-mode-map "\en" 'forward-text-line)
  47       (define-key nroff-mode-map "\ep" 'backward-text-line)))
  48
  49 ;;;###autoload
  50 (defun nroff-mode ()
  51   "Major mode for editing text intended for nroff to format.
  52 \\{nroff-mode-map}
  53 Turning on Nroff mode runs `text-mode-hook', then `nroff-mode-hook'.
  54 Also, try `nroff-electric-mode', for automatically inserting
  55 closing requests for requests that are used in matched pairs."
  56   (interactive)
  57   (kill-all-local-variables)
  58   (use-local-map nroff-mode-map)
  59   (setq mode-name "Nroff")
  60   (setq major-mode 'nroff-mode)
  61   (set-syntax-table text-mode-syntax-table)
  62   (setq local-abbrev-table nroff-mode-abbrev-table)
  63   (make-local-variable 'nroff-electric-mode)
  64   ;; now define a bunch of variables for use by commands in this mode
  65   (make-local-variable 'page-delimiter)
  66   (setq page-delimiter "^\\.\\(bp\\|SK\\|OP\\)")
  67   (make-local-variable 'paragraph-start)
  68   (setq paragraph-start (concat "^[.']\\|" paragraph-start))
  69   (make-local-variable 'paragraph-separate)
  70   (setq paragraph-separate (concat "^[.']\\|" paragraph-separate))
  71   ;; comment syntax added by mit-erl!gildea 18 Apr 86
  72   (make-local-variable 'comment-start)
  73   (setq comment-start "\\\" ")
  74   (make-local-variable 'comment-start-skip)
  75   (setq comment-start-skip "\\\\\"[ \t]*")
  76   (make-local-variable 'comment-column)
  77   (setq comment-column 24)
  78   (make-local-variable 'comment-indent-function)
  79   (setq comment-indent-function 'nroff-comment-indent)
  80   (run-hooks 'text-mode-hook 'nroff-mode-hook))
  81
  82 ;;; Compute how much to indent a comment in nroff/troff source.
  83 ;;; By mit-erl!gildea April 86
  84 (defun nroff-comment-indent ()
  85   "Compute indent for an nroff/troff comment.
  86 Puts a full-stop before comments on a line by themselves."
  87   (let ((pt (point)))
  88     (unwind-protect
  89         (progn
  90           (skip-chars-backward " \t")
  91           (if (bolp)
  92               (progn
  93                 (setq pt (1+ pt))
  94                 (insert ?.)
  95                 1)
  96             (if (save-excursion
  97                   (backward-char 1)
  98                   (looking-at "^[.']"))
  99                 1
 100               (max comment-column
 101                    (* 8 (/ (+ (current-column)
 102                               9) 8)))))) ; add 9 to ensure at least two blanks
 103       (goto-char pt))))
 104
 105 (defun count-text-lines (start end &optional print)
 106   "Count lines in region, except for nroff request lines.
 107 All lines not starting with a period are counted up.
 108 Interactively, print result in echo area.
 109 Noninteractively, return number of non-request lines from START to END."
 110   (interactive "r\np")
 111   (if print
 112       (message "Region has %d text lines" (count-text-lines start end))
 113     (save-excursion
 114       (save-restriction
 115         (narrow-to-region start end)
 116         (goto-char (point-min))
 117         (- (buffer-size) (forward-text-line (buffer-size)))))))
 118
 119 (defun forward-text-line (&optional cnt)
 120   "Go forward one nroff text line, skipping lines of nroff requests.
 121 An argument is a repeat count; if negative, move backward."
 122   (interactive "p")
 123   (if (not cnt) (setq cnt 1))
 124   (while (and (> cnt 0) (not (eobp)))
 125     (forward-line 1)
 126     (while (and (not (eobp)) (looking-at "[.']."))
 127       (forward-line 1))
 128     (setq cnt (- cnt 1)))
 129   (while (and (< cnt 0) (not (bobp)))
 130     (forward-line -1)
 131     (while (and (not (bobp))
 132                 (looking-at "[.']."))
 133       (forward-line -1))
 134     (setq cnt (+ cnt 1)))
 135   cnt)
 136
 137 (defun backward-text-line (&optional cnt)
 138   "Go backward one nroff text line, skipping lines of nroff requests.
 139 An argument is a repeat count; negative means move forward."
 140   (interactive "p")
 141   (forward-text-line (- cnt)))
 142
 143 (defconst nroff-brace-table
 144   '((".(b" . ".)b")
 145     (".(l" . ".)l")
 146     (".(q" . ".)q")
 147     (".(c" . ".)c")
 148     (".(x" . ".)x")
 149     (".(z" . ".)z")
 150     (".(d" . ".)d")
 151     (".(f" . ".)f")
 152     (".LG" . ".NL")
 153     (".SM" . ".NL")
 154     (".LD" . ".DE")
 155     (".CD" . ".DE")
 156     (".BD" . ".DE")
 157     (".DS" . ".DE")
 158     (".DF" . ".DE")
 159     (".FS" . ".FE")
 160     (".KS" . ".KE")
 161     (".KF" . ".KE")
 162     (".LB" . ".LE")
 163     (".AL" . ".LE")
 164     (".BL" . ".LE")
 165     (".DL" . ".LE")
 166     (".ML" . ".LE")
 167     (".RL" . ".LE")
 168     (".VL" . ".LE")
 169     (".RS" . ".RE")
 170     (".TS" . ".TE")
 171     (".EQ" . ".EN")
 172     (".PS" . ".PE")
 173     (".BS" . ".BE")
 174     (".G1" . ".G2")                     ; grap
 175     (".na" . ".ad b")
 176     (".nf" . ".fi")
 177     (".de" . "..")))
 178
 179 (defun electric-nroff-newline (arg)
 180   "Insert newline for nroff mode; special if electric-nroff mode.
 181 In `electric-nroff-mode', if ending a line containing an nroff opening request,
 182 automatically inserts the matching closing request after point."
 183   (interactive "P")
 184   (let ((completion (save-excursion
 185                       (beginning-of-line)
 186                       (and (null arg)
 187                            nroff-electric-mode
 188                            (<= (point) (- (point-max) 3))
 189                            (cdr (assoc (buffer-substring (point)
 190                                                          (+ 3 (point)))
 191                                        nroff-brace-table)))))
 192         (needs-nl (not (looking-at "[ \t]*$"))))
 193     (if (null completion)
 194         (newline (prefix-numeric-value arg))
 195       (save-excursion
 196         (insert "\n\n" completion)
 197         (if needs-nl (insert "\n")))
 198       (forward-char 1))))
 199
 200 (defun electric-nroff-mode (&optional arg)
 201   "Toggle `nroff-electric-newline' minor mode.
 202 `nroff-electric-newline' forces Emacs to check for an nroff request at the
 203 beginning of the line, and insert the matching closing request if necessary.
 204 This command toggles that mode (off->on, on->off), with an argument,
 205 turns it on iff arg is positive, otherwise off."
 206   (interactive "P")
 207   (or (eq major-mode 'nroff-mode) (error "Must be in nroff mode"))
 208   (or (assq 'nroff-electric-mode minor-mode-alist)
 209       (setq minor-mode-alist (append minor-mode-alist
 210                                      (list '(nroff-electric-mode
 211                                              " Electric")))))
 212   (setq nroff-electric-mode
 213         (cond ((null arg) (null nroff-electric-mode))
 214               (t (> (prefix-numeric-value arg) 0)))))
 215
 216 ;;; nroff-mode.el ends here