lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el
   2
   3 ;; Copyright (C) 1988, 1994, 1997, 2001-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: processes, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;    This is a customization of comint-mode (see comint.el)
  27 ;;
  28 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  29 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  30 ;; 8/88
  31 ;;
  32 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  33 ;; merge them into the master source.
  34 ;;
  35 ;; The changelog is at the end of this file.
  36 ;;
  37 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  38 ;; interface that communicates process state back to the superior emacs by
  39 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  40 ;; lots and lots of special purpose code to read these control sequences, and
  41 ;; so is very tightly integrated with the cscheme process. The cscheme
  42 ;; interrupt handler and debugger read single character commands in cbreak
  43 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  44 ;; the single letter command keys to emacs functions that directly send the
  45 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  46 ;; functionality. If you are a cscheme user, you may prefer to use the
  47 ;; xscheme.el/cscheme -emacs interaction.
  48 ;;
  49 ;; Here's a summary of the pros and cons, as I see them.
  50 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  51 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  52 ;;           history only keeps the immediately prior input. Bizarre
  53 ;;           keybindings.
  54 ;;
  55 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  56 ;;            Carefully integrated functionality with the entire suite of
  57 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  58 ;;            Zwei and Hemlock. Good input history. A few commands not in
  59 ;;            xscheme.
  60 ;;
  61 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  62 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  63 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  64 ;; invited to port xscheme functionality on top of comint mode...
  65
  66 ;;; CHANGE LOG
  67 ;; ===========================================================================
  68 ;; 8/88 Olin
  69 ;; Created.
  70 ;;
  71 ;; 2/15/89 Olin
  72 ;; Removed -emacs flag from process invocation. It's only useful for
  73 ;; cscheme, and makes cscheme assume it's running under xscheme.el,
  74 ;; which messes things up royally. A bug.
  75 ;;
  76 ;; 5/22/90 Olin
  77 ;; - Upgraded to use comint-send-string and comint-send-region.
  78 ;; - run-scheme now offers to let you edit the command line if
  79 ;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
  80 ;;   has been removed.
  81 ;; - Explicit references to process "scheme" have been replaced with
  82 ;;   (scheme-proc). This allows better handling of multiple process bufs.
  83 ;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
  84 ;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
  85 ;;   and friends, but interested hackers might find a useful application
  86 ;;   of this facility.
  87 ;;
  88 ;; 3/12/90 Olin
  89 ;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
  90 ;;   Tale suggested this.
  91
  92 ;;; Code:
  93
  94 (require 'scheme)
  95 (require 'comint)
  96
  97
  98 (defgroup cmuscheme nil
  99   "Run a scheme process in a buffer."
 100   :group 'scheme)
 101
 102 ;;; INFERIOR SCHEME MODE STUFF
 103 ;;;============================================================================
 104
 105 (defcustom inferior-scheme-mode-hook nil
 106   "Hook for customizing inferior-scheme mode."
 107   :type 'hook
 108   :group 'cmuscheme)
 109
 110 (defvar inferior-scheme-mode-map
 111   (let ((m (make-sparse-keymap)))
 112     (define-key m "\M-\C-x" 'scheme-send-definition) ;gnu convention
 113     (define-key m "\C-x\C-e" 'scheme-send-last-sexp)
 114     (define-key m "\C-c\C-l" 'scheme-load-file)
 115     (define-key m "\C-c\C-k" 'scheme-compile-file)
 116     (scheme-mode-commands m)
 117     m))
 118
 119 ;; Install the process communication commands in the scheme-mode keymap.
 120 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
 121 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
 122 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
 123 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
 124 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
 125 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
 126 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
 127 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
 128 (define-key scheme-mode-map "\C-c\C-t" 'scheme-trace-procedure)
 129 (define-key scheme-mode-map "\C-c\C-x" 'scheme-expand-current-form)
 130 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 131 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 132 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 133
 134 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 135   (define-key map [separator-eval] '("--"))
 136   (define-key map [compile-file]
 137     '("Compile Scheme File" . scheme-compile-file))
 138   (define-key map [load-file]
 139     '("Load Scheme File" . scheme-load-file))
 140   (define-key map [switch]
 141     '("Switch to Scheme" . switch-to-scheme))
 142   (define-key map [com-def-go]
 143     '("Compile Definition & Go" . scheme-compile-definition-and-go))
 144   (define-key map [com-def]
 145     '("Compile Definition" . scheme-compile-definition))
 146   (define-key map [exp-form]
 147     '("Expand current form" . scheme-expand-current-form))
 148   (define-key map [trace-proc]
 149     '("Trace procedure" . scheme-trace-procedure))
 150   (define-key map [send-def-go]
 151     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 152   (define-key map [send-def]
 153     '("Evaluate Last Definition" . scheme-send-definition))
 154   (define-key map [send-region-go]
 155     '("Evaluate Region & Go" . scheme-send-region-and-go))
 156   (define-key map [send-region]
 157     '("Evaluate Region" . scheme-send-region))
 158   (define-key map [send-sexp]
 159     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 160   )
 161
 162 (defvar scheme-buffer)
 163
 164 (define-derived-mode inferior-scheme-mode comint-mode "Inferior Scheme"
 165   "Major mode for interacting with an inferior Scheme process.
 166
 167 The following commands are available:
 168 \\{inferior-scheme-mode-map}
 169
 170 A Scheme process can be fired up with M-x run-scheme.
 171
 172 Customization: Entry to this mode runs the hooks on comint-mode-hook and
 173 inferior-scheme-mode-hook (in that order).
 174
 175 You can send text to the inferior Scheme process from other buffers containing
 176 Scheme source.
 177     switch-to-scheme switches the current buffer to the Scheme process buffer.
 178     scheme-send-definition sends the current definition to the Scheme process.
 179     scheme-compile-definition compiles the current definition.
 180     scheme-send-region sends the current region to the Scheme process.
 181     scheme-compile-region compiles the current region.
 182
 183     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 184         scheme-send-region-and-go, and scheme-compile-region-and-go
 185         switch to the Scheme process buffer after sending their text.
 186 For information on running multiple processes in multiple buffers, see
 187 documentation for variable scheme-buffer.
 188
 189 Commands:
 190 Return after the end of the process' output sends the text from the
 191     end of process to point.
 192 Return before the end of the process' output copies the sexp ending at point
 193     to the end of the process' output, and sends it.
 194 Delete converts tabs to spaces as it moves back.
 195 Tab indents for Scheme; with argument, shifts rest
 196     of expression rigidly with the current line.
 197 C-M-q does Tab on each line starting within following expression.
 198 Paragraphs are separated only by blank lines.  Semicolons start comments.
 199 If you accidentally suspend your process, use \\[comint-continue-subjob]
 200 to continue it."
 201   ;; Customize in inferior-scheme-mode-hook
 202   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 203   (scheme-mode-variables)
 204   (setq mode-line-process '(":%s"))
 205   (setq comint-input-filter (function scheme-input-filter))
 206   (setq comint-get-old-input (function scheme-get-old-input)))
 207
 208 (defcustom inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 209   "Input matching this regexp are not saved on the history list.
 210 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters."
 211   :type 'regexp
 212   :group 'cmuscheme)
 213
 214 (defun scheme-input-filter (str)
 215   "Don't save anything matching `inferior-scheme-filter-regexp'."
 216   (not (string-match inferior-scheme-filter-regexp str)))
 217
 218 (defun scheme-get-old-input ()
 219   "Snarf the sexp ending at point."
 220   (save-excursion
 221     (let ((end (point)))
 222       (backward-sexp)
 223       (buffer-substring (point) end))))
 224
 225 ;;;###autoload
 226 (defun run-scheme (cmd)
 227   "Run an inferior Scheme process, input and output via buffer `*scheme*'.
 228 If there is a process already running in `*scheme*', switch to that buffer.
 229 With argument, allows you to edit the command line (default is value
 230 of `scheme-program-name').
 231 If the file `~/.emacs_SCHEMENAME' or `~/.emacs.d/init_SCHEMENAME.scm' exists,
 232 it is given as initial input.
 233 Note that this may lose due to a timing error if the Scheme processor
 234 discards input when it starts up.
 235 Runs the hook `inferior-scheme-mode-hook' \(after the `comint-mode-hook'
 236 is run).
 237 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 238
 239   (interactive (list (if current-prefix-arg
 240                          (read-string "Run Scheme: " scheme-program-name)
 241                          scheme-program-name)))
 242   (if (not (comint-check-proc "*scheme*"))
 243       (let ((cmdlist (split-string-and-unquote cmd)))
 244         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 245                            (scheme-start-file (car cmdlist)) (cdr cmdlist)))
 246         (inferior-scheme-mode)))
 247   (setq scheme-program-name cmd)
 248   (setq scheme-buffer "*scheme*")
 249   (pop-to-buffer-same-window "*scheme*"))
 250
 251 (defun scheme-start-file (prog)
 252   "Return the name of the start file corresponding to PROG.
 253 Search in the directories \"~\" and \"~/.emacs.d\", in this
 254 order.  Return nil if no start file found."
 255   (let* ((progname (file-name-nondirectory prog))
 256          (start-file (concat "~/.emacs_" progname))
 257          (alt-start-file (concat user-emacs-directory "init_" progname ".scm")))
 258     (if (file-exists-p start-file)
 259         start-file
 260       (and (file-exists-p alt-start-file) alt-start-file))))
 261
 262 (defun scheme-send-region (start end)
 263   "Send the current region to the inferior Scheme process."
 264   (interactive "r")
 265   (comint-send-region (scheme-proc) start end)
 266   (comint-send-string (scheme-proc) "\n"))
 267
 268 (defun scheme-send-definition ()
 269   "Send the current definition to the inferior Scheme process."
 270   (interactive)
 271   (save-excursion
 272    (end-of-defun)
 273    (let ((end (point)))
 274      (beginning-of-defun)
 275      (scheme-send-region (point) end))))
 276
 277 (defun scheme-send-last-sexp ()
 278   "Send the previous sexp to the inferior Scheme process."
 279   (interactive)
 280   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 281
 282 (defcustom scheme-compile-exp-command "(compile '%s)"
 283   "Template for issuing commands to compile arbitrary Scheme expressions."
 284   :type 'string
 285   :group 'cmuscheme)
 286
 287 (defun scheme-compile-region (start end)
 288   "Compile the current region in the inferior Scheme process.
 289 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 290   (interactive "r")
 291   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 292                                             (format "(begin %s)"
 293                                                     (buffer-substring start end))))
 294   (comint-send-string (scheme-proc) "\n"))
 295
 296 (defun scheme-compile-definition ()
 297   "Compile the current definition in the inferior Scheme process."
 298   (interactive)
 299   (save-excursion
 300    (end-of-defun)
 301    (let ((end (point)))
 302      (beginning-of-defun)
 303      (scheme-compile-region (point) end))))
 304
 305 (defcustom scheme-trace-command "(trace %s)"
 306   "Template for issuing commands to trace a Scheme procedure.
 307 Some Scheme implementations might require more elaborate commands here.
 308 For PLT-Scheme, e.g., one should use
 309
 310    (setq scheme-trace-command \"(begin (require (lib \\\"trace.ss\\\")) (trace %s))\")
 311
 312 For Scheme 48 and Scsh use \",trace %s\"."
 313   :type 'string
 314   :group 'cmuscheme)
 315
 316 (defcustom scheme-untrace-command "(untrace %s)"
 317   "Template for switching off tracing of a Scheme procedure.
 318 Scheme 48 and Scsh users should set this variable to \",untrace %s\"."
 319
 320   :type 'string
 321   :group 'cmuscheme)
 322
 323 (defun scheme-trace-procedure (proc &optional untrace)
 324   "Trace procedure PROC in the inferior Scheme process.
 325 With a prefix argument switch off tracing of procedure PROC."
 326   (interactive
 327    (list (let ((current (symbol-at-point))
 328                (action (if current-prefix-arg "Untrace" "Trace")))
 329            (if current
 330                (read-string (format "%s procedure [%s]: " action current) nil nil (symbol-name current))
 331              (read-string (format "%s procedure: " action))))
 332          current-prefix-arg))
 333   (when (= (length proc) 0)
 334     (error "Invalid procedure name"))
 335   (comint-send-string (scheme-proc)
 336                       (format
 337                        (if untrace scheme-untrace-command scheme-trace-command)
 338                        proc))
 339   (comint-send-string (scheme-proc) "\n"))
 340
 341 (defcustom scheme-macro-expand-command "(expand %s)"
 342   "Template for macro-expanding a Scheme form.
 343 For Scheme 48 and Scsh use \",expand %s\"."
 344   :type 'string
 345   :group 'cmuscheme)
 346
 347 (defun scheme-expand-current-form ()
 348   "Macro-expand the form at point in the inferior Scheme process."
 349   (interactive)
 350   (let ((current-form (scheme-form-at-point)))
 351     (if current-form
 352         (progn
 353           (comint-send-string (scheme-proc)
 354                               (format
 355                                scheme-macro-expand-command
 356                                current-form))
 357           (comint-send-string (scheme-proc) "\n"))
 358       (error "Not at a form"))))
 359
 360 (defun scheme-form-at-point ()
 361   (let ((next-sexp (thing-at-point 'sexp)))
 362     (if (and next-sexp (string-equal (substring next-sexp 0 1) "("))
 363         next-sexp
 364       (save-excursion
 365         (backward-up-list)
 366         (scheme-form-at-point)))))
 367
 368 (defun switch-to-scheme (eob-p)
 369   "Switch to the scheme process buffer.
 370 With argument, position cursor at end of buffer."
 371   (interactive "P")
 372   (if (or (and scheme-buffer (get-buffer scheme-buffer))
 373           (scheme-interactively-start-process))
 374       (pop-to-buffer-same-window scheme-buffer)
 375     (error "No current process buffer.  See variable `scheme-buffer'"))
 376   (when eob-p
 377     (push-mark)
 378     (goto-char (point-max))))
 379
 380 (defun scheme-send-region-and-go (start end)
 381   "Send the current region to the inferior Scheme process.
 382 Then switch to the process buffer."
 383   (interactive "r")
 384   (scheme-send-region start end)
 385   (switch-to-scheme t))
 386
 387 (defun scheme-send-definition-and-go ()
 388   "Send the current definition to the inferior Scheme.
 389 Then switch to the process buffer."
 390   (interactive)
 391   (scheme-send-definition)
 392   (switch-to-scheme t))
 393
 394 (defun scheme-compile-definition-and-go ()
 395   "Compile the current definition in the inferior Scheme.
 396 Then switch to the process buffer."
 397   (interactive)
 398   (scheme-compile-definition)
 399   (switch-to-scheme t))
 400
 401 (defun scheme-compile-region-and-go (start end)
 402   "Compile the current region in the inferior Scheme.
 403 Then switch to the process buffer."
 404   (interactive "r")
 405   (scheme-compile-region start end)
 406   (switch-to-scheme t))
 407
 408 (defcustom scheme-source-modes '(scheme-mode)
 409   "Used to determine if a buffer contains Scheme source code.
 410 If it's loaded into a buffer that is in one of these major modes, it's
 411 considered a scheme source file by `scheme-load-file' and `scheme-compile-file'.
 412 Used by these commands to determine defaults."
 413   :type '(repeat function)
 414   :group 'cmuscheme)
 415
 416 (defvar scheme-prev-l/c-dir/file nil
 417   "Caches the last (directory . file) pair.
 418 Caches the last pair used in the last `scheme-load-file' or
 419 `scheme-compile-file' command.  Used for determining the default
 420 in the next one.")
 421
 422 (defun scheme-load-file (file-name)
 423   "Load a Scheme file FILE-NAME into the inferior Scheme process."
 424   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 425                                   scheme-source-modes t)) ; t because `load'
 426                                                           ; needs an exact name
 427   (comint-check-source file-name) ; Check to see if buffer needs saved.
 428   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 429                                        (file-name-nondirectory file-name)))
 430   (comint-send-string (scheme-proc) (concat "(load \""
 431                                             file-name
 432                                             "\"\)\n")))
 433
 434 (defun scheme-compile-file (file-name)
 435   "Compile a Scheme file FILE-NAME in the inferior Scheme process."
 436   (interactive (comint-get-source "Compile Scheme file: "
 437                                   scheme-prev-l/c-dir/file
 438                                   scheme-source-modes
 439                                   nil)) ; nil because COMPILE doesn't
 440                                         ; need an exact name.
 441   (comint-check-source file-name) ; Check to see if buffer needs saved.
 442   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 443                                        (file-name-nondirectory file-name)))
 444   (comint-send-string (scheme-proc) (concat "(compile-file \""
 445                                             file-name
 446                                             "\"\)\n")))
 447
 448 \f
 449 (defvar scheme-buffer nil "*The current scheme process buffer.
 450
 451 MULTIPLE PROCESS SUPPORT
 452 ===========================================================================
 453 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 454 processes.  To run multiple Scheme processes, you start the first up with
 455 \\[run-scheme].  It will be in a buffer named *scheme*.  Rename this buffer
 456 with \\[rename-buffer].  You may now start up a new process with another
 457 \\[run-scheme].  It will be in a new buffer, named *scheme*.  You can
 458 switch between the different process buffers with \\[switch-to-buffer].
 459
 460 Commands that send text from source buffers to Scheme processes --
 461 like `scheme-send-definition' or `scheme-compile-region' -- have to choose a
 462 process to send to, when you have more than one Scheme process around.  This
 463 is determined by the global variable `scheme-buffer'.  Suppose you
 464 have three inferior Schemes running:
 465     Buffer      Process
 466     foo         scheme
 467     bar         scheme<2>
 468     *scheme*    scheme<3>
 469 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 470 code, what process do you send it to?
 471
 472 - If you're in a process buffer (foo, bar, or *scheme*),
 473   you send it to that process.
 474 - If you're in some other buffer (e.g., a source file), you
 475   send it to the process attached to buffer `scheme-buffer'.
 476 This process selection is performed by function `scheme-proc'.
 477
 478 Whenever \\[run-scheme] fires up a new process, it resets `scheme-buffer'
 479 to be the new process's buffer.  If you only run one process, this will
 480 do the right thing.  If you run multiple processes, you can change
 481 `scheme-buffer' to another process buffer with \\[set-variable].
 482
 483 More sophisticated approaches are, of course, possible.  If you find yourself
 484 needing to switch back and forth between multiple processes frequently,
 485 you may wish to consider ilisp.el, a larger, more sophisticated package
 486 for running inferior Lisp and Scheme processes.  The approach taken here is
 487 for a minimal, simple implementation.  Feel free to extend it.")
 488
 489 (defun scheme-proc ()
 490   "Return the current Scheme process, starting one if necessary.
 491 See variable `scheme-buffer'."
 492   (unless (and scheme-buffer
 493                (get-buffer scheme-buffer)
 494                (comint-check-proc scheme-buffer))
 495     (scheme-interactively-start-process))
 496   (or (scheme-get-process)
 497       (error "No current process.  See variable `scheme-buffer'")))
 498
 499 (defun scheme-get-process ()
 500   "Return the current Scheme process or nil if none is running."
 501   (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 502                           (current-buffer)
 503                         scheme-buffer)))
 504
 505 (defun scheme-interactively-start-process (&optional _cmd)
 506   "Start an inferior Scheme process.  Return the process started.
 507 Since this command is run implicitly, always ask the user for the
 508 command to run."
 509   (save-window-excursion
 510     (run-scheme (read-string "Run Scheme: " scheme-program-name))))
 511
 512 ;;; Do the user's customization...
 513
 514 (defcustom cmuscheme-load-hook nil
 515   "This hook is run when cmuscheme is loaded in.
 516 This is a good place to put keybindings."
 517   :type 'hook
 518   :group 'cmuscheme)
 519
 520 (run-hooks 'cmuscheme-load-hook)
 521
 522 (provide 'cmuscheme)
 523
 524 ;;; cmuscheme.el ends here