lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;; Copyright (C) 1993-1994, 2000-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Keywords: mouse
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; For those who are annoyed by the mouse pointer obscuring text,
  26 ;; this mode moves the mouse pointer - either just a little out of
  27 ;; the way, or all the way to the corner of the frame.
  28 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  29 ;; To set up permanently, put the following in your .emacs:
  30 ;;
  31 ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate))
  32 ;;
  33 ;; Other legitimate alternatives include
  34 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  35 ;; They do somewhat different things.
  36 ;; See the documentation for function `mouse-avoidance-mode' for
  37 ;; details of the different modes.
  38 ;;
  39 ;; For added silliness, make the animatee animate...
  40 ;; put something similar to the following into your .emacs:
  41 ;;
  42 ;; (if (eq window-system 'x)
  43 ;;     (mouse-avoidance-set-pointer-shape
  44 ;;           (nth (random 4)
  45 ;;                (list x-pointer-man x-pointer-spider
  46 ;;                      x-pointer-gobbler x-pointer-gumby))))
  47 ;;
  48 ;; For completely random pointer shape, replace the setq above with:
  49 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  50 ;;
  51 ;; Bugs / Warnings / To-Do:
  52 ;;
  53 ;; - Using this code does slow Emacs down.  "banish" mode shouldn't
  54 ;;   be too bad, and on my workstation even "animate" is reasonable.
  55 ;;
  56 ;; - It ought to find out where any overlapping frames are and avoid them,
  57 ;;   rather than always raising the frame.
  58
  59 ;; Credits:
  60 ;; This code was helped by all those who contributed suggestions,
  61 ;;   fixes, and additions
  62 ;; Joe Harrington (and his advisor), for the original inspiration.
  63 ;; Ken Manheimer, for dreaming up the Protean mode.
  64 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  65 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  66 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  67
  68 ;;; Code:
  69
  70 (eval-when-compile (require 'cl-lib))
  71
  72 (defgroup avoid nil
  73   "Make mouse pointer stay out of the way of editing."
  74   :prefix "mouse-avoidance-"
  75   :group 'mouse)
  76
  77 ;;;###autoload
  78 (defcustom mouse-avoidance-mode nil
  79   "Activate Mouse Avoidance mode.
  80 See function `mouse-avoidance-mode' for possible values.
  81 Setting this variable directly does not take effect;
  82 use either \\[customize] or the function `mouse-avoidance-mode'."
  83   :set (lambda (_symbol value)
  84          ;; 'none below prevents toggling when value is nil.
  85          (mouse-avoidance-mode (or value 'none)))
  86   :initialize 'custom-initialize-default
  87   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  88                  (const animate) (const exile) (const proteus))
  89   :group 'avoid
  90   :require 'avoid
  91   :version "20.3")
  92
  93
  94 (defcustom mouse-avoidance-nudge-dist 15
  95   "Average distance that mouse will be moved when approached by cursor.
  96 Only applies in Mouse Avoidance mode `jump' and its derivatives.
  97 For best results make this larger than `mouse-avoidance-threshold'."
  98   :type 'integer
  99   :group 'avoid)
 100
 101 (defcustom mouse-avoidance-nudge-var 10
 102   "Variability of `mouse-avoidance-nudge-dist' (which see)."
 103   :type 'integer
 104   :group 'avoid)
 105
 106 (defcustom mouse-avoidance-animation-delay .01
 107   "Delay between animation steps, in seconds."
 108   :type 'number
 109   :group 'avoid)
 110
 111 (defcustom mouse-avoidance-threshold 5
 112   "Mouse-pointer's flight distance.
 113 If the cursor gets closer than this, the mouse pointer will move away.
 114 Only applies in Mouse Avoidance modes `animate' and `jump'."
 115   :type 'integer
 116   :group 'avoid)
 117
 118 (defcustom mouse-avoidance-banish-position '((frame-or-window . frame)
 119                                              (side . right)
 120                                              (side-pos . 3)
 121                                              (top-or-bottom . top)
 122                                              (top-or-bottom-pos . 0))
 123   "Position to which Mouse Avoidance mode `banish' moves the mouse.
 124 An alist where keywords mean:
 125 FRAME-OR-WINDOW: banish the mouse to corner of frame or window.
 126 SIDE: banish the mouse on right or left corner of frame or window.
 127 SIDE-POS: Distance from right or left edge of frame or window.
 128 TOP-OR-BOTTOM: banish the mouse to top or bottom of frame or window.
 129 TOP-OR-BOTTOM-POS: Distance from top or bottom edge of frame or window."
 130   :group   'avoid
 131   :version "24.3"
 132   :type    '(alist :key-type symbol :value-type symbol)
 133   :options '(frame-or-window side (side-pos integer)
 134              top-or-bottom (top-or-bottom-pos integer)))
 135
 136 ;; Internal variables
 137 (defvar mouse-avoidance-state nil)
 138 (defvar mouse-avoidance-pointer-shapes nil)
 139 (defvar mouse-avoidance-n-pointer-shapes 0)
 140 (defvar mouse-avoidance-old-pointer-shape nil)
 141 (defvar mouse-avoidance-animating-pointer nil)
 142
 143 ;; This timer is used to run something when Emacs is idle.
 144 (defvar mouse-avoidance-timer nil)
 145
 146 ;;; Functions:
 147
 148 (defsubst mouse-avoidance-set-pointer-shape (shape)
 149   "Set the shape of the mouse pointer to SHAPE."
 150   (when (boundp 'x-pointer-shape)
 151     (setq x-pointer-shape shape)
 152     (set-mouse-color nil)))
 153
 154 (defun mouse-avoidance-point-position ()
 155   "Return the position of point as (FRAME X . Y).
 156 Analogous to `mouse-position'."
 157   (let* ((edges (window-inside-edges))
 158          (posn-at-point (posn-at-point))
 159          (x-y (and posn-at-point (posn-x-y posn-at-point))))
 160     (when x-y
 161       (cons (selected-frame)
 162             (cons (+ (car edges)
 163                      (/ (car x-y) (frame-char-width)))
 164                   (+ (car (cdr edges))
 165                      (/ (cdr x-y) (frame-char-height))))))))
 166
 167 ;(defun mouse-avoidance-point-position-test ()
 168 ;  (interactive)
 169 ;  (message (format "point=%s mouse=%s"
 170 ;                  (cdr (mouse-avoidance-point-position))
 171 ;                  (cdr (mouse-position)))))
 172
 173 (defun mouse-avoidance-set-mouse-position (pos)
 174   ;; Carefully set mouse position to given position (X . Y)
 175   ;; Ideally, should check if X,Y is in the current frame, and if not,
 176   ;; leave the mouse where it was.  However, this is currently
 177   ;; difficult to do, so we just raise the frame to avoid frame switches.
 178   ;; Returns t if it moved the mouse.
 179   (let ((f (selected-frame)))
 180     (raise-frame f)
 181     (set-mouse-position f (car pos) (cdr pos))
 182     t))
 183
 184 (defun mouse-avoidance-too-close-p (mouse)
 185   "Return t if mouse pointer and point cursor are too close.
 186 MOUSE is the current mouse position as returned by `mouse-position'.
 187 Acceptable distance is defined by `mouse-avoidance-threshold'."
 188   (let* ((frame (car mouse))
 189          (mouse-y (cdr (cdr mouse)))
 190          (tool-bar-lines (frame-parameter nil 'tool-bar-lines))
 191          point)
 192     (or tool-bar-lines
 193         (setq tool-bar-lines 0))
 194     (cond
 195      ((and mouse-y (< mouse-y tool-bar-lines))
 196       nil)
 197      ((setq point (mouse-avoidance-point-position))
 198       (let ((mouse-x (car (cdr mouse))))
 199         (and (eq frame (car point))
 200              (not (null mouse-x))
 201              (< (abs (- mouse-x (car (cdr point))))
 202                 mouse-avoidance-threshold)
 203              (< (abs (- mouse-y (cdr (cdr point))))
 204                 mouse-avoidance-threshold)))))))
 205
 206 (defun mouse-avoidance-banish-destination ()
 207   "The position to which Mouse Avoidance mode `banish' moves the mouse.
 208
 209 If you want the mouse banished to a different corner set
 210 `mouse-avoidance-banish-position' as you need."
 211   (let* ((fra-or-win         (assoc-default
 212                               'frame-or-window
 213                               mouse-avoidance-banish-position 'eq))
 214          (list-values        (pcase fra-or-win
 215                                (`frame (list 0 0 (frame-width) (frame-height)))
 216                                (`window (window-edges))))
 217          (alist              (cl-loop for v in list-values
 218                                       for k in '(left top right bottom)
 219                                       collect (cons k v)))
 220          (side               (assoc-default
 221                               'side
 222                               mouse-avoidance-banish-position #'eq))
 223          (side-dist          (assoc-default
 224                               'side-pos
 225                               mouse-avoidance-banish-position #'eq))
 226          (top-or-bottom      (assoc-default
 227                               'top-or-bottom
 228                               mouse-avoidance-banish-position #'eq))
 229          (top-or-bottom-dist (assoc-default
 230                               'top-or-bottom-pos
 231                               mouse-avoidance-banish-position #'eq))
 232          (side-fn            (pcase side
 233                                (`left '+)
 234                                (`right '-)))
 235          (top-or-bottom-fn   (pcase top-or-bottom
 236                                (`top '+)
 237                                (`bottom '-))))
 238     (cons (funcall side-fn                        ; -/+
 239                    (assoc-default side alist 'eq) ; right or left
 240                    side-dist)                     ; distance from side
 241           (funcall top-or-bottom-fn                        ; -/+
 242                    (assoc-default top-or-bottom alist 'eq) ; top/bottom
 243                    top-or-bottom-dist)))) ; distance from top/bottom
 244
 245 (defun mouse-avoidance-banish-mouse ()
 246   "Put the mouse pointer to `mouse-avoidance-banish-position'."
 247   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 248
 249 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 250   ;; Decide how far to move in either dimension.
 251   ;; Args are the CURRENT location, the desired DELTA for
 252   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 253   ;; in distance allowed, and the MIN and MAX possible window positions.
 254   ;; Returns something as close to DELTA as possible within the constraints.
 255   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 256         (R1                  (+ (- dist)    var ))
 257         (L2                  (+    dist  (- var)))
 258         (R2 (min (- max cur) (+    dist     var))))
 259     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 260     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 261     (cond ((and L1 (< delta L1)) L1)
 262           ((and R1 (< delta R1)) delta)
 263           ((and R1 (< delta 0)) R1)
 264           ((and L2 (< delta L2)) L2)
 265           ((and R2 (< delta R2)) delta)
 266           (R2)
 267           ((or R1 L2))
 268           (t 0))))
 269
 270 (defun mouse-avoidance-nudge-mouse ()
 271   ;; Push the mouse a little way away, possibly animating the move.
 272   ;; For these modes, state keeps track of the total offset that we've
 273   ;; accumulated, and tries to keep it close to zero.
 274   (let* ((cur (mouse-position))
 275          (cur-pos (cdr cur))
 276          (pos (window-edges))
 277          (wleft (pop pos))
 278          (wtop (pop pos))
 279          (wright (pop pos))
 280          (wbot (pop pos))
 281          (deltax (mouse-avoidance-delta
 282                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 283                                    (car mouse-avoidance-state))
 284                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 285                   wleft (1- wright)))
 286          (deltay (mouse-avoidance-delta
 287                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 288                                    (cdr mouse-avoidance-state))
 289                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 290                   wtop (1- wbot))))
 291     (setq mouse-avoidance-state
 292           (cons (+ (car mouse-avoidance-state) deltax)
 293                 (+ (cdr mouse-avoidance-state) deltay)))
 294     (if (or (eq mouse-avoidance-mode 'animate)
 295             (eq mouse-avoidance-mode 'proteus))
 296         (let ((i 0.0)
 297               (incr (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 298           (setq mouse-avoidance-animating-pointer t)
 299           (while (<= i 1)
 300             (mouse-avoidance-set-mouse-position
 301              (cons (+ (car cur-pos) (round (* i deltax)))
 302                    (+ (cdr cur-pos) (round (* i deltay)))))
 303             (setq i (+ i incr))
 304             (if (eq mouse-avoidance-mode 'proteus)
 305                 (mouse-avoidance-set-pointer-shape
 306                  (mouse-avoidance-random-shape)))
 307             (sit-for mouse-avoidance-animation-delay))
 308           (setq mouse-avoidance-animating-pointer nil))
 309       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 310                                                 (+ (cdr (cdr cur)) deltay))))))
 311
 312 (defun mouse-avoidance-random-shape ()
 313   "Return a random cursor shape.
 314 This assumes that any variable whose name begins with x-pointer- and
 315 has an integer value is a valid cursor shape.  You might want to
 316 redefine this function to suit your own tastes."
 317   (if (null mouse-avoidance-pointer-shapes)
 318       (progn
 319         (setq mouse-avoidance-pointer-shapes
 320               (mapcar (lambda (x) (symbol-value (intern x)))
 321                       (all-completions "x-pointer-" obarray
 322                                        (lambda (x)
 323                                           (and (boundp x)
 324                                                (integerp (symbol-value x)))))))
 325         (setq mouse-avoidance-n-pointer-shapes
 326               (length mouse-avoidance-pointer-shapes))))
 327   (nth (random mouse-avoidance-n-pointer-shapes)
 328        mouse-avoidance-pointer-shapes))
 329
 330 (defun mouse-avoidance-ignore-p ()
 331   (let ((mp (mouse-position)))
 332     (or (not (frame-pointer-visible-p)) ; The pointer is hidden
 333         (not cursor-type)               ; There's no cursor
 334         executing-kbd-macro            ; don't check inside macro
 335         (null (cadr mp))               ; don't move unless in an Emacs frame
 336         (not (eq (car mp) (selected-frame)))
 337         ;; Don't do anything if last event was a mouse event.
 338         ;; FIXME: this code fails in the case where the mouse was moved
 339         ;; since the last key-press but without generating any event.
 340         (and (consp last-input-event)
 341              (symbolp (car last-input-event))
 342              (let ((modifiers (event-modifiers (car last-input-event))))
 343                (or (memq (car last-input-event)
 344                          '(mouse-movement scroll-bar-movement
 345                            select-window switch-frame))
 346                    (memq 'click modifiers)
 347                    (memq 'double modifiers)
 348                    (memq 'triple modifiers)
 349                    (memq 'drag modifiers)
 350                    (memq 'down modifiers)))))))
 351
 352 (defun mouse-avoidance-banish ()
 353   (if (not (mouse-avoidance-ignore-p))
 354       (mouse-avoidance-banish-mouse)))
 355
 356 (defun mouse-avoidance-exile ()
 357   ;; For exile mode, the state is nil when the mouse is in its normal
 358   ;; position, and set to the old mouse-position when the mouse is in exile.
 359   (if (not (mouse-avoidance-ignore-p))
 360       (let ((mp (mouse-position)))
 361         (cond ((and (not mouse-avoidance-state)
 362                     (mouse-avoidance-too-close-p mp))
 363                (setq mouse-avoidance-state mp)
 364                (mouse-avoidance-banish-mouse))
 365               ((and mouse-avoidance-state
 366                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 367                (if (and (eq (car mp) (selected-frame))
 368                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 369                    (mouse-avoidance-set-mouse-position
 370                     ;; move back only if user has not moved mouse
 371                     (cdr mouse-avoidance-state)))
 372                ;; but clear state anyway, to be ready for another move
 373                (setq mouse-avoidance-state nil))))))
 374
 375 (defun mouse-avoidance-fancy ()
 376   ;; Used for the "fancy" modes, ie jump et al.
 377   (if (and (not mouse-avoidance-animating-pointer)
 378            (not (mouse-avoidance-ignore-p))
 379            (mouse-avoidance-too-close-p (mouse-position)))
 380       (let ((old-pos (mouse-position)))
 381         (mouse-avoidance-nudge-mouse)
 382         (if (not (eq (selected-frame) (car old-pos)))
 383             ;; This should never happen.
 384             (apply 'set-mouse-position old-pos)))))
 385
 386 ;;;###autoload
 387 (defun mouse-avoidance-mode (&optional mode)
 388   "Set Mouse Avoidance mode to MODE.
 389 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 390 `cat-and-mouse', `proteus', or `none'.
 391
 392 If MODE is nil, toggle mouse avoidance between `none' and `banish'
 393 modes.  Positive numbers and symbols other than the above are treated
 394 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 395
 396 Effects of the different modes:
 397  * banish: Move the mouse to the upper-right corner on any keypress.
 398  * exile: Move the mouse to the corner only if the cursor gets too close,
 399      and allow it to return once the cursor is out of the way.
 400  * jump: If the cursor gets too close to the mouse, displace the mouse
 401      a random distance & direction.
 402  * animate: As `jump', but shows steps along the way for illusion of motion.
 403  * cat-and-mouse: Same as `animate'.
 404  * proteus: As `animate', but changes the shape of the mouse pointer too.
 405
 406 Whenever the mouse is moved, the frame is also raised.
 407
 408 \(See `mouse-avoidance-threshold' for definition of \"too close\",
 409 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 410 definition of \"random distance\".)"
 411   (interactive
 412    (list (intern (completing-read
 413                   "Select cursor avoidance technique (SPACE for list): "
 414                   '(("banish") ("exile") ("jump") ("animate")
 415                     ("cat-and-mouse") ("proteus") ("none"))
 416                   nil t))))
 417   (if (eq mode 'cat-and-mouse)
 418       (setq mode 'animate))
 419   (if mouse-avoidance-timer
 420       (cancel-timer mouse-avoidance-timer))
 421   (setq mouse-avoidance-timer nil)
 422
 423   ;; Restore pointer shape if necessary
 424   (if (eq mouse-avoidance-mode 'proteus)
 425       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 426
 427   ;; Do additional setup depending on version of mode requested
 428   (cond ((eq mode 'none)
 429          (setq mouse-avoidance-mode nil))
 430         ((or (eq mode 'jump)
 431              (eq mode 'animate)
 432              (eq mode 'proteus))
 433          (setq mouse-avoidance-timer
 434                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy))
 435          (setq mouse-avoidance-mode mode
 436                mouse-avoidance-state (cons 0 0)
 437                mouse-avoidance-old-pointer-shape
 438                (and (boundp 'x-pointer-shape) x-pointer-shape)))
 439         ((eq mode 'exile)
 440          (setq mouse-avoidance-timer
 441                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile))
 442          (setq mouse-avoidance-mode mode
 443                mouse-avoidance-state nil))
 444         ((or (eq mode 'banish)
 445              (eq mode t)
 446              (and (null mode) (null mouse-avoidance-mode))
 447              (and mode (> (prefix-numeric-value mode) 0)))
 448          (setq mouse-avoidance-timer
 449                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish))
 450          (setq mouse-avoidance-mode 'banish))
 451         (t (setq mouse-avoidance-mode nil)))
 452   (force-mode-line-update))
 453
 454 ;; Most people who use avoid mode leave it on all the time, so it's not
 455 ;; very informative to announce it in the mode line.
 456 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 457 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 458 ;;                               minor-mode-alist)))
 459
 460 ;; Needed for custom.
 461 (if mouse-avoidance-mode
 462     (mouse-avoidance-mode mouse-avoidance-mode))
 463
 464 (provide 'avoid)
 465
 466 ;;; avoid.el ends here