lisp/calendar/holidays.el

   1 ;;; holidays.el --- holiday functions for the calendar package
   2
   3 ;; Copyright (C) 1989, 90, 92, 93, 94, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   6 ;; Keywords: holidays, calendar
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This collection of functions implements the holiday features as described
  28 ;; in calendar.el.
  29
  30 ;; Technical details of all the calendrical calculations can be found in
  31 ;; ``Calendrical Calculations'' by Nachum Dershowitz and Edward M. Reingold,
  32 ;; Cambridge University Press (1997).
  33
  34 ;; An earlier version of the technical details appeared in
  35 ;; ``Calendrical Calculations'' by Nachum Dershowitz and Edward M. Reingold,
  36 ;; Software--Practice and Experience, Volume 20, Number 9 (September, 1990),
  37 ;; pages 899-928.  ``Calendrical Calculations, Part II: Three Historical
  38 ;; Calendars'' by E. M. Reingold,  N. Dershowitz, and S. M. Clamen,
  39 ;; Software--Practice and Experience, Volume 23, Number 4 (April, 1993),
  40 ;; pages 383-404.
  41
  42 ;; Hard copies of these two papers can be obtained by sending email to
  43 ;; reingold@cs.uiuc.edu with the SUBJECT "send-paper-cal" (no quotes) and
  44 ;; the message BODY containing your mailing address (snail).
  45
  46 ;; Comments, corrections, and improvements should be sent to
  47 ;;  Edward M. Reingold               Department of Computer Science
  48 ;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
  49 ;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
  50 ;;                                   Urbana, Illinois 61801
  51
  52 ;;; Code:
  53
  54 (require 'calendar)
  55
  56 (autoload 'holiday-julian "cal-julian"
  57   "Holiday on MONTH, DAY  (Julian) called STRING."
  58   t)
  59
  60 (autoload 'holiday-hebrew "cal-hebrew"
  61   "Holiday on MONTH, DAY (Hebrew) called STRING."
  62   t)
  63
  64 (autoload 'holiday-rosh-hashanah-etc "cal-hebrew"
  65   "List of dates related to Rosh Hashanah, as visible in calendar window."
  66   t)
  67
  68 (autoload 'holiday-hanukkah "cal-hebrew"
  69   "List of dates related to Hanukkah, as visible in calendar window."
  70   t)
  71
  72 (autoload 'holiday-passover-etc "cal-hebrew"
  73   "List of dates related to Passover, as visible in calendar window."
  74   t)
  75
  76 (autoload 'holiday-tisha-b-av-etc "cal-hebrew"
  77   "List of dates around Tisha B'Av, as visible in calendar window."
  78   t)
  79
  80 (autoload 'holiday-islamic "cal-islam"
  81   "Holiday on MONTH, DAY (Islamic) called STRING."
  82   t)
  83
  84 (autoload 'holiday-chinese-new-year "cal-china"
  85   "Date of Chinese New Year."
  86   t)
  87
  88 (autoload 'solar-equinoxes-solstices "solar"
  89   "Date and time of equinoxes and solstices, if visible in the calendar window.
  90 Requires floating point."
  91   t)
  92
  93 (defun holidays (&optional arg)
  94   "Display the holidays for last month, this month, and next month.
  95 If called with an optional prefix argument, prompts for month and year.
  96
  97 This function is suitable for execution in a .emacs file."
  98   (interactive "P")
  99   (save-excursion
 100     (let* ((completion-ignore-case t)
 101            (date (if arg
 102                      (calendar-read-date t)
 103                    (calendar-current-date)))
 104            (displayed-month (extract-calendar-month date))
 105            (displayed-year (extract-calendar-year date)))
 106       (list-calendar-holidays))))
 107
 108 ;;;###autoload
 109 (defun list-holidays (y1 y2 &optional l label)
 110   "Display holidays for years Y1 to Y2 (inclusive).
 111
 112 The optional list of holidays L defaults to `calendar-holidays'.  See the
 113 documentation for that variable for a description of holiday lists.
 114
 115 The optional LABEL is used to label the buffer created."
 116   (interactive
 117    (let* ((start-year (calendar-read
 118                        "Starting year of holidays (>0): "
 119                        '(lambda (x) (> x 0))
 120                        (int-to-string (extract-calendar-year
 121                                        (calendar-current-date)))))
 122           (end-year (calendar-read
 123                        (format "Ending year (inclusive) of holidays (>=%s): "
 124                                start-year)
 125                        '(lambda (x) (>= x start-year))
 126                        (int-to-string start-year)))
 127           (completion-ignore-case t)
 128           (lists
 129            (list
 130             (cons "All" calendar-holidays)
 131             (if (fboundp 'atan)
 132                 (cons "Equinoxes/Solstices"
 133                       (list (list 'solar-equinoxes-solstices))))
 134             (if general-holidays (cons "General" general-holidays))
 135             (if local-holidays (cons "Local" local-holidays))
 136             (if other-holidays (cons "Other" other-holidays))
 137             (if christian-holidays (cons "Christian" christian-holidays))
 138             (if hebrew-holidays (cons "Hebrew" hebrew-holidays))
 139             (if islamic-holidays (cons "Islamic" islamic-holidays))
 140             (if oriental-holidays (cons "Oriental" oriental-holidays))
 141             (if solar-holidays (cons "Solar" solar-holidays))
 142             (cons "Ask" nil)))
 143           (choice (capitalize
 144                    (completing-read "List (TAB for choices): " lists nil t)))
 145           (which (if (string-equal choice "Ask")
 146                      (eval (read-variable "Enter list name: "))
 147                    (cdr (assoc choice lists))))
 148           (name (if (string-equal choice "Equinoxes/Solstices")
 149                     choice
 150                   (if (member choice '("Ask" ""))
 151                       "Holidays"
 152                     (format "%s Holidays" choice)))))
 153      (list start-year end-year which name)))
 154   (message "Computing holidays...")
 155   (let* ((holiday-buffer "*Holidays*")
 156          (calendar-holidays (if l l calendar-holidays))
 157          (title (or label "Holidays"))
 158          (holiday-list nil)
 159          (s (calendar-absolute-from-gregorian (list 2 1 y1)))
 160          (e (calendar-absolute-from-gregorian (list 11 1 y2)))
 161          (d s)
 162          (never t)
 163          (displayed-month 2)
 164          (displayed-year y1))
 165     (while (or never (<= d e))
 166       (setq holiday-list (append holiday-list (calendar-holiday-list)))
 167       (setq never nil)
 168       (increment-calendar-month displayed-month displayed-year 3)
 169       (setq d (calendar-absolute-from-gregorian
 170                (list displayed-month 1 displayed-year))))
 171     (save-excursion
 172       (set-buffer (get-buffer-create holiday-buffer))
 173       (setq buffer-read-only nil)
 174       (calendar-set-mode-line
 175        (if (= y1 y2)
 176            (format "%s for %s" title y1)
 177          (format "%s for %s-%s" title y1 y2)))
 178       (erase-buffer)
 179       (goto-char (point-min))
 180       (insert
 181        (mapconcat
 182         '(lambda (x) (concat (calendar-date-string (car x))
 183                              ": " (car (cdr x))))
 184         holiday-list "\n"))
 185       (goto-char (point-min))
 186       (set-buffer-modified-p nil)
 187       (setq buffer-read-only t)
 188       (display-buffer holiday-buffer)
 189       (message "Computing holidays...done"))))
 190
 191
 192 (defun check-calendar-holidays (date)
 193   "Check the list of holidays for any that occur on DATE.
 194 The value returned is a list of strings of relevant holiday descriptions.
 195 The holidays are those in the list calendar-holidays."
 196   (let* ((displayed-month (extract-calendar-month date))
 197          (displayed-year (extract-calendar-year date))
 198          (h (calendar-holiday-list))
 199          (holiday-list))
 200     (while h
 201       (if (calendar-date-equal date (car (car h)))
 202           (setq holiday-list (append holiday-list (cdr (car h)))))
 203       (setq h (cdr h)))
 204     holiday-list))
 205
 206 (defun calendar-cursor-holidays ()
 207   "Find holidays for the date specified by the cursor in the calendar window."
 208   (interactive)
 209   (message "Checking holidays...")
 210   (let* ((date (calendar-cursor-to-date t))
 211          (date-string (calendar-date-string date))
 212          (holiday-list (check-calendar-holidays date))
 213          (holiday-string (mapconcat 'identity holiday-list ";  "))
 214          (msg (format "%s:  %s" date-string holiday-string)))
 215     (if (not holiday-list)
 216         (message "No holidays known for %s" date-string)
 217       (if (<= (length msg) (frame-width))
 218           (message "%s" msg)
 219         (set-buffer (get-buffer-create holiday-buffer))
 220         (setq buffer-read-only nil)
 221         (calendar-set-mode-line date-string)
 222         (erase-buffer)
 223         (insert (mapconcat 'identity holiday-list "\n"))
 224         (goto-char (point-min))
 225         (set-buffer-modified-p nil)
 226         (setq buffer-read-only t)
 227         (display-buffer holiday-buffer)
 228         (message "Checking holidays...done")))))
 229
 230 (defun mark-calendar-holidays ()
 231   "Mark notable days in the calendar window."
 232   (interactive)
 233   (setq mark-holidays-in-calendar t)
 234   (message "Marking holidays...")
 235   (let ((holiday-list (calendar-holiday-list)))
 236     (while holiday-list
 237       (mark-visible-calendar-date
 238        (car (car holiday-list)) calendar-holiday-marker)
 239       (setq holiday-list (cdr holiday-list))))
 240   (message "Marking holidays...done"))
 241
 242 (defun list-calendar-holidays ()
 243   "Create a buffer containing the holidays for the current calendar window.
 244 The holidays are those in the list calendar-notable-days.  Returns t if any
 245 holidays are found, nil if not."
 246   (interactive)
 247   (message "Looking up holidays...")
 248   (let ((holiday-list (calendar-holiday-list))
 249         (m1 displayed-month)
 250         (y1 displayed-year)
 251         (m2 displayed-month)
 252         (y2 displayed-year))
 253     (if (not holiday-list)
 254         (progn
 255           (message "Looking up holidays...none found")
 256           nil)
 257       (set-buffer (get-buffer-create holiday-buffer))
 258       (setq buffer-read-only nil)
 259       (increment-calendar-month m1 y1 -1)
 260       (increment-calendar-month m2 y2 1)
 261       (calendar-set-mode-line
 262        (if (= y1 y2)
 263            (format "Notable Dates from %s to %s, %d%%-"
 264                    (calendar-month-name m1) (calendar-month-name m2) y2)
 265          (format "Notable Dates from %s, %d to %s, %d%%-"
 266                  (calendar-month-name m1) y1 (calendar-month-name m2) y2)))
 267       (erase-buffer)
 268       (insert
 269        (mapconcat
 270         '(lambda (x) (concat (calendar-date-string (car x))
 271                              ": " (car (cdr x))))
 272         holiday-list "\n"))
 273       (goto-char (point-min))
 274       (set-buffer-modified-p nil)
 275       (setq buffer-read-only t)
 276       (display-buffer holiday-buffer)
 277       (message "Looking up holidays...done")
 278       t)))
 279
 280 (defun calendar-holiday-list ()
 281   "Form the list of holidays that occur on dates in the calendar window.
 282 The holidays are those in the list calendar-holidays."
 283   (let ((p calendar-holidays)
 284         (holiday-list))
 285     (while p
 286       (let* ((holidays
 287               (if calendar-debug-sexp
 288                   (let ((stack-trace-on-error t))
 289                     (eval (car p)))
 290                 (condition-case nil
 291                     (eval (car p))
 292                   (error (beep)
 293                          (message "Bad holiday list item: %s" (car p))
 294                          (sleep-for 2))))))
 295         (if holidays
 296             (setq holiday-list (append holidays holiday-list))))
 297       (setq p (cdr p)))
 298     (setq holiday-list (sort holiday-list 'calendar-date-compare))))
 299
 300 ;; Below are the functions that calculate the dates of holidays; these
 301 ;; are eval'ed in the function calendar-holiday-list.  If you
 302 ;; write other such functions, be sure to imitate the style used below.
 303 ;; Remember that each function must return a list of items of the form
 304 ;; ((month day year) string) of VISIBLE dates in the calendar window.
 305
 306 (defun holiday-fixed (month day string)
 307   "Holiday on MONTH, DAY (Gregorian) called STRING.
 308 If MONTH, DAY is visible, the value returned is the list (((MONTH DAY year)
 309 STRING)).  Returns nil if it is not visible in the current calendar window."
 310   (let ((m displayed-month)
 311         (y displayed-year))
 312     (increment-calendar-month m y (- 11 month))
 313     (if (> m 9)
 314       (list (list (list month day y) string)))))
 315
 316 (defun holiday-float (month dayname n string &optional day)
 317   "Holiday on MONTH, DAYNAME (Nth occurrence) called STRING.
 318 If the Nth DAYNAME in MONTH is visible, the value returned is the list
 319 \(((MONTH DAY year) STRING)).
 320
 321 If N<0, count backward from the end of MONTH.
 322
 323 An optional parameter DAY means the Nth DAYNAME on or after/before MONTH DAY.
 324
 325 Returns nil if it is not visible in the current calendar window."
 326 ;; This is messy because the holiday may be visible, while the date on which
 327 ;; it is based is not.  For example, the first Monday after December 30 may be
 328 ;; visible when January is not.  For large values of |n| the problem is more
 329 ;; grotesque.  If we didn't have to worry about such cases, we could just use
 330
 331 ;;  (let ((m displayed-month)
 332 ;;        (y displayed-year))
 333 ;;    (increment-calendar-month m y (- 11 month))
 334 ;;    (if (> m 9); month in year y is visible
 335 ;;      (list (list (calendar-nth-named-day n dayname month y day) string)))))
 336
 337 ;; which is the way the function was originally written.
 338
 339   (let* ((m1 displayed-month)
 340          (y1 displayed-year)
 341          (m2 m1)
 342          (y2 y1))
 343     (increment-calendar-month m1 y1 -1)
 344     (increment-calendar-month m2 y2 1)
 345     (let* ((d1;  first possible base date for holiday
 346             (+ (calendar-nth-named-absday 1 dayname m1 y1)
 347                (* -7 n)
 348                (if (> n 0) 1 -7)))
 349            (d2;  last possible base date for holiday
 350             (+ (calendar-nth-named-absday -1 dayname m2 y2)
 351                (* -7 n)
 352                (if (> n 0) 7 -1)))
 353            (y1 (extract-calendar-year (calendar-gregorian-from-absolute d1)))
 354            (y2 (extract-calendar-year (calendar-gregorian-from-absolute d2)))
 355            (y; year of base date
 356             (if (or (= y1 y2) (> month 9))
 357                   y1
 358                 y2))
 359            (d; day of base date
 360             (or day (if (> n 0)
 361                         1
 362                       (calendar-last-day-of-month month y))))
 363            (date; base date for holiday
 364             (calendar-absolute-from-gregorian (list month d y))))
 365       (if (and (<= d1 date) (<= date d2))
 366           (list (list (calendar-nth-named-day n dayname month y d)
 367                       string))))))
 368
 369 (defun holiday-sexp (sexp string)
 370   "Sexp holiday for dates in the calendar window.
 371 SEXP is an expression in variable `year' evaluates to `date'.
 372
 373 STRING is an expression in `date' that evaluates to the holiday description
 374 of `date'.
 375
 376 If `date' is visible in the calendar window, the holiday STRING is on that
 377 date.  If date is nil, or if the date is not visible, there is no holiday."
 378   (let ((m displayed-month)
 379         (y displayed-year))
 380     (increment-calendar-month m y -1)
 381     (filter-visible-calendar-holidays
 382      (append
 383       (let* ((year y)
 384              (date (eval sexp))
 385              (string (if date (eval string))))
 386         (list (list date string)))
 387       (let* ((year (1+ y))
 388              (date (eval sexp))
 389              (string (if date (eval string))))
 390         (list (list date string)))))))
 391
 392 (defun holiday-advent ()
 393   "Date of Advent, if visible in calendar window."
 394   (let ((year displayed-year)
 395         (month displayed-month))
 396     (increment-calendar-month month year -1)
 397     (let ((advent (calendar-gregorian-from-absolute
 398                    (calendar-dayname-on-or-before 0
 399                     (calendar-absolute-from-gregorian
 400                      (list 12 3 year))))))
 401       (if (calendar-date-is-visible-p advent)
 402           (list (list advent "Advent"))))))
 403
 404 (defun holiday-easter-etc ()
 405   "List of dates related to Easter, as visible in calendar window."
 406  (if (and (> displayed-month 5) (not all-christian-calendar-holidays))
 407      nil;; Ash Wednesday, Good Friday, and Easter are not visible.
 408    (let* ((century (1+ (/ displayed-year 100)))
 409           (shifted-epact        ;; Age of moon for April 5...
 410            (% (+ 14 (* 11 (% displayed-year 19));;     ...by Nicaean rule
 411                  (-           ;; ...corrected for the Gregorian century rule
 412                   (/ (* 3 century) 4))
 413                  (/    ;; ...corrected for Metonic cycle inaccuracy.
 414                   (+ 5 (* 8 century)) 25)
 415                  (* 30 century));;              Keeps value positive.
 416               30))
 417           (adjusted-epact       ;;  Adjust for 29.5 day month.
 418            (if (or (= shifted-epact 0)
 419                    (and (= shifted-epact 1) (< 10 (% displayed-year 19))))
 420                (1+ shifted-epact)
 421              shifted-epact))
 422           (paschal-moon       ;; Day after the full moon on or after March 21.
 423            (- (calendar-absolute-from-gregorian (list 4 19 displayed-year))
 424               adjusted-epact))
 425           (abs-easter (calendar-dayname-on-or-before 0 (+ paschal-moon 7)))
 426           (mandatory
 427            (list
 428             (list (calendar-gregorian-from-absolute abs-easter)
 429                   "Easter Sunday")
 430             (list (calendar-gregorian-from-absolute (- abs-easter 2))
 431                   "Good Friday")
 432             (list (calendar-gregorian-from-absolute (- abs-easter 46))
 433                   "Ash Wednesday")))
 434           (optional
 435            (list
 436             (list (calendar-gregorian-from-absolute (- abs-easter 63))
 437                   "Septuagesima Sunday")
 438             (list (calendar-gregorian-from-absolute (- abs-easter 56))
 439                   "Sexagesima Sunday")
 440             (list (calendar-gregorian-from-absolute (- abs-easter 49))
 441                   "Shrove Sunday")
 442             (list (calendar-gregorian-from-absolute (- abs-easter 48))
 443                   "Shrove Monday")
 444             (list (calendar-gregorian-from-absolute (- abs-easter 47))
 445                   "Shrove Tuesday")
 446             (list (calendar-gregorian-from-absolute (- abs-easter 14))
 447                   "Passion Sunday")
 448             (list (calendar-gregorian-from-absolute (- abs-easter 7))
 449                   "Palm Sunday")
 450             (list (calendar-gregorian-from-absolute (- abs-easter 3))
 451                   "Maundy Thursday")
 452             (list (calendar-gregorian-from-absolute (+ abs-easter 35))
 453                   "Rogation Sunday")
 454             (list (calendar-gregorian-from-absolute (+ abs-easter 39))
 455                   "Ascension Day")
 456             (list (calendar-gregorian-from-absolute (+ abs-easter 49))
 457                   "Pentecost (Whitsunday)")
 458             (list (calendar-gregorian-from-absolute (+ abs-easter 50))
 459                   "Whitmonday")
 460             (list (calendar-gregorian-from-absolute (+ abs-easter 56))
 461                   "Trinity Sunday")
 462             (list (calendar-gregorian-from-absolute (+ abs-easter 60))
 463                   "Corpus Christi")))
 464           (output-list
 465            (filter-visible-calendar-holidays mandatory)))
 466      (if all-christian-calendar-holidays
 467          (setq output-list
 468                (append
 469                 (filter-visible-calendar-holidays optional)
 470                 output-list)))
 471      output-list)))
 472
 473 (defun holiday-greek-orthodox-easter ()
 474   "Date of Easter according to the rule of the Council of Nicaea."
 475   (let ((m displayed-month)
 476         (y displayed-year))
 477     (increment-calendar-month m y 1)
 478     (let* ((julian-year
 479             (extract-calendar-year
 480              (calendar-julian-from-absolute
 481               (calendar-absolute-from-gregorian
 482                (list m (calendar-last-day-of-month m y) y)))))
 483            (shifted-epact ;; Age of moon for April 5.
 484             (% (+ 14
 485                   (* 11 (% julian-year 19)))
 486                30))
 487            (paschal-moon  ;; Day after full moon on or after March 21.
 488             (- (calendar-absolute-from-julian (list 4 19 julian-year))
 489                shifted-epact))
 490            (nicaean-easter;; Sunday following the Paschal moon
 491             (calendar-gregorian-from-absolute
 492              (calendar-dayname-on-or-before 0 (+ paschal-moon 7)))))
 493       (if (calendar-date-is-visible-p nicaean-easter)
 494           (list (list nicaean-easter "Pascha (Greek Orthodox Easter)"))))))
 495
 496 (defun filter-visible-calendar-holidays (l)
 497   "Return a list of all visible holidays of those on L."
 498   (let ((visible)
 499         (p l))
 500     (while p
 501       (and (car (car p))
 502            (calendar-date-is-visible-p (car (car p)))
 503            (setq visible (append (list (car p)) visible)))
 504       (setq p (cdr p)))
 505     visible))
 506
 507 (provide 'holidays)
 508
 509 ;;; holidays.el ends here