lisp/vc-mtn.el

   1 ;;; vc-mtn.el --- VC backend for Monotone
   2
   3 ;; Copyright (C) 2007, 2008, 2009  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords:
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;
  26
  27 ;;; TODO:
  28
  29 ;; - The `previous-version' VC method needs to be supported, 'D' in
  30 ;;   log-view-mode uses it.
  31
  32 ;;; Code:
  33
  34 (eval-when-compile (require 'cl) (require 'vc))
  35
  36 (defcustom vc-mtn-diff-switches t
  37   "String or list of strings specifying switches for monotone diff under VC.
  38 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  39   :type '(choice (const :tag "Unspecified" nil)
  40                  (const :tag "None" t)
  41                  (string :tag "Argument String")
  42                  (repeat :tag "Argument List" :value ("") string))
  43   :version "23.1"
  44   :group 'vc)
  45
  46 (define-obsolete-variable-alias 'vc-mtn-command 'vc-mtn-program "23.1")
  47 (defcustom vc-mtn-program "mtn"
  48   "Name of the monotone executable."
  49   :type 'string
  50   :group 'vc)
  51
  52 ;; Clear up the cache to force vc-call to check again and discover
  53 ;; new functions when we reload this file.
  54 (put 'Mtn 'vc-functions nil)
  55
  56 (unless (executable-find vc-mtn-program)
  57   ;; vc-mtn.el is 100% non-functional without the `mtn' executable.
  58   (setq vc-handled-backends (delq 'Mtn vc-handled-backends)))
  59
  60 ;;;###autoload
  61 (defconst vc-mtn-admin-dir "_MTN")
  62 ;;;###autoload
  63 (defconst vc-mtn-admin-format (concat vc-mtn-admin-dir "/format"))
  64
  65 ;;;###autoload (defun vc-mtn-registered (file)
  66 ;;;###autoload   (if (vc-find-root file vc-mtn-admin-format)
  67 ;;;###autoload       (progn
  68 ;;;###autoload         (load "vc-mtn")
  69 ;;;###autoload         (vc-mtn-registered file))))
  70
  71 (defun vc-mtn-revision-granularity () 'repository)
  72 (defun vc-mtn-checkout-model (files) 'implicit)
  73
  74 (defun vc-mtn-root (file)
  75   (setq file (if (file-directory-p file)
  76                  (file-name-as-directory file)
  77                (file-name-directory file)))
  78   (or (vc-file-getprop file 'vc-mtn-root)
  79       (vc-file-setprop file 'vc-mtn-root
  80                        (vc-find-root file vc-mtn-admin-format))))
  81
  82
  83 (defun vc-mtn-registered (file)
  84   (let ((root (vc-mtn-root file)))
  85     (when root
  86       (vc-mtn-state file))))
  87
  88 (defun vc-mtn-command (buffer okstatus files &rest flags)
  89   "A wrapper around `vc-do-command' for use in vc-mtn.el."
  90   (let ((process-environment
  91          ;; Avoid localization of messages so we can parse the output.
  92          (cons "LC_MESSAGES=C" process-environment)))
  93     (apply 'vc-do-command (or buffer "*vc*") okstatus vc-mtn-program
  94            files flags)))
  95
  96 (defun vc-mtn-state (file)
  97   ;; If `mtn' fails or returns status>0, or if the search files, just
  98   ;; return nil.
  99   (ignore-errors
 100     (with-temp-buffer
 101       (vc-mtn-command t 0 file "status")
 102       (goto-char (point-min))
 103       (re-search-forward
 104        "^  \\(?:\\(patched\\)\\|\\(added\\) \\(?:.*\\)\\)\\|no changes$")
 105       (cond  ((match-end 1) 'edited)
 106              ((match-end 2) 'added)
 107              (t 'up-to-date)))))
 108
 109 (defun vc-mtn-after-dir-status (update-function)
 110   (let (result)
 111     (goto-char (point-min))
 112     (re-search-forward "Current branch: \\(.*\\)\nChanges against parent \\(.*\\)" nil t)
 113     (while (re-search-forward
 114             "^  \\(?:\\(patched  \\)\\|\\(added    \\)\\)\\(.*\\)$" nil t)
 115       (cond  ((match-end 1) (push (list (match-string 3) 'edited) result))
 116              ((match-end 2) (push (list (match-string 3) 'added) result))))
 117     (funcall update-function result)))
 118
 119 (defun vc-mtn-dir-status (dir update-function)
 120   (vc-mtn-command (current-buffer) 'async dir "status")
 121   (vc-exec-after
 122    `(vc-mtn-after-dir-status (quote ,update-function))))
 123
 124 (defun vc-mtn-working-revision (file)
 125   ;; If `mtn' fails or returns status>0, or if the search fails, just
 126   ;; return nil.
 127   (ignore-errors
 128     (with-temp-buffer
 129       (vc-mtn-command t 0 file "status")
 130       (goto-char (point-min))
 131       (re-search-forward "Current branch: \\(.*\\)\nChanges against parent \\(.*\\)")
 132       (match-string 2))))
 133
 134 (defun vc-mtn-workfile-branch (file)
 135   ;; If `mtn' fails or returns status>0, or if the search files, just
 136   ;; return nil.
 137   (ignore-errors
 138     (with-temp-buffer
 139       (vc-mtn-command t 0 file "status")
 140       (goto-char (point-min))
 141       (re-search-forward "Current branch: \\(.*\\)\nChanges against parent \\(.*\\)")
 142       (match-string 1))))
 143
 144 (defun vc-mtn-workfile-unchanged-p (file)
 145   (not (eq (vc-mtn-state file) 'edited)))
 146
 147 ;; Mode-line rewrite code copied from vc-arch.el.
 148
 149 (defcustom vc-mtn-mode-line-rewrite
 150   '(("\\`[^:/#]*[:/#]" . ""))           ;Drop the host part.
 151   "Rewrite rules to shorten Mtn's revision names on the mode-line."
 152   :type '(repeat (cons regexp string))
 153   :version "22.2"
 154   :group 'vc)
 155
 156 (defun vc-mtn-mode-line-string (file)
 157   "Return string for placement in modeline by `vc-mode-line' for FILE."
 158   (let ((branch (vc-mtn-workfile-branch file)))
 159     (dolist (rule vc-mtn-mode-line-rewrite)
 160       (if (string-match (car rule) branch)
 161           (setq branch (replace-match (cdr rule) t nil branch))))
 162     (format "Mtn%c%s"
 163             (case (vc-state file)
 164               ((up-to-date needs-update) ?-)
 165               (added ?@)
 166               (t ?:))
 167             branch)))
 168
 169 (defun vc-mtn-register (files &optional rev comment)
 170   (vc-mtn-command nil 0 files "add"))
 171
 172 (defun vc-mtn-responsible-p (file) (vc-mtn-root file))
 173 (defun vc-mtn-could-register (file) (vc-mtn-root file))
 174
 175 (defun vc-mtn-checkin (files rev comment)
 176   (vc-mtn-command nil 0 files "commit" "-m" comment))
 177
 178 (defun vc-mtn-find-revision (file rev buffer)
 179   (vc-mtn-command buffer 0 file "cat" "-r" rev))
 180
 181 ;; (defun vc-mtn-checkout (file &optional editable rev)
 182 ;;   )
 183
 184 (defun vc-mtn-revert (file &optional contents-done)
 185   (unless contents-done
 186     (vc-mtn-command nil 0 file "revert")))
 187
 188 ;; (defun vc-mtn-roolback (files)
 189 ;;   )
 190
 191 (defun vc-mtn-print-log (files &optional buffer shortlog)
 192   (vc-mtn-command buffer 0 files "log"))
 193
 194 (defvar log-view-message-re)
 195 (defvar log-view-file-re)
 196 (defvar log-view-font-lock-keywords)
 197 (defvar log-view-per-file-logs)
 198
 199 (define-derived-mode vc-mtn-log-view-mode log-view-mode "Mtn-Log-View"
 200   ;; Don't match anything.
 201   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 202   (set (make-local-variable 'log-view-per-file-logs) nil)
 203   ;; TODO: Use a more precise regexp than "[ |/]+" to avoid false positives
 204   ;; in the ChangeLog text.
 205   (set (make-local-variable 'log-view-message-re)
 206        "^[ |/]+Revision: \\([0-9a-f]+\\)")
 207   (require 'add-log)                    ;For change-log faces.
 208   (set (make-local-variable 'log-view-font-lock-keywords)
 209        (append log-view-font-lock-keywords
 210                '(("^[ |]+Author: \\(.*\\)" (1 'change-log-email))
 211                  ("^[ |]+Date: \\(.*\\)" (1 'change-log-date-face))))))
 212
 213 ;; (defun vc-mtn-show-log-entry (revision)
 214 ;;   )
 215
 216 (defun vc-mtn-diff (files &optional rev1 rev2 buffer)
 217   "Get a difference report using monotone between two revisions of FILES."
 218   (apply 'vc-mtn-command (or buffer "*vc-diff*") 1 files "diff"
 219          (append
 220            (vc-switches 'mtn 'diff)
 221            (if rev1 (list "-r" rev1)) (if rev2 (list "-r" rev2)))))
 222
 223 (defun vc-mtn-annotate-command (file buf &optional rev)
 224   (apply 'vc-mtn-command buf 'async file "annotate"
 225          (if rev (list "-r" rev))))
 226
 227 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 228
 229 (defconst vc-mtn-annotate-full-re
 230   "^ *\\([0-9a-f]+\\)\\.* by [^ ]+ \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\): ")
 231 (defconst vc-mtn-annotate-any-re
 232   (concat "^\\(?: +: \\|" vc-mtn-annotate-full-re "\\)"))
 233
 234 (defun vc-mtn-annotate-time ()
 235   (when (looking-at vc-mtn-annotate-any-re)
 236     (goto-char (match-end 0))
 237     (let ((year (match-string 2)))
 238       (if (not year)
 239           ;; Look for the date on a previous line.
 240           (save-excursion
 241             (get-text-property (1- (previous-single-property-change
 242                                     (point) 'vc-mtn-time nil (point-min)))
 243                                'vc-mtn-time))
 244         (let ((time (vc-annotate-convert-time
 245                      (encode-time 0 0 0
 246                                   (string-to-number (match-string 4))
 247                                   (string-to-number (match-string 3))
 248                                   (string-to-number year)
 249                                   t))))
 250           (let ((inhibit-read-only t)
 251                 (inhibit-modification-hooks t))
 252             (put-text-property (match-beginning 0) (match-end 0)
 253                                'vc-mtn-time time))
 254           time)))))
 255
 256 (defun vc-mtn-annotate-extract-revision-at-line ()
 257   (save-excursion
 258     (when (or (looking-at vc-mtn-annotate-full-re)
 259               (re-search-backward vc-mtn-annotate-full-re nil t))
 260       (match-string 1))))
 261
 262 ;;; Revision completion.
 263
 264 (defun vc-mtn-list-tags ()
 265   (with-temp-buffer
 266     (vc-mtn-command t 0 nil "list" "tags")
 267     (goto-char (point-min))
 268     (let ((tags ()))
 269       (while (re-search-forward "^[^ ]+" nil t)
 270         (push (match-string 0) tags))
 271       tags)))
 272
 273 (defun vc-mtn-list-branches ()
 274   (with-temp-buffer
 275     (vc-mtn-command t 0 nil "list" "branches")
 276     (goto-char (point-min))
 277     (let ((branches ()))
 278       (while (re-search-forward "^.+" nil t)
 279         (push (match-string 0) branches))
 280       branches)))
 281
 282 (defun vc-mtn-list-revision-ids (prefix)
 283   (with-temp-buffer
 284     (vc-mtn-command t 0 nil "complete" "revision" prefix)
 285     (goto-char (point-min))
 286     (let ((ids ()))
 287       (while (re-search-forward "^.+" nil t)
 288         (push (match-string 0) ids))
 289       ids)))
 290
 291 (defun vc-mtn-revision-completion-table (files)
 292   ;; TODO: Implement completion for for selectors
 293   ;; TODO: Implement completion for composite selectors.
 294   (lexical-let ((files files))
 295     ;; What about using `files'?!?  --Stef
 296     (lambda (string pred action)
 297       (cond
 298        ;; "Tag" selectors.
 299        ((string-match "\\`t:" string)
 300         (complete-with-action action
 301                               (mapcar (lambda (tag) (concat "t:" tag))
 302                                       (vc-mtn-list-tags))
 303                               string pred))
 304        ;; "Branch" selectors.
 305        ((string-match "\\`b:" string)
 306         (complete-with-action action
 307                               (mapcar (lambda (tag) (concat "b:" tag))
 308                                       (vc-mtn-list-branches))
 309                               string pred))
 310        ;; "Head" selectors.  Not sure how they differ from "branch" selectors.
 311        ((string-match "\\`h:" string)
 312         (complete-with-action action
 313                               (mapcar (lambda (tag) (concat "h:" tag))
 314                                       (vc-mtn-list-branches))
 315                               string pred))
 316        ;; "ID" selectors.
 317        ((string-match "\\`i:" string)
 318         (complete-with-action action
 319                               (mapcar (lambda (tag) (concat "i:" tag))
 320                                       (vc-mtn-list-revision-ids
 321                                        (substring string (match-end 0))))
 322                               string pred))
 323        (t
 324         (complete-with-action action
 325                               '("t:" "b:" "h:" "i:"
 326                                 ;; Completion not implemented for these.
 327                                 "a:" "c:" "d:" "e:" "l:")
 328                               string pred))))))
 329
 330
 331
 332 (provide 'vc-mtn)
 333
 334 ;; arch-tag: 2b89ffbc-cbb8-405a-9080-2eafd4becb70
 335 ;;; vc-mtn.el ends here