lisp/help.el

   1 ;;; help.el --- help commands for Emacs  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2018 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This code implements GNU Emacs's built-in help system, the one invoked by
  28 ;; `M-x help-for-help'.
  29
  30 ;;; Code:
  31
  32 ;; Get the macro make-help-screen when this is compiled,
  33 ;; or run interpreted, but not when the compiled code is loaded.
  34 (eval-when-compile (require 'help-macro))
  35
  36 ;; This makes `with-output-to-temp-buffer' buffers use `help-mode'.
  37 (add-hook 'temp-buffer-setup-hook 'help-mode-setup)
  38 (add-hook 'temp-buffer-show-hook 'help-mode-finish)
  39
  40 ;; `help-window-point-marker' is a marker you can move to a valid
  41 ;; position of the buffer shown in the help window in order to override
  42 ;; the standard positioning mechanism (`point-min') chosen by
  43 ;; `with-output-to-temp-buffer' and `with-temp-buffer-window'.
  44 ;; `with-help-window' has this point nowhere before exiting.  Currently
  45 ;; used by `view-lossage' to assert that the last keystrokes are always
  46 ;; visible.
  47 (defvar help-window-point-marker (make-marker)
  48   "Marker to override default `window-point' in help windows.")
  49
  50 (defvar help-window-old-frame nil
  51   "Frame selected at the time `with-help-window' is invoked.")
  52
  53 (defvar help-map
  54   (let ((map (make-sparse-keymap)))
  55     (define-key map (char-to-string help-char) 'help-for-help)
  56     (define-key map [help] 'help-for-help)
  57     (define-key map [f1] 'help-for-help)
  58     (define-key map "." 'display-local-help)
  59     (define-key map "?" 'help-for-help)
  60
  61     (define-key map "\C-a" 'about-emacs)
  62     (define-key map "\C-c" 'describe-copying)
  63     (define-key map "\C-d" 'view-emacs-debugging)
  64     (define-key map "\C-e" 'view-external-packages)
  65     (define-key map "\C-f" 'view-emacs-FAQ)
  66     (define-key map "\C-m" 'view-order-manuals)
  67     (define-key map "\C-n" 'view-emacs-news)
  68     (define-key map "\C-o" 'describe-distribution)
  69     (define-key map "\C-p" 'view-emacs-problems)
  70     (define-key map "\C-t" 'view-emacs-todo)
  71     (define-key map "\C-w" 'describe-no-warranty)
  72
  73     ;; This does not fit the pattern, but it is natural given the C-\ command.
  74     (define-key map "\C-\\" 'describe-input-method)
  75
  76     (define-key map "C" 'describe-coding-system)
  77     (define-key map "F" 'Info-goto-emacs-command-node)
  78     (define-key map "I" 'describe-input-method)
  79     (define-key map "K" 'Info-goto-emacs-key-command-node)
  80     (define-key map "L" 'describe-language-environment)
  81     (define-key map "S" 'info-lookup-symbol)
  82
  83     (define-key map "a" 'apropos-command)
  84     (define-key map "b" 'describe-bindings)
  85     (define-key map "c" 'describe-key-briefly)
  86     (define-key map "d" 'apropos-documentation)
  87     (define-key map "e" 'view-echo-area-messages)
  88     (define-key map "f" 'describe-function)
  89     (define-key map "g" 'describe-gnu-project)
  90     (define-key map "h" 'view-hello-file)
  91
  92     (define-key map "i" 'info)
  93     (define-key map "4i" 'info-other-window)
  94
  95     (define-key map "k" 'describe-key)
  96     (define-key map "l" 'view-lossage)
  97     (define-key map "m" 'describe-mode)
  98     (define-key map "o" 'describe-symbol)
  99     (define-key map "n" 'view-emacs-news)
 100     (define-key map "p" 'finder-by-keyword)
 101     (define-key map "P" 'describe-package)
 102     (define-key map "r" 'info-emacs-manual)
 103     (define-key map "s" 'describe-syntax)
 104     (define-key map "t" 'help-with-tutorial)
 105     (define-key map "w" 'where-is)
 106     (define-key map "v" 'describe-variable)
 107     (define-key map "q" 'help-quit)
 108     map)
 109   "Keymap for characters following the Help key.")
 110
 111 (define-key global-map (char-to-string help-char) 'help-command)
 112 (define-key global-map [help] 'help-command)
 113 (define-key global-map [f1] 'help-command)
 114 (fset 'help-command help-map)
 115
 116 ;; insert-button makes the action nil if it is not store somewhere
 117 (defvar help-button-cache nil)
 118
 119 \f
 120 (defun help-quit ()
 121   "Just exit from the Help command's command loop."
 122   (interactive)
 123   nil)
 124
 125 (defvar help-return-method nil
 126   "What to do to \"exit\" the help buffer.
 127 This is a list
 128  (WINDOW . t)              delete the selected window (and possibly its frame,
 129                            see `quit-window'), go to WINDOW.
 130  (WINDOW . quit-window)    do quit-window, then select WINDOW.
 131  (WINDOW BUF START POINT)  display BUF at START, POINT, then select WINDOW.")
 132
 133 (define-obsolete-function-alias 'print-help-return-message 'help-print-return-message "23.2")
 134 (defun help-print-return-message (&optional function)
 135   "Display or return message saying how to restore windows after help command.
 136 This function assumes that `standard-output' is the help buffer.
 137 It computes a message, and applies the optional argument FUNCTION to it.
 138 If FUNCTION is nil, it applies `message', thus displaying the message.
 139 In addition, this function sets up `help-return-method', which see, that
 140 specifies what to do when the user exits the help buffer.
 141
 142 Do not call this in the scope of `with-help-window'."
 143   (and (not (get-buffer-window standard-output))
 144        (let ((first-message
 145               (cond ((or
 146                       pop-up-frames
 147                       (special-display-p (buffer-name standard-output)))
 148                      (setq help-return-method (cons (selected-window) t))
 149                      ;; If the help output buffer is a special display buffer,
 150                      ;; don't say anything about how to get rid of it.
 151                      ;; First of all, the user will do that with the window
 152                      ;; manager, not with Emacs.
 153                      ;; Secondly, the buffer has not been displayed yet,
 154                      ;; so we don't know whether its frame will be selected.
 155                      nil)
 156                     ((not (one-window-p t))
 157                      (setq help-return-method
 158                            (cons (selected-window) 'quit-window))
 159                      "Type \\[display-buffer] RET to restore the other window.")
 160                     (pop-up-windows
 161                      (setq help-return-method (cons (selected-window) t))
 162                      "Type \\[delete-other-windows] to remove help window.")
 163                     (t
 164                      (setq help-return-method
 165                            (list (selected-window) (window-buffer)
 166                                  (window-start) (window-point)))
 167                      "Type \\[switch-to-buffer] RET to remove help window."))))
 168          (funcall (or function 'message)
 169                   (concat
 170                    (if first-message
 171                        (substitute-command-keys first-message))
 172                    (if first-message "  ")
 173                    ;; If the help buffer will go in a separate frame,
 174                    ;; it's no use mentioning a command to scroll, so don't.
 175                    (if (or pop-up-windows
 176                            (special-display-p (buffer-name standard-output)))
 177                        nil
 178                      (if (same-window-p (buffer-name standard-output))
 179                          ;; Say how to scroll this window.
 180                          (substitute-command-keys
 181                           "\\[scroll-up] to scroll the help.")
 182                        ;; Say how to scroll some other window.
 183                        (substitute-command-keys
 184                         "\\[scroll-other-window] to scroll the help."))))))))
 185
 186 ;; So keyboard macro definitions are documented correctly
 187 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 188
 189 (defalias 'help 'help-for-help-internal)
 190 ;; find-function can find this.
 191 (defalias 'help-for-help 'help-for-help-internal)
 192 ;; It can't find this, but nobody will look.
 193 (make-help-screen help-for-help-internal
 194   (purecopy "Type a help option: [abcCdefFgiIkKlLmnprstvw.] C-[cdefmnoptw] or ?")
 195   ;; Don't purecopy this one, because it's not evaluated (it's
 196   ;; directly used as a docstring in a function definition, so it'll
 197   ;; be moved to the DOC file anyway: no need for purecopying it).
 198   "You have typed %THIS-KEY%, the help character.  Type a Help option:
 199 \(Use SPC or DEL to scroll through this text.  Type \\<help-map>\\[help-quit] to exit the Help command.)
 200
 201 a PATTERN   Show commands whose name matches the PATTERN (a list of words
 202               or a regexp).  See also the `apropos' command.
 203 b           Display all key bindings.
 204 c KEYS      Display the command name run by the given key sequence.
 205 C CODING    Describe the given coding system, or RET for current ones.
 206 d PATTERN   Show a list of functions, variables, and other items whose
 207               documentation matches the PATTERN (a list of words or a regexp).
 208 e           Go to the *Messages* buffer which logs echo-area messages.
 209 f FUNCTION  Display documentation for the given function.
 210 F COMMAND   Show the Emacs manual's section that describes the command.
 211 g           Display information about the GNU project.
 212 h           Display the HELLO file which illustrates various scripts.
 213 i           Start the Info documentation reader: read included manuals.
 214 I METHOD    Describe a specific input method, or RET for current.
 215 k KEYS      Display the full documentation for the key sequence.
 216 K KEYS      Show the Emacs manual's section for the command bound to KEYS.
 217 l           Show last 300 input keystrokes (lossage).
 218 L LANG-ENV  Describes a specific language environment, or RET for current.
 219 m           Display documentation of current minor modes and current major mode,
 220               including their special commands.
 221 n           Display news of recent Emacs changes.
 222 o SYMBOL    Display the given function or variable's documentation and value.
 223 p TOPIC     Find packages matching a given topic keyword.
 224 P PACKAGE   Describe the given Emacs Lisp package.
 225 r           Display the Emacs manual in Info mode.
 226 s           Display contents of current syntax table, plus explanations.
 227 S SYMBOL    Show the section for the given symbol in the Info manual
 228               for the programming language used in this buffer.
 229 t           Start the Emacs learn-by-doing tutorial.
 230 v VARIABLE  Display the given variable's documentation and value.
 231 w COMMAND   Display which keystrokes invoke the given command (where-is).
 232 .           Display any available local help at point in the echo area.
 233
 234 C-a         Information about Emacs.
 235 C-c         Emacs copying permission (GNU General Public License).
 236 C-d         Instructions for debugging GNU Emacs.
 237 C-e         External packages and information about Emacs.
 238 C-f         Emacs FAQ.
 239 C-m         How to order printed Emacs manuals.
 240 C-n         News of recent Emacs changes.
 241 C-o         Emacs ordering and distribution information.
 242 C-p         Info about known Emacs problems.
 243 C-t         Emacs TODO list.
 244 C-w         Information on absence of warranty for GNU Emacs."
 245   help-map)
 246
 247 \f
 248
 249 (defun function-called-at-point ()
 250   "Return a function around point or else called by the list containing point.
 251 If that doesn't give a function, return nil."
 252   (with-syntax-table emacs-lisp-mode-syntax-table
 253     (or (condition-case ()
 254             (save-excursion
 255               (or (not (zerop (skip-syntax-backward "_w")))
 256                   (eq (char-syntax (following-char)) ?w)
 257                   (eq (char-syntax (following-char)) ?_)
 258                   (forward-sexp -1))
 259               (skip-chars-forward "'")
 260               (let ((obj (read (current-buffer))))
 261                 (and (symbolp obj) (fboundp obj) obj)))
 262           (error nil))
 263         (condition-case ()
 264             (save-excursion
 265               (save-restriction
 266                 (narrow-to-region (max (point-min)
 267                                        (- (point) 1000)) (point-max))
 268                 ;; Move up to surrounding paren, then after the open.
 269                 (backward-up-list 1)
 270                 (forward-char 1)
 271                 ;; If there is space here, this is probably something
 272                 ;; other than a real Lisp function call, so ignore it.
 273                 (if (looking-at "[ \t]")
 274                     (error "Probably not a Lisp function call"))
 275                 (let ((obj (read (current-buffer))))
 276                   (and (symbolp obj) (fboundp obj) obj))))
 277           (error nil))
 278         (let* ((str (find-tag-default))
 279                (sym (if str (intern-soft str))))
 280           (if (and sym (fboundp sym))
 281               sym
 282             (save-match-data
 283               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 284                 (setq sym (intern-soft (match-string 1 str)))
 285                 (and (fboundp sym) sym))))))))
 286
 287 \f
 288 ;;; `User' help functions
 289
 290 (defun view-help-file (file &optional dir)
 291   (view-file (expand-file-name file (or dir data-directory)))
 292   (goto-address-mode 1)
 293   (goto-char (point-min)))
 294
 295 (defun describe-distribution ()
 296   "Display info on how to obtain the latest version of GNU Emacs."
 297   (interactive)
 298   (view-help-file "DISTRIB"))
 299
 300 (defun describe-copying ()
 301   "Display info on how you may redistribute copies of GNU Emacs."
 302   (interactive)
 303   (view-help-file "COPYING"))
 304
 305 ;; Maybe this command should just be removed.
 306 (defun describe-gnu-project ()
 307   "Browse online information on the GNU project."
 308   (interactive)
 309   (browse-url "https://www.gnu.org/gnu/thegnuproject.html"))
 310
 311 (define-obsolete-function-alias 'describe-project 'describe-gnu-project "22.2")
 312
 313 (defun describe-no-warranty ()
 314   "Display info on all the kinds of warranty Emacs does NOT have."
 315   (interactive)
 316   (describe-copying)
 317   (let (case-fold-search)
 318     (search-forward "Disclaimer of Warranty")
 319     (forward-line 0)
 320     (recenter 0)))
 321
 322 (defun describe-prefix-bindings ()
 323   "Describe the bindings of the prefix used to reach this command.
 324 The prefix described consists of all but the last event
 325 of the key sequence that ran this command."
 326   (interactive)
 327   (let ((key (this-command-keys)))
 328     (describe-bindings
 329      (if (stringp key)
 330          (substring key 0 (1- (length key)))
 331        (let ((prefix (make-vector (1- (length key)) nil))
 332              (i 0))
 333          (while (< i (length prefix))
 334            (aset prefix i (aref key i))
 335            (setq i (1+ i)))
 336          prefix)))))
 337 ;; Make C-h after a prefix, when not specifically bound,
 338 ;; run describe-prefix-bindings.
 339 (setq prefix-help-command 'describe-prefix-bindings)
 340
 341 (defun view-emacs-news (&optional version)
 342   "Display info on recent changes to Emacs.
 343 With argument, display info only for the selected version."
 344   (interactive "P")
 345   (unless version
 346     (setq version emacs-major-version))
 347   (when (consp version)
 348     (let* ((all-versions
 349             (let (res)
 350               (mapc
 351                (lambda (file)
 352                  (with-temp-buffer
 353                    (insert-file-contents
 354                     (expand-file-name file data-directory))
 355                    (while (re-search-forward
 356                            (if (member file '("NEWS.18" "NEWS.1-17"))
 357                                "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 358                              "^\\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t)
 359                      (setq res (cons (match-string-no-properties 1) res)))))
 360                (cons "NEWS"
 361                      (directory-files data-directory nil
 362                                       "^NEWS\\.[0-9][-0-9]*$" nil)))
 363               (sort (delete-dups res) #'string>)))
 364            (current (car all-versions)))
 365       (setq version (completing-read
 366                      (format "Read NEWS for the version (default %s): " current)
 367                      all-versions nil nil nil nil current))
 368       (if (integerp (string-to-number version))
 369           (setq version (string-to-number version))
 370         (unless (or (member version all-versions)
 371                     (<= (string-to-number version) (string-to-number current)))
 372           (error "No news about version %s" version)))))
 373   (when (integerp version)
 374     (cond ((<= version 12)
 375            (setq version (format "1.%d" version)))
 376           ((<= version 18)
 377            (setq version (format "%d" version)))
 378           ((> version emacs-major-version)
 379            (error "No news about Emacs %d (yet)" version))))
 380   (let* ((vn (if (stringp version)
 381                  (string-to-number version)
 382                version))
 383          (file (cond
 384                 ((>= vn emacs-major-version) "NEWS")
 385                 ((< vn 18) "NEWS.1-17")
 386                 (t (format "NEWS.%d" vn))))
 387          res)
 388     (view-file (expand-file-name file data-directory))
 389     (widen)
 390     (goto-char (point-min))
 391     (when (stringp version)
 392       (when (re-search-forward
 393              (concat (if (< vn 19)
 394                          "Changes in Emacs[ \t]*"
 395                        "^\\* [^0-9\n]*") version "$")
 396              nil t)
 397         (beginning-of-line)
 398         (narrow-to-region
 399          (point)
 400          (save-excursion
 401            (while (and (setq res
 402                              (re-search-forward
 403                               (if (< vn 19)
 404                                   "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 405                                 "^\\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t))
 406                        (equal (match-string-no-properties 1) version)))
 407            (or res (goto-char (point-max)))
 408            (beginning-of-line)
 409            (point)))))))
 410
 411 (defun view-emacs-todo (&optional _arg)
 412   "Display the Emacs TODO list."
 413   (interactive "P")
 414   (view-help-file "TODO"))
 415
 416 (define-obsolete-function-alias 'view-todo 'view-emacs-todo "22.2")
 417
 418
 419 (defun view-echo-area-messages ()
 420   "View the log of recent echo-area messages: the `*Messages*' buffer.
 421 The number of messages retained in that buffer
 422 is specified by the variable `message-log-max'."
 423   (interactive)
 424   (with-current-buffer (messages-buffer)
 425     (goto-char (point-max))
 426     (display-buffer (current-buffer))))
 427
 428 (defun view-order-manuals ()
 429   "Display information on how to buy printed copies of Emacs manuals."
 430   (interactive)
 431 ;;  (view-help-file "ORDERS")
 432   (info "(emacs)Printed Books"))
 433
 434 (defun view-emacs-FAQ ()
 435   "Display the Emacs Frequently Asked Questions (FAQ) file."
 436   (interactive)
 437   ;; (find-file-read-only (expand-file-name "FAQ" data-directory))
 438   (info "(efaq)"))
 439
 440 (defun view-emacs-problems ()
 441   "Display info on known problems with Emacs and possible workarounds."
 442   (interactive)
 443   (view-help-file "PROBLEMS"))
 444
 445 (defun view-emacs-debugging ()
 446   "Display info on how to debug Emacs problems."
 447   (interactive)
 448   (view-help-file "DEBUG"))
 449
 450 ;; This used to visit MORE.STUFF; maybe it should just be removed.
 451 (defun view-external-packages ()
 452   "Display info on where to get more Emacs packages."
 453   (interactive)
 454   (info "(efaq)Packages that do not come with Emacs"))
 455
 456 (defun view-lossage ()
 457   "Display last few input keystrokes and the commands run.
 458
 459 To record all your input, use `open-dribble-file'."
 460   (interactive)
 461   (help-setup-xref (list #'view-lossage)
 462                    (called-interactively-p 'interactive))
 463   (with-help-window (help-buffer)
 464     (princ " ")
 465     (princ (mapconcat (lambda (key)
 466                         (cond
 467                          ((and (consp key) (null (car key)))
 468                           (format "[%s]\n" (if (symbolp (cdr key)) (cdr key)
 469                                            "anonymous-command")))
 470                          ((or (integerp key) (symbolp key) (listp key))
 471                           (single-key-description key))
 472                          (t
 473                           (prin1-to-string key nil))))
 474                       (recent-keys 'include-cmds)
 475                       " "))
 476     (with-current-buffer standard-output
 477       (goto-char (point-min))
 478       (while (not (eobp))
 479         (move-to-column 50)
 480         (unless (eolp)
 481           (fill-region (line-beginning-position) (line-end-position)))
 482         (forward-line 1))
 483       ;; jidanni wants to see the last keystrokes immediately.
 484       (set-marker help-window-point-marker (point)))))
 485
 486 \f
 487 ;; Key bindings
 488
 489 (defun describe-bindings (&optional prefix buffer)
 490   "Display a buffer showing a list of all defined keys, and their definitions.
 491 The keys are displayed in order of precedence.
 492
 493 The optional argument PREFIX, if non-nil, should be a key sequence;
 494 then we display only bindings that start with that prefix.
 495 The optional argument BUFFER specifies which buffer's bindings
 496 to display (default, the current buffer).  BUFFER can be a buffer
 497 or a buffer name."
 498   (interactive)
 499   (or buffer (setq buffer (current-buffer)))
 500   (help-setup-xref (list #'describe-bindings prefix buffer)
 501                    (called-interactively-p 'interactive))
 502   (with-help-window (help-buffer)
 503     ;; Be aware that `describe-buffer-bindings' puts its output into
 504     ;; the current buffer.
 505     (with-current-buffer (help-buffer)
 506       (describe-buffer-bindings buffer prefix))))
 507
 508 ;; This function used to be in keymap.c.
 509 (defun describe-bindings-internal (&optional menus prefix)
 510   "Show a list of all defined keys, and their definitions.
 511 We put that list in a buffer, and display the buffer.
 512
 513 The optional argument MENUS, if non-nil, says to mention menu bindings.
 514 \(Ordinarily these are omitted from the output.)
 515 The optional argument PREFIX, if non-nil, should be a key sequence;
 516 then we display only bindings that start with that prefix."
 517   (declare (obsolete describe-buffer-bindings "24.4"))
 518   (let ((buf (current-buffer)))
 519     (with-help-window (help-buffer)
 520       ;; Be aware that `describe-buffer-bindings' puts its output into
 521       ;; the current buffer.
 522       (with-current-buffer (help-buffer)
 523         (describe-buffer-bindings buf prefix menus)))))
 524
 525 (defun where-is (definition &optional insert)
 526   "Print message listing key sequences that invoke the command DEFINITION.
 527 Argument is a command definition, usually a symbol with a function definition.
 528 If INSERT (the prefix arg) is non-nil, insert the message in the buffer."
 529   (interactive
 530    (let ((fn (function-called-at-point))
 531          (enable-recursive-minibuffers t)
 532          val)
 533      (setq val (completing-read
 534                 (if fn
 535                     (format "Where is command (default %s): " fn)
 536                   "Where is command: ")
 537                 obarray 'commandp t nil nil
 538                 (and fn (symbol-name fn))))
 539      (list (unless (equal val "") (intern val))
 540            current-prefix-arg)))
 541   (unless definition (error "No command"))
 542   (let ((func (indirect-function definition))
 543         (defs nil)
 544         (standard-output (if insert (current-buffer) standard-output)))
 545     ;; In DEFS, find all symbols that are aliases for DEFINITION.
 546     (mapatoms (lambda (symbol)
 547                 (and (fboundp symbol)
 548                      (not (eq symbol definition))
 549                      (eq func (condition-case ()
 550                                   (indirect-function symbol)
 551                                 (error symbol)))
 552                      (push symbol defs))))
 553     ;; Look at all the symbols--first DEFINITION,
 554     ;; then its aliases.
 555     (dolist (symbol (cons definition defs))
 556       (let* ((remapped (command-remapping symbol))
 557              (keys (where-is-internal
 558                     symbol overriding-local-map nil nil remapped))
 559              (keys (mapconcat 'key-description keys ", "))
 560              string)
 561         (setq string
 562               (if insert
 563                   (if (> (length keys) 0)
 564                       (if remapped
 565                           (format "%s (%s) (remapped from %s)"
 566                                   keys remapped symbol)
 567                         (format "%s (%s)" keys symbol))
 568                     (format "M-x %s RET" symbol))
 569                 (if (> (length keys) 0)
 570                     (if remapped
 571                         (format "%s is remapped to %s which is on %s"
 572                                 symbol remapped keys)
 573                       (format "%s is on %s" symbol keys))
 574                   ;; If this is the command the user asked about,
 575                   ;; and it is not on any key, say so.
 576                   ;; For other symbols, its aliases, say nothing
 577                   ;; about them unless they are on keys.
 578                   (if (eq symbol definition)
 579                       (format "%s is not on any key" symbol)))))
 580         (when string
 581           (unless (eq symbol definition)
 582             (princ ";\n its alias "))
 583           (princ string)))))
 584   nil)
 585
 586 (defun help-key-description (key untranslated)
 587   (let ((string (key-description key)))
 588     (if (or (not untranslated)
 589             (and (eq (aref untranslated 0) ?\e) (not (eq (aref key 0) ?\e))))
 590         string
 591       (let ((otherstring (key-description untranslated)))
 592         (if (equal string otherstring)
 593             string
 594           (format "%s (translated from %s)" string otherstring))))))
 595
 596 (defun help--binding-undefined-p (defn)
 597   (or (null defn) (integerp defn) (equal defn 'undefined)))
 598
 599 (defun help--analyze-key (key untranslated)
 600   "Get information about KEY its corresponding UNTRANSLATED events.
 601 Returns a list of the form (BRIEF-DESC DEFN EVENT MOUSE-MSG)."
 602   (if (numberp untranslated)
 603       (error "Missing `untranslated'!"))
 604   (let* ((event (when (> (length key) 0)
 605                   (aref key (if (and (symbolp (aref key 0))
 606                                      (> (length key) 1)
 607                                      (consp (aref key 1)))
 608                                 ;; Look at the second event when the first
 609                                 ;; is a pseudo-event like `mode-line' or
 610                                 ;; `left-fringe'.
 611                                 1
 612                               0))))
 613          (modifiers (event-modifiers event))
 614          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 615                             (memq 'drag modifiers))
 616                         " at that spot" ""))
 617          (defn (key-binding key t)))
 618     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 619     (when (and (eq defn nil)
 620                (stringp (aref key (1- (length key))))
 621                (eq (key-binding (substring key 0 -1)) 'yank-menu))
 622       (setq defn 'menu-bar-select-yank))
 623     ;; Don't bother user with strings from (e.g.) the select-paste menu.
 624     (when (stringp (aref key (1- (length key))))
 625       (aset key (1- (length key)) "(any string)"))
 626     (when (and untranslated
 627                (stringp (aref untranslated (1- (length untranslated)))))
 628       (aset untranslated (1- (length untranslated)) "(any string)"))
 629     (list
 630      ;; Now describe the key, perhaps as changed.
 631      (let ((key-desc (help-key-description key untranslated)))
 632        (if (help--binding-undefined-p defn)
 633            (format "%s%s is undefined" key-desc mouse-msg)
 634          (format "%s%s runs the command %S" key-desc mouse-msg defn)))
 635      defn event mouse-msg)))
 636
 637 (defun help--filter-info-list (info-list i)
 638   "Drop the undefined keys."
 639   (or
 640    ;; Remove all `undefined' keys.
 641    (delq nil (mapcar (lambda (x)
 642                        (unless (help--binding-undefined-p (nth i x)) x))
 643                      info-list))
 644    ;; If nothing left, then keep one (the last one).
 645    (last info-list)))
 646
 647 (defun describe-key-briefly (&optional key-list insert untranslated)
 648   "Print the name of the functions KEY-LIST invokes.
 649 KEY-LIST is a list of pairs (SEQ . RAW-SEQ) of key sequences, where
 650 RAW-SEQ is the untranslated form of the key sequence SEQ.
 651 If INSERT (the prefix arg) is non-nil, insert the message in the buffer.
 652
 653 While reading KEY-LIST interactively, this command temporarily enables
 654 menu items or tool-bar buttons that are disabled to allow getting help
 655 on them."
 656   (declare (advertised-calling-convention (key-list &optional insert) "27.1"))
 657   (interactive
 658    ;; Ignore mouse movement events because it's too easy to miss the
 659    ;; message while moving the mouse.
 660    (let ((key-list (help--read-key-sequence 'no-mouse-movement)))
 661      `(,key-list ,current-prefix-arg)))
 662   (when (arrayp key-list)
 663     ;; Old calling convention, changed
 664     (setq key-list (list (cons key-list
 665                                (if (numberp untranslated)
 666                                    (this-single-command-raw-keys)
 667                                  untranslated)))))
 668   (let* ((info-list (mapcar (lambda (kr)
 669                               (help--analyze-key (car kr) (cdr kr)))
 670                             key-list))
 671          (msg (mapconcat #'car (help--filter-info-list info-list 1) "\n")))
 672     (if insert (insert msg) (message "%s" msg))))
 673
 674 (defun help--key-binding-keymap (key &optional accept-default no-remap position)
 675   "Return a keymap holding a binding for KEY within current keymaps.
 676 The effect of the arguments KEY, ACCEPT-DEFAULT, NO-REMAP and
 677 POSITION is as documented in the function `key-binding'."
 678   (let* ((active-maps (current-active-maps t position))
 679          map found)
 680     ;; We loop over active maps like key-binding does.
 681     (while (and
 682             (not found)
 683             (setq map (pop active-maps)))
 684       (setq found (lookup-key map key accept-default))
 685       (when (integerp found)
 686         ;; The first `found' characters of KEY were found but not the
 687         ;; whole sequence.
 688         (setq found nil)))
 689     (when found
 690       (if (and (symbolp found)
 691                (not no-remap)
 692                (command-remapping found))
 693           ;; The user might want to know in which map the binding is
 694           ;; found, or in which map the remapping is found.  The
 695           ;; default is to show the latter.
 696           (help--key-binding-keymap (vector 'remap found))
 697         map))))
 698
 699 (defun help--binding-locus (key position)
 700   "Describe in which keymap KEY is defined.
 701 Return a symbol pointing to that keymap if one exists ; otherwise
 702 return nil.  The argument POSITION is as documented in the
 703 function `key-binding'."
 704   (let ((map (help--key-binding-keymap key t nil position)))
 705     (when map
 706       (catch 'found
 707         (let ((advertised-syms (nconc
 708                                 (list 'overriding-terminal-local-map
 709                                       'overriding-local-map)
 710                                 (delq nil
 711                                       (mapcar
 712                                        (lambda (mode-and-map)
 713                                          (let ((mode (car mode-and-map)))
 714                                            (when (symbol-value mode)
 715                                              (intern-soft
 716                                               (format "%s-map" mode)))))
 717                                        minor-mode-map-alist))
 718                                 (list 'global-map
 719                                       (intern-soft (format "%s-map" major-mode))))))
 720           ;; Look into these advertised symbols first.
 721           (dolist (sym advertised-syms)
 722             (when (and
 723                    (boundp sym)
 724                    (eq map (symbol-value sym)))
 725               (throw 'found sym)))
 726           ;; Only look in other symbols otherwise.
 727           (mapatoms
 728            (lambda (x)
 729              (when (and (boundp x)
 730                         ;; Avoid let-bound symbols.
 731                         (special-variable-p x)
 732                         (eq (symbol-value x) map))
 733                (throw 'found x))))
 734           nil)))))
 735
 736 (defun help--read-key-sequence (&optional no-mouse-movement)
 737   "Read a key sequence from the user.
 738 Usually reads a single key sequence, except when that sequence might
 739 hide another one (e.g. a down event, where the user is interested
 740 in getting info about the up event, or a click event, where the user
 741 wants to get info about the double click).
 742 Return a list of elements of the form (SEQ . RAW-SEQ), where SEQ is a key
 743 sequence, and RAW-SEQ is its untranslated form.
 744 If NO-MOUSE-MOVEMENT is non-nil, ignore key sequences starting
 745 with `mouse-movement' events."
 746   (let ((enable-disabled-menus-and-buttons t)
 747         (cursor-in-echo-area t)
 748         saved-yank-menu)
 749     (unwind-protect
 750         (let (last-modifiers key-list)
 751           ;; If yank-menu is empty, populate it temporarily, so that
 752           ;; "Select and Paste" menu can generate a complete event.
 753           (when (null (cdr yank-menu))
 754             (setq saved-yank-menu (copy-sequence yank-menu))
 755             (menu-bar-update-yank-menu "(any string)" nil))
 756           (while
 757               ;; Read at least one key-sequence.
 758               (or (null key-list)
 759                   ;; After a down event, also read the (presumably) following
 760                   ;; up-event.
 761                   (memq 'down last-modifiers)
 762                   ;; After a click, see if a double click is on the way.
 763                   (and (memq 'click last-modifiers)
 764                        (not (sit-for (/ double-click-time 1000.0) t))))
 765             (let* ((seq (read-key-sequence "\
 766 Describe the following key, mouse click, or menu item: "))
 767                    (raw-seq (this-single-command-raw-keys))
 768                    (keyn (when (> (length seq) 0)
 769                            (aref seq (1- (length seq)))))
 770                    (base (event-basic-type keyn))
 771                    (modifiers (event-modifiers keyn)))
 772               (cond
 773                ((zerop (length seq)))   ;FIXME: Can this happen?
 774                ((and no-mouse-movement (eq base 'mouse-movement)) nil)
 775                ((eq base 'help-echo) nil)
 776                (t
 777                 (setq last-modifiers modifiers)
 778                 (push (cons seq raw-seq) key-list)))))
 779           (nreverse key-list))
 780       ;; Put yank-menu back as it was, if we changed it.
 781       (when saved-yank-menu
 782         (setq yank-menu (copy-sequence saved-yank-menu))
 783         (fset 'yank-menu (cons 'keymap yank-menu))))))
 784
 785 (defun describe-key (&optional key-list buffer up-event)
 786   "Display documentation of the function invoked by KEY-LIST.
 787 KEY-LIST can be any kind of a key sequence; it can include keyboard events,
 788 mouse events, and/or menu events.  When calling from a program,
 789 pass KEY-LIST as a list of elements (SEQ . RAW-SEQ) where SEQ is
 790 a key-sequence and RAW-SEQ is its untranslated form.
 791
 792 While reading KEY-LIST interactively, this command temporarily enables
 793 menu items or tool-bar buttons that are disabled to allow getting help
 794 on them.
 795
 796 BUFFER is the buffer in which to lookup those keys; it defaults to the
 797 current buffer."
 798   (declare (advertised-calling-convention (key-list &optional buffer) "27.1"))
 799   (interactive (list (help--read-key-sequence)))
 800   (when (arrayp key-list)
 801     ;; Compatibility with old calling convention.
 802     (setq key-list (cons (list key-list) (if up-event (list up-event))))
 803     (when buffer
 804       (let ((raw (if (numberp buffer) (this-single-command-raw-keys) buffer)))
 805         (setf (cdar (last key-list)) raw)))
 806     (setq buffer nil))
 807   (let* ((buf (or buffer (current-buffer)))
 808          (on-link
 809           (mapcar (lambda (kr)
 810                     (let ((raw (cdr kr)))
 811                       (and (not (memq mouse-1-click-follows-link '(nil double)))
 812                            (> (length raw) 0)
 813                            (eq (car-safe (aref raw 0)) 'mouse-1)
 814                            (with-current-buffer buf
 815                              (mouse-on-link-p (event-start (aref raw 0)))))))
 816                   key-list))
 817          (info-list
 818           (help--filter-info-list
 819            (with-current-buffer buf
 820              (mapcar (lambda (x)
 821                        (pcase-let* ((`(,seq . ,raw-seq) x)
 822                                     (`(,brief-desc ,defn ,event ,_mouse-msg)
 823                                      (help--analyze-key seq raw-seq))
 824                                     (locus
 825                                      (help--binding-locus
 826                                       seq (event-start event))))
 827                          `(,seq ,brief-desc ,defn ,locus)))
 828                      key-list))
 829            2)))
 830     (help-setup-xref (list (lambda (key-list buf)
 831                              (describe-key key-list
 832                                            (if (buffer-live-p buf) buf)))
 833                            key-list buf)
 834                      (called-interactively-p 'interactive))
 835     (if (and (<= (length info-list) 1)
 836              (help--binding-undefined-p (nth 2 (car info-list))))
 837         (message "%s" (nth 1 (car info-list)))
 838       (with-help-window (help-buffer)
 839         (when (> (length info-list) 1)
 840           ;; FIXME: Make this into clickable hyperlinks.
 841           (princ "There were several key-sequences:\n\n")
 842           (princ (mapconcat (lambda (info)
 843                               (pcase-let ((`(,_seq ,brief-desc ,_defn ,_locus)
 844                                            info))
 845                                 (concat "  " brief-desc)))
 846                             info-list
 847                             "\n"))
 848           (when (delq nil on-link)
 849             (princ "\n\nThose are influenced by `mouse-1-click-follows-link'"))
 850           (princ "\n\nThey're all described below."))
 851         (pcase-dolist (`(,_seq ,brief-desc ,defn ,locus)
 852                        info-list)
 853           (when defn
 854             (when (> (length info-list) 1)
 855               (with-current-buffer standard-output
 856                 (insert "\n\n"
 857                         ;; FIXME: Can't use eval-when-compile because purified
 858                         ;; strings lose their text properties :-(
 859                         (propertize "\n" 'face '(:height 0.1 :inverse-video t))
 860                         "\n")))
 861
 862             (princ brief-desc)
 863             (when locus
 864               (princ (format " (found in %s)" locus)))
 865             (princ ", which is ")
 866             (describe-function-1 defn)))))))
 867 \f
 868 (defun describe-mode (&optional buffer)
 869   "Display documentation of current major mode and minor modes.
 870 A brief summary of the minor modes comes first, followed by the
 871 major mode description.  This is followed by detailed
 872 descriptions of the minor modes, each on a separate page.
 873
 874 For this to work correctly for a minor mode, the mode's indicator
 875 variable \(listed in `minor-mode-alist') must also be a function
 876 whose documentation describes the minor mode.
 877
 878 If called from Lisp with a non-nil BUFFER argument, display
 879 documentation for the major and minor modes of that buffer."
 880   (interactive "@")
 881   (unless buffer (setq buffer (current-buffer)))
 882   (help-setup-xref (list #'describe-mode buffer)
 883                    (called-interactively-p 'interactive))
 884   ;; For the sake of help-do-xref and help-xref-go-back,
 885   ;; don't switch buffers before calling `help-buffer'.
 886   (with-help-window (help-buffer)
 887     (with-current-buffer buffer
 888       (let (minor-modes)
 889         ;; Older packages do not register in minor-mode-list but only in
 890         ;; minor-mode-alist.
 891         (dolist (x minor-mode-alist)
 892           (setq x (car x))
 893           (unless (memq x minor-mode-list)
 894             (push x minor-mode-list)))
 895         ;; Find enabled minor mode we will want to mention.
 896         (dolist (mode minor-mode-list)
 897           ;; Document a minor mode if it is listed in minor-mode-alist,
 898           ;; non-nil, and has a function definition.
 899           (let ((fmode (or (get mode :minor-mode-function) mode)))
 900             (and (boundp mode) (symbol-value mode)
 901                  (fboundp fmode)
 902                  (let ((pretty-minor-mode
 903                         (if (string-match "\\(\\(-minor\\)?-mode\\)?\\'"
 904                                           (symbol-name fmode))
 905                             (capitalize
 906                              (substring (symbol-name fmode)
 907                                         0 (match-beginning 0)))
 908                           fmode)))
 909                    (push (list fmode pretty-minor-mode
 910                                (format-mode-line (assq mode minor-mode-alist)))
 911                          minor-modes)))))
 912         (setq minor-modes
 913               (sort minor-modes
 914                     (lambda (a b) (string-lessp (cadr a) (cadr b)))))
 915         (when minor-modes
 916           (princ "Enabled minor modes:\n")
 917           (make-local-variable 'help-button-cache)
 918           (with-current-buffer standard-output
 919             (dolist (mode minor-modes)
 920               (let ((mode-function (nth 0 mode))
 921                     (pretty-minor-mode (nth 1 mode))
 922                     (indicator (nth 2 mode)))
 923                 (save-excursion
 924                   (goto-char (point-max))
 925                   (princ "\n\f\n")
 926                   (push (point-marker) help-button-cache)
 927                   ;; Document the minor modes fully.
 928                   (insert-text-button
 929                    pretty-minor-mode 'type 'help-function
 930                    'help-args (list mode-function)
 931                    'button '(t))
 932                   (princ (format " minor mode (%s):\n"
 933                                  (if (zerop (length indicator))
 934                                      "no indicator"
 935                                    (format "indicator%s"
 936                                            indicator))))
 937                   (princ (documentation mode-function)))
 938                 (insert-button pretty-minor-mode
 939                                'action (car help-button-cache)
 940                                'follow-link t
 941                                'help-echo "mouse-2, RET: show full information")
 942                 (newline)))
 943             (forward-line -1)
 944             (fill-paragraph nil)
 945             (forward-line 1))
 946
 947           (princ "\n(Information about these minor modes follows the major mode info.)\n\n"))
 948         ;; Document the major mode.
 949         (let ((mode mode-name))
 950           (with-current-buffer standard-output
 951             (let ((start (point)))
 952               (insert (format-mode-line mode nil nil buffer))
 953               (add-text-properties start (point) '(face bold)))))
 954         (princ " mode")
 955         (let* ((mode major-mode)
 956                (file-name (find-lisp-object-file-name mode nil)))
 957           (when file-name
 958             (princ (format-message " defined in `%s'"
 959                                    (file-name-nondirectory file-name)))
 960             ;; Make a hyperlink to the library.
 961             (with-current-buffer standard-output
 962               (save-excursion
 963                 (re-search-backward (substitute-command-keys "`\\([^`']+\\)'")
 964                                     nil t)
 965                 (help-xref-button 1 'help-function-def mode file-name)))))
 966         (princ ":\n")
 967         (princ (documentation major-mode)))))
 968   ;; For the sake of IELM and maybe others
 969   nil)
 970
 971
 972 (defun describe-minor-mode (minor-mode)
 973   "Display documentation of a minor mode given as MINOR-MODE.
 974 MINOR-MODE can be a minor mode symbol or a minor mode indicator string
 975 appeared on the mode-line."
 976   (interactive (list (completing-read
 977                       "Minor mode: "
 978                               (nconc
 979                                (describe-minor-mode-completion-table-for-symbol)
 980                                (describe-minor-mode-completion-table-for-indicator)
 981                                ))))
 982   (if (symbolp minor-mode)
 983       (setq minor-mode (symbol-name minor-mode)))
 984   (let ((symbols (describe-minor-mode-completion-table-for-symbol))
 985         (indicators (describe-minor-mode-completion-table-for-indicator)))
 986     (cond
 987      ((member minor-mode symbols)
 988       (describe-minor-mode-from-symbol (intern minor-mode)))
 989      ((member minor-mode indicators)
 990       (describe-minor-mode-from-indicator minor-mode))
 991      (t
 992       (error "No such minor mode: %s" minor-mode)))))
 993
 994 ;; symbol
 995 (defun describe-minor-mode-completion-table-for-symbol ()
 996   ;; In order to list up all minor modes, minor-mode-list
 997   ;; is used here instead of minor-mode-alist.
 998   (delq nil (mapcar 'symbol-name minor-mode-list)))
 999
1000 (defun describe-minor-mode-from-symbol (symbol)
1001   "Display documentation of a minor mode given as a symbol, SYMBOL"
1002   (interactive (list (intern (completing-read
1003                               "Minor mode symbol: "
1004                               (describe-minor-mode-completion-table-for-symbol)))))
1005   (if (fboundp symbol)
1006       (describe-function symbol)
1007     (describe-variable symbol)))
1008
1009 ;; indicator
1010 (defun describe-minor-mode-completion-table-for-indicator ()
1011   (delq nil
1012         (mapcar (lambda (x)
1013                   (let ((i (format-mode-line x)))
1014                     ;; remove first space if existed
1015                     (cond
1016                      ((= 0 (length i))
1017                       nil)
1018                      ((eq (aref i 0) ?\s)
1019                       (substring i 1))
1020                      (t
1021                       i))))
1022                 minor-mode-alist)))
1023
1024 (defun describe-minor-mode-from-indicator (indicator)
1025   "Display documentation of a minor mode specified by INDICATOR.
1026 If you call this function interactively, you can give indicator which
1027 is currently activated with completion."
1028   (interactive (list
1029                 (completing-read
1030                  "Minor mode indicator: "
1031                  (describe-minor-mode-completion-table-for-indicator))))
1032   (let ((minor-mode (lookup-minor-mode-from-indicator indicator)))
1033     (if minor-mode
1034         (describe-minor-mode-from-symbol minor-mode)
1035       (error "Cannot find minor mode for `%s'" indicator))))
1036
1037 (defun lookup-minor-mode-from-indicator (indicator)
1038   "Return a minor mode symbol from its indicator on the mode line."
1039   ;; remove first space if existed
1040   (if (and (< 0 (length indicator))
1041            (eq (aref indicator 0) ?\s))
1042       (setq indicator (substring indicator 1)))
1043   (let ((minor-modes minor-mode-alist)
1044         result)
1045     (while minor-modes
1046       (let* ((minor-mode (car (car minor-modes)))
1047              (anindicator (format-mode-line
1048                            (car (cdr (car minor-modes))))))
1049         ;; remove first space if existed
1050         (if (and (stringp anindicator)
1051                  (> (length anindicator) 0)
1052                  (eq (aref anindicator 0) ?\s))
1053             (setq anindicator (substring anindicator 1)))
1054         (if (equal indicator anindicator)
1055             (setq result minor-mode
1056                   minor-modes nil)
1057           (setq minor-modes (cdr minor-modes)))))
1058     result))
1059 \f
1060 ;;; Automatic resizing of temporary buffers.
1061 (defcustom temp-buffer-max-height
1062   (lambda (_buffer)
1063     (if (and (display-graphic-p) (eq (selected-window) (frame-root-window)))
1064         (/ (x-display-pixel-height) (frame-char-height) 2)
1065       (/ (- (frame-height) 2) 2)))
1066   "Maximum height of a window displaying a temporary buffer.
1067 This is effective only when Temp Buffer Resize mode is enabled.
1068 The value is the maximum height (in lines) which
1069 `resize-temp-buffer-window' will give to a window displaying a
1070 temporary buffer.  It can also be a function to be called to
1071 choose the height for such a buffer.  It gets one argument, the
1072 buffer, and should return a positive integer.  At the time the
1073 function is called, the window to be resized is selected."
1074   :type '(choice integer function)
1075   :group 'help
1076   :version "24.3")
1077
1078 (defcustom temp-buffer-max-width
1079   (lambda (_buffer)
1080     (if (and (display-graphic-p) (eq (selected-window) (frame-root-window)))
1081         (/ (x-display-pixel-width) (frame-char-width) 2)
1082       (/ (- (frame-width) 2) 2)))
1083   "Maximum width of a window displaying a temporary buffer.
1084 This is effective only when Temp Buffer Resize mode is enabled.
1085 The value is the maximum width (in columns) which
1086 `resize-temp-buffer-window' will give to a window displaying a
1087 temporary buffer.  It can also be a function to be called to
1088 choose the width for such a buffer.  It gets one argument, the
1089 buffer, and should return a positive integer.  At the time the
1090 function is called, the window to be resized is selected."
1091   :type '(choice integer function)
1092   :group 'help
1093   :version "24.4")
1094
1095 (define-minor-mode temp-buffer-resize-mode
1096   "Toggle auto-resizing temporary buffer windows (Temp Buffer Resize Mode).
1097 With a prefix argument ARG, enable Temp Buffer Resize mode if ARG
1098 is positive, and disable it otherwise.  If called from Lisp,
1099 enable the mode if ARG is omitted or nil.
1100
1101 When Temp Buffer Resize mode is enabled, the windows in which we
1102 show a temporary buffer are automatically resized in height to
1103 fit the buffer's contents, but never more than
1104 `temp-buffer-max-height' nor less than `window-min-height'.
1105
1106 A window is resized only if it has been specially created for the
1107 buffer.  Windows that have shown another buffer before are not
1108 resized.  A frame is resized only if `fit-frame-to-buffer' is
1109 non-nil.
1110
1111 This mode is used by `help', `apropos' and `completion' buffers,
1112 and some others."
1113   :global t :group 'help
1114   (if temp-buffer-resize-mode
1115       ;; `help-make-xrefs' may add a `back' button and thus increase the
1116       ;; text size, so `resize-temp-buffer-window' must be run *after* it.
1117       (add-hook 'temp-buffer-show-hook 'resize-temp-buffer-window 'append)
1118     (remove-hook 'temp-buffer-show-hook 'resize-temp-buffer-window)))
1119
1120 (defun resize-temp-buffer-window (&optional window)
1121   "Resize WINDOW to fit its contents.
1122 WINDOW must be a live window and defaults to the selected one.
1123 Do not resize if WINDOW was not created by `display-buffer'.
1124
1125 If WINDOW is part of a vertical combination, restrain its new
1126 size by `temp-buffer-max-height' and do not resize if its minimum
1127 accessible position is scrolled out of view.  If WINDOW is part
1128 of a horizontal combination, restrain its new size by
1129 `temp-buffer-max-width'.  In both cases, the value of the option
1130 `fit-window-to-buffer-horizontally' can inhibit resizing.
1131
1132 If WINDOW is the root window of its frame, resize the frame
1133 provided `fit-frame-to-buffer' is non-nil.
1134
1135 This function may call `preserve-window-size' to preserve the
1136 size of WINDOW."
1137   (setq window (window-normalize-window window t))
1138   (let ((height (if (functionp temp-buffer-max-height)
1139                     (with-selected-window window
1140                       (funcall temp-buffer-max-height (window-buffer)))
1141                   temp-buffer-max-height))
1142         (width (if (functionp temp-buffer-max-width)
1143                    (with-selected-window window
1144                      (funcall temp-buffer-max-width (window-buffer)))
1145                  temp-buffer-max-width))
1146         (quit-cadr (cadr (window-parameter window 'quit-restore))))
1147     ;; Resize WINDOW iff it was made by `display-buffer'.
1148     (when (or (and (eq quit-cadr 'window)
1149                    (or (and (window-combined-p window)
1150                             (not (eq fit-window-to-buffer-horizontally
1151                                      'only))
1152                             (pos-visible-in-window-p (point-min) window))
1153                        (and (window-combined-p window t)
1154                             fit-window-to-buffer-horizontally)))
1155               (and (eq quit-cadr 'frame)
1156                    fit-frame-to-buffer
1157                    (eq window (frame-root-window window))))
1158         (fit-window-to-buffer window height nil width nil t))))
1159
1160 ;;; Help windows.
1161 (defcustom help-window-select nil
1162   "Non-nil means select help window for viewing.
1163 Choices are:
1164
1165  never (nil) Select help window only if there is no other window
1166              on its frame.
1167
1168  other       Select help window if and only if it appears on the
1169              previously selected frame, that frame contains at
1170              least two other windows and the help window is
1171              either new or showed a different buffer before.
1172
1173  always (t)  Always select the help window.
1174
1175 If this option is non-nil and the help window appears on another
1176 frame, then give that frame input focus too.  Note also that if
1177 the help window appears on another frame, it may get selected and
1178 its frame get input focus even if this option is nil.
1179
1180 This option has effect if and only if the help window was created
1181 by `with-help-window'."
1182   :type '(choice (const :tag "never (nil)" nil)
1183                  (const :tag "other" other)
1184                  (const :tag "always (t)" t))
1185   :group 'help
1186   :version "23.1")
1187
1188 (defcustom help-enable-auto-load t
1189   "Whether Help commands can perform autoloading.
1190 If non-nil, whenever \\[describe-function] is called for an
1191 autoloaded function whose docstring contains any key substitution
1192 construct (see `substitute-command-keys'), the library is loaded,
1193 so that the documentation can show the right key bindings."
1194   :type 'boolean
1195   :group 'help
1196   :version "24.3")
1197
1198 (defun help-window-display-message (quit-part window &optional scroll)
1199   "Display message telling how to quit and scroll help window.
1200 QUIT-PART is a string telling how to quit the help window WINDOW.
1201 Optional argument SCROLL non-nil means tell how to scroll WINDOW.
1202 SCROLL equal `other' means tell how to scroll the \"other\"
1203 window."
1204   (let ((scroll-part
1205          (cond
1206           ;; If we don't have QUIT-PART we probably reuse a window
1207           ;; showing the same buffer so we don't show any message.
1208           ((not quit-part) nil)
1209           ((pos-visible-in-window-p
1210             (with-current-buffer (window-buffer window)
1211               (point-max)) window t)
1212            ;; Buffer end is at least partially visible, no need to talk
1213            ;; about scrolling.
1214            ".")
1215           ((eq scroll 'other)
1216            ", \\[scroll-other-window] to scroll help.")
1217           (scroll ", \\[scroll-up] to scroll help."))))
1218     (message "%s"
1219      (substitute-command-keys (concat quit-part scroll-part)))))
1220
1221 (defun help-window-setup (window &optional value)
1222   "Set up help window WINDOW for `with-help-window'.
1223 WINDOW is the window used for displaying the help buffer.
1224 Return VALUE."
1225   (let* ((help-buffer (when (window-live-p window)
1226                         (window-buffer window)))
1227          (help-setup (when (window-live-p window)
1228                        (car (window-parameter window 'quit-restore))))
1229          (frame (window-frame window)))
1230
1231     (when help-buffer
1232       ;; Handle `help-window-point-marker'.
1233       (when (eq (marker-buffer help-window-point-marker) help-buffer)
1234         (set-window-point window help-window-point-marker)
1235         ;; Reset `help-window-point-marker'.
1236         (set-marker help-window-point-marker nil))
1237
1238       ;; If the help window appears on another frame, select it if
1239       ;; `help-window-select' is non-nil and give that frame input focus
1240       ;; too.  See also Bug#19012.
1241       (when (and help-window-select
1242                  (frame-live-p help-window-old-frame)
1243                  (not (eq frame help-window-old-frame)))
1244         (select-window window)
1245         (select-frame-set-input-focus frame))
1246
1247       (cond
1248        ((or (eq window (selected-window))
1249             ;; If the help window is on the selected frame, select
1250             ;; it if `help-window-select' is t or `help-window-select'
1251             ;; is 'other, the frame contains at least three windows, and
1252             ;; the help window did show another buffer before.  See also
1253             ;; Bug#11039.
1254             (and (eq frame (selected-frame))
1255                  (or (eq help-window-select t)
1256                      (and (eq help-window-select 'other)
1257                           (> (length (window-list nil 'no-mini)) 2)
1258                           (not (eq help-setup 'same))))
1259                  (select-window window)))
1260         ;; The help window is or gets selected ...
1261         (help-window-display-message
1262          (cond
1263           ((eq help-setup 'window)
1264            ;; ... and is new, ...
1265            "Type \"q\" to delete help window")
1266           ((eq help-setup 'frame)
1267            ;; ... on a new frame, ...
1268            "Type \"q\" to quit the help frame")
1269           ((eq help-setup 'other)
1270            ;; ... or displayed some other buffer before.
1271            "Type \"q\" to restore previous buffer"))
1272          window t))
1273        ((and (eq (window-frame window) help-window-old-frame)
1274              (= (length (window-list nil 'no-mini)) 2))
1275         ;; There are two windows on the help window's frame and the
1276         ;; other one is the selected one.
1277         (help-window-display-message
1278          (cond
1279           ((eq help-setup 'window)
1280            "Type \\[delete-other-windows] to delete the help window")
1281           ((eq help-setup 'other)
1282            "Type \"q\" in help window to restore its previous buffer"))
1283          window 'other))
1284        (t
1285         ;; The help window is not selected ...
1286         (help-window-display-message
1287          (cond
1288           ((eq help-setup 'window)
1289            ;; ... and is new, ...
1290            "Type \"q\" in help window to delete it")
1291           ((eq help-setup 'other)
1292            ;; ... or displayed some other buffer before.
1293            "Type \"q\" in help window to restore previous buffer"))
1294          window))))
1295     ;; Return VALUE.
1296     value))
1297
1298 ;; `with-help-window' is a wrapper for `with-temp-buffer-window'
1299 ;; providing the following additional twists:
1300
1301 ;; (1) It puts the buffer in `help-mode' (via `help-mode-setup') and
1302 ;;     adds cross references (via `help-mode-finish').
1303
1304 ;; (2) It issues a message telling how to scroll and quit the help
1305 ;;     window (via `help-window-setup').
1306
1307 ;; (3) An option (customizable via `help-window-select') to select the
1308 ;;     help window automatically.
1309
1310 ;; (4) A marker (`help-window-point-marker') to move point in the help
1311 ;;     window to an arbitrary buffer position.
1312 (defmacro with-help-window (buffer-name &rest body)
1313   "Display buffer named BUFFER-NAME in a help window.
1314 Evaluate the forms in BODY with standard output bound to a buffer
1315 called BUFFER-NAME (creating it if it does not exist), put that
1316 buffer in `help-mode', display the buffer in a window (see
1317 `with-temp-buffer-window' for details) and issue a message how to
1318 deal with that \"help\" window when it's no more needed.  Select
1319 the help window if the current value of the user option
1320 `help-window-select' says so.  Return last value in BODY."
1321   (declare (indent 1) (debug t))
1322   `(progn
1323      ;; Make `help-window-point-marker' point nowhere.  The only place
1324      ;; where this should be set to a buffer position is within BODY.
1325      (set-marker help-window-point-marker nil)
1326      (let ((temp-buffer-window-setup-hook
1327             (cons 'help-mode-setup temp-buffer-window-setup-hook))
1328            (temp-buffer-window-show-hook
1329             (cons 'help-mode-finish temp-buffer-window-show-hook)))
1330        (setq help-window-old-frame (selected-frame))
1331        (with-temp-buffer-window
1332         ,buffer-name nil 'help-window-setup (progn ,@body)))))
1333
1334 ;; Called from C, on encountering `help-char' when reading a char.
1335 ;; Don't print to *Help*; that would clobber Help history.
1336 (defun help-form-show ()
1337   "Display the output of a non-nil `help-form'."
1338   (let ((msg (eval help-form)))
1339     (if (stringp msg)
1340         (with-output-to-temp-buffer " *Char Help*"
1341           (princ msg)))))
1342
1343 \f
1344 (defun help--docstring-quote (string)
1345   "Return a doc string that represents STRING.
1346 The result, when formatted by `substitute-command-keys', should equal STRING."
1347   (replace-regexp-in-string "['\\`‘’]" "\\\\=\\&" string))
1348
1349 ;; The following functions used to be in help-fns.el, which is not preloaded.
1350 ;; But for various reasons, they are more widely needed, so they were
1351 ;; moved to this file, which is preloaded.  https://debbugs.gnu.org/17001
1352
1353 (defun help-split-fundoc (docstring def)
1354   "Split a function DOCSTRING into the actual doc and the usage info.
1355 Return (USAGE . DOC) or nil if there's no usage info, where USAGE info
1356 is a string describing the argument list of DEF, such as
1357 \"(apply FUNCTION &rest ARGUMENTS)\".
1358 DEF is the function whose usage we're looking for in DOCSTRING."
1359   ;; Functions can get the calling sequence at the end of the doc string.
1360   ;; In cases where `function' has been fset to a subr we can't search for
1361   ;; function's name in the doc string so we use `fn' as the anonymous
1362   ;; function name instead.
1363   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
1364     (let ((doc (unless (zerop (match-beginning 0))
1365                  (substring docstring 0 (match-beginning 0))))
1366           (usage-tail (match-string 1 docstring)))
1367       (cons (format "(%s%s"
1368                     ;; Replace `fn' with the actual function name.
1369                     (if (symbolp def)
1370                         (help--docstring-quote (format "%S" def))
1371                       'anonymous)
1372                     usage-tail)
1373             doc))))
1374
1375 (defun help-add-fundoc-usage (docstring arglist)
1376   "Add the usage info to DOCSTRING.
1377 If DOCSTRING already has a usage info, then just return it unchanged.
1378 The usage info is built from ARGLIST.  DOCSTRING can be nil.
1379 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
1380   (unless (stringp docstring) (setq docstring ""))
1381   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring)
1382           (eq arglist t))
1383       docstring
1384     (concat docstring
1385             (if (string-match "\n?\n\\'" docstring)
1386                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
1387               "\n\n")
1388             (if (stringp arglist)
1389                 (if (string-match "\\`[^ ]+\\(.*\\))\\'" arglist)
1390                     (concat "(fn" (match-string 1 arglist) ")")
1391                   (error "Unrecognized usage format"))
1392               (help--make-usage-docstring 'fn arglist)))))
1393
1394 (defun help-function-arglist (def &optional preserve-names)
1395   "Return a formal argument list for the function DEF.
1396 If PRESERVE-NAMES is non-nil, return a formal arglist that uses
1397 the same names as used in the original source code, when possible."
1398   ;; Handle symbols aliased to other symbols.
1399   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
1400   ;; Advice wrappers have "catch all" args, so fetch the actual underlying
1401   ;; function to find the real arguments.
1402   (while (advice--p def) (setq def (advice--cdr def)))
1403   ;; If definition is a macro, find the function inside it.
1404   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
1405   (cond
1406    ((and (byte-code-function-p def) (listp (aref def 0))) (aref def 0))
1407    ((eq (car-safe def) 'lambda) (nth 1 def))
1408    ((eq (car-safe def) 'closure) (nth 2 def))
1409    ((or (and (byte-code-function-p def) (integerp (aref def 0)))
1410         (subrp def) (module-function-p def))
1411     (or (when preserve-names
1412           (let* ((doc (condition-case nil (documentation def) (error nil)))
1413                  (docargs (if doc (car (help-split-fundoc doc nil))))
1414                  (arglist (if docargs
1415                               (cdar (read-from-string (downcase docargs)))))
1416                  (valid t))
1417             ;; Check validity.
1418             (dolist (arg arglist)
1419               (unless (and (symbolp arg)
1420                            (let ((name (symbol-name arg)))
1421                              (if (eq (aref name 0) ?&)
1422                                  (memq arg '(&rest &optional))
1423                                (not (string-match "\\." name)))))
1424                 (setq valid nil)))
1425             (when valid arglist)))
1426         (let* ((arity (func-arity def))
1427                (max (cdr arity))
1428                (min (car arity))
1429                (arglist ()))
1430           (dotimes (i min)
1431             (push (intern (concat "arg" (number-to-string (1+ i)))) arglist))
1432           (when (and (integerp max) (> max min))
1433             (push '&optional arglist)
1434             (dotimes (i (- max min))
1435               (push (intern (concat "arg" (number-to-string (+ 1 i min))))
1436                     arglist)))
1437           (unless (integerp max) (push '&rest arglist) (push 'rest arglist))
1438           (nreverse arglist))))
1439    ((and (autoloadp def) (not (eq (nth 4 def) 'keymap)))
1440     "[Arg list not available until function definition is loaded.]")
1441    (t t)))
1442
1443 (defun help--make-usage (function arglist)
1444   (cons (if (symbolp function) function 'anonymous)
1445         (mapcar (lambda (arg)
1446                   (if (not (symbolp arg)) arg
1447                     (let ((name (symbol-name arg)))
1448                       (cond
1449                        ((string-match "\\`&" name) arg)
1450                        ((string-match "\\`_." name)
1451                         (intern (upcase (substring name 1))))
1452                        (t (intern (upcase name)))))))
1453                 arglist)))
1454
1455 (define-obsolete-function-alias 'help-make-usage 'help--make-usage "25.1")
1456
1457 (defun help--make-usage-docstring (fn arglist)
1458   (let ((print-escape-newlines t))
1459     (help--docstring-quote (format "%S" (help--make-usage fn arglist)))))
1460
1461 \f
1462 (provide 'help)
1463
1464 ;;; help.el ends here