lisp/descr-text.el

   1 ;;; descr-text.el --- describe text mode
   2
   3 ;; Copyright (C) 1994-1996, 2001-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Maintainer: FSF
   7 ;; Keywords: faces, i18n, Unicode, multilingual
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Describe-Text Mode.
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'quail))
  31 (require 'help-mode)
  32
  33 ;;; Describe-Text Utilities.
  34
  35 (defun describe-text-widget (widget)
  36   "Insert text to describe WIDGET in the current buffer."
  37   (insert-text-button
  38    (symbol-name (if (symbolp widget) widget (car widget)))
  39    'action `(lambda (&rest ignore)
  40               (widget-browse ',widget))
  41    'help-echo "mouse-2, RET: browse this widget")
  42   (insert " ")
  43   (insert-text-button
  44    "(widget)Top" 'type 'help-info 'help-args '("(widget)Top")))
  45
  46 (defun describe-text-sexp (sexp)
  47   "Insert a short description of SEXP in the current buffer."
  48   (let ((pp (condition-case signal
  49                 (pp-to-string sexp)
  50               (error (prin1-to-string signal)))))
  51     (when (string-match-p "\n\\'" pp)
  52       (setq pp (substring pp 0 (1- (length pp)))))
  53
  54     (if (and (not (string-match-p "\n" pp))
  55              (<= (length pp) (- (window-width) (current-column))))
  56         (insert pp)
  57       (insert-text-button
  58        "[Show]" 'action `(lambda (&rest ignore)
  59                            (with-output-to-temp-buffer
  60                                "*Pp Eval Output*"
  61                              (princ ',pp)))
  62        'help-echo "mouse-2, RET: pretty print value in another buffer"))))
  63
  64 (defun describe-property-list (properties)
  65   "Insert a description of PROPERTIES in the current buffer.
  66 PROPERTIES should be a list of overlay or text properties.
  67 The `category', `face' and `font-lock-face' properties are made
  68 into help buttons that call `describe-text-category' or
  69 `describe-face' when pushed."
  70   ;; Sort the properties by the size of their value.
  71   (dolist (elt (sort (let (ret)
  72                        (while properties
  73                          (push (list (pop properties) (pop properties)) ret))
  74                        ret)
  75                      (lambda (a b) (string< (prin1-to-string (nth 0 a) t)
  76                                             (prin1-to-string (nth 0 b) t)))))
  77     (let ((key (nth 0 elt))
  78           (value (nth 1 elt)))
  79       (insert (propertize (format "  %-20s " key)
  80                           'face 'help-argument-name))
  81       (cond ((eq key 'category)
  82              (insert-text-button
  83               (symbol-name value)
  84               'action `(lambda (&rest ignore)
  85                          (describe-text-category ',value))
  86               'follow-link t
  87               'help-echo "mouse-2, RET: describe this category"))
  88             ((memq key '(face font-lock-face mouse-face))
  89              (insert-text-button
  90               (format "%S" value)
  91               'type 'help-face 'help-args (list value)))
  92             ((widgetp value)
  93              (describe-text-widget value))
  94             (t
  95              (describe-text-sexp value))))
  96     (insert "\n")))
  97 \f
  98 ;;; Describe-Text Commands.
  99
 100 (defun describe-text-category (category)
 101   "Describe a text property category."
 102   (interactive "SCategory: ")
 103   (help-setup-xref (list #'describe-text-category category)
 104                    (called-interactively-p 'interactive))
 105   (with-help-window (help-buffer)
 106     (with-current-buffer standard-output
 107       (insert "Category " (format "%S" category) ":\n\n")
 108       (describe-property-list (symbol-plist category))
 109       (goto-char (point-min)))))
 110
 111 ;;;###autoload
 112 (defun describe-text-properties (pos &optional output-buffer buffer)
 113   "Describe widgets, buttons, overlays, and text properties at POS.
 114 POS is taken to be in BUFFER or in current buffer if nil.
 115 Interactively, describe them for the character after point.
 116 If optional second argument OUTPUT-BUFFER is non-nil,
 117 insert the output into that buffer, and don't initialize or clear it
 118 otherwise."
 119   (interactive "d")
 120   (let ((src-buf (current-buffer)))
 121     (if buffer (set-buffer buffer) (setq buffer (current-buffer)))
 122   (if (>= pos (point-max))
 123       (error "No character follows specified position"))
 124   (if output-buffer
 125       (describe-text-properties-1 pos output-buffer)
 126     (if (not (or (text-properties-at pos) (overlays-at pos)))
 127         (message "This is plain text.")
 128         (with-temp-buffer
 129             (setq output-buffer (current-buffer))
 130             (insert "Text content at position " (format "%d" pos) ":\n\n")
 131           (set-buffer buffer)
 132           (describe-text-properties-1 pos output-buffer)
 133           (set-buffer src-buf)
 134           (help-setup-xref (list 'describe-text-properties pos nil buffer)
 135                            (called-interactively-p 'interactive))
 136           (with-help-window (help-buffer)
 137             (with-current-buffer standard-output
 138               (buffer-swap-text output-buffer)
 139               (goto-char (point-min)))))))))
 140
 141 (defun describe-text-properties-1 (pos output-buffer)
 142   (let* ((properties (text-properties-at pos))
 143          (overlays (overlays-at pos))
 144          (wid-field (get-char-property pos 'field))
 145          (wid-button (get-char-property pos 'button))
 146          (wid-doc (get-char-property pos 'widget-doc))
 147          ;; If button.el is not loaded, we have no buttons in the text.
 148          (button (and (fboundp 'button-at) (button-at pos)))
 149          (button-type (and button (button-type button)))
 150          (button-label (and button (button-label button)))
 151          (widget (or wid-field wid-button wid-doc)))
 152     (with-current-buffer output-buffer
 153       ;; Widgets
 154       (when (widgetp widget)
 155         (newline)
 156         (insert (cond (wid-field "This is an editable text area")
 157                       (wid-button "This is an active area")
 158                       (wid-doc "This is documentation text")))
 159         (insert " of a ")
 160         (describe-text-widget widget)
 161         (insert ".\n\n"))
 162       ;; Buttons
 163       (when (and button (not (widgetp wid-button)))
 164         (newline)
 165         (insert "Here is a `" (format "%S" button-type)
 166                 "' button labeled `" button-label "'.\n\n"))
 167       ;; Overlays
 168       (when overlays
 169         (newline)
 170         (if (eq (length overlays) 1)
 171             (insert "There is an overlay here:\n")
 172           (insert "There are " (format "%d" (length overlays))
 173                          " overlays here:\n"))
 174         (dolist (overlay overlays)
 175           (insert " From " (format "%d" (overlay-start overlay))
 176                          " to " (format "%d" (overlay-end overlay)) "\n")
 177           (describe-property-list (overlay-properties overlay)))
 178         (insert "\n"))
 179       ;; Text properties
 180       (when properties
 181         (newline)
 182         (insert "There are text properties here:\n")
 183         (describe-property-list properties)))))
 184 \f
 185 (defcustom describe-char-unidata-list
 186   '(name old-name general-category decomposition)
 187   "List of Unicode-based character property names shown by `describe-char'."
 188   :group 'mule
 189   :version "23.1"
 190   :type '(choice (const :tag "All properties" t)
 191           (set
 192            (const :tag "Unicode name" name)
 193            (const :tag "Unicode old name" old-name)
 194            (const :tag "Unicode general category " general-category)
 195            (const :tag "Unicode canonical combining class"
 196                   canonical-combining-class)
 197            (const :tag "Unicode bidi class" bidi-class)
 198            (const :tag "Unicode decomposition mapping" decomposition)
 199            (const :tag "Unicode decimal digit value" decimal-digit-value)
 200            (const :tag "Unicode digit value" digit-value)
 201            (const :tag "Unicode numeric value" numeric-value)
 202            (const :tag "Unicode mirrored" mirrored)
 203            (const :tag "Unicode ISO 10646 comment" iso-10646-comment)
 204            (const :tag "Unicode simple uppercase mapping" uppercase)
 205            (const :tag "Unicode simple lowercase mapping" lowercase)
 206            (const :tag "Unicode simple titlecase mapping" titlecase))))
 207
 208 (defcustom describe-char-unicodedata-file nil
 209   "Location of Unicode data file.
 210 This is the UnicodeData.txt file from the Unicode Consortium, used for
 211 diagnostics.  If it is non-nil `describe-char' will print data
 212 looked up from it.  This facility is mostly of use to people doing
 213 multilingual development.
 214
 215 This is a fairly large file, not typically present on GNU systems.
 216 At the time of writing it is at the URL
 217 `http://www.unicode.org/Public/UNIDATA/UnicodeData.txt'."
 218   :group 'mule
 219   :version "22.1"
 220   :type '(choice (const :tag "None" nil)
 221                  file))
 222
 223 (defun describe-char-unicode-data (char)
 224   "Return a list of Unicode data for Unicode CHAR.
 225 Each element is a list of a property description and the property value.
 226 The list is null if CHAR isn't found in `describe-char-unicodedata-file'.
 227 This function is semi-obsolete.  Use `get-char-code-property'."
 228   (when describe-char-unicodedata-file
 229     (unless (file-exists-p describe-char-unicodedata-file)
 230       (error "`unicodedata-file' %s not found" describe-char-unicodedata-file))
 231     (with-current-buffer (get-buffer-create " *Unicode Data*")
 232       (when (zerop (buffer-size))
 233         ;; Don't use -literally in case of DOS line endings.
 234         (insert-file-contents describe-char-unicodedata-file))
 235       (goto-char (point-min))
 236       (let ((hex (format "%04X" char))
 237             found first last)
 238         (if (re-search-forward (concat "^" hex) nil t)
 239             (setq found t)
 240           ;; It's not listed explicitly.  Look for ranges, e.g. CJK
 241           ;; ideographs, and check whether it's in one of them.
 242           (while (and (re-search-forward "^\\([^;]+\\);[^;]+First>;" nil t)
 243                       (>= char (setq first
 244                                      (string-to-number (match-string 1) 16)))
 245                       (progn
 246                         (forward-line 1)
 247                         (looking-at "^\\([^;]+\\);[^;]+Last>;")
 248                         (> char
 249                            (setq last
 250                                  (string-to-number (match-string 1) 16))))))
 251           (if (and (>= char first)
 252                    (<= char last))
 253               (setq found t)))
 254         (if found
 255             (let ((fields (mapcar (lambda (elt)
 256                                     (if (> (length elt) 0)
 257                                         elt))
 258                                   (cdr (split-string
 259                                         (buffer-substring
 260                                          (line-beginning-position)
 261                                          (line-end-position))
 262                                         ";")))))
 263               ;; The length depends on whether the last field was empty.
 264               (unless (or (= 13 (length fields))
 265                           (= 14 (length fields)))
 266                 (error "Invalid contents in %s" describe-char-unicodedata-file))
 267               ;; The field names and values lists are slightly
 268               ;; modified from Mule-UCS unidata.el.
 269               (list
 270                (list "Name" (let ((name (nth 0 fields)))
 271                               ;; Check for <..., First>, <..., Last>
 272                               (if (string-match "\\`\\(<[^,]+\\)," name)
 273                                   (concat (match-string 1 name) ">")
 274                                 name)))
 275                (list "Category"
 276                      (let ((val (nth 1 fields)))
 277                        (or (char-code-property-description
 278                             'general-category (intern val))
 279                            val)))
 280                (list "Combining class"
 281                      (let ((val (nth 1 fields)))
 282                        (or (char-code-property-description
 283                             'canonical-combining-class (intern val))
 284                            val)))
 285                (list "Bidi category"
 286                      (let ((val (nth 1 fields)))
 287                        (or (char-code-property-description
 288                             'bidi-class (intern val))
 289                            val)))
 290                (list
 291                 "Decomposition"
 292                 (if (nth 4 fields)
 293                     (let* ((parts (split-string (nth 4 fields)))
 294                            (info (car parts)))
 295                       (if (string-match "\\`<\\(.+\\)>\\'" info)
 296                           (setq info (match-string 1 info))
 297                         (setq info nil))
 298                       (if info (setq parts (cdr parts)))
 299                       (setq parts (mapconcat
 300                                    (lambda (arg)
 301                                      (string (string-to-number arg 16)))
 302                                    parts " "))
 303                       (concat info (if info " ") parts))))
 304                (list "Decimal digit value"
 305                      (nth 5 fields))
 306                (list "Digit value"
 307                      (nth 6 fields))
 308                (list "Numeric value"
 309                      (nth 7 fields))
 310                (list "Mirrored"
 311                      (if (equal "Y" (nth 8 fields))
 312                          "yes"))
 313                (list "Old name" (nth 9 fields))
 314                (list "ISO 10646 comment" (nth 10 fields))
 315                (list "Uppercase" (and (nth 11 fields)
 316                                       (string (string-to-number
 317                                                (nth 11 fields) 16))))
 318                (list "Lowercase" (and (nth 12 fields)
 319                                       (string (string-to-number
 320                                                (nth 12 fields) 16))))
 321                (list "Titlecase" (and (nth 13 fields)
 322                                       (string (string-to-number
 323                                                (nth 13 fields) 16)))))))))))
 324
 325 ;; Not defined on builds without X, but behind display-graphic-p.
 326 (declare-function internal-char-font "fontset.c" (position &optional ch))
 327
 328 ;; Return information about how CHAR is displayed at the buffer
 329 ;; position POS.  If the selected frame is on a graphic display,
 330 ;; return a string "FONT-DRIVER:FONT-NAME (GLYPH-CODE)" where:
 331 ;;   FONT-DRIVER is the font-driver name,
 332 ;;   FONT-NAME is the font name,
 333 ;;   GLYPH-CODE is a hexadigit string representing the glyph-ID.
 334 ;; Otherwise, return a string describing the terminal codes for the
 335 ;; character.
 336 (defun describe-char-display (pos char)
 337   (if (display-graphic-p (selected-frame))
 338       (let ((char-font-info (internal-char-font pos char)))
 339         (if char-font-info
 340             (let ((type (font-get (car char-font-info) :type))
 341                   (name (font-xlfd-name (car char-font-info)))
 342                   (code (cdr char-font-info)))
 343                (if (integerp code)
 344                    (format "%s:%s (#x%02X)" type name code)
 345                  (format "%s:%s (#x%04X%04X)"
 346                          type name (car code) (cdr code))))))
 347     (let* ((charset (get-text-property pos 'charset))
 348            (coding (or (terminal-coding-system) 'us-ascii))
 349            (encoded (encode-coding-char char coding charset)))
 350       (if encoded
 351           (encoded-string-description encoded coding)))))
 352
 353 \f
 354 ;; Return a string of CH with composition for padding on both sides.
 355 ;; It is displayed without overlapping with the left/right columns.
 356 (defsubst describe-char-padded-string (ch)
 357   (if (internal-char-font nil ch)
 358       (compose-string (string ch) 0 1 (format "\t%c\t" ch))
 359     (string ch)))
 360
 361 ;; Return a nicely formatted list of categories; extended category
 362 ;; description is added to the category name as a tooltip
 363 (defsubst describe-char-categories (category-set)
 364   (let ((mnemonics (category-set-mnemonics category-set)))
 365     (unless (eq mnemonics "")
 366       (list (mapconcat
 367              (lambda (x)
 368                (let* ((c (category-docstring x))
 369                       (doc (if (string-match "\\`\\(.*?\\)\n" c)
 370                                (propertize (match-string 1 c)
 371                                            'help-echo
 372                                            (substring c (1+ (match-end 1))))
 373                              c)))
 374                  (format "%c:%s" x doc)))
 375              mnemonics ", ")))))
 376
 377 ;;;###autoload
 378 (defun describe-char (pos &optional buffer)
 379   "Describe the character after POS (interactively, the character after point).
 380 Is POS is taken to be in buffer BUFFER or current buffer if nil.
 381 The information includes character code, charset and code points in it,
 382 syntax, category, how the character is encoded in a file,
 383 character composition information (if relevant),
 384 as well as widgets, buttons, overlays, and text properties."
 385   (interactive "d")
 386   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 387   (let ((src-buf (current-buffer)))
 388     (set-buffer buffer)
 389     (if (>= pos (point-max))
 390         (error "No character follows specified position"))
 391     (let* ((char (char-after pos))
 392            (eight-bit-p (and (not enable-multibyte-characters) (>= char 128)))
 393            (charset (if eight-bit-p 'eight-bit
 394                       (or (get-text-property pos 'charset)
 395                           (char-charset char))))
 396            (composition (find-composition pos nil nil t))
 397            (component-chars nil)
 398            (display-table (or (window-display-table)
 399                               buffer-display-table
 400                               standard-display-table))
 401            (disp-vector (and display-table (aref display-table char)))
 402            (multibyte-p enable-multibyte-characters)
 403            (overlays (mapcar (lambda (o) (overlay-properties o))
 404                              (overlays-at pos)))
 405            (char-description (if (not multibyte-p)
 406                                  (single-key-description char)
 407                                (if (< char 128)
 408                                    (single-key-description char)
 409                                  (string-to-multibyte
 410                                   (char-to-string char)))))
 411            (text-props-desc
 412             (let ((tmp-buf (generate-new-buffer " *text-props*")))
 413               (unwind-protect
 414                   (progn
 415                     (describe-text-properties pos tmp-buf)
 416                     (with-current-buffer tmp-buf (buffer-string)))
 417                 (kill-buffer tmp-buf))))
 418            item-list max-width code)
 419
 420       (if multibyte-p
 421           (or (setq code (encode-char char charset))
 422               (setq charset (char-charset char)
 423                     code (encode-char char charset)))
 424         (setq code char))
 425       (cond
 426        ;; Append a PDF character to directional embeddings and
 427        ;; overrides, to prevent potential messup of the following
 428        ;; text.
 429        ((memq char '(?\x202a ?\x202b ?\x202d ?\x202e))
 430         (setq char-description
 431               (concat char-description
 432                       (propertize (string ?\x202c) 'invisible t))))
 433        ;; Append a LRM character to any strong character to avoid
 434        ;; messing up the numerical codepoint.
 435        ((memq (get-char-code-property char 'bidi-class) '(R AL))
 436         (setq char-description
 437               (concat char-description
 438                       (propertize (string ?\x200e) 'invisible t)))))
 439       (when composition
 440         ;; When the composition is trivial (i.e. composed only with the
 441         ;; current character itself without any alternate characters),
 442         ;; we don't show the composition information.  Otherwise, store
 443         ;; two descriptive strings in the first two elements of
 444         ;; COMPOSITION.
 445         (or (catch 'tag
 446               (let ((from (car composition))
 447                     (to (nth 1 composition))
 448                     (components (nth 2 composition))
 449                     ch)
 450                 (if (and (vectorp components) (vectorp (aref components 0)))
 451                     (let ((idx (- pos from))
 452                           (nglyphs (lgstring-glyph-len components))
 453                           (i 0) j glyph glyph-from)
 454                       ;; COMPONENTS is a gstring.  Find a grapheme
 455                       ;; cluster containing the current character.
 456                       (while (and (< i nglyphs)
 457                                   (setq glyph (lgstring-glyph components i))
 458                                   (< (lglyph-to glyph) idx))
 459                         (setq i (1+ i)))
 460                       (if (or (not glyph) (= i nglyphs))
 461                           ;; The composition is broken.
 462                           (throw 'tag nil))
 463                       (setq glyph-from (lglyph-from glyph)
 464                             to (+ from (lglyph-to glyph) 1)
 465                             from (+ from glyph-from)
 466                             j i)
 467                       (while (and (< j nglyphs)
 468                                   (setq glyph (lgstring-glyph components j))
 469                                   (= (lglyph-from glyph) glyph-from))
 470                         (setq j (1+ j)))
 471                       (if (and (= to (1+ from))
 472                                (= i (1- j))
 473                                (setq glyph (lgstring-glyph components i))
 474                                (= char (lglyph-char glyph)))
 475                           ;; The composition is trivial.
 476                           (throw 'tag nil))
 477                       (nconc composition (list i (1- j))))
 478                   (dotimes (i (length components))
 479                     (if (integerp (setq ch (aref components i)))
 480                         (push (cons ch (describe-char-display pos ch))
 481                               component-chars)))
 482                   (setq component-chars (nreverse component-chars)))
 483                 (if (< from pos)
 484                     (if (< (1+ pos) to)
 485                         (setcar composition
 486                                 (concat
 487                                  " with the surrounding characters \""
 488                                  (mapconcat 'describe-char-padded-string
 489                                             (buffer-substring from pos) "")
 490                                  "\" and \""
 491                                  (mapconcat 'describe-char-padded-string
 492                                             (buffer-substring (1+ pos) to) "")
 493                                  "\""))
 494                       (setcar composition
 495                               (concat
 496                                " with the preceding character(s) \""
 497                                (mapconcat 'describe-char-padded-string
 498                                           (buffer-substring from pos) "")
 499                                "\"")))
 500                   (if (< (1+ pos) to)
 501                       (setcar composition
 502                               (concat
 503                                " with the following character(s) \""
 504                                (mapconcat 'describe-char-padded-string
 505                                           (buffer-substring (1+ pos) to) "")
 506                                "\""))
 507                     (setcar composition nil)))
 508                 (setcar (cdr composition)
 509                         (format "composed to form \"%s\" (see below)"
 510                                 (buffer-substring from to)))))
 511             (setq composition nil)))
 512
 513       (setq item-list
 514             `(("character"
 515                ,(format "%s (%d, #o%o, #x%x)"
 516                         (apply 'propertize char-description
 517                                (text-properties-at pos))
 518                         char char char))
 519               ("preferred charset"
 520                ,`(insert-text-button
 521                   ,(symbol-name charset)
 522                   'type 'help-character-set 'help-args '(,charset))
 523                ,(format "(%s)" (charset-description charset)))
 524               ("code point"
 525                ,(let ((str (if (integerp code)
 526                                (format (if (< code 256) "0x%02X" "0x%04X")
 527                                        code)
 528                              (format "0x%04X%04X" (car code) (cdr code)))))
 529                   (if (<= (charset-dimension charset) 2)
 530                       `(insert-text-button
 531                         ,str
 532                         'action (lambda (&rest ignore)
 533                                   (list-charset-chars ',charset)
 534                                   (with-selected-window
 535                                       (get-buffer-window "*Character List*" 0)
 536                                     (goto-char (point-min))
 537                                     (forward-line 2) ;Skip the header.
 538                                     (let ((case-fold-search nil))
 539                                       (if (search-forward
 540                                            ,(char-to-string char) nil t)
 541                                           (goto-char (match-beginning 0))))))
 542                         'follow-link t
 543                         'help-echo
 544                         "mouse-2, RET: show this character in its character set")
 545                     str)))
 546               ("syntax"
 547                ,(let ((syntax (syntax-after pos)))
 548                   (with-temp-buffer
 549                     (internal-describe-syntax-value syntax)
 550                     (buffer-string))))
 551               ("category"
 552                ,@(if (not eight-bit-p)
 553                      (let ((category-set (char-category-set char)))
 554                        (if category-set
 555                            (describe-char-categories category-set)
 556                          '("-- none --")))))
 557               ("to input"
 558                ,@(if (not eight-bit-p)
 559                      (let ((key-list (and (eq input-method-function
 560                                               'quail-input-method)
 561                                           (quail-find-key char))))
 562                        (if (consp key-list)
 563                            (list "type"
 564                                  (concat "\""
 565                                          (mapconcat 'identity
 566                                                     key-list "\" or \"")
 567                                          "\"")
 568                                  "with"
 569                                  `(insert-text-button
 570                                    ,current-input-method
 571                                    'type 'help-input-method
 572                                    'help-args '(,current-input-method)))))))
 573               ("buffer code"
 574                ,(if multibyte-p
 575                     (encoded-string-description
 576                      (string-as-unibyte (char-to-string char)) nil)
 577                   (format "#x%02X" char)))
 578               ("file code"
 579                ,@(if multibyte-p
 580                      (let* ((coding buffer-file-coding-system)
 581                             (encoded (encode-coding-char char coding charset)))
 582                        (if encoded
 583                            (list (encoded-string-description encoded coding)
 584                                  (format "(encoded by coding system %S)"
 585                                          coding))
 586                          (list "not encodable by coding system"
 587                                (symbol-name coding))))
 588                    (list (format "#x%02X" char))))
 589               ("display"
 590                ,(cond
 591                  (disp-vector
 592                   (setq disp-vector (copy-sequence disp-vector))
 593                   (dotimes (i (length disp-vector))
 594                     (aset disp-vector i
 595                           (cons (aref disp-vector i)
 596                                 (describe-char-display
 597                                  pos (glyph-char (aref disp-vector i))))))
 598                   (format "by display table entry [%s] (see below)"
 599                           (mapconcat
 600                            (lambda (x)
 601                              (format "?%c" (glyph-char (car x))))
 602                            disp-vector " ")))
 603                  (composition
 604                   (cadr composition))
 605                  (t
 606                   (let ((display (describe-char-display pos char)))
 607                     (if (display-graphic-p (selected-frame))
 608                         (if display
 609                             (concat "by this font (glyph code)\n    " display)
 610                           "no font available")
 611                       (if display
 612                           (format "terminal code %s" display)
 613                         "not encodable for terminal"))))))
 614               ,@(let ((face
 615                        (if (not (or disp-vector composition))
 616                            (cond
 617                             ((and show-trailing-whitespace
 618                                   (save-excursion (goto-char pos)
 619                                                   (looking-at-p "[ \t]+$")))
 620                              'trailing-whitespace)
 621                             ((and nobreak-char-display char (eq char '#xa0))
 622                              'nobreak-space)
 623                             ((and nobreak-char-display char
 624                                   (memq char '(#xad #x2010 #x2011)))
 625                              'escape-glyph)
 626                             ((and (< char 32) (not (memq char '(9 10))))
 627                              'escape-glyph)))))
 628                   (if face (list (list "hardcoded face"
 629                                        `(insert-text-button
 630                                          ,(symbol-name face)
 631                                          'type 'help-face
 632                                          'help-args '(,face))))))
 633               ,@(if (not eight-bit-p)
 634                     (let ((unicodedata (describe-char-unicode-data char)))
 635                       (if unicodedata
 636                           (cons (list "Unicode data" "") unicodedata))))))
 637       (setq max-width (apply 'max (mapcar (lambda (x)
 638                                             (if (cadr x) (length (car x)) 0))
 639                                           item-list)))
 640       (set-buffer src-buf)
 641       (help-setup-xref (list 'describe-char pos buffer)
 642                        (called-interactively-p 'interactive))
 643       (with-help-window (help-buffer)
 644         (with-current-buffer standard-output
 645           (set-buffer-multibyte multibyte-p)
 646           (let ((formatter (format "%%%ds:" max-width)))
 647             (dolist (elt item-list)
 648               (when (cadr elt)
 649                 (insert (format formatter (car elt)))
 650                 (dolist (clm (cdr elt))
 651                   (if (eq (car-safe clm) 'insert-text-button)
 652                       (progn (insert " ") (eval clm))
 653                     (when (>= (+ (current-column)
 654                                  (or (string-match-p "\n" clm)
 655                                      (string-width clm))
 656                                  1)
 657                               (window-width))
 658                       (insert "\n")
 659                       (indent-to (1+ max-width)))
 660                     (unless (zerop (length clm))
 661                       (insert " " clm))))
 662                 (insert "\n"))))
 663
 664           (when overlays
 665             (save-excursion
 666               (goto-char (point-min))
 667               (re-search-forward "character:[ \t\n]+")
 668               (let ((end (+ (point) (length char-description))))
 669                 (mapc (lambda (props)
 670                         (let ((o (make-overlay (point) end)))
 671                           (while props
 672                             (overlay-put o (car props) (nth 1 props))
 673                             (setq props (cddr props)))))
 674                       overlays))))
 675
 676           (when disp-vector
 677             (insert
 678              "\nThe display table entry is displayed by ")
 679             (if (display-graphic-p (selected-frame))
 680                 (progn
 681                   (insert "these fonts (glyph codes):\n")
 682                   (dotimes (i (length disp-vector))
 683                     (insert (glyph-char (car (aref disp-vector i))) ?:
 684                             (propertize " " 'display '(space :align-to 5))
 685                             (or (cdr (aref disp-vector i)) "-- no font --")
 686                             "\n")
 687                     (let ((face (glyph-face (car (aref disp-vector i)))))
 688                       (when face
 689                         (insert (propertize " " 'display '(space :align-to 5))
 690                                 "face: ")
 691                         (insert (concat "`" (symbol-name face) "'"))
 692                         (insert "\n")))))
 693               (insert "these terminal codes:\n")
 694               (dotimes (i (length disp-vector))
 695                 (insert (car (aref disp-vector i))
 696                         (propertize " " 'display '(space :align-to 5))
 697                         (or (cdr (aref disp-vector i)) "-- not encodable --")
 698                         "\n"))))
 699
 700           (when composition
 701             (insert "\nComposed")
 702             (if (car composition)
 703                 (insert (car composition)))
 704             (if (and (vectorp (nth 2 composition))
 705                      (vectorp (aref (nth 2 composition) 0)))
 706                 (let* ((gstring (nth 2 composition))
 707                        (font (lgstring-font gstring))
 708                        (from (nth 3 composition))
 709                        (to (nth 4 composition))
 710                        glyph)
 711                   (if (fontp font)
 712                       (progn
 713                         (insert " using this font:\n  "
 714                                 (symbol-name (font-get font :type))
 715                                 ?:
 716                                 (aref (query-font font) 0)
 717                                 "\nby these glyphs:\n")
 718                         (while (and (<= from to)
 719                                     (setq glyph (lgstring-glyph gstring from)))
 720                           (insert (format "  %S\n" glyph))
 721                           (setq from (1+ from))))
 722                     (insert " by these characters:\n")
 723                     (while (and (<= from to)
 724                                 (setq glyph (lgstring-glyph gstring from)))
 725                       (insert (format " %c (#x%d)\n"
 726                                       (lglyph-char glyph) (lglyph-char glyph)))
 727                       (setq from (1+ from)))))
 728               (insert " by the rule:\n\t(")
 729               (let ((first t))
 730                 (mapc (lambda (x)
 731                         (if first (setq first nil)
 732                           (insert " "))
 733                         (if (consp x) (insert (format "%S" x))
 734                           (if (= x ?\t) (insert (single-key-description x))
 735                             (insert ??)
 736                             (insert (describe-char-padded-string x)))))
 737                       (nth 2 composition)))
 738               (insert  ")\nThe component character(s) are displayed by ")
 739               (if (display-graphic-p (selected-frame))
 740                   (progn
 741                     (insert "these fonts (glyph codes):")
 742                     (dolist (elt component-chars)
 743                       (if (/= (car elt) ?\t)
 744                           (insert "\n "
 745                                   (describe-char-padded-string (car elt))
 746                                   ?:
 747                                   (propertize " "
 748                                               'display '(space :align-to 5))
 749                                   (or (cdr elt) "-- no font --")))))
 750                 (insert "these terminal codes:")
 751                 (dolist (elt component-chars)
 752                   (insert "\n  " (car elt) ":"
 753                           (propertize " " 'display '(space :align-to 4))
 754                           (or (cdr elt) "-- not encodable --"))))
 755               (insert "\nSee the variable `reference-point-alist' for "
 756                       "the meaning of the rule.\n")))
 757
 758           (unless eight-bit-p
 759             (insert (if (not describe-char-unidata-list)
 760                         "\nCharacter code properties are not shown: "
 761                       "\nCharacter code properties: "))
 762             (insert-text-button
 763              "customize what to show"
 764              'action (lambda (&rest _ignore)
 765                        (customize-variable
 766                         'describe-char-unidata-list))
 767              'follow-link t)
 768             (insert "\n")
 769             (dolist (elt (if (eq describe-char-unidata-list t)
 770                              (nreverse (mapcar 'car char-code-property-alist))
 771                            describe-char-unidata-list))
 772               (let ((val (get-char-code-property char elt))
 773                     description)
 774                 (when val
 775                   (setq description (char-code-property-description elt val))
 776                   (insert (if description
 777                               (format "  %s: %s (%s)\n" elt val description)
 778                             (format "  %s: %s\n" elt val)))))))
 779
 780           (if text-props-desc (insert text-props-desc))
 781           (toggle-read-only 1))))))
 782
 783 (define-obsolete-function-alias 'describe-char-after 'describe-char "22.1")
 784
 785 (provide 'descr-text)
 786
 787 ;;; descr-text.el ends here