lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains those help commands which are complicated, and
  29 ;; which may not be used in every session.  For example
  30 ;; `describe-function' will probably be heavily used when doing elisp
  31 ;; programming, but not if just editing C files.  Simpler help commands
  32 ;; are in help.el
  33
  34 ;;; Code:
  35
  36 (require 'help-mode)
  37
  38 ;; Functions
  39
  40 ;;;###autoload
  41 (defun describe-function (function)
  42   "Display the full documentation of FUNCTION (a symbol)."
  43   (interactive
  44    (let ((fn (function-called-at-point))
  45          (enable-recursive-minibuffers t)
  46          val)
  47      (setq val (completing-read (if fn
  48                                     (format "Describe function (default %s): " fn)
  49                                   "Describe function: ")
  50                                 obarray 'fboundp t nil nil
  51                                 (and fn (symbol-name fn))))
  52      (list (if (equal val "")
  53                fn (intern val)))))
  54   (if (null function)
  55       (message "You didn't specify a function")
  56     (help-setup-xref (list #'describe-function function) (interactive-p))
  57     (save-excursion
  58       (with-output-to-temp-buffer (help-buffer)
  59         (prin1 function)
  60         ;; Use " is " instead of a colon so that
  61         ;; it is easier to get out the function name using forward-sexp.
  62         (princ " is ")
  63         (describe-function-1 function)
  64         (print-help-return-message)
  65         (with-current-buffer standard-output
  66           ;; Return the text we displayed.
  67           (buffer-string))))))
  68
  69 (defun help-split-fundoc (docstring def)
  70   "Split a function DOCSTRING into the actual doc and the usage info.
  71 Return (USAGE . DOC) or nil if there's no usage info.
  72 DEF is the function whose usage we're looking for in DOCSTRING."
  73   ;; Functions can get the calling sequence at the end of the doc string.
  74   ;; In cases where `function' has been fset to a subr we can't search for
  75   ;; function's name in the doc string so we use `fn' as the anonymous
  76   ;; function name instead.
  77   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  78     (cons (format "(%s%s"
  79                   ;; Replace `fn' with the actual function name.
  80                   (if (consp def) "anonymous" def)
  81                   (match-string 1 docstring))
  82           (substring docstring 0 (match-beginning 0)))))
  83
  84 (defun help-add-fundoc-usage (docstring arglist)
  85   "Add the usage info to DOCSTRING.
  86 If DOCSTRING already has a usage info, then just return it unchanged.
  87 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  88 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  89   (unless (stringp docstring) (setq docstring "Not documented"))
  90   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  91       docstring
  92     (concat docstring
  93             (if (string-match "\n?\n\\'" docstring)
  94                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  95               "\n\n")
  96             (if (and (stringp arglist)
  97                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  98                 (concat "(fn" (match-string 1 arglist) ")")
  99               (format "%S" (help-make-usage 'fn arglist))))))
 100
 101 (defun help-function-arglist (def)
 102   ;; Handle symbols aliased to other symbols.
 103   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 104   ;; If definition is a macro, find the function inside it.
 105   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 106   (cond
 107    ((byte-code-function-p def) (aref def 0))
 108    ((eq (car-safe def) 'lambda) (nth 1 def))
 109    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 110     "[Arg list not available until function definition is loaded.]")
 111    (t t)))
 112
 113 (defun help-make-usage (function arglist)
 114   (cons (if (symbolp function) function 'anonymous)
 115         (mapcar (lambda (arg)
 116                   (if (not (symbolp arg))
 117                       (if (and (consp arg) (symbolp (car arg)))
 118                           ;; CL style default values for optional args.
 119                           (cons (intern (upcase (symbol-name (car arg))))
 120                                 (cdr arg))
 121                         arg)
 122                     (let ((name (symbol-name arg)))
 123                       (if (string-match "\\`&" name) arg
 124                         (intern (upcase name))))))
 125                 arglist)))
 126
 127 ;; Could be this, if we make symbol-file do the work below.
 128 ;; (defun help-C-file-name (subr-or-var kind)
 129 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 130 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 131 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 132 ;;               (subr-name subr-or-var))
 133 ;;             (if (eq kind 'var) 'defvar 'defun)))
 134 ;;;###autoload
 135 (defun help-C-file-name (subr-or-var kind)
 136   "Return the name of the C file where SUBR-OR-VAR is defined.
 137 KIND should be `var' for a variable or `subr' for a subroutine."
 138   (let ((docbuf (get-buffer-create " *DOC*"))
 139         (name (if (eq 'var kind)
 140                   (concat "V" (symbol-name subr-or-var))
 141                 (concat "F" (subr-name subr-or-var)))))
 142     (with-current-buffer docbuf
 143       (goto-char (point-min))
 144       (if (eobp)
 145           (insert-file-contents-literally
 146            (expand-file-name internal-doc-file-name doc-directory)))
 147       (let ((file (catch 'loop
 148                     (while t
 149                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
 150                         (re-search-backward "\x1fS\\(.*\\)")
 151                         (let ((file (match-string 1)))
 152                           (if (member file build-files)
 153                               (throw 'loop file)
 154                             (goto-char pnt))))))))
 155         (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 156             (setq file (replace-match ".c" t t file)))
 157         (if (string-match "\\.c\\'" file)
 158             (concat "src/" file)
 159           file)))))
 160
 161 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
 162   "Face to highlight argument names in *Help* buffers."
 163   :group 'help)
 164
 165 (defun help-default-arg-highlight (arg)
 166   "Default function to highlight arguments in *Help* buffers.
 167 It returns ARG in face `help-argument-name'; ARG is also
 168 downcased if it displays differently than the default
 169 face (according to `face-differs-from-default-p')."
 170   (propertize (if (face-differs-from-default-p 'help-argument-name)
 171                   (downcase arg)
 172                 arg)
 173               'face 'help-argument-name))
 174
 175 (defun help-do-arg-highlight (doc args)
 176   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 177     (modify-syntax-entry ?\- "w")
 178     (dolist (arg args doc)
 179       (setq doc (replace-regexp-in-string
 180                  ;; This is heuristic, but covers all common cases
 181                  ;; except ARG1-ARG2
 182                  (concat "\\<"                   ; beginning of word
 183                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 184                          "\\("
 185                          (regexp-quote arg)
 186                          "\\)"
 187                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 188                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 189                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 190                          "\\>")                  ; end of word
 191                  (help-default-arg-highlight arg)
 192                  doc t t 1)))))
 193
 194 (defun help-highlight-arguments (usage doc &rest args)
 195   (when usage
 196     (with-temp-buffer
 197       (insert usage)
 198       (goto-char (point-min))
 199       (let ((case-fold-search nil)
 200             (next (not (or args (looking-at "\\["))))
 201             (opt nil))
 202         ;; Make a list of all arguments
 203         (skip-chars-forward "^ ")
 204         (while next
 205           (or opt (not (looking-at " &")) (setq opt t))
 206           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 207               (setq next nil)
 208             (setq args (cons (match-string 2) args))
 209             (when (and opt (string= (match-string 1) "("))
 210               ;; A pesky CL-style optional argument with default value,
 211               ;; so let's skip over it
 212               (search-backward "(")
 213               (goto-char (scan-sexps (point) 1)))))
 214         ;; Highlight aguments in the USAGE string
 215         (setq usage (help-do-arg-highlight (buffer-string) args))
 216         ;; Highlight arguments in the DOC string
 217         (setq doc (and doc (help-do-arg-highlight doc args))))))
 218   ;; Return value is like the one from help-split-fundoc, but highlighted
 219   (cons usage doc))
 220
 221 ;;;###autoload
 222 (defun describe-simplify-lib-file-name (file)
 223   "Simplify a library name FILE to a relative name, and make it a source file."
 224   (if file
 225       ;; Try converting the absolute file name to a library name.
 226       (let ((libname (file-name-nondirectory file)))
 227         ;; Now convert that back to a file name and see if we get
 228         ;; the original one.  If so, they are equivalent.
 229         (if (equal file (locate-file libname load-path '("")))
 230             (if (string-match "[.]elc\\'" libname)
 231                 (substring libname 0 -1)
 232               libname)
 233           file))))
 234
 235 (defun find-source-lisp-file (file-name)
 236   (let* ((elc-file (locate-file (concat file-name
 237                                  (if (string-match "\\.el" file-name)
 238                                      "c"
 239                                    ".elc"))
 240                                  load-path))
 241          (str (if (and elc-file (file-readable-p elc-file))
 242                   (with-temp-buffer
 243                     (insert-file-contents-literally elc-file nil 0 256)
 244                     (buffer-string))))
 245          (src-file (and str
 246                         (string-match ";;; from file \\(.*\\.el\\)" str)
 247                         (match-string 1 str))))
 248     (if (and src-file (file-readable-p src-file))
 249         src-file
 250       file-name)))
 251
 252 ;;;###autoload
 253 (defun describe-function-1 (function)
 254   (let* ((def (if (symbolp function)
 255                   (symbol-function function)
 256                 function))
 257          file-name string
 258          (beg (if (commandp def) "an interactive " "a ")))
 259     (setq string
 260           (cond ((or (stringp def)
 261                      (vectorp def))
 262                  "a keyboard macro")
 263                 ((subrp def)
 264                  (if (eq 'unevalled (cdr (subr-arity def)))
 265                      (concat beg "special form")
 266                    (concat beg "built-in function")))
 267                 ((byte-code-function-p def)
 268                  (concat beg "compiled Lisp function"))
 269                 ((symbolp def)
 270                  (while (symbolp (symbol-function def))
 271                    (setq def (symbol-function def)))
 272                  (format "an alias for `%s'" def))
 273                 ((eq (car-safe def) 'lambda)
 274                  (concat beg "Lisp function"))
 275                 ((eq (car-safe def) 'macro)
 276                  "a Lisp macro")
 277                 ((eq (car-safe def) 'autoload)
 278                  (setq file-name (nth 1 def))
 279                  (format "%s autoloaded %s"
 280                          (if (commandp def) "an interactive" "an")
 281                          (if (eq (nth 4 def) 'keymap) "keymap"
 282                            (if (nth 4 def) "Lisp macro" "Lisp function"))
 283                          ))
 284                 ((keymapp def)
 285                  (let ((is-full nil)
 286                        (elts (cdr-safe def)))
 287                    (while elts
 288                      (if (char-table-p (car-safe elts))
 289                          (setq is-full t
 290                                elts nil))
 291                      (setq elts (cdr-safe elts)))
 292                    (if is-full
 293                        "a full keymap"
 294                      "a sparse keymap")))
 295                 (t "")))
 296     (princ string)
 297     (with-current-buffer standard-output
 298       (save-excursion
 299         (save-match-data
 300           (if (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 301               (help-xref-button 1 'help-function def)))))
 302     (or file-name
 303         (setq file-name (symbol-file function 'defun)))
 304     (setq file-name (describe-simplify-lib-file-name file-name))
 305     (when (equal file-name "loaddefs.el")
 306       ;; Find the real def site of the preloaded function.
 307       ;; This is necessary only for defaliases.
 308       (let ((location
 309              (condition-case nil
 310                  (find-function-search-for-symbol function nil "loaddefs.el")
 311                (error nil))))
 312         (when location
 313           (with-current-buffer (car location)
 314             (goto-char (cdr location))
 315             (when (re-search-backward
 316                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 317               (setq file-name (match-string 1)))))))
 318     (when (and (null file-name) (subrp def))
 319       ;; Find the C source file name.
 320       (setq file-name (if (get-buffer " *DOC*")
 321                           (help-C-file-name def 'subr)
 322                         'C-source)))
 323     (when file-name
 324       (princ " in `")
 325       ;; We used to add .el to the file name,
 326       ;; but that's completely wrong when the user used load-file.
 327       (princ (if (eq file-name 'C-source) "C source code" file-name))
 328       (princ "'")
 329       ;; See if lisp files are present where they where installed from.
 330       (if (not (eq file-name 'C-source))
 331           (setq file-name (find-source-lisp-file file-name)))
 332
 333       ;; Make a hyperlink to the library.
 334       (with-current-buffer standard-output
 335         (save-excursion
 336           (re-search-backward "`\\([^`']+\\)'" nil t)
 337           (help-xref-button 1 'help-function-def function file-name))))
 338     (princ ".")
 339     (terpri)
 340     (when (commandp function)
 341       (if (and (eq function 'self-insert-command)
 342                (eq (key-binding "a") 'self-insert-command)
 343                (eq (key-binding "b") 'self-insert-command)
 344                (eq (key-binding "c") 'self-insert-command))
 345           (princ "It is bound to many ordinary text characters.\n")
 346         (let* ((remapped (command-remapping function))
 347                (keys (where-is-internal
 348                       (or remapped function) overriding-local-map nil nil))
 349                non-modified-keys)
 350           ;; Which non-control non-meta keys run this command?
 351           (dolist (key keys)
 352             (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 353                 (push key non-modified-keys)))
 354           (when remapped
 355             (princ "It is remapped to `")
 356             (princ (symbol-name remapped))
 357             (princ "'"))
 358
 359           (when keys
 360             (princ (if remapped " which is bound to " "It is bound to "))
 361             ;; If lots of ordinary text characters run this command,
 362             ;; don't mention them one by one.
 363             (if (< (length non-modified-keys) 10)
 364                 (princ (mapconcat 'key-description keys ", "))
 365               (dolist (key non-modified-keys)
 366                 (setq keys (delq key keys)))
 367               (if keys
 368                   (progn
 369                     (princ (mapconcat 'key-description keys ", "))
 370                     (princ ", and many ordinary text characters"))
 371                 (princ "many ordinary text characters"))))
 372           (when (or remapped keys non-modified-keys)
 373             (princ ".")
 374             (terpri)))))
 375     (let* ((arglist (help-function-arglist def))
 376            (doc (documentation function))
 377            (usage (help-split-fundoc doc function)))
 378       (with-current-buffer standard-output
 379         ;; If definition is a keymap, skip arglist note.
 380         (unless (keymapp def)
 381           (let* ((use (cond
 382                         (usage (setq doc (cdr usage)) (car usage))
 383                         ((listp arglist)
 384                          (format "%S" (help-make-usage function arglist)))
 385                         ((stringp arglist) arglist)
 386                         ;; Maybe the arglist is in the docstring of the alias.
 387                         ((let ((fun function))
 388                            (while (and (symbolp fun)
 389                                        (setq fun (symbol-function fun))
 390                                        (not (setq usage (help-split-fundoc
 391                                                          (documentation fun)
 392                                                          function)))))
 393                            usage)
 394                          (car usage))
 395                         ((or (stringp def)
 396                              (vectorp def))
 397                          (format "\nMacro: %s" (format-kbd-macro def)))
 398                         (t "[Missing arglist.  Please make a bug report.]")))
 399                  (high (help-highlight-arguments use doc)))
 400             (let ((fill-begin (point)))
 401               (insert (car high) "\n")
 402               (fill-region fill-begin (point)))
 403             (setq doc (cdr high))))
 404         (let ((obsolete (and
 405                          ;; function might be a lambda construct.
 406                          (symbolp function)
 407                          (get function 'byte-obsolete-info))))
 408           (when obsolete
 409             (princ "\nThis function is obsolete")
 410             (when (nth 2 obsolete)
 411               (insert (format " since %s" (nth 2 obsolete))))
 412             (insert ";\n"
 413                     (if (stringp (car obsolete)) (car obsolete)
 414                       (format "use `%s' instead." (car obsolete)))
 415                     "\n"))
 416           (insert "\n"
 417                   (or doc "Not documented.")))))))
 418
 419 \f
 420 ;; Variables
 421
 422 ;;;###autoload
 423 (defun variable-at-point (&optional any-symbol)
 424   "Return the bound variable symbol found at or before point.
 425 Return 0 if there is no such symbol.
 426 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 427   (or (condition-case ()
 428           (with-syntax-table emacs-lisp-mode-syntax-table
 429             (save-excursion
 430               (or (not (zerop (skip-syntax-backward "_w")))
 431                   (eq (char-syntax (following-char)) ?w)
 432                   (eq (char-syntax (following-char)) ?_)
 433                   (forward-sexp -1))
 434               (skip-chars-forward "'")
 435               (let ((obj (read (current-buffer))))
 436                 (and (symbolp obj) (boundp obj) obj))))
 437         (error nil))
 438       (let* ((str (find-tag-default))
 439              (sym (if str (intern-soft str))))
 440         (if (and sym (or any-symbol (boundp sym)))
 441             sym
 442           (save-match-data
 443             (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 444               (setq sym (intern-soft (match-string 1 str)))
 445               (and (or any-symbol (boundp sym)) sym)))))
 446       0))
 447
 448 ;;;###autoload
 449 (defun describe-variable (variable &optional buffer frame)
 450   "Display the full documentation of VARIABLE (a symbol).
 451 Returns the documentation as a string, also.
 452 If VARIABLE has a buffer-local value in BUFFER or FRAME
 453 \(default to the current buffer and current frame),
 454 it is displayed along with the global value."
 455   (interactive
 456    (let ((v (variable-at-point))
 457          (enable-recursive-minibuffers t)
 458          val)
 459      (setq val (completing-read (if (symbolp v)
 460                                     (format
 461                                      "Describe variable (default %s): " v)
 462                                   "Describe variable: ")
 463                                 obarray
 464                                 '(lambda (vv)
 465                                    (or (boundp vv)
 466                                        (get vv 'variable-documentation)))
 467                                 t nil nil
 468                                 (if (symbolp v) (symbol-name v))))
 469      (list (if (equal val "")
 470                v (intern val)))))
 471   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 472   (unless (frame-live-p frame) (setq frame (selected-frame)))
 473   (if (not (symbolp variable))
 474       (message "You did not specify a variable")
 475     (save-excursion
 476       (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 477             val val-start-pos locus)
 478         ;; Extract the value before setting up the output buffer,
 479         ;; in case `buffer' *is* the output buffer.
 480         (unless valvoid
 481           (with-selected-frame frame
 482             (with-current-buffer buffer
 483               (setq val (symbol-value variable)
 484                     locus (variable-binding-locus variable)))))
 485         (help-setup-xref (list #'describe-variable variable buffer)
 486                          (interactive-p))
 487         (with-output-to-temp-buffer (help-buffer)
 488           (with-current-buffer buffer
 489             (prin1 variable)
 490             ;; Make a hyperlink to the library if appropriate.  (Don't
 491             ;; change the format of the buffer's initial line in case
 492             ;; anything expects the current format.)
 493             (let ((file-name (symbol-file variable 'defvar)))
 494               (setq file-name (describe-simplify-lib-file-name file-name))
 495               (when (equal file-name "loaddefs.el")
 496                 ;; Find the real def site of the preloaded variable.
 497                 (let ((location
 498                        (condition-case nil
 499                            (find-variable-noselect variable file-name)
 500                          (error nil))))
 501                   (when location
 502                     (with-current-buffer (car location)
 503                       (when (cdr location)
 504                         (goto-char (cdr location)))
 505                       (when (re-search-backward
 506                              "^;;; Generated autoloads from \\(.*\\)" nil t)
 507                         (setq file-name (match-string 1)))))))
 508               (when (and (null file-name)
 509                          (integerp (get variable 'variable-documentation)))
 510                 ;; It's a variable not defined in Elisp but in C.
 511                 (setq file-name
 512                       (if (get-buffer " *DOC*")
 513                           (help-C-file-name variable 'var)
 514                         'C-source)))
 515               (if file-name
 516                   (progn
 517                     (princ " is a variable defined in `")
 518                     (princ (if (eq file-name 'C-source) "C source code" file-name))
 519                     (princ "'.\n")
 520                     (with-current-buffer standard-output
 521                       (save-excursion
 522                         (re-search-backward "`\\([^`']+\\)'" nil t)
 523                         (help-xref-button 1 'help-variable-def
 524                                           variable file-name)))
 525                     (if valvoid
 526                         (princ "It is void as a variable.")
 527                       (princ "Its ")))
 528                 (if valvoid
 529                     (princ " is void as a variable.")
 530                   (princ "'s "))))
 531             (if valvoid
 532                 nil
 533               (with-current-buffer standard-output
 534                 (setq val-start-pos (point))
 535                 (princ "value is ")
 536                 (terpri)
 537                 (let ((from (point)))
 538                   (pp val)
 539                   ;; Hyperlinks in variable's value are quite frequently
 540                   ;; inappropriate e.g C-h v <RET> features <RET>
 541                   ;; (help-xref-on-pp from (point))
 542                   (if (< (point) (+ from 20))
 543                       (delete-region (1- from) from)))))
 544             (terpri)
 545
 546             (when locus
 547               (if (bufferp locus)
 548                   (princ (format "%socal in buffer %s; "
 549                                  (if (get variable 'permanent-local)
 550                                      "Permanently l" "L")
 551                                  (buffer-name)))
 552                 (princ (format "It is a frame-local variable; ")))
 553               (if (not (default-boundp variable))
 554                   (princ "globally void")
 555                 (let ((val (default-value variable)))
 556                   (with-current-buffer standard-output
 557                     (princ "global value is ")
 558                     (terpri)
 559                     ;; Fixme: pp can take an age if you happen to
 560                     ;; ask for a very large expression.  We should
 561                     ;; probably print it raw once and check it's a
 562                     ;; sensible size before prettyprinting.  -- fx
 563                     (let ((from (point)))
 564                       (pp val)
 565                       ;; See previous comment for this function.
 566                       ;; (help-xref-on-pp from (point))
 567                       (if (< (point) (+ from 20))
 568                           (delete-region (1- from) from))))))
 569               (terpri))
 570
 571             ;; If the value is large, move it to the end.
 572             (with-current-buffer standard-output
 573               (when (> (count-lines (point-min) (point-max)) 10)
 574                 ;; Note that setting the syntax table like below
 575                 ;; makes forward-sexp move over a `'s' at the end
 576                 ;; of a symbol.
 577                 (set-syntax-table emacs-lisp-mode-syntax-table)
 578                 (goto-char val-start-pos)
 579                 ;; The line below previously read as
 580                 ;; (delete-region (point) (progn (end-of-line) (point)))
 581                 ;; which suppressed display of the buffer local value for
 582                 ;; large values.
 583                 (when (looking-at "value is") (replace-match ""))
 584                 (save-excursion
 585                   (insert "\n\nValue:")
 586                   (set (make-local-variable 'help-button-cache)
 587                        (point-marker)))
 588                 (insert "value is shown ")
 589                 (insert-button "below"
 590                                'action help-button-cache
 591                                'follow-link t
 592                                'help-echo "mouse-2, RET: show value")
 593                 (insert ".\n")))
 594             (terpri)
 595
 596             (let* ((alias (condition-case nil
 597                              (indirect-variable variable)
 598                            (error variable)))
 599                    (obsolete (get variable 'byte-obsolete-variable))
 600                    (safe-var (get variable 'safe-local-variable))
 601                    (doc (or (documentation-property variable 'variable-documentation)
 602                             (documentation-property alias 'variable-documentation)))
 603                    (extra-line nil))
 604               ;; Add a note for variables that have been make-var-buffer-local.
 605               (when (and (local-variable-if-set-p variable)
 606                          (or (not (local-variable-p variable))
 607                              (with-temp-buffer
 608                                (local-variable-if-set-p variable))))
 609                 (setq extra-line t)
 610                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 611
 612               ;; Mention if it's an alias
 613               (unless (eq alias variable)
 614                 (setq extra-line t)
 615                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 616
 617               (when obsolete
 618                 (setq extra-line t)
 619                 (princ "  This variable is obsolete")
 620                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 621                 (princ ";\n  ")
 622                 (princ (if (stringp (car obsolete)) (car obsolete)
 623                          (format "use `%s' instead." (car obsolete))))
 624                 (terpri))
 625               (when safe-var
 626                 (setq extra-line t)
 627                 (princ "  This variable is safe as a file local variable ")
 628                 (princ "if its value\n  satisfies the predicate ")
 629                 (princ (if (byte-code-function-p safe-var)
 630                            "which is byte-compiled expression.\n"
 631                          (format "`%s'.\n" safe-var))))
 632
 633               (if extra-line (terpri))
 634               (princ "Documentation:\n")
 635               (with-current-buffer standard-output
 636                 (insert (or doc "Not documented as a variable."))))
 637             ;; Make a link to customize if this variable can be customized.
 638             (if (custom-variable-p variable)
 639                 (let ((customize-label "customize"))
 640                   (terpri)
 641                   (terpri)
 642                   (princ (concat "You can " customize-label " this variable."))
 643                   (with-current-buffer standard-output
 644                     (save-excursion
 645                       (re-search-backward
 646                        (concat "\\(" customize-label "\\)") nil t)
 647                       (help-xref-button 1 'help-customize-variable variable)))))
 648             (print-help-return-message)
 649             (save-excursion
 650               (set-buffer standard-output)
 651               ;; Return the text we displayed.
 652               (buffer-string))))))))
 653
 654
 655 ;;;###autoload
 656 (defun describe-syntax (&optional buffer)
 657   "Describe the syntax specifications in the syntax table of BUFFER.
 658 The descriptions are inserted in a help buffer, which is then displayed.
 659 BUFFER defaults to the current buffer."
 660   (interactive)
 661   (setq buffer (or buffer (current-buffer)))
 662   (help-setup-xref (list #'describe-syntax buffer) (interactive-p))
 663   (with-output-to-temp-buffer (help-buffer)
 664     (let ((table (with-current-buffer buffer (syntax-table))))
 665       (with-current-buffer standard-output
 666         (describe-vector table 'internal-describe-syntax-value)
 667         (while (setq table (char-table-parent table))
 668           (insert "\nThe parent syntax table is:")
 669           (describe-vector table 'internal-describe-syntax-value))))))
 670
 671 (defun help-describe-category-set (value)
 672   (insert (cond
 673            ((null value) "default")
 674            ((char-table-p value) "deeper char-table ...")
 675            (t (condition-case err
 676                   (category-set-mnemonics value)
 677                 (error "invalid"))))))
 678
 679 ;;;###autoload
 680 (defun describe-categories (&optional buffer)
 681   "Describe the category specifications in the current category table.
 682 The descriptions are inserted in a buffer, which is then displayed.
 683 If BUFFER is non-nil, then describe BUFFER's category table instead.
 684 BUFFER should be a buffer or a buffer name."
 685   (interactive)
 686   (setq buffer (or buffer (current-buffer)))
 687   (help-setup-xref (list #'describe-categories buffer) (interactive-p))
 688   (with-output-to-temp-buffer (help-buffer)
 689     (let ((table (with-current-buffer buffer (category-table))))
 690       (with-current-buffer standard-output
 691         (describe-vector table 'help-describe-category-set)
 692         (let ((docs (char-table-extra-slot table 0)))
 693           (if (or (not (vectorp docs)) (/= (length docs) 95))
 694               (insert "Invalid first extra slot in this char table\n")
 695             (insert "Meanings of mnemonic characters are:\n")
 696             (dotimes (i 95)
 697               (let ((elt (aref docs i)))
 698                 (when elt
 699                   (insert (+ i ?\s) ": " elt "\n"))))
 700             (while (setq table (char-table-parent table))
 701               (insert "\nThe parent category table is:")
 702               (describe-vector table 'help-describe-category-set))))))))
 703
 704 (provide 'help-fns)
 705
 706 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 707 ;;; help-fns.el ends here