lisp/hi-lock.el

   1 ;;; hi-lock.el --- Minor mode for interactive automatic highlighting.
   2
   3 ;; Copyright (C) 2000 Free Software Foundation, Inc.
   4
   5 ;; Author: David M. Koppelman, koppel@ee.lsu.edu
   6 ;; Keywords: faces, minor-mode, matching, display
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary
  26 ;;
  27 ;;  With the hi-lock commands text matching interactively entered
  28 ;;  regexp's can be highlighted.  For example, `M-x highlight-regexp
  29 ;;  RET clearly RET RET' will highlight all occurrences of `clearly'
  30 ;;  using a yellow background face.  New occurrences of `clearly' will
  31 ;;  be highlighted as they are typed.  `M-x unhighlight-regexp RET'
  32 ;;  will remove the highlighting.  Any existing face can be used for
  33 ;;  highlighting and a set of appropriate faces is provided.  The
  34 ;;  regexps can be written into the current buffer in a form that will
  35 ;;  be recognized the next time the corresponding file is read.
  36 ;;
  37 ;;  Applications:
  38 ;;
  39 ;;    In program source code highlight a variable to quickly see all
  40 ;;    places it is modified or referenced:
  41 ;;    M-x highlight-regexp ground_contact_switches_closed RET RET
  42 ;;
  43 ;;    In a shell or other buffer that is showing lots of program
  44 ;;    output, highlight the parts of the output you're interested in:
  45 ;;    M-x highlight-regexp Total execution time [0-9]+ RET hi-blue-b RET
  46 ;;
  47 ;;    In buffers displaying tables, highlight the lines you're interested in:
  48 ;;    M-x highlight-lines-matching-regexp January 2000 RET hi-black-b RET
  49 ;;
  50 ;;    When writing text, highlight personal cliches.  This can be
  51 ;;    amusing.
  52 ;;    M-x highlight-regexp as can be seen RET RET
  53 ;;
  54 ;;  Setup
  55 ;;
  56 ;;    Put the following code in your .emacs file.  This turns on
  57 ;;    hi-lock mode and adds an "Automatic Highlighting" entry
  58 ;;    to the edit menu.
  59 ;;
  60 ;;    (hi-lock-mode 1)
  61 ;;
  62 ;;    You might also want to bind the hi-lock commands to more
  63 ;;    finger-friendly sequences:
  64
  65 ;;    (define-key hi-lock-map "\C-z\C-h" 'highlight-lines-matching-regexp)
  66 ;;    (define-key hi-lock-map "\C-zi" 'hi-lock-find-patterns)
  67 ;;    (define-key hi-lock-map "\C-zh" 'highlight-regexp)
  68 ;;    (define-key hi-lock-map "\C-zr" 'unhighlight-regexp)
  69 ;;    (define-key hi-lock-map "\C-zb" 'hi-lock-write-interactive-patterns))
  70
  71 ;;    See the documentation for hi-lock-mode `C-h f hi-lock-mode' for
  72 ;;    additional instructions.
  73
  74 ;; Sample file patterns:
  75
  76 ; Hi-lock: (("^;;; .*" (0 (quote hi-black-hb) t)))
  77 ; Hi-lock: ( ("make-variable-buffer-\\(local\\)" (0 font-lock-keyword-face)(1 'italic append)))))
  78 ; Hi-lock: end
  79
  80 ;;; Code:
  81
  82 (eval-and-compile
  83   (require 'font-lock))
  84
  85 ;;;###autoload
  86 (defgroup hi-lock-interactive-text-highlighting nil
  87   "Interactively add and remove font-lock patterns for highlighting text."
  88   :group 'faces)
  89
  90 ;;;###autoload
  91 (defcustom hi-lock-mode nil
  92   "Toggle hi-lock, for interactively adding font-lock text-highlighting patterns."
  93   :set (lambda (symbol value)
  94          (hi-lock-mode (or value 0)))
  95   :initialize 'custom-initialize-default
  96   :type 'boolean
  97   :group 'hi-lock-interactive-text-highlighting
  98   :require 'hi-lock)
  99
 100 (defcustom hi-lock-file-patterns-range 10000
 101   "Limit of search in a buffer for hi-lock patterns.
 102 When a file is visited and hi-lock mode is on patterns starting
 103 up to this limit are added to font-lock's patterns.  See documentation
 104 of functions `hi-lock-mode' and `hi-lock-find-patterns'."
 105   :type 'integer
 106   :group 'hi-lock-interactive-text-highlighting)
 107
 108 (defcustom hi-lock-exclude-modes
 109   '(rmail-mode mime/viewer-mode gnus-article-mode)
 110   "List of major modes in which hi-lock will not run.
 111 For security reasons since font lock patterns can specify function
 112 calls."
 113   :type '(repeat symbol)
 114   :group 'hi-lock-interactive-text-highlighting)
 115
 116
 117 (defgroup hi-lock-faces nil
 118   "Faces for hi-lock."
 119   :group 'hi-lock-interactive-text-highlighting)
 120
 121 (defface hi-yellow
 122   '((((background dark)) (:background "yellow" :foreground "black"))
 123     (t (:background "yellow")))
 124   "Default face for hi-lock mode."
 125   :group 'hi-lock-faces)
 126
 127 (defface hi-pink
 128   '((((background dark)) (:background "pink" :foreground "black"))
 129     (t (:background "pink")))
 130   "Face for hi-lock mode."
 131   :group 'hi-lock-faces)
 132
 133 (defface hi-green
 134   '((((background dark)) (:background "green" :foreground "black"))
 135     (t (:background "green")))
 136   "Face for hi-lock mode."
 137   :group 'hi-lock-faces)
 138
 139 (defface hi-blue
 140   '((((background dark)) (:background "light blue" :foreground "black"))
 141     (t (:background "light blue")))
 142   "Face for hi-lock mode."
 143   :group 'hi-lock-faces)
 144
 145 (defface hi-black-b
 146   '((t (:weight bold)))
 147   "Face for hi-lock mode."
 148   :group 'hi-lock-faces)
 149
 150 (defface hi-blue-b
 151   '((t (:weight bold :foreground "blue")))
 152   "Face for hi-lock mode."
 153   :group 'hi-lock-faces)
 154
 155 (defface hi-green-b
 156   '((t (:weight bold :foreground "green")))
 157   "Face for hi-lock mode."
 158   :group 'hi-lock-faces)
 159
 160 (defface hi-red-b
 161   '((t (:weight bold :foreground "red")))
 162   "Face for hi-lock mode."
 163   :group 'hi-lock-faces)
 164
 165 (defface hi-black-hb
 166   '((t (:weight bold :height 1.67 :inherit variable-pitch)))
 167   "Face for hi-lock mode."
 168   :group 'hi-lock-faces)
 169
 170 (defvar hi-lock-file-patterns nil
 171   "Patterns found in file for hi-lock.  Should not be changed.")
 172
 173 (defvar hi-lock-interactive-patterns nil
 174   "Patterns provided to hi-lock by user.  Should not be changed.")
 175
 176 (defvar hi-lock-face-history
 177   (list "hi-yellow" "hi-pink" "hi-green" "hi-blue" "hi-black-b"
 178         "hi-blue-b" "hi-red-b" "hi-green-b" "hi-black-hb")
 179       "History list of faces for hi-lock interactive functions.")
 180
 181 ;(dolist (f hi-lock-face-history) (unless (facep f) (error "%s not a face" f)))
 182
 183 (defvar hi-lock-regexp-history nil
 184   "History of regexps used for interactive fontification.")
 185
 186 (defvar hi-lock-file-patterns-prefix "Hi-lock"
 187   "Regexp for finding hi-lock patterns at top of file.")
 188
 189 (make-variable-buffer-local 'hi-lock-interactive-patterns)
 190 (put 'hi-lock-interactive-patterns 'permanent-local t)
 191 (make-variable-buffer-local 'hi-lock-regexp-history)
 192 (put 'hi-lock-regexp-history 'permanent-local t)
 193 (make-variable-buffer-local 'hi-lock-file-patterns)
 194 (put 'hi-lock-file-patterns 'permanent-local t)
 195
 196 (defvar hi-lock-menu (make-sparse-keymap "Hi Lock")
 197   "Menu for hi-lock mode.")
 198
 199 (define-key-after hi-lock-menu [highlight-regexp]
 200   '(menu-item "Highlight Regexp..." highlight-regexp
 201               :help "Highlight text matching PATTERN (a regexp)."))
 202
 203 (define-key-after hi-lock-menu [highlight-lines-matching-regexp]
 204   '(menu-item "Highlight Lines..." highlight-lines-matching-regexp
 205               :help "Highlight lines containing match of PATTERN (a regexp).."))
 206
 207 (define-key-after hi-lock-menu [unhighlight-regexp]
 208   '(menu-item "Remove Highlighting..." unhighlight-regexp
 209               :help "Remove previously entered highlighting pattern."
 210               :enable hi-lock-interactive-patterns))
 211
 212 (define-key-after hi-lock-menu [hi-lock-write-interactive-patterns]
 213   '(menu-item "Patterns to Buffer" hi-lock-write-interactive-patterns
 214               :help "Insert interactively added REGEXPs into buffer at point."
 215               :enable hi-lock-interactive-patterns))
 216
 217 (define-key-after hi-lock-menu [hi-lock-find-patterns]
 218   '(menu-item "Patterns from Buffer" hi-lock-find-patterns
 219               :help "Use patterns (if any) near top of buffer."))
 220
 221 (defvar hi-lock-map (make-sparse-keymap "Hi Lock")
 222   "Key map for hi-lock.")
 223
 224 (define-key hi-lock-map "\C-xwi" 'hi-lock-find-patterns)
 225 (define-key hi-lock-map "\C-xwl" 'highlight-lines-matching-regexp)
 226 (define-key hi-lock-map "\C-xwh" 'highlight-regexp)
 227 (define-key hi-lock-map "\C-xwr" 'unhighlight-regexp)
 228 (define-key hi-lock-map "\C-xwb" 'hi-lock-write-interactive-patterns)
 229
 230 (unless (assq 'hi-lock-mode minor-mode-map-alist)
 231   (setq minor-mode-map-alist (cons (cons 'hi-lock-mode hi-lock-map)
 232                                    minor-mode-map-alist)))
 233
 234 (unless (assq 'hi-lock-mode minor-mode-alist)
 235   (setq minor-mode-alist (cons '(hi-lock-mode " H") minor-mode-alist)))
 236
 237
 238 ;; Visible Functions
 239
 240
 241 ;;;###autoload
 242 (defun hi-lock-mode (&optional arg)
 243   "Toggle minor mode for interactively adding font-lock highlighting patterns.
 244
 245 If ARG positive turn hi-lock on.  Issuing a hi-lock command will also
 246 turn hi-lock on.  When hi-lock turned on an \"Automatic Highlighting\"
 247 submenu is added to the \"Edit\" menu.  The commands in the submenu,
 248 which can be called interactively, are:
 249
 250 \\[highlight-regexp] REGEXP FACE
 251   Highlight matches of pattern REGEXP in current buffer with FACE.
 252
 253 \\[highlight-lines-matching-regexp] REGEXP FACE
 254   Highlight lines containing matches of REGEXP in current buffer with FACE.
 255
 256 \\[unhighlight-regexp] REGEXP
 257   Remove highlighting on matches of REGEXP in current buffer.
 258
 259 \\[hi-lock-write-interactive-patterns]
 260   Write active REGEXPs into buffer as comments (if possible). They will
 261   be read the next time file is loaded or when the \\[hi-lock-find-patterns] command
 262   is issued.  The inserted regexps are in the form of font lock keywords.
 263   (See `font-lock-keywords') They may be edited and re-loaded with \\[hi-lock-find-patterns],
 264   any valid `font-lock-keywords' form is acceptable.
 265
 266 \\[hi-lock-find-patterns]
 267   Re-read patterns stored in buffer (in the format produced by \\[hi-lock-write-interactive-patterns]).
 268
 269 When hi-lock is started and if the mode is not excluded, the
 270 beginning of the buffer is searched for lines of the form:
 271   Hi-lock: FOO
 272 where FOO is a list of patterns. These are added to the font lock keywords
 273 already present.  The patterns must start before position (number
 274 of characters into buffer) `hi-lock-file-patterns-range'.  Patterns
 275 will be read until
 276  Hi-lock: end
 277 is found. A mode is excluded if it's in the list `hi-lock-exclude-modes'."
 278   (interactive)
 279   (let ((hi-lock-mode-prev hi-lock-mode))
 280     (setq hi-lock-mode
 281            (if (null arg) (not hi-lock-mode)
 282              (> (prefix-numeric-value arg) 0)))
 283     ;; Turned on.
 284     (when (and (not hi-lock-mode-prev) hi-lock-mode)
 285       (if (not font-lock-mode) (turn-on-font-lock))
 286       (add-hook 'find-file-hooks 'hi-lock-find-file-hook)
 287       (add-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook)
 288       (define-key-after menu-bar-edit-menu [hi-lock]
 289         (cons "Automatic Highlighting" hi-lock-menu))
 290       (hi-lock-find-patterns))
 291     ;; Turned off.
 292     (when (and hi-lock-mode-prev (not hi-lock-mode))
 293       (font-lock-remove-keywords nil hi-lock-interactive-patterns)
 294       (font-lock-remove-keywords nil hi-lock-file-patterns)
 295       (setq hi-lock-interactive-patterns nil)
 296       (hi-lock-refontify)
 297       (define-key-after menu-bar-edit-menu [hi-lock] nil)
 298       (remove-hook 'find-file-hooks 'hi-lock-find-file-hook)
 299       (remove-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook))))
 300
 301
 302 ;;;###autoload
 303 (defalias 'highlight-lines-matching-regexp 'hi-lock-line-face-buffer)
 304 ;;;###autoload
 305 (defun hi-lock-line-face-buffer (regexp &optional face)
 306   "Set face of all lines containing matches of REGEXP to FACE.
 307
 308 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 309 list maintained for regexps, global history maintained for faces.
 310 \\<minibuffer-local-map>Use \\[next-history-element] and \\[previous-history-element] to retrieve next or previous history item.
 311 (See info node `Minibuffer History')"
 312   (interactive
 313    (list
 314     (hi-lock-regexp-okay
 315      (read-from-minibuffer "Regexp to highlight line: "
 316                            (cons (or (car hi-lock-regexp-history) "") 1 )
 317                            nil nil 'hi-lock-regexp-history))
 318     (hi-lock-read-face-name)))
 319   (unless hi-lock-mode (hi-lock-mode))
 320   (or (facep face) (setq face 'rwl-yellow))
 321   (hi-lock-set-pattern
 322    (list (concat "^.*" regexp ".*$") (list 0 (list 'quote face) t))))
 323
 324 ;;;###autoload
 325 (defalias 'highlight-regexp 'hi-lock-face-buffer)
 326 ;;;###autoload
 327 (defun hi-lock-face-buffer (regexp &optional face)
 328   "Set face of all matches of REGEXP to FACE.
 329
 330 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 331 list maintained for regexps, global history maintained for faces.
 332 \\<minibuffer-local-map>Use \\[next-history-element] and \\[previous-history-element] to retrieve next or previous history item.
 333 (See info node `Minibuffer History')"
 334   (interactive
 335    (list
 336     (hi-lock-regexp-okay
 337      (read-from-minibuffer "Regexp to highlight: "
 338                            (cons (or (car hi-lock-regexp-history) "") 1 )
 339                            nil nil 'hi-lock-regexp-history))
 340     (hi-lock-read-face-name)))
 341   (or (facep face) (setq face 'rwl-yellow))
 342   (unless hi-lock-mode (hi-lock-mode))
 343   (hi-lock-set-pattern (list regexp (list 0 (list 'quote face) t))))
 344
 345 ;;;###autoload
 346 (defalias 'unhighlight-regexp 'hi-lock-unface-buffer)
 347 ;;;###autoload
 348 (defun hi-lock-unface-buffer (regexp)
 349   "Remove highlighting of matches to REGEXP set by hi-lock.
 350
 351 Interactively, prompt for REGEXP.  Buffer-local history of inserted
 352 regexp's maintained.  Will accept only regexps inserted by hi-lock
 353 interactive functions. \(See `hi-lock-interactive-patterns'.\)
 354 \\<minibuffer-local-must-match-map>Use \\[minibuffer-complete] to complete a partially typed regexp.
 355 \(See info node `Minibuffer History'.\)"
 356   (interactive
 357    (if (vectorp (this-command-keys))
 358        (catch 'snafu
 359          (or
 360           (x-popup-menu
 361            t
 362            (cons
 363             `keymap
 364             (cons "Select Pattern to Unhighlight"
 365                   (mapcar (lambda (pattern)
 366                             (list (car pattern)
 367                                   (format
 368                                    "%s (%s)" (car pattern)
 369                                    (symbol-name
 370                                     (car
 371                                      (cdr (car (cdr (car (cdr pattern))))))))
 372                                   (cons nil nil)
 373                                   (car pattern)))
 374                           hi-lock-interactive-patterns))))
 375           ;; If the user clicks outside the menu, meaning that they
 376           ;; change their mind, x-popup-menu returns nil, and
 377           ;; interactive signals a wrong number of arguments error.
 378           ;; To prevent that, we return an empty string, which will
 379           ;; effectively disable the rest of the function.
 380           (throw 'snafu '(""))))
 381      (let ((history-list (mapcar (lambda (p) (car p))
 382                                  hi-lock-interactive-patterns)))
 383        (unless hi-lock-interactive-patterns
 384          (error "No highlighting to remove"))
 385        (list
 386         (completing-read "Regexp to unhighlight: "
 387                          hi-lock-interactive-patterns t t
 388                          (car (car hi-lock-interactive-patterns))
 389                          (cons 'history-list 1))))))
 390   (let ((keyword (assoc regexp hi-lock-interactive-patterns)))
 391     (when keyword
 392       (font-lock-remove-keywords nil (list keyword))
 393       (setq hi-lock-interactive-patterns
 394             (delq keyword hi-lock-interactive-patterns))
 395       (hi-lock-refontify))))
 396
 397 ;;;###autoload
 398 (defun hi-lock-write-interactive-patterns ()
 399   "Write interactively added patterns, if any, into buffer at point.
 400
 401 Interactively added patterns are those normally specified using
 402 `highlight-regexp' and `highlight-lines-matching-regexp'; they can
 403 be found in variable `hi-lock-interactive-patterns'."
 404   (interactive)
 405   (let ((prefix (format "%s %s:" (or comment-start "") "Hi-lock")))
 406     (when (> (+ (point) (length prefix)) hi-lock-file-patterns-range)
 407       (beep)
 408       (message
 409        "Warning, inserted keywords not close enough to top of file."))
 410     (mapcar
 411      (lambda (pattern)
 412        (insert (format "%s (%s) %s\n"
 413                        prefix (prin1-to-string pattern) (or comment-end ""))))
 414      hi-lock-interactive-patterns)))
 415
 416
 417 ;; Implementation Functions
 418
 419 (defun hi-lock-regexp-okay (regexp)
 420   "Return REGEXP if it appears suitable for a font-lock pattern.
 421
 422 Otherwise signal an error.  A pattern that matches the null string is
 423 not suitable."
 424   (if (string-match regexp "")
 425       (error "Regexp cannot match an empty string")
 426     regexp))
 427
 428 (defun hi-lock-read-face-name ()
 429   "Read face name from minibuffer with completion and history."
 430   (intern (completing-read
 431            "Highlight using face: "
 432            obarray 'facep t
 433            (cons (car hi-lock-face-history)
 434                  (let ((prefix
 435                         (try-completion
 436                          (substring (car hi-lock-face-history) 0 1)
 437                          (mapcar (lambda (f) (cons f f))
 438                                  hi-lock-face-history))))
 439                    (if (and (stringp prefix)
 440                             (not (equal prefix (car hi-lock-face-history))))
 441                        (length prefix) 0)))
 442            '(hi-lock-face-history . 0))))
 443
 444 (defun hi-lock-find-file-hook ()
 445   "Add hi-lock patterns, if present."
 446   (hi-lock-find-patterns))
 447
 448 (defun hi-lock-current-line (&optional end)
 449   "Return line number of line at point.
 450 Optional argument END is maximum excursion."
 451   (interactive)
 452   (save-excursion
 453     (beginning-of-line)
 454     (1+ (count-lines 1 (or end (point))))))
 455
 456 (defun hi-lock-set-pattern (pattern)
 457   "Add PATTERN to list of interactively highlighted patterns and refontify."
 458   (hi-lock-set-patterns (list pattern)))
 459
 460 (defun hi-lock-set-patterns (patterns)
 461   "Add PATTERNS to list of interactively highlighted patterns and refontify.."
 462   (dolist (pattern patterns)
 463     (unless (member pattern hi-lock-interactive-patterns)
 464       (font-lock-add-keywords nil (list pattern))
 465       (add-to-list 'hi-lock-interactive-patterns pattern)))
 466   (hi-lock-refontify))
 467
 468 (defun hi-lock-set-file-patterns (patterns)
 469   "Replace file patterns list with PATTERNS and refontify."
 470   (font-lock-remove-keywords nil hi-lock-file-patterns)
 471   (setq hi-lock-file-patterns patterns)
 472   (font-lock-add-keywords nil hi-lock-file-patterns)
 473   (hi-lock-refontify))
 474
 475 (defun hi-lock-refontify ()
 476   "Unfontify then refontify buffer.  Used when hi-lock patterns change."
 477   (interactive)
 478   (font-lock-unfontify-buffer)
 479   (cond
 480    (jit-lock-mode (jit-lock-refontify))
 481    ;; Need a better way, since this assumes too much about lazy lock.
 482    (lazy-lock-mode
 483     (let ((windows (get-buffer-window-list (current-buffer) 'nomini t)))
 484         (while windows
 485           (lazy-lock-fontify-window (car windows))
 486           (setq windows (cdr windows)))))
 487    (t (font-lock-fontify-buffer))))
 488
 489
 490 (defun hi-lock-find-patterns ()
 491   "Find patterns in current buffer for hi-lock."
 492   (interactive)
 493   (unless (memq major-mode hi-lock-exclude-modes)
 494     (let ((all-patterns nil)
 495           (target-regexp (concat "\\<" hi-lock-file-patterns-prefix ":")))
 496       (save-excursion
 497         (widen)
 498         (goto-char (point-min))
 499         (re-search-forward target-regexp
 500                            (+ (point) hi-lock-file-patterns-range) t)
 501         (beginning-of-line)
 502         (while
 503             (and
 504              (re-search-forward target-regexp (+ (point) 100) t)
 505              (not (looking-at "\\s-*end")))
 506           (let
 507               ((patterns
 508                 (condition-case nil
 509                     (read (current-buffer))
 510                   (error  (message
 511                            (format "Could not read expression at %d"
 512                                    (hi-lock-current-line))) nil))))
 513             (if patterns
 514                 (setq all-patterns (append patterns all-patterns))))))
 515       (if (and (not hi-lock-mode) all-patterns)
 516           (hi-lock-mode 1))
 517       (if hi-lock-mode (hi-lock-set-file-patterns all-patterns))
 518       (if (interactive-p)
 519         (message (format "Hi-lock added %d patterns." (length all-patterns)))))))
 520
 521 (defun hi-lock-font-lock-hook ()
 522   "Add hi lock patterns to font-lock's."
 523   (when hi-lock-mode
 524     (font-lock-add-keywords nil hi-lock-file-patterns)
 525     (font-lock-add-keywords nil hi-lock-interactive-patterns)))
 526
 527 (provide 'hi-lock)
 528
 529 ;;; hi-lock.el ends here